test/runtest

   1 #! /usr/bin/env perl
   2 # We use env, because in some environments of our build farm
   3 # the Perl 5.010 interpreter is only reachable via $PATH
   4
   5 ###############################################################################
   6 # This is the controlling script for the "new" test suite for Exim. It should #
   7 # be possible to export this suite for running on a wide variety of hosts, in #
   8 # contrast to the old suite, which was very dependent on the environment of   #
   9 # Philip Hazel's desktop computer. This implementation inspects the version   #
  10 # of Exim that it finds, and tests only those features that are included. The #
  11 # surrounding environment is also tested to discover what is available. See   #
  12 # the README file for details of how it all works.                            #
  13 #                                                                             #
  14 # Implementation started: 03 August 2005 by Philip Hazel                      #
  15 # Placed in the Exim CVS: 06 February 2006                                    #
  16 ###############################################################################
  17
  18 #use strict;
  19 use v5.10.1;
  20 use warnings;
  21 use if $^V >= v5.19.11, experimental => 'smartmatch';
  22
  23 use Errno;
  24 use FileHandle;
  25 use Socket;
  26 use Time::Local;
  27 use Cwd;
  28 use File::Basename;
  29 use Pod::Usage;
  30 use Getopt::Long;
  31 use FindBin qw'$RealBin';
  32
  33 use lib "$RealBin/lib";
  34 use Exim::Runtest;
  35 use Exim::Utils qw(uniq numerically);
  36
  37 use if $ENV{DEBUG} && scalar($ENV{DEBUG} =~ /\bruntest\b/) => 'Smart::Comments' => '####';
  38 use if $ENV{DEBUG} && scalar($ENV{DEBUG} =~ /\bruntest\b/) => 'Data::Dumper';
  39
  40 use constant TEST_TOP => 8999;
  41 use constant TEST_SPECIAL_TOP => 9999;
  42
  43
  44 # Start by initializing some global variables
  45
  46 chomp(my $testversion = `git describe --always --dirty 2>&1` || '<unknown>');
  47
  48 # This gets embedded in the D-H params filename, and the value comes
  49 # from asking GnuTLS for "normal", but there appears to be no way to
  50 # use certtool/... to ask what that value currently is.  *sigh*
  51 # We also clamp it because of NSS interop, see addition of tls_dh_max_bits.
  52 # This value is correct as of GnuTLS 2.12.18 as clamped by tls_dh_max_bits.
  53 # normal = 2432   tls_dh_max_bits = 2236
  54 my $gnutls_dh_bits_normal = 2236;
  55
  56 my $cf = 'bin/cf -exact';
  57 my $cr = "\r";
  58 my $debug = 0;
  59 my $flavour = do {
  60   my $f = Exim::Runtest::flavour() // '';
  61   (grep { $f eq $_ } Exim::Runtest::flavours()) ? $f : 'FOO';
  62 };
  63 my $force_continue = 0;
  64 my $force_update = 0;
  65 my $log_failed_filename = 'failed-summary.log';
  66 my $log_summary_filename = 'run-summary.log';
  67 my $more = 'less -XF';
  68 my $optargs = '';
  69 my $save_output = 0;
  70 my $server_opts = '';
  71 my $slow = 0;
  72 my $valgrind = 0;
  73
  74 my $have_ipv4 = 1;
  75 my $have_ipv6 = 1;
  76 my $have_largefiles = 0;
  77
  78 my @test_list = ();
  79
  80
  81 # Networks to use for DNS tests. We need to choose some networks that will
  82 # never be used so that there is no chance that the host on which we are
  83 # running is actually in one of the test networks. Private networks such as
  84 # the IPv4 10.0.0.0/8 network are no good because hosts may well use them.
  85 # Rather than use some unassigned numbers (that might become assigned later),
  86 # I have chosen some multicast networks, in the belief that such addresses
  87 # won't ever be assigned to hosts. This is the only place where these numbers
  88 # are defined, so it is trivially possible to change them should that ever
  89 # become necessary.
  90
  91 my $parm_ipv4_test_net = 224;
  92 my $parm_ipv6_test_net = 'ff00';
  93
  94 # Port numbers are currently hard-wired
  95
  96 my $parm_port_n = 1223;         # Nothing listening on this port
  97 my $parm_port_s = 1224;         # Used for the "server" command
  98 my $parm_port_d = 1225;         # Used for the Exim daemon
  99 my $parm_port_d2 = 1226;        # Additional for daemon
 100 my $parm_port_d3 = 1227;        # Additional for daemon
 101 my $parm_port_d4 = 1228;        # Additional for daemon
 102 my $dynamic_socket;          # allocated later for PORT_DYNAMIC
 103
 104 # Find a suiteable group name for test (currently only 0001
 105 # uses a group name. A numeric group id would do
 106 my $parm_mailgroup = Exim::Runtest::mailgroup('mail');
 107
 108 # Manually set locale
 109 $ENV{LC_ALL} = 'C';
 110
 111 # In some environments USER does not exist, but we need it for some test(s)
 112 $ENV{USER} = getpwuid($>) if not exists $ENV{USER};
 113
 114 my ($parm_configure_owner, $parm_configure_group);
 115 my ($parm_ipv4, $parm_ipv6);
 116 my $parm_hostname;
 117
 118 ###############################################################################
 119 ###############################################################################
 120
 121 # Define a number of subroutines
 122
 123 ###############################################################################
 124 ###############################################################################
 125
 126
 127 ##################################################
 128 #              Handle signals                    #
 129 ##################################################
 130
 131 sub pipehandler { $sigpipehappened = 1; }
 132
 133 sub inthandler { print "\n"; tests_exit(-1, "Caught SIGINT"); }
 134
 135
 136 ##################################################
 137 #       Do global macro substitutions            #
 138 ##################################################
 139
 140 # This function is applied to configurations, command lines and data lines in
 141 # scripts, and to lines in the files of the aux-var-src and the dnszones-src
 142 # directory. It takes one argument: the current test number, or zero when
 143 # setting up files before running any tests.
 144
 145 sub do_substitute{
 146 s?\bCALLER\b?$parm_caller?g;
 147 s?\bCALLERGROUP\b?$parm_caller_group?g;
 148 s?\bCALLER_UID\b?$parm_caller_uid?g;
 149 s?\bCALLER_GID\b?$parm_caller_gid?g;
 150 s?\bCLAMSOCKET\b?$parm_clamsocket?g;
 151 s?\bDIR/?$parm_cwd/?g;
 152 s?\bEXIMGROUP\b?$parm_eximgroup?g;
 153 s?\bEXIMUSER\b?$parm_eximuser?g;
 154 s?\bHOSTIPV4\b?$parm_ipv4?g;
 155 s?\bHOSTIPV6\b?$parm_ipv6?g;
 156 s?\bHOSTNAME\b?$parm_hostname?g;
 157 s?\bPORT_D\b?$parm_port_d?g;
 158 s?\bPORT_D2\b?$parm_port_d2?g;
 159 s?\bPORT_D3\b?$parm_port_d3?g;
 160 s?\bPORT_D4\b?$parm_port_d4?g;
 161 s?\bPORT_N\b?$parm_port_n?g;
 162 s?\bPORT_S\b?$parm_port_s?g;
 163 s?\bTESTNUM\b?$_[0]?g;
 164 s?(\b|_)V4NET([\._])?$1$parm_ipv4_test_net$2?g;
 165 s?\bV6NET:?$parm_ipv6_test_net:?g;
 166 s?\bPORT_DYNAMIC\b?$dynamic_socket->sockport()?eg;
 167 s?\bMAILGROUP\b?$parm_mailgroup?g;
 168 }
 169
 170
 171 ##################################################
 172 #     Any state to be preserved across tests     #
 173 ##################################################
 174
 175 my $TEST_STATE = {};
 176
 177
 178 ##################################################
 179 #        Subroutine to tidy up and exit          #
 180 ##################################################
 181
 182 # In all cases, we check for any Exim daemons that have been left running, and
 183 # kill them. Then remove all the spool data, test output, and the modified Exim
 184 # binary if we are ending normally.
 185
 186 # Arguments:
 187 #    $_[0] = 0 for a normal exit; full cleanup done
 188 #    $_[0] > 0 for an error exit; no files cleaned up
 189 #    $_[0] < 0 for a "die" exit; $_[1] contains a message
 190
 191 sub tests_exit{
 192 my($rc) = $_[0];
 193 my($spool);
 194
 195 # Search for daemon pid files and kill the daemons. We kill with SIGINT rather
 196 # than SIGTERM to stop it outputting "Terminated" to the terminal when not in
 197 # the background.
 198
 199 if (exists $TEST_STATE->{exim_pid})
 200   {
 201   $pid = $TEST_STATE->{exim_pid};
 202   print "Tidyup: killing wait-mode daemon pid=$pid\n";
 203   system("sudo kill -INT $pid");
 204   }
 205
 206 if (opendir(DIR, "spool"))
 207   {
 208   my(@spools) = sort readdir(DIR);
 209   closedir(DIR);
 210   foreach $spool (@spools)
 211     {
 212     next if $spool !~ /^exim-daemon./;
 213     open(PID, "spool/$spool") || die "** Failed to open \"spool/$spool\": $!\n";
 214     chomp($pid = <PID>);
 215     close(PID);
 216     print "Tidyup: killing daemon pid=$pid\n";
 217     system("sudo rm -f spool/$spool; sudo kill -INT $pid");
 218     }
 219   }
 220 else
 221   { die "** Failed to opendir(\"spool\"): $!\n" unless $!{ENOENT}; }
 222
 223 # Close the terminal input and remove the test files if all went well, unless
 224 # the option to save them is set. Always remove the patched Exim binary. Then
 225 # exit normally, or die.
 226
 227 close(T);
 228 system("sudo /bin/rm -rf ./spool test-* ./dnszones/*")
 229   if ($rc == 0 && !$save_output);
 230
 231 system("sudo /bin/rm -rf ./eximdir/*")
 232   if (!$save_output);
 233
 234 print "\nYou were in test $test at the end there.\n\n" if defined $test;
 235 exit $rc if ($rc >= 0);
 236 die "** runtest error: $_[1]\n";
 237 }
 238
 239
 240
 241 ##################################################
 242 #   Subroutines used by the munging subroutine   #
 243 ##################################################
 244
 245 # This function is used for things like message ids, where we want to generate
 246 # more than one value, but keep a consistent mapping throughout.
 247 #
 248 # Arguments:
 249 #   $oldid        the value from the file
 250 #   $base         a base string into which we insert a sequence
 251 #   $sequence     the address of the current sequence counter
 252
 253 sub new_value {
 254 my($oldid, $base, $sequence) = @_;
 255 my($newid) = $cache{$oldid};
 256 if (! defined $newid)
 257   {
 258   $newid = sprintf($base, $$sequence++);
 259   $cache{$oldid} = $newid;
 260   }
 261 return $newid;
 262 }
 263
 264
 265 # This is used while munging the output from exim_dumpdb.
 266 # May go wrong across DST changes.
 267
 268 sub date_seconds {
 269 my($day,$month,$year,$hour,$min,$sec) =
 270   $_[0] =~ /^(\d\d)-(\w\w\w)-(\d{4})\s(\d\d):(\d\d):(\d\d)/;
 271 my($mon);
 272 if   ($month =~ /Jan/) {$mon = 0;}
 273 elsif($month =~ /Feb/) {$mon = 1;}
 274 elsif($month =~ /Mar/) {$mon = 2;}
 275 elsif($month =~ /Apr/) {$mon = 3;}
 276 elsif($month =~ /May/) {$mon = 4;}
 277 elsif($month =~ /Jun/) {$mon = 5;}
 278 elsif($month =~ /Jul/) {$mon = 6;}
 279 elsif($month =~ /Aug/) {$mon = 7;}
 280 elsif($month =~ /Sep/) {$mon = 8;}
 281 elsif($month =~ /Oct/) {$mon = 9;}
 282 elsif($month =~ /Nov/) {$mon = 10;}
 283 elsif($month =~ /Dec/) {$mon = 11;}
 284 return timelocal($sec,$min,$hour,$day,$mon,$year);
 285 }
 286
 287
 288 # This is a subroutine to sort maildir files into time-order. The second field
 289 # is the microsecond field, and may vary in length, so must be compared
 290 # numerically.
 291
 292 sub maildirsort {
 293 return $a cmp $b if ($a !~ /^\d+\.H\d/ || $b !~ /^\d+\.H\d/);
 294 my($x1,$y1) = $a =~ /^(\d+)\.H(\d+)/;
 295 my($x2,$y2) = $b =~ /^(\d+)\.H(\d+)/;
 296 return ($x1 != $x2)? ($x1 <=> $x2) : ($y1 <=> $y2);
 297 }
 298
 299
 300
 301 ##################################################
 302 #   Subroutine list files below a directory      #
 303 ##################################################
 304
 305 # This is used to build up a list of expected mail files below a certain path
 306 # in the directory tree. It has to be recursive in order to deal with multiple
 307 # maildir mailboxes.
 308
 309 sub list_files_below {
 310 my($dir) = $_[0];
 311 my(@yield) = ();
 312 my(@sublist, $file);
 313
 314 opendir(DIR, $dir) || tests_exit(-1, "Failed to open $dir: $!");
 315 @sublist = sort maildirsort readdir(DIR);
 316 closedir(DIR);
 317
 318 foreach $file (@sublist)
 319   {
 320   next if $file eq "." || $file eq ".." || $file eq "CVS";
 321   if (-d "$dir/$file")
 322     { @yield = (@yield, list_files_below("$dir/$file")); }
 323   else
 324     { push @yield, "$dir/$file"; }
 325   }
 326
 327 return @yield;
 328 }
 329
 330
 331
 332 ##################################################
 333 #         Munge a file before comparing          #
 334 ##################################################
 335
 336 # The pre-processing turns all dates, times, Exim versions, message ids, and so
 337 # on into standard values, so that the compare works. Perl's substitution with
 338 # an expression provides a neat way to do some of these changes.
 339
 340 # We keep a global associative array for repeatedly turning the same values
 341 # into the same standard values throughout the data from a single test.
 342 # Message ids get this treatment (can't be made reliable for times), and
 343 # times in dumped retry databases are also handled in a special way, as are
 344 # incoming port numbers.
 345
 346 # On entry to the subroutine, the file to write to is already opened with the
 347 # name MUNGED. The input file name is the only argument to the subroutine.
 348 # Certain actions are taken only when the name contains "stderr", "stdout",
 349 # or "log". The yield of the function is 1 if a line matching "*** truncated
 350 # ***" is encountered; otherwise it is 0.
 351
 352 sub munge {
 353 my($file) = $_[0];
 354 my($extra) = $_[1];
 355 my($yield) = 0;
 356 my(@saved) = ();
 357
 358 local $_;
 359
 360 open(IN, "$file") || tests_exit(-1, "Failed to open $file: $!");
 361
 362 my($is_log) = $file =~ /log/;
 363 my($is_stdout) = $file =~ /stdout/;
 364 my($is_stderr) = $file =~ /stderr/;
 365 my($is_mail) = $file =~ /mail/;
 366
 367 # Date pattern
 368
 369 $date = "\\d{2}-\\w{3}-\\d{4}\\s\\d{2}:\\d{2}:\\d{2}";
 370
 371 # Pattern for matching pids at start of stderr lines; initially something
 372 # that won't match.
 373
 374 $spid = "xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx";
 375
 376 # Scan the file and make the changes. Near the bottom there are some changes
 377 # that are specific to certain file types, though there are also some of those
 378 # inline too.
 379
 380 LINE: while(<IN>)
 381   {
 382 RESET_AFTER_EXTRA_LINE_READ:
 383   # Custom munges
 384   if ($extra)
 385     {
 386     next if $extra =~ m%^/%  &&  eval $extra;
 387     eval $extra if $extra =~ m/^s/;
 388     }
 389
 390   # Check for "*** truncated ***"
 391   $yield = 1 if /\*\*\* truncated \*\*\*/;
 392
 393   # Replace the name of this host
 394   s/\Q$parm_hostname\E/the.local.host.name/g;
 395
 396   # But convert "name=the.local.host address=127.0.0.1" to use "localhost"
 397   s/name=the\.local\.host address=127\.0\.0\.1/name=localhost address=127.0.0.1/g;
 398
 399   # The name of the shell may vary
 400   s/\s\Q$parm_shell\E\b/ ENV_SHELL/;
 401
 402   # Replace the path to the testsuite directory
 403   s?\Q$parm_cwd\E?TESTSUITE?g;
 404
 405   # Replace the Exim version number (may appear in various places)
 406   # patchexim should have fixed this for us
 407   #s/(Exim) \d+\.\d+[\w_-]*/$1 x.yz/i;
 408
 409   # Replace Exim message ids by a unique series
 410   s/((?:[^\W_]{6}-){2}[^\W_]{2})
 411     /new_value($1, "10Hm%s-0005vi-00", \$next_msgid)/egx;
 412
 413   # The names of lock files appear in some error and debug messages
 414   s/\.lock(\.[-\w]+)+(\.[\da-f]+){2}/.lock.test.ex.dddddddd.pppppppp/;
 415
 416   # Unless we are in an IPv6 test, replace IPv4 and/or IPv6 in "listening on
 417   # port" message, because it is not always the same.
 418   s/port (\d+) \([^)]+\)/port $1/g
 419     if !$is_ipv6test && m/listening for SMTP(S?) on port/;
 420
 421   # Challenges in SPA authentication
 422   s/TlRMTVNTUAACAAAAAAAAAAAoAAABgg[\w+\/]+/TlRMTVNTUAACAAAAAAAAAAAoAAABggAAAEbBRwqFwwIAAAAAAAAAAAAt1sgAAAAA/;
 423
 424   # PRVS values
 425   s?prvs=([^/]+)/[\da-f]{10}@?prvs=$1/xxxxxxxxxx@?g;    # Old form
 426   s?prvs=[\da-f]{10}=([^@]+)@?prvs=xxxxxxxxxx=$1@?g;    # New form
 427
 428   # There are differences in error messages between OpenSSL versions
 429   s/SSL_CTX_set_cipher_list/SSL_connect/;
 430
 431   # One error test in expansions mentions base 62 or 36
 432   s/is not a base (36|62) number/is not a base 36\/62 number/;
 433
 434   # This message sometimes has a different number of seconds
 435   s/forced fail after \d seconds/forced fail after d seconds/;
 436
 437   # This message may contain a different DBM library name
 438   s/Failed to open \S+( \([^\)]+\))? file/Failed to open DBM file/;
 439
 440   # The message for a non-listening FIFO varies
 441   s/:[^:]+: while opening named pipe/: Error: while opening named pipe/;
 442
 443   # Debugging output of lists of hosts may have different sort keys
 444   s/sort=\S+/sort=xx/ if /^\S+ (?:\d+\.){3}\d+ mx=\S+ sort=\S+/;
 445
 446   # Random local part in callout cache testing
 447   s/myhost.test.ex-\d+-testing/myhost.test.ex-dddddddd-testing/;
 448   s/the.local.host.name-\d+-testing/the.local.host.name-dddddddd-testing/;
 449
 450   # File descriptor numbers may vary
 451   s/^writing data block fd=\d+/writing data block fd=dddd/;
 452   s/(running as transport filter:) fd_write=\d+ fd_read=\d+/$1 fd_write=dddd fd_read=dddd/;
 453
 454
 455   # ======== Dumpdb output ========
 456   # This must be before the general date/date munging.
 457   # Time data lines, which look like this:
 458   # 25-Aug-2000 12:11:37  25-Aug-2000 12:11:37  26-Aug-2000 12:11:37
 459   if (/^($date)\s+($date)\s+($date)(\s+\*)?\s*$/)
 460     {
 461     my($date1,$date2,$date3,$expired) = ($1,$2,$3,$4);
 462     $expired = '' if !defined $expired;
 463
 464     # Round the time-difference up to nearest even value
 465     my($increment) = ((date_seconds($date3) - date_seconds($date2) + 1) >> 1) << 1;
 466
 467     # We used to use globally unique replacement values, but timing
 468     # differences make this impossible. Just show the increment on the
 469     # last one.
 470
 471     printf MUNGED ("first failed = time last try = time2 next try = time2 + %s%s\n",
 472       $increment, $expired);
 473     next;
 474     }
 475
 476   # more_errno values in exim_dumpdb output which are times
 477   s/T:(\S+)\s-22\s(\S+)\s/T:$1 -22 xxxx /;
 478
 479   # port numbers in dumpdb output
 480   s/T:([a-z.]+(:[0-9.]+)?):$parm_port_n /T:$1:PORT_N /;
 481
 482   # port numbers in stderr
 483   s/^set_process_info: .*\]:\K$parm_port_d /PORT_D /;
 484   s/^set_process_info: .*\]:\K$parm_port_s /PORT_S /;
 485
 486
 487   # ======== Dates and times ========
 488
 489   # Dates and times are all turned into the same value - trying to turn
 490   # them into different ones cannot be done repeatedly because they are
 491   # real time stamps generated while running the test. The actual date and
 492   # time used was fixed when I first started running automatic Exim tests.
 493
 494   # Date/time in header lines and SMTP responses
 495   s/[A-Z][a-z]{2},\s\d\d?\s[A-Z][a-z]{2}\s\d\d\d\d\s\d\d\:\d\d:\d\d\s[-+]\d{4}
 496     /Tue, 2 Mar 1999 09:44:33 +0000/gx;
 497   # and in a French locale
 498   s/\S{4},\s\d\d?\s[^,]+\s\d\d\d\d\s\d\d\:\d\d:\d\d\s[-+]\d{4}
 499     /dim., 10 f\xE9vr 2019 20:05:49 +0000/gx;
 500
 501   # Date/time in logs and in one instance of a filter test
 502   s/^\d{4}-\d\d-\d\d\s\d\d:\d\d:\d\d(\s[+-]\d\d\d\d)?\s/1999-03-02 09:44:33 /gx;
 503   s/^\d{4}-\d\d-\d\d\s\d\d:\d\d:\d\d\.\d{3}(\s[+-]\d\d\d\d)?\s/2017-07-30 18:51:05.712 /gx;
 504   s/^Logwrite\s"\d{4}-\d\d-\d\d\s\d\d:\d\d:\d\d/Logwrite "1999-03-02 09:44:33/gx;
 505   # Date/time in syslog test
 506   s/^SYSLOG:\s\'\K\d{4}-\d\d-\d\d\s\d\d:\d\d:\d\d\s/2017-07-30 18:51:05 /gx;
 507   s/^SYSLOG:\s\'\K\d{4}-\d\d-\d\d\s\d\d:\d\d:\d\d\.\d{3}\s/2017-07-30 18:51:05.712 /gx;
 508   s/^SYSLOG:\s\'\K\d{4}-\d\d-\d\d\s\d\d:\d\d:\d\d\s[+-]\d\d\d\d\s/2017-07-30 18:51:05 +9999 /gx;
 509   s/^SYSLOG:\s\'\K\d{4}-\d\d-\d\d\s\d\d:\d\d:\d\d\.\d{3}\s[+-]\d\d\d\d\s/2017-07-30 18:51:05.712 +9999 /gx;
 510
 511   s/((D|[RQD]T)=)\d+s/$1qqs/g;
 512   s/((D|[RQD]T)=)\d\.\d{3}s/$1q.qqqs/g;
 513
 514   # Date/time in message separators
 515   s/(?:[A-Z][a-z]{2}\s){2}\d\d\s\d\d:\d\d:\d\d\s\d\d\d\d
 516     /Tue Mar 02 09:44:33 1999/gx;
 517
 518   # Date of message arrival in spool file as shown by -Mvh
 519   s/^\d{9,10}\s0$/ddddddddd 0/;
 520
 521   # Date/time in mbx mailbox files
 522   s/\d\d-\w\w\w-\d\d\d\d\s\d\d:\d\d:\d\d\s[-+]\d\d\d\d,/06-Sep-1999 15:52:48 +0100,/gx;
 523
 524   # Dates/times in debugging output for writing retry records
 525   if (/^  first failed=(\d+) last try=(\d+) next try=(\d+) (.*)$/)
 526     {
 527     my($next) = $3 - $2;
 528     $_ = "  first failed=dddd last try=dddd next try=+$next $4\n";
 529     }
 530   s/^(\s*)now=\d+ first_failed=\d+ next_try=\d+ expired=(\w)/$1now=tttt first_failed=tttt next_try=tttt expired=$2/;
 531   s/^(\s*)received_time=\d+ diff=\d+ timeout=(\d+)/$1received_time=tttt diff=tttt timeout=$2/;
 532
 533   # Time to retry may vary
 534   s/time to retry = \S+/time to retry = tttt/;
 535   s/retry record exists: age=\S+/retry record exists: age=ttt/;
 536   s/failing_interval=\S+ message_age=\S+/failing_interval=ttt message_age=ttt/;
 537
 538   # Date/time in exim -bV output
 539   s/\d\d-[A-Z][a-z]{2}-\d{4}\s\d\d:\d\d:\d\d/07-Mar-2000 12:21:52/g;
 540
 541   # Eximstats heading
 542   s/Exim\sstatistics\sfrom\s\d{4}-\d\d-\d\d\s\d\d:\d\d:\d\d\sto\s
 543     \d{4}-\d\d-\d\d\s\d\d:\d\d:\d\d/Exim statistics from <time> to <time>/x;
 544
 545   # Treat ECONNRESET the same as ECONNREFUSED.  At least some systems give
 546   # us the former on a new connection.
 547   s/(could not connect to .*: Connection) reset by peer$/$1 refused/;
 548
 549   # ======== TLS certificate algorithms ========
 550   #
 551   # In Received: headers, convert RFC 8314 style ciphersuite to
 552   # the older (comment) style, keeping only the Auth element
 553   # (discarding kex, cipher, mac).  For TLS 1.3 there is no kex
 554   # element (and no _WITH); insert a spurious "RSA".
 555
 556   s/^\s+by .+ with .+ \K tls TLS_.*?([^_]+)_WITH.+$/(TLS1.x:ke-$1-AES256-SHAnnn:xxx)/;
 557   s/^\s+by .+ with .+ \K tls TLS_.+$/(TLS1.x:ke-RSA-AES256-SHAnnn:xxx)/;
 558
 559   # Test machines might have various different TLS library versions supporting
 560   # different protocols; can't rely upon TLS 1.2's AES256-GCM-SHA384, so we
 561   # treat the standard algorithms the same.
 562   #
 563   # TLSversion : KeyExchange? - Authentication/Signature - C_iph_er - MAC : ???
 564   #
 565   # So far, have seen:
 566   #   TLSv1:AES128-GCM-SHA256:128
 567   #   TLSv1:AES256-SHA:256
 568   #   TLSv1.1:AES256-SHA:256
 569   #   TLSv1.2:AES256-GCM-SHA384:256
 570   #   TLSv1.2:DHE-RSA-AES256-SHA:256
 571   #   TLSv1.3:TLS_AES_256_GCM_SHA384:256
 572   #   TLS1.2:DHE_RSA_AES_128_CBC_SHA1:128
 573   # We also need to handle the ciphersuite without the TLS part present, for
 574   # client-ssl's output.  We also see some older forced ciphersuites, but
 575   # negotiating TLS 1.2 instead of 1.0.
 576   # Mail headers (...), log-lines X=..., client-ssl output ...
 577   # (and \b doesn't match between ' ' and '(' )
 578   #
 579   # Retain the authentication algorith field as we want to test that.
 580
 581   s/( (?: (?:\b|\s) [\(=] ) | \s )TLSv1(\.[123])?:/$1TLS1.x:/xg;
 582   s/(?<!ke-)((EC)?DHE-)?(RSA|ECDSA)-AES(128|256)-(GCM-SHA(256|384)|SHA)(?!:)/ke-$3-AES256-SHAnnn/g;
 583   s/(?<!ke-)((EC)?DHE-)?(RSA|ECDSA)-AES(128|256)-(GCM-SHA(256|384)|SHA):(128|256)/ke-$3-AES256-SHAnnn:xxx/g;
 584
 585   # OpenSSL TLSv1.3 - unsure what to do about the authentication-variant testcases now,
 586   # as it seems the protocol no longer supports a user choice.  Replace the "TLS" field with "RSA".
 587   # Also insert a key-exchange field for back-compat, even though 1.3 doesn't do that.
 588   #
 589   # TLSversion : "TLS" - C_iph_er - MAC : ???
 590   #
 591   s/TLS_AES(_256)?_GCM_SHA384(?!:)/ke-RSA-AES256-SHAnnn/g;
 592   s/:TLS_AES(_256)?_GCM_SHA384:256/:ke-RSA-AES256-SHAnnn:xxx/g;
 593
 594   # LibreSSL
 595   # TLSv1:AES256-GCM-SHA384:256
 596   # TLSv1:ECDHE-RSA-CHACHA20-POLY1305:256
 597   #
 598   # ECDHE-RSA-CHACHA20-POLY1305
 599   # AES256-GCM-SHA384
 600
 601   s/(?<!-)(AES256-GCM-SHA384)/RSA-$1/;
 602   s/(?<!ke-)((EC)?DHE-)?(RSA|ECDSA)-(AES256|CHACHA20)-(GCM-SHA384|POLY1305)(?!:)/ke-$3-AES256-SHAnnn/g;
 603   s/(?<!ke-)((EC)?DHE-)?(RSA|ECDSA)-(AES256|CHACHA20)-(GCM-SHA384|POLY1305):256/ke-$3-AES256-SHAnnn:xxx/g;
 604
 605   # GnuTLS have seen:
 606   #   TLS1.3:ECDHE_RSA_AES_256_GCM_SHA384:256
 607   #   TLS1.3:ECDHE_SECP256R1__RSA_PSS_RSAE_SHA256__AES_256_GCM__AEAD:256
 608   #   TLS1.3:ECDHE_X25519__RSA_PSS_RSAE_SHA256__AES_256_GCM:256
 609   #   TLS1.3:ECDHE_PSK_SECP256R1__AES_256_GCM__AEAD:256
 610   #
 611   #   TLS1.2:ECDHE_RSA_AES_256_GCM_SHA384:256
 612   #   TLS1.2:ECDHE_RSA_AES_128_GCM_SHA256:128
 613   #   TLS1.2:RSA_AES_256_CBC_SHA1:256 (canonical)
 614   #   TLS1.2:DHE_RSA_AES_128_CBC_SHA1:128
 615   #   TLS1.2:ECDHE_SECP256R1__RSA_SHA256__AES_256_GCM:256
 616   #   TLS1.2:ECDHE_SECP256R1__RSA_SHA256__AES_128_CBC__SHA256:128
 617   #   TLS1.2:ECDHE_SECP256R1__ECDSA_SHA512__AES_256_GCM:256
 618   #   TLS1.2:ECDHE_RSA_SECP256R1__AES_256_GCM:256 (! 3.5.18 !)
 619   #   TLS1.2:RSA__CAMELLIA_256_GCM:256  (leave the cipher name)
 620   #
 621   #   X=TLS1.2:DHE_RSA_AES_256_CBC_SHA256:256
 622   #   X=TLS1.2:RSA_AES_256_CBC_SHA1:256
 623   #   X=TLS1.1:RSA_AES_256_CBC_SHA1:256
 624   #   X=TLS1.0:DHE_RSA_AES_256_CBC_SHA1:256
 625   # and as stand-alone cipher:
 626   #   ECDHE-RSA-AES256-SHA
 627   #   DHE-RSA-AES256-SHA256
 628   #   DHE-RSA-AES256-SHA
 629   # picking latter as canonical simply because regex easier that way.
 630   s/\bDHE_RSA_AES_128_CBC_SHA1:128/RSA-AES256-SHA1:256/g;
 631   s/TLS1.[0123]:                                                                # TLS version
 632     ((EC)?DHE(_((?<psk>PSK)_)?((?<auth>RSA|ECDSA)_)?(SECP256R1|X25519))?__?)?   # key-exchange
 633     ((?<auth>RSA|ECDSA)((_PSS_RSAE)?_SHA(512|256))?__?)?                        # authentication
 634     AES_(256|128)_(CBC|GCM)                                                     # cipher
 635     (__?SHA(1|256|384))?:                                                       # PRF
 636     (256|128)                                                                   # cipher strength
 637     /"TLS1.x:ke-"
 638         . (defined($+{psk}) ? $+{psk} : "")
 639         . (defined($+{auth}) ? $+{auth} : "")
 640         . "-AES256-SHAnnn:xxx"/gex;
 641   s/TLS1.2:RSA__CAMELLIA_256_GCM(_SHA384)?:256/TLS1.2:RSA_CAMELLIA_256_GCM-SHAnnn:256/g;
 642   s/\b(ECDHE-(RSA|ECDSA)-AES256-SHA|DHE-RSA-AES256-SHA256)\b/ke-$2-AES256-SHAnnn/g;
 643
 644   # GnuTLS library error message changes
 645   s/(No certificate was found|Certificate is required)/The peer did not send any certificate/g;
 646 #(dodgy test?)  s/\(certificate verification failed\): invalid/\(gnutls_handshake\): The peer did not send any certificate./g;
 647   s/\(gnutls_priority_set\): No or insufficient priorities were set/\(gnutls_handshake\): Could not negotiate a supported cipher suite/g;
 648   s/\(gnutls_handshake\): \KNo supported cipher suites have been found.$/Could not negotiate a supported cipher suite./;
 649
 650   # (this new one is a generic channel-read error, but the testsuite
 651   # only hits it in one place)
 652   s/TLS error on connection \(gnutls_handshake\): Error in the pull function\./a TLS session is required but an attempt to start TLS failed/g;
 653
 654   # (replace old with new, hoping that old only happens in one situation)
 655   s/TLS error on connection to \d{1,3}(.\d{1,3}){3} \[\d{1,3}(.\d{1,3}){3}\] \(gnutls_handshake\): A TLS packet with unexpected length was received./a TLS session is required for ip4.ip4.ip4.ip4 [ip4.ip4.ip4.ip4], but an attempt to start TLS failed/g;
 656   s/TLS error on connection from \[127.0.0.1\] \(recv\): A TLS packet with unexpected length was received./TLS error on connection from [127.0.0.1] (recv): The TLS connection was non-properly terminated./g;
 657
 658   # signature algorithm names
 659   s/RSA-SHA1/RSA-SHA/;
 660
 661
 662   # ======== Caller's login, uid, gid, home, gecos ========
 663
 664   s/\Q$parm_caller_home\E/CALLER_HOME/g;   # NOTE: these must be done
 665   s/\b\Q$parm_caller\E\b/CALLER/g;         #       in this order!
 666   s/\b\Q$parm_caller_group\E\b/CALLER/g;   # In case group name different
 667
 668   s/\beuid=$parm_caller_uid\b/euid=CALLER_UID/g;
 669   s/\begid=$parm_caller_gid\b/egid=CALLER_GID/g;
 670
 671   s/\buid=$parm_caller_uid\b/uid=CALLER_UID/g;
 672   s/\bgid=$parm_caller_gid\b/gid=CALLER_GID/g;
 673
 674   s/\bname="?$parm_caller_gecos"?/name=CALLER_GECOS/g;
 675
 676   # When looking at spool files with -Mvh, we will find not only the caller
 677   # login, but also the uid and gid. It seems that $) in some Perls gives all
 678   # the auxiliary gids as well, so don't bother checking for that.
 679
 680   s/^CALLER $> \d+$/CALLER UID GID/;
 681
 682   # There is one case where the caller's login is forced to something else,
 683   # in order to test the processing of logins that contain spaces. Weird what
 684   # some people do, isn't it?
 685
 686   s/^spaced user $> \d+$/CALLER UID GID/;
 687
 688
 689   # ======== Exim's login ========
 690   # For messages received by the daemon, this is in the -H file, which some
 691   # tests inspect. For bounce messages, this will appear on the U= lines in
 692   # logs and also after Received: and in addresses. In one pipe test it appears
 693   # after "Running as:". It also appears in addresses, and in the names of lock
 694   # files.
 695
 696   s/U=$parm_eximuser/U=EXIMUSER/;
 697   s/user=$parm_eximuser/user=EXIMUSER/;
 698   s/login=$parm_eximuser/login=EXIMUSER/;
 699   s/Received: from $parm_eximuser /Received: from EXIMUSER /;
 700   s/Running as: $parm_eximuser/Running as: EXIMUSER/;
 701   s/\b$parm_eximuser@/EXIMUSER@/;
 702   s/\b$parm_eximuser\.lock\./EXIMUSER.lock./;
 703
 704   s/\beuid=$parm_exim_uid\b/euid=EXIM_UID/g;
 705   s/\begid=$parm_exim_gid\b/egid=EXIM_GID/g;
 706
 707   s/\buid=$parm_exim_uid\b/uid=EXIM_UID/g;
 708   s/\bgid=$parm_exim_gid\b/gid=EXIM_GID/g;
 709
 710   s/^$parm_eximuser $parm_exim_uid $parm_exim_gid/EXIMUSER EXIM_UID EXIM_GID/;
 711
 712
 713   # ======== General uids, gids, and pids ========
 714   # Note: this must come after munges for caller's and exim's uid/gid
 715
 716   # These are for systems where long int is 64
 717   s/\buid=4294967295/uid=-1/;
 718   s/\beuid=4294967295/euid=-1/;
 719   s/\bgid=4294967295/gid=-1/;
 720   s/\begid=4294967295/egid=-1/;
 721
 722   s/\bgid=\d+/gid=gggg/;
 723   s/\begid=\d+/egid=gggg/;
 724   s/\b(pid=|PID: )\d+/$1pppp/;
 725   s/\buid=\d+/uid=uuuu/;
 726   s/\beuid=\d+/euid=uuuu/;
 727   s/set_process_info:\s+\d+/set_process_info: pppp/;
 728   s/queue run pid \d+/queue run pid ppppp/;
 729   s/process \d+ running as transport filter/process pppp running as transport filter/;
 730   s/process \d+ writing to transport filter/process pppp writing to transport filter/;
 731   s/reading pipe for subprocess \d+/reading pipe for subprocess pppp/;
 732   s/remote delivery process \d+ ended/remote delivery process pppp ended/;
 733
 734   # Pid in temp file in appendfile transport
 735   s"test-mail/temp\.\d+\."test-mail/temp.pppp.";
 736
 737   # Optional pid in log lines
 738   s/^(\d{4}-\d\d-\d\d\s\d\d:\d\d:\d\d)(\.\d{3}|)(\s[+-]\d{4}|)(\s\[\d+\])/
 739     "$1$2$3 [" . new_value($4, "%s", \$next_pid) . "]"/gxe;
 740
 741   # Optional pid in syslog test lines
 742   s/^(SYSLOG:\s\'([-0-9]{10}\s[:.0-9]{8,12}\s([-+]\d{4}\s)?|))(\[\d+\] )/
 743     "$1\[" . new_value($4, "%s", \$next_pid) . "]"/gxe;
 744
 745   # Detect a daemon stderr line with a pid and save the pid for subsequent
 746   # removal from following lines.
 747   $spid = $1 if /^(\s*\d+) (?:listening|LOG: MAIN|(?:daemon_smtp_port|local_interfaces) overridden by)/;
 748   s/^$spid //;
 749
 750   # Queue runner waiting messages
 751   s/waiting for children of \d+/waiting for children of pppp/;
 752   s/waiting for (\S+) \(\d+\)/waiting for $1 (pppp)/;
 753
 754   # ======== Port numbers ========
 755   # Incoming port numbers may vary, but not in daemon startup line.
 756
 757   s/^Port: (\d+)/"Port: " . new_value($1, "%s", \$next_port)/e;
 758   s/\(port=(\d+)/"(port=" . new_value($1, "%s", \$next_port)/e;
 759
 760   # This handles "connection from" and the like, when the port is given
 761   if (!/listening for SMTP on/ && !/Connecting to/ && !/=>/ && !/->/
 762       && !/\*>/ && !/Connection refused/)
 763     {
 764     s/\[([a-z\d:]+|\d+(?:\.\d+){3})\]:(\d+)/"[".$1."]:".new_value($2,"%s",\$next_port)/ie;
 765     }
 766
 767   # Port in host address in spool file output from -Mvh
 768   s/^-host_address (.*)\.\d+/-host_address $1.9999/;
 769
 770   if ($dynamic_socket and $dynamic_socket->opened and my $port = $dynamic_socket->sockport) {
 771     s/^Connecting to 127\.0\.0\.1 port \K$port/<dynamic port>/;
 772   }
 773
 774
 775   # ======== Local IP addresses ========
 776   # The amount of space between "host" and the address in verification output
 777   # depends on the length of the host name. We therefore reduce it to one space
 778   # for all of them.
 779   # Also, the length of space at the end of the host line is dependent
 780   # on the length of the longest line, so strip it also on otherwise
 781   # un-rewritten lines like localhost
 782
 783   s/^\s+host\s(\S+)\s+(\S+)/  host $1 $2/;
 784   s/^\s+(host\s\S+\s\S+)\s+(port=.*)/  host $1 $2/;
 785   s/^\s+(host\s\S+\s\S+)\s+(?=MX=)/  $1 /;
 786   s/host\s\Q$parm_ipv4\E\s\[\Q$parm_ipv4\E\]/host ipv4.ipv4.ipv4.ipv4 [ipv4.ipv4.ipv4.ipv4]/;
 787   s/host\s\Q$parm_ipv6\E\s\[\Q$parm_ipv6\E\]/host ip6:ip6:ip6:ip6:ip6:ip6:ip6:ip6 [ip6:ip6:ip6:ip6:ip6:ip6:ip6:ip6]/;
 788   s/\b\Q$parm_ipv4\E\b/ip4.ip4.ip4.ip4/g;
 789   s/(^|\W)\K\Q$parm_ipv6\E/ip6:ip6:ip6:ip6:ip6:ip6:ip6:ip6/g;
 790   s/\b\Q$parm_ipv4r\E\b/ip4-reverse/g;
 791   s/(^|\W)\K\Q$parm_ipv6r\E/ip6-reverse/g;
 792   s/^(\s+host\s\S+\s+\[\S+\]) +$/$1 /;
 793
 794
 795   # ======== Test network IP addresses ========
 796   s/(\b|_)\Q$parm_ipv4_test_net\E(?=\.\d+\.\d+\.\d+\b|_|\.rbl|\.in-addr|\.test\.again\.dns)/$1V4NET/g;
 797   s/\b\Q$parm_ipv6_test_net\E(?=:[\da-f]+:[\da-f]+:[\da-f]+)/V6NET/gi;
 798
 799
 800   # ======== IP error numbers and messages ========
 801   # These vary between operating systems
 802   s/Can't assign requested address/Network Error/;
 803   s/Cannot assign requested address/Network Error/;
 804   s/Operation timed out/Connection timed out/;
 805   s/Address family not supported by protocol family/Network Error/;
 806   s/Network is unreachable/Network Error/;
 807   s/Invalid argument/Network Error/;
 808
 809   s/\(\d+\): Network/(dd): Network/;
 810   s/\(\d+\): Connection refused/(dd): Connection refused/;
 811   s/\(\d+\): Connection timed out/(dd): Connection timed out/;
 812   s/\d+ 65 Connection refused/dd 65 Connection refused/;
 813   s/\d+ 321 Connection timed out/dd 321 Connection timed out/;
 814
 815
 816   # ======== Other error numbers ========
 817   s/errno=\d+/errno=dd/g;
 818
 819   # ======== System Error Messages ======
 820   # depending on the underlaying file system the error message seems to differ
 821   s/(?: is not a regular file)|(?: has too many links \(\d+\))/ not a regular file or too many links/;
 822
 823   # ======== Output from ls ========
 824   # Different operating systems use different spacing on long output
 825   #s/ +/ /g if /^[-rwd]{10} /;
 826   # (Bug 1226) SUSv3 allows a trailing printable char for modified access method control.
 827   # Handle only the Gnu and MacOS space, dot, plus and at-sign.  A full [[:graph:]]
 828   # unfortunately matches a non-ls linefull of dashes.
 829   # Allow the case where we've already picked out the file protection bits.
 830   if (s/^([-d](?:[-r][-w][-SsTtx]){3})[.+@]?( +|$)/$1$2/) {
 831     s/ +/ /g;
 832   }
 833
 834
 835   # ======== Message sizes =========
 836   # Message sizes vary, owing to different logins and host names that get
 837   # automatically inserted. I can't think of any way of even approximately
 838   # comparing these.
 839
 840   s/([\s,])S=\d+\b/$1S=sss/;
 841   s/:S\d+\b/:Ssss/;
 842   s/^(\s*\d+m\s+)\d+(\s+[a-z0-9-]{16} <)/$1sss$2/i if $is_stdout;
 843   s/\sSIZE=\d+\b/ SIZE=ssss/;
 844   s/\ssize=\d+\b/ size=sss/ if $is_stderr;
 845   s/old size = \d+\b/old size = sssss/;
 846   s/message size = \d+\b/message size = sss/;
 847   s/this message = \d+\b/this message = sss/;
 848   s/Size of headers = \d+/Size of headers = sss/;
 849   s/sum=(?!0)\d+/sum=dddd/;
 850   s/(?<=sum=dddd )count=\d+\b/count=dd/;
 851   s/(?<=sum=0 )count=\d+\b/count=dd/;
 852   s/,S is \d+\b/,S is ddddd/;
 853   s/\+0100,\d+;/+0100,ddd;/;
 854   s/\(\d+ bytes written\)/(ddd bytes written)/;
 855   s/added '\d+ 1'/added 'ddd 1'/;
 856   s/Received\s+\d+/Received               nnn/;
 857   s/Delivered\s+\d+/Delivered              nnn/;
 858
 859
 860   # ======== Values in spool space failure message ========
 861   s/space=\d+ inodes=[+-]?\d+/space=xxxxx inodes=xxxxx/;
 862
 863
 864   # ======== Filter sizes ========
 865   # The sizes of filter files may vary because of the substitution of local
 866   # filenames, logins, etc.
 867
 868   s/^\d+(?= bytes read from )/ssss/;
 869
 870
 871   # ======== OpenSSL error messages ========
 872   # Different releases of the OpenSSL libraries seem to give different error
 873   # numbers, or handle specific bad conditions in different ways, leading to
 874   # different wording in the error messages, so we cannot compare them.
 875
 876 #XXX This loses any trailing "deliving unencypted to" which is unfortunate
 877 #    but I can't work out how to deal with that.
 878   s/(TLS session: \(SSL_\w+\): error:)(.*)(?!: delivering)/$1 <<detail omitted>>/;
 879   s/(TLS error on connection from .* \(SSL_\w+\): error:)(.*)/$1 <<detail omitted>>/;
 880   next if /SSL verify error: depth=0 error=certificate not trusted/;
 881
 882   # ======== Maildir things ========
 883   # timestamp output in maildir processing
 884   s/(timestamp=|\(timestamp_only\): )\d+/$1ddddddd/g;
 885
 886   # maildir delivery files appearing in log lines (in cases of error)
 887   s/writing to(?: file)? tmp\/\d+\.[^.]+\.(\S+)/writing to tmp\/MAILDIR.$1/;
 888
 889   s/renamed tmp\/\d+\.[^.]+\.(\S+) as new\/\d+\.[^.]+\.(\S+)/renamed tmp\/MAILDIR.$1 as new\/MAILDIR.$1/;
 890
 891   # Maildir file names in general
 892   s/\b\d+\.H\d+P\d+\b/dddddddddd.HddddddPddddd/;
 893
 894   # Maildirsize data
 895   while (/^\d+S,\d+C\s*$/)
 896     {
 897     print MUNGED;
 898     while (<IN>)
 899       {
 900       last if !/^\d+ \d+\s*$/;
 901       print MUNGED "ddd d\n";
 902       }
 903     last if !defined $_;
 904     }
 905   last if !defined $_;
 906
 907
 908   # ======== Output from the "fd" program about open descriptors ========
 909   # The statuses seem to be different on different operating systems, but
 910   # at least we'll still be checking the number of open fd's.
 911
 912   s/max fd = \d+/max fd = dddd/;
 913   s/status=0 RDONLY/STATUS/g;
 914   s/status=1 WRONLY/STATUS/g;
 915   s/status=2 RDWR/STATUS/g;
 916
 917
 918   # ======== Contents of spool files ========
 919   # A couple of tests dump the contents of the -H file. The length fields
 920   # will be wrong because of different user names, etc.
 921   s/^\d\d\d(?=[PFS*])/ddd/;
 922
 923
 924   # ========= Exim lookups ==================
 925   # Lookups have a char which depends on the number of lookup types compiled in,
 926   # in stderr output.  Replace with a "0".  Recognising this while avoiding
 927   # other output is fragile; perhaps the debug output should be revised instead.
 928   s%(?<!sqlite)(?<!lsearch\*@)(?<!lsearch\*)(?<!lsearch)[0-?]TESTSUITE/aux-fixed/%0TESTSUITE/aux-fixed/%g;
 929
 930   # ==========================================================
 931   # MIME boundaries in RFC3461 DSN messages
 932   s/\d{8,10}-eximdsn-\d+/NNNNNNNNNN-eximdsn-MMMMMMMMMM/;
 933
 934   # ==========================================================
 935   # Some munging is specific to the specific file types
 936
 937   # ======== stdout ========
 938
 939   if ($is_stdout)
 940     {
 941     # Skip translate_ip_address and use_classresources in -bP output because
 942     # they aren't always there.
 943
 944     next if /translate_ip_address =/;
 945     next if /use_classresources/;
 946
 947     # In certain filter tests, remove initial filter lines because they just
 948     # clog up by repetition.
 949
 950     if ($rmfiltertest)
 951       {
 952       next if /^(Sender\staken\sfrom|
 953                  Return-path\scopied\sfrom|
 954                  Sender\s+=|
 955                  Recipient\s+=)/x;
 956       if (/^Testing \S+ filter/)
 957         {
 958         $_ = <IN>;    # remove blank line
 959         next;
 960         }
 961       }
 962
 963     # remote IPv6 addrs vary
 964     s/^(Connection request from) \[.*:.*:.*\]$/$1 \[ipv6\]/;
 965
 966     # openssl version variances
 967   # Error lines on stdout from SSL contain process id values and file names.
 968   # They also contain a source file name and line number, which may vary from
 969   # release to release.
 970
 971     next if /^SSL info:/;
 972     next if /SSL verify error: depth=0 error=certificate not trusted/;
 973     s/SSL3_READ_BYTES/ssl3_read_bytes/i;
 974     s/CONNECT_CR_FINISHED/ssl3_read_bytes/i;
 975     s/^\d+:error:\d+(?:E\d+)?(:SSL routines:ssl3_read_bytes:[^:]+:).*(:SSL alert number \d\d)$/pppp:error:dddddddd$1\[...\]$2/;
 976     s/^error:[^:]*:(SSL routines:ssl3_read_bytes:(tls|ssl)v\d+ alert)/error:dddddddd:$1/;
 977
 978     # gnutls version variances
 979     next if /^Error in the pull function./;
 980
 981     # optional IDN2 variant conversions.  Accept either IDN1 or IDN2
 982     s/conversion  strasse.de/conversion  xn--strae-oqa.de/;
 983     s/conversion: german.xn--strae-oqa.de/conversion: german.straße.de/;
 984
 985     # subsecond timstamp info in reported header-files
 986     s/^(-received_time_usec \.)\d{6}$/$1uuuuuu/;
 987
 988     # Postgres server takes varible time to shut down; lives in various places
 989     s/^waiting for server to shut down\.+ done$/waiting for server to shut down.... done/;
 990     s/^\/.*postgres /POSTGRES /;
 991
 992     # DMARC is not always supported by the build
 993     next if /^dmarc_tld_file =/;
 994
 995     # ARC is not always supported by the build
 996     next if /^arc_sign =/;
 997     }
 998
 999   # ======== stderr ========
1000
1001   elsif ($is_stderr)
1002     {
1003     # The very first line of debugging output will vary
1004
1005     s/^Exim version .*/Exim version x.yz ..../;
1006
1007     # Debugging lines for Exim terminations and process-generation
1008
1009     s/(?<=^>>>>>>>>>>>>>>>> Exim pid=)\d+(?= terminating)/pppp/;
1010     s/^(proxy-proc \w{5}-pid) \d+$/$1 pppp/;
1011
1012     # IP address lookups use gethostbyname() when IPv6 is not supported,
1013     # and gethostbyname2() or getipnodebyname() when it is.
1014
1015     s/\b(gethostbyname2?|\bgetipnodebyname)(\(af=inet\))?/get[host|ipnode]byname[2]/;
1016
1017     # we don't care what TZ enviroment the testhost was running
1018     next if /^Reset TZ to/;
1019
1020     # drop gnutls version strings
1021     next if /GnuTLS compile-time version: \d+[\.\d]+$/;
1022     next if /GnuTLS runtime version: \d+[\.\d]+$/;
1023
1024     # drop openssl version strings
1025     next if /OpenSSL compile-time version: OpenSSL \d+[\.\da-z]+/;
1026     next if /OpenSSL runtime version: OpenSSL \d+[\.\da-z]+/;
1027
1028     # drop lookups
1029     next if /^Lookups \(built-in\):/;
1030     next if /^Loading lookup modules from/;
1031     next if /^Loaded \d+ lookup modules/;
1032     next if /^Total \d+ lookups/;
1033
1034     # drop compiler information
1035     next if /^Compiler:/;
1036
1037     # and the ugly bit
1038     # different libraries will have different numbers (possibly 0) of follow-up
1039     # lines, indenting with more data
1040     if (/^Library version:/) {
1041       while (1) {
1042         $_ = <IN>;
1043         next if /^\s/;
1044         goto RESET_AFTER_EXTRA_LINE_READ;
1045       }
1046     }
1047
1048     # drop other build-time controls emitted for debugging
1049     next if /^WHITELIST_D_MACROS:/;
1050     next if /^TRUSTED_CONFIG_LIST:/;
1051
1052     # As of Exim 4.74, we log when a setgid fails; because we invoke Exim
1053     # with -be, privileges will have been dropped, so this will always
1054     # be the case
1055     next if /^changing group to \d+ failed: (Operation not permitted|Not owner)/;
1056
1057     # We might not keep this check; rather than change all the tests, just
1058     # ignore it as long as it succeeds; then we only need to change the
1059     # TLS tests where tls_require_ciphers has been set.
1060     if (m{^changed uid/gid: calling tls_validate_require_cipher}) {
1061       my $discard = <IN>;
1062       next;
1063     }
1064     next if /^tls_validate_require_cipher child \d+ ended: status=0x0/;
1065
1066     # We invoke Exim with -D, so we hit this new message as of Exim 4.73:
1067     next if /^macros_trusted overridden to true by whitelisting/;
1068
1069     # We have to omit the localhost ::1 address so that all is well in
1070     # the IPv4-only case.
1071
1072     print MUNGED "MUNGED: ::1 will be omitted in what follows\n"
1073       if (/looked up these IP addresses/);
1074     next if /name=localhost address=::1/;
1075
1076     # drop pdkim debugging header
1077     next if /^PDKIM( <<<<<<<<<<<<<<<<<<<<<<<<<<<<<+|: no signatures)$/;
1078
1079     # Various other IPv6 lines must be omitted too
1080
1081     next if /using host_fake_gethostbyname for \S+ \(IPv6\)/;
1082     next if /get\[host\|ipnode\]byname\[2\]\(af=inet6\)/;
1083     next if /DNS lookup of \S+ \(AAAA\) using fakens/;
1084     next if / in dns_ipv4_lookup?/;
1085
1086     if (/DNS lookup of \S+ \(AAAA\) gave NO_DATA/)
1087       {
1088       $_= <IN>;     # Gets "returning DNS_NODATA"
1089       next;
1090       }
1091
1092     # Skip tls_advertise_hosts and hosts_require_tls checks when the options
1093     # are unset, because tls ain't always there.
1094
1095     next if /in\s(?:tls_advertise_hosts\?|hosts_require_tls\?)
1096                 \sno\s\((option\sunset|end\sof\slist)\)/x;
1097
1098     # Skip auxiliary group lists because they will vary.
1099
1100     next if /auxiliary group list:/;
1101
1102     # Skip "extracted from gecos field" because the gecos field varies
1103
1104     next if /extracted from gecos field/;
1105
1106     # Skip "waiting for data on socket" and "read response data: size=" lines
1107     # because some systems pack more stuff into packets than others.
1108
1109     next if /waiting for data on socket/;
1110     next if /read response data: size=/;
1111
1112     # If Exim is compiled with readline support but it can't find the library
1113     # to load, there will be an extra debug line. Omit it.
1114
1115     next if /failed to load readline:/;
1116
1117     # Some DBM libraries seem to make DBM files on opening with O_RDWR without
1118     # O_CREAT; other's don't. In the latter case there is some debugging output
1119     # which is not present in the former. Skip the relevant lines (there are
1120     # three of them).
1121
1122     if (/returned from EXIM_DBOPEN: \(nil\)/)
1123       {
1124       $_ .= <IN>;
1125       s?\Q$parm_cwd\E?TESTSUITE?g;
1126       if (/TESTSUITE\/spool\/db\/\S+ appears not to exist: trying to create/)
1127         { $_ = <IN>; next; }
1128       }
1129
1130     # Some tests turn on +expand debugging to check on expansions.
1131     # Unfortunately, the Received: expansion varies, depending on whether TLS
1132     # is compiled or not. So we must remove the relevant debugging if it is.
1133
1134     if (/^condition: def:tls_cipher/)
1135       {
1136       while (<IN>) { last if /^condition: def:sender_address/; }
1137       }
1138     elsif (/^expanding: Received: /)
1139       {
1140       while (<IN>) { last if !/^\s/; }
1141       }
1142
1143     # remote port numbers vary
1144     s/(Connection request from 127.0.0.1 port) \d{1,5}/$1 sssss/;
1145
1146     # Skip hosts_require_dane checks when the options
1147     # are unset, because dane ain't always there.
1148     next if /in\shosts_require_dane\?\sno\s\(option\sunset\)/x;
1149
1150     # DISABLE_OCSP
1151     next if /in hosts_requ(est|ire)_ocsp\? (no|yes)/;
1152
1153     # SUPPORT_PROXY
1154     next if /host in hosts_proxy\?/;
1155
1156     # Experimental_International
1157     next if / in smtputf8_advertise_hosts\? no \(option unset\)/;
1158
1159     # Experimental_REQUIRETLS
1160     next if / in tls_advertise_requiretls?\? no \(end of list\)/;
1161
1162     # TCP Fast Open
1163     next if /^(ppppp )?setsockopt FASTOPEN: Network Error/;
1164
1165     # Experimental_PIPE_CONNECT
1166     next if / in (pipelining_connect_advertise_hosts|hosts_pipe_connect)?\? no /;
1167
1168     # Environment cleaning
1169     next if /\w+ in keep_environment\? (yes|no)/;
1170
1171     # Sizes vary with test hostname
1172     s/^cmd buf flush \d+ bytes$/cmd buf flush ddd bytes/;
1173
1174     # Spool filesystem free space changes on different systems.
1175     s/^((?:spool|log) directory space =) -?\d+K (inodes =)\s*-?\d+/$1 nnnnnK $2 nnnnn/;
1176
1177     # Non-TLS builds have different expansions for received_header_text
1178     if (s/(with \$received_protocol)\}\} \$\{if def:tls_cipher \{\(\$tls_cipher\)\n$/$1/)
1179       {
1180       $_ .= <IN>;
1181       s/[\s╎]+\}\}(?=\(Exim )/\}\} /;
1182       }
1183     if (/^ ├──condition: def:tls_cipher$/)
1184       {
1185       <IN>; <IN>; <IN>; <IN>; <IN>; <IN>;
1186       <IN>; <IN>; <IN>; <IN>; <IN>; next;
1187       }
1188
1189     # Not all platforms build with DKIM enabled
1190     next if /^PDKIM >> Body data for hash, canonicalized/;
1191
1192     # Not all platforms have sendfile support
1193     next if /^cannot use sendfile for body: no support$/;
1194
1195     #  Parts of DKIM-specific debug output depend on the time/date
1196     next if /^date:\w+,\{SP\}/;
1197     next if /^PDKIM \[[^[]+\] (Header hash|b) computed:/;
1198
1199     # Not all platforms support TCP Fast Open, and the compile omits the check
1200     if (s/\S+ in hosts_try_fastopen\? no \(option unset\)\n$//)
1201       {
1202       $_ .= <IN>;
1203       s/ \.\.\. >>> / ... /;
1204       s/Address family not supported by protocol family/Network Error/;
1205       s/Network is unreachable/Network Error/;
1206       }
1207     next if /^(ppppp )?setsockopt FASTOPEN: Protocol not available$/;
1208     s/^(Connecting to .* \.\.\. sending) \d+ (nonTFO early-data)$/$1 dd $2/;
1209
1210     # Specific pointer values reported for DB operations change from run to run
1211     s/^(\s*returned from EXIM_DBOPEN: )(0x)?[0-9a-f]+/${1}0xAAAAAAAA/;
1212     s/^(\s*EXIM_DBCLOSE.)(0x)?[0-9a-f]+/${1}0xAAAAAAAA/;
1213
1214     # Platform-dependent output during MySQL startup
1215     next if /PerconaFT file system space/;
1216     next if /^Waiting for MySQL server to answer/;
1217     next if /mysqladmin: CREATE DATABASE failed; .* database exists/;
1218
1219     # Not all builds include DMARC
1220     next if /^DMARC: no (dmarc_tld_file|sender_host_address)$/ ;
1221
1222     # When Exim is checking the size of directories for maildir, it uses
1223     # the check_dir_size() function to scan directories. Of course, the order
1224     # of the files that are obtained using readdir() varies from system to
1225     # system. We therefore buffer up debugging lines from check_dir_size()
1226     # and sort them before outputting them.
1227
1228     if (/^check_dir_size:/ || /^skipping TESTSUITE\/test-mail\//)
1229       {
1230       push @saved, $_;
1231       }
1232     else
1233       {
1234       if (@saved > 0)
1235         {
1236         print MUNGED "MUNGED: the check_dir_size lines have been sorted " .
1237           "to ensure consistency\n";
1238         @saved = sort(@saved);
1239         print MUNGED @saved;
1240         @saved = ();
1241         }
1242
1243       # Skip some lines that Exim puts out at the start of debugging output
1244       # because they will be different in different binaries.
1245
1246       print MUNGED
1247         unless (/^Berkeley DB: / ||
1248                 /^Probably (?:Berkeley DB|ndbm|GDBM)/ ||
1249                 /^Authenticators:/ ||
1250                 /^Lookups:/ ||
1251                 /^Support for:/ ||
1252                 /^Routers:/ ||
1253                 /^Transports:/ ||
1254                 /^Malware:/ ||
1255                 /^log selectors =/ ||
1256                 /^cwd=/ ||
1257                 /^Fixed never_users:/ ||
1258                 /^Configure owner:/ ||
1259                 /^Size of off_t:/
1260                 );
1261
1262
1263       }
1264
1265     next;
1266     }
1267
1268   # ======== log ========
1269
1270   elsif ($is_log)
1271     {
1272     # Berkeley DB version differences
1273     next if / Berkeley DB error: /;
1274
1275     # CHUNKING: exact sizes depend on hostnames in headers
1276     s/(=>.* K C="250- \d)\d+ (byte chunk, total \d)\d+/$1nn $2nn/;
1277
1278     # openssl version variances
1279     s/(TLS error on connection [^:]*: error:)[0-9A-F]{8}(:system library):(?:fopen|func\(4095\)):(No such file or directory)$/$1xxxxxxxx$2:fopen:$3/;
1280     s/(DANE attempt failed.*error:)[0-9A-F]{8}(:SSL routines:)(ssl3_get_server_certificate|tls_process_server_certificate|CONNECT_CR_CERT)(?=:certificate verify failed$)/$1xxxxxxxx$2ssl3_get_server_certificate/;
1281     s/(DKIM: validation error: )error:[0-9A-F]{8}:rsa routines:(?:(?i)int_rsa_verify|CRYPTO_internal):(?:bad signature|algorithm mismatch)$/$1Public key signature verification has failed./;
1282     s/ARC: AMS signing: privkey PEM-block import: error:\K[0-9A-F]{8}:(PEM routines):get_name:(no start line)/0906D06C:$1:PEM_read_bio:$2/;
1283
1284     # gnutls version variances
1285     if (/TLS error on connection \(recv\): .* (Decode error|peer did not send any certificate)/)
1286       {
1287       my $prev = $_;
1288       $_ = <IN>;
1289       if (/error on first read/)
1290         {
1291         s/TLS session: \Kerror on first read:/(gnutls_handshake): A TLS fatal alert has been received.:/;
1292         goto RESET_AFTER_EXTRA_LINE_READ;
1293         }
1294       else
1295         { $_ = $prev; }
1296       }
1297
1298     # DKIM timestamps
1299     if ( /(DKIM: d=.*) t=([0-9]*) x=([0-9]*) / )
1300       {
1301       my ($prefix, $t_diff) = ($1, $3 - $2);
1302       s/DKIM: d=.* t=[0-9]* x=[0-9]* /${prefix} t=T x=T+${t_diff} /;
1303       }
1304
1305     # port numbers
1306     s/(?:\[[^\]]*\]:|port )\K$parm_port_d/PORT_D/;
1307     s/(?:\[[^\]]*\]:|port )\K$parm_port_d2/PORT_D2/;
1308     s/(?:\[[^\]]*\]:|port )\K$parm_port_d3/PORT_D3/;
1309     s/(?:\[[^\]]*\]:|port )\K$parm_port_d4/PORT_D4/;
1310     s/(?:\[[^\]]*\]:|port )\K$parm_port_s/PORT_S/;
1311     s/(?:\[[^\]]*\]:|port )\K$parm_port_n/PORT_N/;
1312     s/I=\[[^\]]*\]:\K\d+/ppppp/;
1313
1314     }
1315
1316   # ======== mail ========
1317
1318   elsif ($is_mail)
1319     {
1320     # DKIM timestamps, and signatures depending thereon
1321     if ( /^(\s+)t=([0-9]*); x=([0-9]*); b=[A-Za-z0-9+\/]+$/ )
1322       {
1323       my ($indent, $t_diff) = ($1, $3 - $2);
1324       s/.*/${indent}t=T; x=T+${t_diff}; b=bbbb;/;
1325       <IN>;
1326       <IN>;
1327       }
1328     }
1329
1330   # ======== All files other than stderr ========
1331
1332   print MUNGED;
1333   }
1334
1335 close(IN);
1336 return $yield;
1337 }
1338
1339
1340
1341
1342 ##################################################
1343 #        Subroutine to interact with caller      #
1344 ##################################################
1345
1346 # Arguments: [0] the prompt string
1347 #            [1] if there is a U in the prompt and $force_update is true
1348 #            [2] if there is a C in the prompt and $force_continue is true
1349 # Returns:   returns the answer
1350
1351 sub interact {
1352   my ($prompt, $have_u, $have_c) = @_;
1353
1354   print $prompt;
1355
1356   if ($have_u) {
1357     print "... update forced\n";
1358     return 'u';
1359   }
1360
1361   if ($have_c) {
1362     print "... continue forced\n";
1363     return 'c';
1364   }
1365
1366   return lc <T>;
1367 }
1368
1369
1370
1371 ##################################################
1372 #    Subroutine to log in force_continue mode    #
1373 ##################################################
1374
1375 # In force_continue mode, we just want a terse output to a statically
1376 # named logfile.  If multiple files in same batch (stdout, stderr, etc)
1377 # all have mismatches, it will log multiple times.
1378 #
1379 # Arguments: [0] the logfile to append to
1380 #            [1] the testno that failed
1381 # Returns:   nothing
1382
1383
1384
1385 sub log_failure {
1386   my ($logfile, $testno, $detail) = @_;
1387
1388   open(my $fh, '>>', $logfile) or return;
1389
1390   print $fh "Test $testno "
1391         . (defined $detail ? "$detail " : '')
1392         . "failed\n";
1393 }
1394
1395 # Computer-readable summary results logfile
1396
1397 sub log_test {
1398   my ($logfile, $testno, $resultchar) = @_;
1399
1400   open(my $fh, '>>', $logfile) or return;
1401   print $fh "$testno $resultchar\n";
1402 }
1403
1404
1405
1406 ##################################################
1407 #    Subroutine to compare one output file       #
1408 ##################################################
1409
1410 # When an Exim server is part of the test, its output is in separate files from
1411 # an Exim client. The server data is concatenated with the client data as part
1412 # of the munging operation.
1413 #
1414 # Arguments:  [0] the name of the main raw output file
1415 #             [1] the name of the server raw output file or undef
1416 #             [2] where to put the munged copy
1417 #             [3] the name of the saved file
1418 #             [4] TRUE if this is a log file whose deliveries must be sorted
1419 #             [5] optionally, a custom munge command
1420 #
1421 # Returns:    0 comparison succeeded
1422 #             1 comparison failed; differences to be ignored
1423 #             2 comparison failed; files may have been updated (=> re-compare)
1424 #
1425 # Does not return if the user replies "Q" to a prompt.
1426
1427 sub check_file{
1428 my($rf,$rsf,$mf,$sf,$sortfile,$extra) = @_;
1429
1430 # If there is no saved file, the raw files must either not exist, or be
1431 # empty. The test ! -s is TRUE if the file does not exist or is empty.
1432
1433 # we check if there is a flavour specific file, but we remember
1434 # the original file name as "generic"
1435 $sf_generic = $sf;
1436 $sf_flavour = "$sf_generic.$flavour";
1437 $sf_current = -e $sf_flavour ? $sf_flavour : $sf_generic;
1438
1439 if (! -e $sf_current)
1440   {
1441   return 0 if (! -s $rf && (! defined $rsf || ! -s $rsf));
1442
1443   print "\n";
1444   print "** $rf is not empty\n" if (-s $rf);
1445   print "** $rsf is not empty\n" if (defined $rsf && -s $rsf);
1446
1447   for (;;)
1448     {
1449     $_ = interact('Continue, Show, or Quit? [Q] ', undef, $force_continue);
1450     tests_exit(1) if /^q?$/;
1451     if (/^c$/ && $force_continue) {
1452       log_failure($log_failed_filename, $testno, $rf);
1453       log_test($log_summary_filename, $testno, 'F') if ($force_continue);
1454     }
1455     return 1 if /^c$/i && $rf !~ /paniclog/ && $rsf !~ /paniclog/;
1456     last if (/^[sc]$/);
1457     }
1458
1459   foreach $f ($rf, $rsf)
1460     {
1461     if (defined $f && -s $f)
1462       {
1463       print "\n";
1464       print "------------ $f -----------\n"
1465         if (defined $rf && -s $rf && defined $rsf && -s $rsf);
1466       system("$more '$f'");
1467       }
1468     }
1469
1470   print "\n";
1471   for (;;)
1472     {
1473     $_ = interact('Continue, Update & retry, Quit? [Q] ', $force_update, $force_continue);
1474     tests_exit(1) if /^q?$/;
1475     if (/^c$/ && $force_continue) {
1476       log_failure($log_failed_filename, $testno, $rf);
1477       log_test($log_summary_filename, $testno, 'F')
1478     }
1479     return 1 if /^c$/i;
1480     last if (/^u$/i);
1481     }
1482   }
1483
1484 #### $_
1485
1486 # Control reaches here if either (a) there is a saved file ($sf), or (b) there
1487 # was a request to create a saved file. First, create the munged file from any
1488 # data that does exist.
1489
1490 open(MUNGED, '>', $mf) || tests_exit(-1, "Failed to open $mf: $!");
1491 my($truncated) = munge($rf, $extra) if -e $rf;
1492
1493 # Append the raw server log, if it is non-empty
1494 if (defined $rsf && -e $rsf)
1495   {
1496   print MUNGED "\n******** SERVER ********\n";
1497   $truncated |= munge($rsf, $extra);
1498   }
1499 close(MUNGED);
1500
1501 # If a saved file exists, do the comparison. There are two awkward cases:
1502 #
1503 # If "*** truncated ***" was found in the new file, it means that a log line
1504 # was overlong, and truncated. The problem is that it may be truncated at
1505 # different points on different systems, because of different user name
1506 # lengths. We reload the file and the saved file, and remove lines from the new
1507 # file that precede "*** truncated ***" until we reach one that matches the
1508 # line that precedes it in the saved file.
1509 #
1510 # If $sortfile is set, we are dealing with a mainlog file where the deliveries
1511 # for an individual message might vary in their order from system to system, as
1512 # a result of parallel deliveries. We load the munged file and sort sequences
1513 # of delivery lines.
1514
1515 if (-e $sf_current)
1516   {
1517   # Deal with truncated text items
1518
1519   if ($truncated)
1520     {
1521     my(@munged, @saved, $i, $j, $k);
1522
1523     open(MUNGED, $mf) || tests_exit(-1, "Failed to open $mf: $!");
1524     @munged = <MUNGED>;
1525     close(MUNGED);
1526     open(SAVED, $sf_current) || tests_exit(-1, "Failed to open $sf_current: $!");
1527     @saved = <SAVED>;
1528     close(SAVED);
1529
1530     $j = 0;
1531     for ($i = 0; $i < @munged; $i++)
1532       {
1533       if ($munged[$i] =~ /\*\*\* truncated \*\*\*/)
1534         {
1535         for (; $j < @saved; $j++)
1536           { last if $saved[$j] =~ /\*\*\* truncated \*\*\*/; }
1537         last if $j >= @saved;     # not found in saved
1538
1539         for ($k = $i - 1; $k >= 0; $k--)
1540           { last if $munged[$k] eq $saved[$j - 1]; }
1541
1542         last if $k <= 0;          # failed to find previous match
1543         splice @munged, $k + 1, $i - $k - 1;
1544         $i = $k + 1;
1545         }
1546       }
1547
1548     open(MUNGED, '>', $mf) || tests_exit(-1, "Failed to open $mf: $!");
1549     for ($i = 0; $i < @munged; $i++)
1550       { print MUNGED $munged[$i]; }
1551     close(MUNGED);
1552     }
1553
1554   # Deal with log sorting
1555
1556   if ($sortfile)
1557     {
1558     my(@munged, $i, $j);
1559
1560     open(MUNGED, $mf) || tests_exit(-1, "Failed to open $mf: $!");
1561     @munged = <MUNGED>;
1562     close(MUNGED);
1563
1564     for ($i = 0; $i < @munged; $i++)
1565       {
1566       if ($munged[$i] =~ /^[-\d]{10}\s[:\d]{8}\s[-A-Za-z\d]{16}\s[-=*]>/)
1567         {
1568         for ($j = $i + 1; $j < @munged; $j++)
1569           {
1570           last if $munged[$j] !~
1571             /^[-\d]{10}\s[:\d]{8}\s[-A-Za-z\d]{16}\s[-=*]>/;
1572           }
1573         @temp = splice(@munged, $i, $j - $i);
1574         @temp = sort(@temp);
1575         splice(@munged, $i, 0, @temp);
1576         }
1577       }
1578
1579     open(MUNGED, ">$mf") || tests_exit(-1, "Failed to open $mf: $!");
1580     print MUNGED "**NOTE: The delivery lines in this file have been sorted.\n";
1581     for ($i = 0; $i < @munged; $i++)
1582       { print MUNGED $munged[$i]; }
1583     close(MUNGED);
1584     }
1585
1586   # Do the comparison
1587
1588   return 0 if (system("$cf '$mf' '$sf_current' >test-cf") == 0);
1589
1590   # Handle comparison failure
1591
1592   print "** Comparison of $mf with $sf_current failed";
1593   system("$more test-cf");
1594
1595   print "\n";
1596   for (;;)
1597     {
1598     $_ = interact('Continue, Retry, Update current'
1599         . ($sf_current ne $sf_flavour  ? "/Save for flavour '$flavour'" : '')
1600         . ' & retry, Quit? [Q] ', $force_update, $force_continue);
1601     tests_exit(1) if /^q?$/;
1602     if (/^c$/ && $force_continue) {
1603       log_failure($log_failed_filename, $testno, $sf_current);
1604       log_test($log_summary_filename, $testno, 'F')
1605     }
1606     return 1 if /^c$/i;
1607     return 2 if /^r$/i;
1608     last if (/^[us]$/i);
1609     }
1610   }
1611
1612 # Update or delete the saved file, and give the appropriate return code.
1613
1614 if (-s $mf)
1615   {
1616     my $sf = /^u/i ? $sf_current : $sf_flavour;
1617     tests_exit(-1, "Failed to cp $mf $sf") if system("cp '$mf' '$sf'") != 0;
1618   }
1619 else
1620   {
1621     # if we deal with a flavour file, we can't delete it, because next time the generic
1622     # file would be used again
1623     if ($sf_current eq $sf_flavour) {
1624       open(FOO, ">$sf_current");
1625       close(FOO);
1626     }
1627     else {
1628       tests_exit(-1, "Failed to unlink $sf_current") if !unlink($sf_current);
1629     }
1630   }
1631
1632 return 2;
1633 }
1634
1635
1636
1637 ##################################################
1638 # Custom munges
1639 # keyed by name of munge; value is a ref to a hash
1640 # which is keyed by file, value a string to look for.
1641 # Usable files are:
1642 #  paniclog, rejectlog, mainlog, stdout, stderr, msglog, mail
1643 # Search strings starting with 's' do substitutions;
1644 # with '/' do line-skips.
1645 # Triggered by a scriptfile line "munge <name>"
1646 ##################################################
1647 $munges =
1648   { 'dnssec' =>
1649     { 'stderr' => '/^Reverse DNS security status: unverified\n/' },
1650
1651     'gnutls_unexpected' =>
1652     { 'mainlog' => '/\(recv\): A TLS packet with unexpected length was received./' },
1653
1654     'gnutls_handshake' =>
1655     { 'mainlog' => 's/\(gnutls_handshake\): Error in the push function/\(gnutls_handshake\): A TLS packet with unexpected length was received/' },
1656
1657     'gnutls_bad_clientcert' =>
1658     { 'mainlog' => 's/\(certificate verification failed\): certificate invalid/\(gnutls_handshake\): The peer did not send any certificate./',
1659       'stdout'  => 's/Succeeded in starting TLS/A TLS fatal alert has been received.\nFailed to start TLS'
1660     },
1661
1662     'optional_events' =>
1663     { 'stdout' => '/event_action =/' },
1664
1665     'optional_ocsp' =>
1666     { 'stderr' => '/127.0.0.1 in hosts_requ(ire|est)_ocsp/' },
1667
1668     'optional_cert_hostnames' =>
1669     { 'stderr' => '/in tls_verify_cert_hostnames\? no/' },
1670
1671     'loopback' =>
1672     { 'stdout' => 's/[[](127\.0\.0\.1|::1)]/[IP_LOOPBACK_ADDR]/' },
1673
1674     'scanfile_size' =>
1675     { 'stdout' => 's/(Content-length:) \d\d\d/$1 ddd/' },
1676
1677     'delay_1500' =>
1678     { 'stderr' => 's/(1[5-9]|23\d)\d\d msec/ssss msec/' },
1679
1680     'tls_anycipher' =>
1681     { 'mainlog'   => 's! X=TLS\S+ ! X=TLS_proto_and_cipher !;
1682                       s! DN="C=! DN="/C=!;
1683                       s! DN="[^,"]*\K,!/!;
1684                       s! DN="[^,"]*\K,!/!;
1685                       s! DN="[^,"]*\K,!/!;
1686                      ',
1687       'rejectlog' => 's/ X=TLS\S+ / X=TLS_proto_and_cipher /',
1688       'mail'      => 's/^\s+by .+ with .+ \K tls TLS_.+$/(TLS_proto_and_cipher)/;
1689                       s/ \(TLS[^)]*\)/ (TLS_proto_and_cipher)/;
1690                      ',
1691     },
1692
1693     'debug_pid' =>
1694     { 'stderr' => 's/(^\s{0,4}|(?<=Process )|(?<=child ))\d{1,5}/ppppp/g' },
1695
1696     'optional_dsn_info' =>
1697     { 'mail' => '/^(X-(Remote-MTA-(smtp-greeting|helo-response)|Exim-Diagnostic|(body|message)-linecount):|Remote-MTA: X-ip;)/'
1698     },
1699
1700     'optional_config' =>
1701     { 'stdout' => '/^(
1702                   dkim_(canon|domain|private_key|selector|sign_headers|strict|hash|identity|timestamps)
1703                   |gnutls_require_(kx|mac|protocols)
1704                   |hosts_pipe_connect
1705                   |hosts_(requ(est|ire)|try)_(dane|ocsp)
1706                   |dane_require_tls_ciphers
1707                   |hosts_(avoid|nopass|noproxy|require|verify_avoid)_tls
1708                   |pipelining_connect_advertise_hosts
1709                   |socks_proxy
1710                   |tls_[^ ]*
1711                   |utf8_downconvert
1712                   )($|[ ]=)/x'
1713     },
1714
1715     'sys_bindir' =>
1716     { 'mainlog' => 's%/(usr/(local/)?)?bin/%SYSBINDIR/%' },
1717
1718     'sync_check_data' =>
1719     { 'mainlog'   => 's/^(.* SMTP protocol synchronization error .* next input=.{8}).*$/$1<suppressed>/',
1720       'rejectlog' => 's/^(.* SMTP protocol synchronization error .* next input=.{8}).*$/$1<suppressed>/'},
1721
1722     'debuglog_stdout' =>
1723     { 'stdout' => 's/^\d\d:\d\d:\d\d\s+\d+ //;
1724                   s/Process \d+ is ready for new message/Process pppp is ready for new message/'
1725     },
1726
1727     'timeout_errno' =>          # actual errno differs Solaris vs. Linux
1728     { 'mainlog' => 's/(host deferral .* errno) <\d+> /$1 <EEE> /' },
1729
1730     'peer_terminated_conn' =>   # actual error differs FreedBSD vs. Linux
1731     { 'stderr' => 's/^(  SMTP\()Connection reset by peer(\)<<)$/$1closed$2/' },
1732
1733     'perl_variants' =>          # result of hash-in-scalar-context changed from bucket-fill to keycount
1734     { 'stdout' => 's%^> X/X$%> X%' },
1735   };
1736
1737
1738 sub max {
1739   my ($a, $b) = @_;
1740   return $a if ($a > $b);
1741   return $b;
1742 }
1743
1744 ##################################################
1745 #    Subroutine to check the output of a test    #
1746 ##################################################
1747
1748 # This function is called when the series of subtests is complete. It makes
1749 # use of check_file(), whose arguments are:
1750 #
1751 #  [0] the name of the main raw output file
1752 #  [1] the name of the server raw output file or undef
1753 #  [2] where to put the munged copy
1754 #  [3] the name of the saved file
1755 #  [4] TRUE if this is a log file whose deliveries must be sorted
1756 #  [5] an optional custom munge command
1757 #
1758 # Arguments: Optionally, name of a single custom munge to run.
1759 # Returns:   0 if the output compared equal
1760 #            1 if comparison failed; differences to be ignored
1761 #            2 if re-run needed (files may have been updated)
1762
1763 sub check_output{
1764 my($mungename) = $_[0];
1765 my($yield) = 0;
1766 my($munge) = $munges->{$mungename} if defined $mungename;
1767
1768 $yield = max($yield,  check_file("spool/log/paniclog",
1769                        "spool/log/serverpaniclog",
1770                        "test-paniclog-munged",
1771                        "paniclog/$testno", 0,
1772                        $munge->{paniclog}));
1773
1774 $yield = max($yield,  check_file("spool/log/rejectlog",
1775                        "spool/log/serverrejectlog",
1776                        "test-rejectlog-munged",
1777                        "rejectlog/$testno", 0,
1778                        $munge->{rejectlog}));
1779
1780 $yield = max($yield,  check_file("spool/log/mainlog",
1781                        "spool/log/servermainlog",
1782                        "test-mainlog-munged",
1783                        "log/$testno", $sortlog,
1784                        $munge->{mainlog}));
1785
1786 if (!$stdout_skip)
1787   {
1788   $yield = max($yield,  check_file("test-stdout",
1789                        "test-stdout-server",
1790                        "test-stdout-munged",
1791                        "stdout/$testno", 0,
1792                        $munge->{stdout}));
1793   }
1794
1795 if (!$stderr_skip)
1796   {
1797   $yield = max($yield,  check_file("test-stderr",
1798                        "test-stderr-server",
1799                        "test-stderr-munged",
1800                        "stderr/$testno", 0,
1801                        $munge->{stderr}));
1802   }
1803
1804 # Compare any delivered messages, unless this test is skipped.
1805
1806 if (! $message_skip)
1807   {
1808   my($msgno) = 0;
1809
1810   # Get a list of expected mailbox files for this script. We don't bother with
1811   # directories, just the files within them.
1812
1813   foreach $oldmail (@oldmails)
1814     {
1815     next unless $oldmail =~ /^mail\/$testno\./;
1816     print ">> EXPECT $oldmail\n" if $debug;
1817     $expected_mails{$oldmail} = 1;
1818     }
1819
1820   # If there are any files in test-mail, compare them. Note that "." and
1821   # ".." are automatically omitted by list_files_below().
1822
1823   @mails = list_files_below("test-mail");
1824
1825   foreach $mail (@mails)
1826     {
1827     next if $mail eq "test-mail/oncelog";
1828
1829     $saved_mail = substr($mail, 10);               # Remove "test-mail/"
1830     $saved_mail =~ s/^$parm_caller(\/|$)/CALLER/;  # Convert caller name
1831
1832     if ($saved_mail =~ /(\d+\.[^.]+\.)/)
1833       {
1834       $msgno++;
1835       $saved_mail =~ s/(\d+\.[^.]+\.)/$msgno./gx;
1836       }
1837
1838     print ">> COMPARE $mail mail/$testno.$saved_mail\n" if $debug;
1839     $yield = max($yield,  check_file($mail, undef, "test-mail-munged",
1840       "mail/$testno.$saved_mail", 0,
1841       $munge->{mail}));
1842     delete $expected_mails{"mail/$testno.$saved_mail"};
1843     }
1844
1845   # Complain if not all expected mails have been found
1846
1847   if (scalar(keys %expected_mails) != 0)
1848     {
1849     foreach $key (keys %expected_mails)
1850       { print "** no test file found for $key\n"; }
1851
1852     for (;;)
1853       {
1854       $_ = interact('Continue, Update & retry, or Quit? [Q] ', $force_update, $force_continue);
1855       tests_exit(1) if /^q?$/;
1856       if (/^c$/ && $force_continue) {
1857         log_failure($log_failed_filename, $testno, "missing email");
1858         log_test($log_summary_filename, $testno, 'F')
1859       }
1860       last if /^c$/;
1861
1862       # For update, we not only have to unlink the file, but we must also
1863       # remove it from the @oldmails vector, as otherwise it will still be
1864       # checked for when we re-run the test.
1865
1866       if (/^u$/)
1867         {
1868         foreach $key (keys %expected_mails)
1869           {
1870           my($i);
1871           tests_exit(-1, "Failed to unlink $key") if !unlink("$key");
1872           for ($i = 0; $i < @oldmails; $i++)
1873             {
1874             if ($oldmails[$i] eq $key)
1875               {
1876               splice @oldmails, $i, 1;
1877               last;
1878               }
1879             }
1880           }
1881         last;
1882         }
1883       }
1884     }
1885   }
1886
1887 # Compare any remaining message logs, unless this test is skipped.
1888
1889 if (! $msglog_skip)
1890   {
1891   # Get a list of expected msglog files for this test
1892
1893   foreach $oldmsglog (@oldmsglogs)
1894     {
1895     next unless $oldmsglog =~ /^$testno\./;
1896     $expected_msglogs{$oldmsglog} = 1;
1897     }
1898
1899   # If there are any files in spool/msglog, compare them. However, we have
1900   # to munge the file names because they are message ids, which are
1901   # time dependent.
1902
1903   if (opendir(DIR, "spool/msglog"))
1904     {
1905     @msglogs = sort readdir(DIR);
1906     closedir(DIR);
1907
1908     foreach $msglog (@msglogs)
1909       {
1910       next if ($msglog eq "." || $msglog eq ".." || $msglog eq "CVS");
1911       ($munged_msglog = $msglog) =~
1912         s/((?:[^\W_]{6}-){2}[^\W_]{2})
1913           /new_value($1, "10Hm%s-0005vi-00", \$next_msgid)/egx;
1914       $yield = max($yield,  check_file("spool/msglog/$msglog", undef,
1915         "test-msglog-munged", "msglog/$testno.$munged_msglog", 0,
1916         $munge->{msglog}));
1917       delete $expected_msglogs{"$testno.$munged_msglog"};
1918       }
1919     }
1920
1921   # Complain if not all expected msglogs have been found
1922
1923   if (scalar(keys %expected_msglogs) != 0)
1924     {
1925     foreach $key (keys %expected_msglogs)
1926       {
1927       print "** no test msglog found for msglog/$key\n";
1928       ($msgid) = $key =~ /^\d+\.(.*)$/;
1929       foreach $cachekey (keys %cache)
1930         {
1931         if ($cache{$cachekey} eq $msgid)
1932           {
1933           print "** original msgid $cachekey\n";
1934           last;
1935           }
1936         }
1937       }
1938
1939     for (;;)
1940       {
1941       $_ = interact('Continue, Update, or Quit? [Q] ', $force_update, $force_continue);
1942       tests_exit(1) if /^q?$/;
1943       if (/^c$/ && $force_continue) {
1944         log_failure($log_failed_filename, $testno, "missing msglog");
1945         log_test($log_summary_filename, $testno, 'F')
1946       }
1947       last if /^c$/;
1948       if (/^u$/)
1949         {
1950         foreach $key (keys %expected_msglogs)
1951           {
1952           tests_exit(-1, "Failed to unlink msglog/$key")
1953             if !unlink("msglog/$key");
1954           }
1955         last;
1956         }
1957       }
1958     }
1959   }
1960
1961 return $yield;
1962 }
1963
1964
1965
1966 ##################################################
1967 #     Subroutine to run one "system" command     #
1968 ##################################################
1969
1970 # We put this in a subroutine so that the command can be reflected when
1971 # debugging.
1972 #
1973 # Argument: the command to be run
1974 # Returns:  nothing
1975
1976 sub run_system {
1977 my($cmd) = $_[0];
1978 if ($debug)
1979   {
1980   my($prcmd) = $cmd;
1981   $prcmd =~ s/; /;\n>> /;
1982   print ">> $prcmd\n";
1983   }
1984 system("$cmd");
1985 }
1986
1987
1988
1989 ##################################################
1990 #      Subroutine to run one script command      #
1991 ##################################################
1992
1993 # The <SCRIPT> file is open for us to read an optional return code line,
1994 # followed by the command line and any following data lines for stdin. The
1995 # command line can be continued by the use of \. Data lines are not continued
1996 # in this way. In all lines, the following substitutions are made:
1997 #
1998 # DIR    => the current directory
1999 # CALLER => the caller of this script
2000 #
2001 # Arguments: the current test number
2002 #            reference to the subtest number, holding previous value
2003 #            reference to the expected return code value
2004 #            reference to where to put the command name (for messages)
2005 #            auxiliary information returned from a previous run
2006 #
2007 # Returns:   0 the command was executed inline, no subprocess was run
2008 #            1 a non-exim command was run and waited for
2009 #            2 an exim command was run and waited for
2010 #            3 a command was run and not waited for (daemon, server, exim_lock)
2011 #            4 EOF was encountered after an initial return code line
2012 # Optionally also a second parameter, a hash-ref, with auxiliary information:
2013 #            exim_pid: pid of a run process
2014 #            munge: name of a post-script results munger
2015
2016 sub run_command{
2017 my($testno) = $_[0];
2018 my($subtestref) = $_[1];
2019 my($commandnameref) = $_[3];
2020 my($aux_info) = $_[4];
2021 my($yield) = 1;
2022
2023 our %ENV = map { $_ => $ENV{$_} } grep { /^(?:USER|SHELL|PATH|TERM|EXIM_TEST_.*)$/ } keys %ENV;
2024
2025 if (/^(\d+)\s*$/)                # Handle unusual return code
2026   {
2027   my($r) = $_[2];
2028   $$r = $1 << 8;
2029   $_ = <SCRIPT>;
2030   return 4 if !defined $_;       # Missing command
2031   $lineno++;
2032   }
2033
2034 chomp;
2035 $wait_time = 0;
2036
2037 # Handle concatenated command lines
2038
2039 s/\s+$//;
2040 while (substr($_, -1) eq"\\")
2041   {
2042   my($temp);
2043   $_ = substr($_, 0, -1);
2044   chomp($temp = <SCRIPT>);
2045   if (defined $temp)
2046     {
2047     $lineno++;
2048     $temp =~ s/\s+$//;
2049     $temp =~ s/^\s+//;
2050     $_ .= $temp;
2051     }
2052   }
2053
2054 # Do substitutions
2055
2056 do_substitute($testno);
2057 if ($debug) { printf ">> $_\n"; }
2058
2059 # Pass back the command name (for messages)
2060
2061 ($$commandnameref) = /^(\S+)/;
2062
2063 # Here follows code for handling the various different commands that are
2064 # supported by this script. The first group of commands are all freestanding
2065 # in that they share no common code and are not followed by any data lines.
2066
2067
2068 ###################
2069 ###################
2070
2071 # The "dbmbuild" command runs exim_dbmbuild. This is used both to test the
2072 # utility and to make DBM files for testing DBM lookups.
2073
2074 if (/^dbmbuild\s+(\S+)\s+(\S+)/)
2075   {
2076   run_system("(./eximdir/exim_dbmbuild $parm_cwd/$1 $parm_cwd/$2;" .
2077          "echo exim_dbmbuild exit code = \$?)" .
2078          ">>test-stdout");
2079   return 1;
2080   }
2081
2082
2083 # The "dump" command runs exim_dumpdb. On different systems, the output for
2084 # some types of dump may appear in a different order because it's just hauled
2085 # out of the DBM file. We can solve this by sorting. Ignore the leading
2086 # date/time, as it will be flattened later during munging.
2087
2088 if (/^dump\s+(\S+)/)
2089   {
2090   my($which) = $1;
2091   my(@temp);
2092   print ">> ./eximdir/exim_dumpdb $parm_cwd/spool $which\n" if $debug;
2093   open(IN, "./eximdir/exim_dumpdb $parm_cwd/spool $which |");
2094   open(OUT, ">>test-stdout");
2095   print OUT "+++++++++++++++++++++++++++\n";
2096
2097   if ($which eq "retry")
2098     {
2099     $/ = "\n  ";
2100     @temp = <IN>;
2101     $/ = "\n";
2102
2103     @temp = sort {
2104                    my($aa) = split(' ', $a);
2105                    my($bb) = split(' ', $b);
2106                    return $aa cmp $bb;
2107                  } @temp;
2108
2109     foreach $item (@temp)
2110       {
2111       $item =~ s/^\s*(.*)\n(.*)\n?\s*$/$1\n$2/m;
2112       print OUT "  $item\n";
2113       }
2114     }
2115   else
2116     {
2117     @temp = <IN>;
2118     if ($which eq "callout")
2119       {
2120       @temp = sort {
2121                    my($aa) = substr $a, 21;
2122                    my($bb) = substr $b, 21;
2123                    return $aa cmp $bb;
2124                    } @temp;
2125       }
2126     print OUT @temp;
2127     }
2128
2129   close(IN);
2130   close(OUT);
2131   return 1;
2132   }
2133
2134
2135 # verbose comments start with ###
2136 if (/^###\s/) {
2137   for my $file (qw(test-stdout test-stderr test-stderr-server test-stdout-server)) {
2138     open my $fh, '>>', $file or die "Can't open >>$file: $!\n";
2139     say {$fh} $_;
2140   }
2141   return 0;
2142 }
2143
2144 # The "echo" command is a way of writing comments to the screen.
2145 if (/^echo\s+(.*)$/)
2146   {
2147   print "$1\n";
2148   return 0;
2149   }
2150
2151
2152 # The "exim_lock" command runs exim_lock in the same manner as "server",
2153 # but it doesn't use any input.
2154
2155 if (/^exim_lock\s+(.*)$/)
2156   {
2157   $cmd = "./eximdir/exim_lock $1 >>test-stdout";
2158   $server_pid = open SERVERCMD, "|$cmd" ||
2159     tests_exit(-1, "Failed to run $cmd\n");
2160
2161   # This gives the process time to get started; otherwise the next
2162   # process may not find it there when it expects it.
2163
2164   select(undef, undef, undef, 0.1);
2165   return 3;
2166   }
2167
2168
2169 # The "exinext" command runs exinext
2170
2171 if (/^exinext\s+(.*)/)
2172   {
2173   run_system("(./eximdir/exinext " .
2174     "-DEXIM_PATH=$parm_cwd/eximdir/exim " .
2175     "-C $parm_cwd/test-config $1;" .
2176     "echo exinext exit code = \$?)" .
2177     ">>test-stdout");
2178   return 1;
2179   }
2180
2181
2182 # The "exigrep" command runs exigrep on the current mainlog
2183
2184 if (/^exigrep\s+(.*)/)
2185   {
2186   run_system("(./eximdir/exigrep " .
2187     "$1 $parm_cwd/spool/log/mainlog;" .
2188     "echo exigrep exit code = \$?)" .
2189     ">>test-stdout");
2190   return 1;
2191   }
2192
2193
2194 # The "eximstats" command runs eximstats on the current mainlog
2195
2196 if (/^eximstats\s+(.*)/)
2197   {
2198   run_system("(./eximdir/eximstats " .
2199     "$1 $parm_cwd/spool/log/mainlog;" .
2200     "echo eximstats exit code = \$?)" .
2201     ">>test-stdout");
2202   return 1;
2203   }
2204
2205
2206 # The "gnutls" command makes a copy of saved GnuTLS parameter data in the
2207 # spool directory, to save Exim from re-creating it each time.
2208
2209 if (/^gnutls/)
2210   {
2211   my $gen_fn = "spool/gnutls-params-$gnutls_dh_bits_normal";
2212   run_system "sudo cp -p aux-fixed/gnutls-params $gen_fn;" .
2213          "sudo chown $parm_eximuser:$parm_eximgroup $gen_fn;" .
2214          "sudo chmod 0400 $gen_fn";
2215   return 1;
2216   }
2217
2218
2219 # The "killdaemon" command should ultimately follow the starting of any Exim
2220 # daemon with the -bd option. We kill with SIGINT rather than SIGTERM to stop
2221 # it outputting "Terminated" to the terminal when not in the background.
2222
2223 if (/^killdaemon/)
2224   {
2225   my $return_extra = {};
2226   if (exists $aux_info->{exim_pid})
2227     {
2228     $pid = $aux_info->{exim_pid};
2229     $return_extra->{exim_pid} = undef;
2230     print ">> killdaemon: recovered pid $pid\n" if $debug;
2231     if ($pid)
2232       {
2233       run_system("sudo /bin/kill -INT $pid");
2234       wait;
2235       }
2236     } else {
2237     $pid = `cat $parm_cwd/spool/exim-daemon.*`;
2238     if ($pid)
2239       {
2240       run_system("sudo /bin/kill -INT $pid");
2241       close DAEMONCMD;                                   # Waits for process
2242       }
2243     }
2244     run_system("sudo /bin/rm -f spool/exim-daemon.*");
2245   return (1, $return_extra);
2246   }
2247
2248
2249 # The "millisleep" command is like "sleep" except that its argument is in
2250 # milliseconds, thus allowing for a subsecond sleep, which is, in fact, all it
2251 # is used for.
2252
2253 elsif (/^millisleep\s+(.*)$/)
2254   {
2255   select(undef, undef, undef, $1/1000);
2256   return 0;
2257   }
2258
2259
2260 # The "munge" command selects one of a hardwired set of test-result modifications
2261 # to be made before result compares are run against the golden set.  This lets
2262 # us account for test-system dependent things which only affect a few, but known,
2263 # test-cases.
2264 # Currently only the last munge takes effect.
2265
2266 if (/^munge\s+(.*)$/)
2267   {
2268   return (0, { munge => $1 });
2269   }
2270
2271
2272 # The "sleep" command does just that. For sleeps longer than 1 second we
2273 # tell the user what's going on.
2274
2275 if (/^sleep\s+(.*)$/)
2276   {
2277   if ($1 == 1)
2278     {
2279     sleep(1);
2280     }
2281   else
2282     {
2283     printf("  Test %d sleep $1 ", $$subtestref);
2284     for (1..$1)
2285       {
2286       print ".";
2287       sleep(1);
2288       }
2289     printf("\r  Test %d                            $cr", $$subtestref);
2290     }
2291   return 0;
2292   }
2293
2294
2295 # Various Unix management commands are recognized
2296
2297 if (/^(ln|ls|du|mkdir|mkfifo|touch|cp|cat)\s/ ||
2298     /^sudo\s(rmdir|rm|mv|chown|chmod)\s/)
2299   {
2300   run_system("$_ >>test-stdout 2>>test-stderr");
2301   return 1;
2302   }
2303
2304
2305
2306 ###################
2307 ###################
2308
2309 # The next group of commands are also freestanding, but they are all followed
2310 # by data lines.
2311
2312
2313 # The "server" command starts up a script-driven server that runs in parallel
2314 # with the following exim command. Therefore, we want to run a subprocess and
2315 # not yet wait for it to complete. The waiting happens after the next exim
2316 # command, triggered by $server_pid being non-zero. The server sends its output
2317 # to a different file. The variable $server_opts, if not empty, contains
2318 # options to disable IPv4 or IPv6 if necessary.
2319 # This works because "server" swallows its stdin before waiting for a connection.
2320
2321 if (/^server\s+(.*)$/)
2322   {
2323   $pidfile = "$parm_cwd/aux-var/server-daemon.pid";
2324   $cmd = "./bin/server $server_opts -oP $pidfile $1 >>test-stdout-server";
2325   print ">> $cmd\n" if ($debug);
2326   $server_pid = open SERVERCMD, "|$cmd" || tests_exit(-1, "Failed to run $cmd");
2327   SERVERCMD->autoflush(1);
2328   print ">> Server pid is $server_pid\n" if $debug;
2329   while (<SCRIPT>)
2330     {
2331     $lineno++;
2332     last if /^\*{4}\s*$/;
2333     print SERVERCMD;
2334     }
2335   print SERVERCMD "++++\n"; # Send end to server; can't send EOF yet
2336                             # because close() waits for the process.
2337
2338   # Interlock the server startup; otherwise the next
2339   # process may not find it there when it expects it.
2340   while (! stat("$pidfile") ) { select(undef, undef, undef, 0.3); }
2341   return 3;
2342   }
2343
2344
2345 # The "write" command is a way of creating files of specific sizes for
2346 # buffering tests, or containing specific data lines from within the script
2347 # (rather than hold lots of little files). The "catwrite" command does the
2348 # same, but it also copies the lines to test-stdout.
2349
2350 if (/^(cat)?write\s+(\S+)(?:\s+(.*))?\s*$/)
2351   {
2352   my($cat) = defined $1;
2353   @sizes = ();
2354   @sizes = split /\s+/, $3 if defined $3;
2355   open FILE, ">$2" || tests_exit(-1, "Failed to open \"$2\": $!");
2356
2357   if ($cat)
2358     {
2359     open CAT, ">>test-stdout" ||
2360       tests_exit(-1, "Failed to open test-stdout: $!");
2361     print CAT "==========\n";
2362     }
2363
2364   if (scalar @sizes > 0)
2365     {
2366     # Pre-data
2367
2368     while (<SCRIPT>)
2369       {
2370       $lineno++;
2371       last if /^\+{4}\s*$/;
2372       print FILE;
2373       print CAT if $cat;
2374       }
2375
2376     # Sized data
2377
2378     while (scalar @sizes > 0)
2379       {
2380       ($count,$len,$leadin) = (shift @sizes) =~ /(\d+)x(\d+)(?:=(.*))?/;
2381       $leadin = '' if !defined $leadin;
2382       $leadin =~ s/_/ /g;
2383       $len -= length($leadin) + 1;
2384       while ($count-- > 0)
2385         {
2386         print FILE $leadin, "a" x $len, "\n";
2387         print CAT $leadin, "a" x $len, "\n" if $cat;
2388         }
2389       }
2390     }
2391
2392   # Post data, or only data if no sized data
2393
2394   while (<SCRIPT>)
2395     {
2396     $lineno++;
2397     last if /^\*{4}\s*$/;
2398     print FILE;
2399     print CAT if $cat;
2400     }
2401   close FILE;
2402
2403   if ($cat)
2404     {
2405     print CAT "==========\n";
2406     close CAT;
2407     }
2408
2409   return 0;
2410   }
2411
2412
2413 ###################
2414 ###################
2415
2416 # From this point on, script commands are implemented by setting up a shell
2417 # command in the variable $cmd. Shared code to run this command and handle its
2418 # input and output follows.
2419
2420 # The "client", "client-gnutls", and "client-ssl" commands run a script-driven
2421 # program that plays the part of an email client. We also have the availability
2422 # of running Perl for doing one-off special things. Note that all these
2423 # commands expect stdin data to be supplied.
2424
2425 if (/^client/ || /^(sudo\s+)?perl\b/)
2426   {
2427   s"client"./bin/client";
2428   $cmd = "$_ >>test-stdout 2>>test-stderr";
2429   }
2430
2431 # For the "exim" command, replace the text "exim" with the path for the test
2432 # binary, plus -D options to pass over various parameters, and a -C option for
2433 # the testing configuration file. When running in the test harness, Exim does
2434 # not drop privilege when -C and -D options are present. To run the exim
2435 # command as root, we use sudo.
2436
2437 elsif (/^((?i:[A-Z\d_]+=\S+\s+)+)?(\d+)?\s*(sudo(?:\s+-u\s+(\w+))?\s+)?exim(_\S+)?\s+(.*)$/)
2438   {
2439   $args = $6;
2440   my($envset) = (defined $1)? $1      : '';
2441   my($sudo)   = (defined $3)? "sudo " . (defined $4 ? "-u $4 ":'')  : '';
2442   my($special)= (defined $5)? $5      : '';
2443   $wait_time  = (defined $2)? $2      : 0;
2444
2445   # Return 2 rather than 1 afterwards
2446
2447   $yield = 2;
2448
2449   # Update the test number
2450
2451   $$subtestref = $$subtestref + 1;
2452   printf("  Test %d       $cr", $$subtestref);
2453
2454   # Copy the configuration file, making the usual substitutions.
2455
2456   open (IN, "$parm_cwd/confs/$testno") ||
2457     tests_exit(-1, "Couldn't open $parm_cwd/confs/$testno: $!\n");
2458   open (OUT, ">test-config") ||
2459     tests_exit(-1, "Couldn't open test-config: $!\n");
2460   while (<IN>)
2461     {
2462     do_substitute($testno);
2463     print OUT;
2464     }
2465   close(IN);
2466   close(OUT);
2467
2468   # The string $msg1 in args substitutes the message id of the first
2469   # message on the queue, and so on. */
2470
2471   if ($args =~ /\$msg/)
2472     {
2473     my @listcmd  = ("$parm_cwd/eximdir/exim", '-bp',
2474                    "-DEXIM_PATH=$parm_cwd/eximdir/exim",
2475                    -C => "$parm_cwd/test-config");
2476     print ">> Getting queue list from:\n>>    @listcmd\n" if $debug;
2477     # We need the message ids sorted in ascending order.
2478     # Message id is: <timestamp>-<pid>-<fractional-time>. On some systems (*BSD) the
2479     # PIDs are randomized, so sorting just the whole PID doesn't work.
2480     # We do the Schartz' transformation here (sort on
2481     # <timestamp><fractional-time>). Thanks to Kirill Miazine
2482     my @msglist =
2483       map { $_->[1] }                                   # extract the values
2484       sort { $a->[0] cmp $b->[0] }                      # sort by key
2485       map { [join('.' => (split /-/, $_)[0,2]) => $_] } # key (timestamp.fractional-time) => value(message_id)
2486       map { /^\s*\d+[smhdw]\s+\S+\s+(\S+)/ } `@listcmd` or tests_exit(-1, "No output from `exim -bp` (@listcmd)\n");
2487
2488     # Done backwards just in case there are more than 9
2489
2490     for (my $i = @msglist; $i > 0; $i--) { $args =~ s/\$msg$i/$msglist[$i-1]/g; }
2491     if ( $args =~ /\$msg\d/ )
2492       {
2493       tests_exit(-1, "Not enough messages in spool, for test $testno line $lineno\n")
2494         unless $force_continue;
2495       }
2496     }
2497
2498   # If -d is specified in $optargs, remove it from $args; i.e. let
2499   # the command line for runtest override. Then run Exim.
2500
2501   $args =~ s/(?:^|\s)-d\S*// if $optargs =~ /(?:^|\s)-d/;
2502
2503   my $opt_valgrind = $valgrind ? "valgrind --leak-check=yes --suppressions=$parm_cwd/aux-fixed/valgrind.supp " : '';
2504
2505   $cmd = "$envset$sudo$opt_valgrind" .
2506          "$parm_cwd/eximdir/exim$special$optargs " .
2507          "-DEXIM_PATH=$parm_cwd/eximdir/exim$special " .
2508          "-C $parm_cwd/test-config $args " .
2509          ">>test-stdout 2>>test-stderr";
2510   # If the command is starting an Exim daemon, we run it in the same
2511   # way as the "server" command above, that is, we don't want to wait
2512   # for the process to finish. That happens when "killdaemon" is obeyed later
2513   # in the script. We also send the stderr output to test-stderr-server. The
2514   # daemon has its log files put in a different place too (by configuring with
2515   # log_file_path). This requires the  directory to be set up in advance.
2516   #
2517   # There are also times when we want to run a non-daemon version of Exim
2518   # (e.g. a queue runner) with the server configuration. In this case,
2519   # we also define -DNOTDAEMON.
2520
2521   if ($cmd =~ /\s-DSERVER=server\s/ && $cmd !~ /\s-DNOTDAEMON\s/)
2522     {
2523     if ($debug) { printf ">> daemon: $cmd\n"; }
2524     run_system("sudo mkdir spool/log 2>/dev/null");
2525     run_system("sudo chown $parm_eximuser:$parm_eximgroup spool/log");
2526
2527     # Before running the command, convert the -bd option into -bdf so that an
2528     # Exim daemon doesn't double fork. This means that when we wait close
2529     # DAEMONCMD, it waits for the correct process. Also, ensure that the pid
2530     # file is written to the spool directory, in case the Exim binary was
2531     # built with PID_FILE_PATH pointing somewhere else.
2532
2533     if ($cmd =~ /\s-oP\s/)
2534       {
2535       ($pidfile = $cmd) =~ s/^.*-oP ([^ ]+).*$/$1/;
2536       $cmd =~ s!\s-bd\s! -bdf !;
2537       }
2538     else
2539       {
2540       $pidfile = "$parm_cwd/spool/exim-daemon.pid";
2541       $cmd =~ s!\s-bd\s! -bdf -oP $pidfile !;
2542       }
2543     print ">> |${cmd}-server\n" if ($debug);
2544     open DAEMONCMD, "|${cmd}-server" || tests_exit(-1, "Failed to run $cmd");
2545     DAEMONCMD->autoflush(1);
2546     while (<SCRIPT>) { $lineno++; last if /^\*{4}\s*$/; }   # Ignore any input
2547
2548     # Interlock with daemon startup
2549     for (my $count = 0; ! stat("$pidfile") && $count < 30; $count++ )
2550       { select(undef, undef, undef, 0.3); }
2551     return 3;                                     # Don't wait
2552     }
2553   elsif ($cmd =~ /\s-DSERVER=wait:(\d+)\s/)
2554     {
2555
2556     # The port and the $dynamic_socket was already allocated while parsing the
2557     # script file, where -DSERVER=wait:PORT_DYNAMIC was encountered.
2558
2559     my $listen_port = $1;
2560     if ($debug) { printf ">> wait-mode daemon: $cmd\n"; }
2561     run_system("sudo mkdir spool/log 2>/dev/null");
2562     run_system("sudo chown $parm_eximuser:$parm_eximgroup spool/log");
2563
2564     my $pid = fork();
2565     if (not defined $pid) { die "** fork failed: $!\n" }
2566     if (not $pid) {
2567       close(STDIN);
2568       open(STDIN, '<&', $dynamic_socket) or die "** dup sock to stdin failed: $!\n";
2569       close($dynamic_socket);
2570       print "[$$]>> ${cmd}-server\n" if ($debug);
2571       exec "exec ${cmd}-server";
2572       die "Can't exec ${cmd}-server: $!\n";
2573     }
2574     while (<SCRIPT>) { $lineno++; last if /^\*{4}\s*$/; }   # Ignore any input
2575     select(undef, undef, undef, 0.3);             # Let the daemon get going
2576     return (3, { exim_pid => $pid });             # Don't wait
2577     }
2578   }
2579
2580 # The "background" command is run but not waited-for, like exim -DSERVER=server.
2581 # One script line is read and fork-exec'd.  The PID is stored for a later
2582 # killdaemon.
2583
2584 elsif (/^background$/)
2585   {
2586   my $line;
2587 #  $pidfile = "$parm_cwd/aux-var/server-daemon.pid";
2588
2589   $_ = <SCRIPT>; $lineno++;
2590   chomp;
2591   do_substitute($testno);
2592   $line = $_;
2593   if ($debug) { printf ">> daemon: $line >>test-stdout 2>>test-stderr\n"; }
2594
2595   my $pid = fork();
2596   if (not defined $pid) { die "** fork failed: $!\n" }
2597   if (not $pid) {
2598     print "[$$]>> ${line}\n" if ($debug);
2599     close(STDIN);
2600     open(STDIN, "<", "test-stdout");
2601     close(STDOUT);
2602     open(STDOUT, ">>", "test-stdout");
2603     close(STDERR);
2604     open(STDERR, ">>", "test-stderr-server");
2605     exec "exec ${line}";
2606     exit(1);
2607   }
2608
2609 #  open(my $fh, ">", $pidfile) ||
2610 #      tests_exit(-1, "Failed to open $pidfile: $!");
2611 #  printf($fh, "%d\n", $pid);
2612 #  close($fh);
2613
2614   while (<SCRIPT>) { $lineno++; last if /^\*{4}\s*$/; }   # Ignore any input
2615   select(undef, undef, undef, 0.3);             # Let the daemon get going
2616   return (3, { exim_pid => $pid });             # Don't wait
2617   }
2618
2619
2620
2621 # Unknown command
2622
2623 else { tests_exit(-1, "Command unrecognized in line $lineno: $_"); }
2624
2625
2626 # Run the command, with stdin connected to a pipe, and write the stdin data
2627 # to it, with appropriate substitutions. If a line ends with \NONL\, chop off
2628 # the terminating newline (and the \NONL\). If the command contains
2629 # -DSERVER=server add "-server" to the command, where it will adjoin the name
2630 # for the stderr file. See comment above about the use of -DSERVER.
2631
2632 $stderrsuffix = ($cmd =~ /\s-DSERVER=server\s/)? "-server" : '';
2633 print ">> |${cmd}${stderrsuffix}\n" if ($debug);
2634 open CMD, "|${cmd}${stderrsuffix}" || tests_exit(1, "Failed to run $cmd");
2635
2636 CMD->autoflush(1);
2637 while (<SCRIPT>)
2638   {
2639   $lineno++;
2640   last if /^\*{4}\s*$/;
2641   do_substitute($testno);
2642   if (/^(.*)\\NONL\\\s*$/) { print CMD $1; } else { print CMD; }
2643   }
2644
2645 # For timeout tests, wait before closing the pipe; we expect a
2646 # SIGPIPE error in this case.
2647
2648 if ($wait_time > 0)
2649   {
2650   printf("  Test %d sleep $wait_time ", $$subtestref);
2651   while ($wait_time-- > 0)
2652     {
2653     print ".";
2654     sleep(1);
2655     }
2656   printf("\r  Test %d                                       $cr", $$subtestref);
2657   }
2658
2659 $sigpipehappened = 0;
2660 close CMD;                # Waits for command to finish
2661 return $yield;            # Ran command and waited
2662 }
2663
2664
2665
2666
2667 ###############################################################################
2668 ###############################################################################
2669
2670 # Here begins the Main Program ...
2671
2672 ###############################################################################
2673 ###############################################################################
2674
2675
2676 autoflush STDOUT 1;
2677 print "Exim tester $testversion\n";
2678
2679 # extend the PATH with .../sbin
2680 # we map all (.../bin) to (.../sbin:.../bin)
2681 $ENV{PATH} = do {
2682   my %seen = map { $_, 1 } split /:/, $ENV{PATH};
2683   join ':' => map { m{(.*)/bin$}
2684                 ? ( $seen{"$1/sbin"} ? () : ("$1/sbin"), $_)
2685                 : ($_) }
2686       split /:/, $ENV{PATH};
2687 };
2688
2689 ##################################################
2690 #      Some tests check created file modes       #
2691 ##################################################
2692
2693 umask 022;
2694
2695
2696 ##################################################
2697 #       Check for the "less" command             #
2698 ##################################################
2699
2700 $more = 'more' if system('which less >/dev/null 2>&1') != 0;
2701
2702
2703
2704 ##################################################
2705 #      See if an Exim binary has been given      #
2706 ##################################################
2707
2708 # If the first character of the first argument is '/', the argument is taken
2709 # as the path to the binary. If the first argument does not start with a
2710 # '/' but exists in the file system, it's assumed to be the Exim binary.
2711
2712
2713 ##################################################
2714 # Sort out options and which tests are to be run #
2715 ##################################################
2716
2717 # There are a few possible options for the test script itself; after these, any
2718 # options are passed on to Exim calls within the tests. Typically, this is used
2719 # to turn on Exim debugging while setting up a test.
2720
2721 Getopt::Long::Configure qw(no_getopt_compat);
2722 GetOptions(
2723     'debug'    => sub { $debug          = 1; $cr   = "\n" },
2724     'diff'     => sub { $cf             = 'diff -u' },
2725     'continue' => sub { $force_continue = 1; $more = 'cat' },
2726     'update'   => \$force_update,
2727     'ipv4!'    => \$have_ipv4,
2728     'ipv6!'    => \$have_ipv6,
2729     'keep'     => \$save_output,
2730     'slow'     => \$slow,
2731     'valgrind' => \$valgrind,
2732     'range=s{2}'       => \my @range_wanted,
2733     'test=i@'          => \my @tests_wanted,
2734     'flavor|flavour=s' => \$flavour,
2735     'help'             => sub { pod2usage(-exit => 0) },
2736     'man'              => sub {
2737         pod2usage(
2738             -exit      => 0,
2739             -verbose   => 2,
2740             -noperldoc => system('perldoc -V 2>/dev/null 1>&2')
2741         );
2742     },
2743 ) or pod2usage;
2744
2745 ($parm_exim, @ARGV) = Exim::Runtest::exim_binary(@ARGV);
2746 print "Exim binary is `$parm_exim'\n" if defined $parm_exim;
2747
2748
2749 my @wanted = sort numerically uniq
2750   @tests_wanted ? @tests_wanted : (),
2751   @range_wanted ? $range_wanted[0] .. $range_wanted[1] : (),
2752   @ARGV ? @ARGV == 1 ? $ARGV[0] :
2753           $ARGV[1] eq '+' ? $ARGV[0]..($ARGV[0] >= 9000 ? TEST_SPECIAL_TOP : TEST_TOP) :
2754           0+$ARGV[0]..0+$ARGV[1]    # add 0 to cope with test numbers starting with zero
2755         : ();
2756 @wanted = 1..TEST_TOP if not @wanted;
2757
2758 ##################################################
2759 #        Check for sudo access to root           #
2760 ##################################################
2761
2762 print "You need to have sudo access to root to run these tests. Checking ...\n";
2763 if (system('sudo true >/dev/null') != 0)
2764   {
2765   die "** Test for sudo failed: testing abandoned.\n";
2766   }
2767 else
2768   {
2769   print "Test for sudo OK\n";
2770   }
2771
2772
2773
2774
2775 ##################################################
2776 #      Make the command's directory current      #
2777 ##################################################
2778
2779 # After doing so, we find its absolute path name.
2780
2781 $cwd = $0;
2782 $cwd = '.' if ($cwd !~ s|/[^/]+$||);
2783 chdir($cwd) || die "** Failed to chdir to \"$cwd\": $!\n";
2784 $parm_cwd = Cwd::getcwd();
2785
2786
2787 ##################################################
2788 #     Search for an Exim binary to test          #
2789 ##################################################
2790
2791 # If an Exim binary hasn't been provided, try to find one. We can handle the
2792 # case where exim-testsuite is installed alongside Exim source directories. For
2793 # PH's private convenience, if there's a directory just called "exim4", that
2794 # takes precedence; otherwise exim-snapshot takes precedence over any numbered
2795 # releases.
2796
2797 # If $parm_exim is still empty, ask the caller
2798
2799 if (not $parm_exim)
2800   {
2801   print "** Did not find an Exim binary to test\n";
2802   for ($i = 0; $i < 5; $i++)
2803     {
2804     my($trybin);
2805     print "** Enter pathname for Exim binary: ";
2806     chomp($trybin = <STDIN>);
2807     if (-e $trybin)
2808       {
2809       $parm_exim = $trybin;
2810       last;
2811       }
2812     else
2813       {
2814       print "** $trybin does not exist\n";
2815       }
2816     }
2817   die "** Too many tries\n" if $parm_exim eq '';
2818   }
2819
2820
2821
2822 ##################################################
2823 #          Find what is in the binary            #
2824 ##################################################
2825
2826 # deal with TRUSTED_CONFIG_LIST restrictions
2827 unlink("$parm_cwd/test-config") if -e "$parm_cwd/test-config";
2828 open (IN, "$parm_cwd/confs/0000") ||
2829   tests_exit(-1, "Couldn't open $parm_cwd/confs/0000: $!\n");
2830 open (OUT, ">test-config") ||
2831   tests_exit(-1, "Couldn't open test-config: $!\n");
2832 while (<IN>) { print OUT; }
2833 close(IN);
2834 close(OUT);
2835
2836 print("Probing with config file: $parm_cwd/test-config\n");
2837
2838 my $eximinfo = "$parm_exim -d -C $parm_cwd/test-config -DDIR=$parm_cwd -bP exim_user exim_group";
2839 chomp(my @eximinfo = `$eximinfo 2>&1`);
2840 die "$0: Can't run $eximinfo\n" if $? == -1;
2841
2842 warn 'Got ' . $?>>8 . " from $eximinfo\n" if $?;
2843 foreach (@eximinfo)
2844   {
2845   if (my ($version) = /^Exim version (\S+)/) {
2846     my $git = `git describe --dirty=-XX --match 'exim-4*'`;
2847     if (defined $git and $? == 0) {
2848       chomp $git;
2849       $git =~ s/^exim-//i;
2850       $git =~ s/.*-\Kg([[:xdigit:]]+(?:-XX)?)/$1/;
2851       print <<___
2852
2853 *** Version mismatch
2854 *** Exim binary: $version
2855 *** Git        : $git
2856
2857 ___
2858         if not $version eq $git;
2859     }
2860   }
2861   $parm_eximuser = $1 if /^exim_user = (.*)$/;
2862   $parm_eximgroup = $1 if /^exim_group = (.*)$/;
2863   $parm_trusted_config_list = $1 if /^TRUSTED_CONFIG_LIST:.*?"(.*?)"$/;
2864   ($parm_configure_owner, $parm_configure_group) = ($1, $2)
2865         if /^Configure owner:\s*(\d+):(\d+)/;
2866   print if /wrong owner/;
2867   }
2868
2869 if (not defined $parm_eximuser) {
2870   die <<XXX, map { "|$_\n" } @eximinfo;
2871 Unable to extract exim_user from binary.
2872 Check if Exim refused to run; if so, consider:
2873   TRUSTED_CONFIG_LIST ALT_CONFIG_PREFIX WHITELIST_D_MACROS
2874 If debug permission denied, are you in the exim group?
2875 Failing to get information from binary.
2876 Output from $eximinfo:
2877 XXX
2878
2879 }
2880
2881 if ($parm_eximuser =~ /^\d+$/) { $parm_exim_uid = $parm_eximuser; }
2882 else { $parm_exim_uid = getpwnam($parm_eximuser); }
2883
2884 if (defined $parm_eximgroup)
2885   {
2886   if ($parm_eximgroup =~ /^\d+$/) { $parm_exim_gid = $parm_eximgroup; }
2887     else { $parm_exim_gid = getgrnam($parm_eximgroup); }
2888   }
2889
2890 # check the permissions on the TRUSTED_CONFIG_LIST
2891 if (defined $parm_trusted_config_list)
2892   {
2893   die "TRUSTED_CONFIG_LIST: $parm_trusted_config_list: $!\n"
2894     if not -f $parm_trusted_config_list;
2895
2896   die "TRUSTED_CONFIG_LIST $parm_trusted_config_list must not be world writable!\n"
2897     if 02 & (stat _)[2];
2898
2899   die sprintf "TRUSTED_CONFIG_LIST: $parm_trusted_config_list %d is group writable, but not owned by group '%s' or '%s'.\n",
2900   (stat _)[1],
2901     scalar(getgrgid 0), scalar(getgrgid $>)
2902     if (020 & (stat _)[2]) and not ((stat _)[5] == $> or (stat _)[5] == 0);
2903
2904   die sprintf "TRUSTED_CONFIG_LIST: $parm_trusted_config_list is not owned by user '%s' or '%s'.\n",
2905   scalar(getpwuid 0), scalar(getpwuid $>)
2906      if (not (-o _ or (stat _)[4] == 0));
2907
2908   open(TCL, $parm_trusted_config_list) or die "Can't open $parm_trusted_config_list: $!\n";
2909   my $test_config = getcwd() . '/test-config';
2910   die "Can't find '$test_config' in TRUSTED_CONFIG_LIST $parm_trusted_config_list."
2911   if not grep { /^\Q$test_config\E$/ } <TCL>;
2912   }
2913 else
2914   {
2915   die "Unable to check the TRUSTED_CONFIG_LIST, seems to be empty?\n";
2916   }
2917
2918 die "CONFIGURE_OWNER ($parm_configure_owner) does not match the user invoking $0 ($>)\n"
2919         if $parm_configure_owner != $>;
2920
2921 die "CONFIGURE_GROUP ($parm_configure_group) does not match the group invoking $0 ($))\n"
2922         if 0020 & (stat "$parm_cwd/test-config")[2]
2923         and $parm_configure_group != $);
2924
2925 die "aux-fixed file is group-writeable; best to strip them all, recursively\n"
2926         if 0020 & (stat "aux-fixed/0037.f-1")[2];
2927
2928
2929 open(EXIMINFO, "$parm_exim -d-all+transport -bV -C $parm_cwd/test-config -DDIR=$parm_cwd |") ||
2930   die "** Cannot run $parm_exim: $!\n";
2931
2932 print "-" x 78, "\n";
2933
2934 while (<EXIMINFO>)
2935   {
2936   my(@temp);
2937
2938   if (/^(Exim|Library) version/) { print; }
2939   if (/Runtime: /) {print; }
2940
2941   elsif (/^Size of off_t: (\d+)/)
2942     {
2943     print;
2944     $have_largefiles = 1 if $1 > 4;
2945     die "** Size of off_t > 32 which seems improbable, not running tests\n"
2946         if ($1 > 32);
2947     }
2948
2949   elsif (/^Support for: (.*)/)
2950     {
2951     print;
2952     @temp = split /(\s+)/, $1;
2953     push(@temp, ' ');
2954     %parm_support = @temp;
2955     }
2956
2957   elsif (/^Lookups \(built-in\): (.*)/)
2958     {
2959     print;
2960     @temp = split /(\s+)/, $1;
2961     push(@temp, ' ');
2962     %parm_lookups = @temp;
2963     }
2964
2965   elsif (/^Authenticators: (.*)/)
2966     {
2967     print;
2968     @temp = split /(\s+)/, $1;
2969     push(@temp, ' ');
2970     %parm_authenticators = @temp;
2971     }
2972
2973   elsif (/^Routers: (.*)/)
2974     {
2975     print;
2976     @temp = split /(\s+)/, $1;
2977     push(@temp, ' ');
2978     %parm_routers = @temp;
2979     }
2980
2981   # Some transports have options, e.g. appendfile/maildir. For those, ensure
2982   # that the basic transport name is set, and then the name with each of the
2983   # options.
2984
2985   elsif (/^Transports: (.*)/)
2986     {
2987     print;
2988     @temp = split /(\s+)/, $1;
2989     my($i,$k);
2990     push(@temp, ' ');
2991     %parm_transports = @temp;
2992     foreach $k (keys %parm_transports)
2993       {
2994       if ($k =~ "/")
2995         {
2996         @temp = split /\//, $k;
2997         $parm_transports{$temp[0]} = " ";
2998         for ($i = 1; $i < @temp; $i++)
2999           { $parm_transports{"$temp[0]/$temp[$i]"} = " "; }
3000         }
3001       }
3002     }
3003
3004   elsif (/^Malware: (.*)/)
3005     {
3006     print;
3007     @temp = split /(\s+)/, $1;
3008     push(@temp, ' ');
3009     %parm_malware = @temp;
3010     }
3011
3012   }
3013 close(EXIMINFO);
3014 print "-" x 78, "\n";
3015
3016 unlink("$parm_cwd/test-config");
3017
3018 ##################################################
3019 #    Check for SpamAssassin and ClamAV           #
3020 ##################################################
3021
3022 # These are crude tests. If they aren't good enough, we'll have to improve
3023 # them, for example by actually passing a message through spamc or clamscan.
3024
3025 if (defined $parm_support{Content_Scanning})
3026   {
3027   my $sock = new FileHandle;
3028
3029   if (system("spamc -h 2>/dev/null >/dev/null") == 0)
3030     {
3031     print "The spamc command works:\n";
3032
3033     # This test for an active SpamAssassin is courtesy of John Jetmore.
3034     # The tests are hard coded to localhost:783, so no point in making
3035     # this test flexible like the clamav test until the test scripts are
3036     # changed.  spamd doesn't have the nice PING/PONG protocol that
3037     # clamd does, but it does respond to errors in an informative manner,
3038     # so use that.
3039
3040     my($sint,$sport) = ('127.0.0.1',783);
3041     eval
3042       {
3043       my $sin = sockaddr_in($sport, inet_aton($sint))
3044           or die "** Failed packing $sint:$sport\n";
3045       socket($sock, PF_INET, SOCK_STREAM, getprotobyname('tcp'))
3046           or die "** Unable to open socket $sint:$sport\n";
3047
3048       local $SIG{ALRM} =
3049           sub { die "** Timeout while connecting to socket $sint:$sport\n"; };
3050       alarm(5);
3051       connect($sock, $sin)
3052           or die "** Unable to connect to socket $sint:$sport\n";
3053       alarm(0);
3054
3055       select((select($sock), $| = 1)[0]);
3056       print $sock "bad command\r\n";
3057
3058       $SIG{ALRM} =
3059           sub { die "** Timeout while reading from socket $sint:$sport\n"; };
3060       alarm(10);
3061       my $res = <$sock>;
3062       alarm(0);
3063
3064       $res =~ m|^SPAMD/|
3065           or die "** Did not get SPAMD from socket $sint:$sport. "
3066                 ."It said: $res\n";
3067       };
3068     alarm(0);
3069     if($@)
3070       {
3071       print "  $@";
3072       print "  Assume SpamAssassin (spamd) is not running\n";
3073       }
3074     else
3075       {
3076       $parm_running{SpamAssassin} = ' ';
3077       print "  SpamAssassin (spamd) seems to be running\n";
3078       }
3079     }
3080   else
3081     {
3082     print "The spamc command failed: assume SpamAssassin (spamd) is not running\n";
3083     }
3084
3085   # For ClamAV, we need to find the clamd socket for use in the Exim
3086   # configuration. Search for the clamd configuration file.
3087
3088   if (system("clamscan -h 2>/dev/null >/dev/null") == 0)
3089     {
3090     my($f, $clamconf, $test_prefix);
3091
3092     print "The clamscan command works";
3093
3094     $test_prefix = $ENV{EXIM_TEST_PREFIX};
3095     $test_prefix = '' if !defined $test_prefix;
3096
3097     foreach $f ("$test_prefix/etc/clamd.conf",
3098                 "$test_prefix/usr/local/etc/clamd.conf",
3099                 "$test_prefix/etc/clamav/clamd.conf", '')
3100       {
3101       if (-e $f)
3102         {
3103         $clamconf = $f;
3104         last;
3105         }
3106       }
3107
3108     # Read the ClamAV configuration file and find the socket interface.
3109
3110     if ($clamconf ne '')
3111       {
3112       my $socket_domain;
3113       open(IN, "$clamconf") || die "\n** Unable to open $clamconf: $!\n";
3114       while (<IN>)
3115         {
3116         if (/^LocalSocket\s+(.*)/)
3117           {
3118           $parm_clamsocket = $1;
3119           $socket_domain = AF_UNIX;
3120           last;
3121           }
3122         if (/^TCPSocket\s+(\d+)/)
3123           {
3124           if (defined $parm_clamsocket)
3125             {
3126             $parm_clamsocket .= " $1";
3127             $socket_domain = AF_INET;
3128             last;
3129             }
3130           else
3131             {
3132             $parm_clamsocket = " $1";
3133             }
3134           }
3135         elsif (/^TCPAddr\s+(\S+)/)
3136           {
3137           if (defined $parm_clamsocket)
3138             {
3139             $parm_clamsocket = $1 . $parm_clamsocket;
3140             $socket_domain = AF_INET;
3141             last;
3142             }
3143           else
3144             {
3145             $parm_clamsocket = $1;
3146             }
3147           }
3148         }
3149       close(IN);
3150
3151       if (defined $socket_domain)
3152         {
3153         print ":\n  The clamd socket is $parm_clamsocket\n";
3154         # This test for an active ClamAV is courtesy of Daniel Tiefnig.
3155         eval
3156           {
3157           my $socket;
3158           if ($socket_domain == AF_UNIX)
3159             {
3160             $socket = sockaddr_un($parm_clamsocket) or die "** Failed packing '$parm_clamsocket'\n";
3161             }
3162           elsif ($socket_domain == AF_INET)
3163             {
3164             my ($ca_host, $ca_port) = split(/\s+/,$parm_clamsocket);
3165             my $ca_hostent = gethostbyname($ca_host) or die "** Failed to get raw address for host '$ca_host'\n";
3166             $socket = sockaddr_in($ca_port, $ca_hostent) or die "** Failed packing '$parm_clamsocket'\n";
3167             }
3168           else
3169             {
3170             die "** Unknown socket domain '$socket_domain' (should not happen)\n";
3171             }
3172           socket($sock, $socket_domain, SOCK_STREAM, 0) or die "** Unable to open socket '$parm_clamsocket'\n";
3173           local $SIG{ALRM} = sub { die "** Timeout while connecting to socket '$parm_clamsocket'\n"; };
3174           alarm(5);
3175           connect($sock, $socket) or die "** Unable to connect to socket '$parm_clamsocket'\n";
3176           alarm(0);
3177
3178           my $ofh = select $sock; $| = 1; select $ofh;
3179           print $sock "PING\n";
3180
3181           $SIG{ALRM} = sub { die "** Timeout while reading from socket '$parm_clamsocket'\n"; };
3182           alarm(10);
3183           my $res = <$sock>;
3184           alarm(0);
3185
3186           $res =~ /PONG/ or die "** Did not get PONG from socket '$parm_clamsocket'. It said: $res\n";
3187           };
3188         alarm(0);
3189
3190         if($@)
3191           {
3192           print "  $@";
3193           print "  Assume ClamAV is not running\n";
3194           }
3195         else
3196           {
3197           $parm_running{ClamAV} = ' ';
3198           print "  ClamAV seems to be running\n";
3199           }
3200         }
3201       else
3202         {
3203         print ", but the socket for clamd could not be determined\n";
3204         print "Assume ClamAV is not running\n";
3205         }
3206       }
3207
3208     else
3209       {
3210       print ", but I can't find a configuration for clamd\n";
3211       print "Assume ClamAV is not running\n";
3212       }
3213     }
3214   }
3215
3216
3217 ##################################################
3218 #       Check for redis                          #
3219 ##################################################
3220 if (defined $parm_lookups{redis})
3221   {
3222   if (system("redis-server -v 2>/dev/null >/dev/null") == 0)
3223     {
3224     print "The redis-server command works\n";
3225     $parm_running{redis} = ' ';
3226     }
3227   else
3228     {
3229     print "The redis-server command failed: assume Redis not installed\n";
3230     }
3231   }
3232
3233 ##################################################
3234 #         Test for the basic requirements        #
3235 ##################################################
3236
3237 # This test suite assumes that Exim has been built with at least the "usual"
3238 # set of routers, transports, and lookups. Ensure that this is so.
3239
3240 $missing = '';
3241
3242 $missing .= "     Lookup: lsearch\n" if (!defined $parm_lookups{lsearch});
3243
3244 $missing .= "     Router: accept\n" if (!defined $parm_routers{accept});
3245 $missing .= "     Router: dnslookup\n" if (!defined $parm_routers{dnslookup});
3246 $missing .= "     Router: manualroute\n" if (!defined $parm_routers{manualroute});
3247 $missing .= "     Router: redirect\n" if (!defined $parm_routers{redirect});
3248
3249 $missing .= "     Transport: appendfile\n" if (!defined $parm_transports{appendfile});
3250 $missing .= "     Transport: autoreply\n" if (!defined $parm_transports{autoreply});
3251 $missing .= "     Transport: pipe\n" if (!defined $parm_transports{pipe});
3252 $missing .= "     Transport: smtp\n" if (!defined $parm_transports{smtp});
3253
3254 if ($missing ne '')
3255   {
3256   print "\n";
3257   print "** Many features can be included or excluded from Exim binaries.\n";
3258   print "** This test suite requires that Exim is built to contain a certain\n";
3259   print "** set of basic facilities. It seems that some of these are missing\n";
3260   print "** from the binary that is under test, so the test cannot proceed.\n";
3261   print "** The missing facilities are:\n";
3262   print "$missing";
3263   die "** Test script abandoned\n";
3264   }
3265
3266
3267 ##################################################
3268 #      Check for the auxiliary programs          #
3269 ##################################################
3270
3271 # These are always required:
3272
3273 for $prog ("cf", "checkaccess", "client", "client-ssl", "client-gnutls",
3274            "fakens", "iefbr14", "server")
3275   {
3276   next if ($prog eq "client-ssl" && !defined $parm_support{OpenSSL});
3277   next if ($prog eq "client-gnutls" && !defined $parm_support{GnuTLS});
3278   if (!-e "bin/$prog")
3279     {
3280     print "\n";
3281     print "** bin/$prog does not exist. Have you run ./configure and make?\n";
3282     die "** Test script abandoned\n";
3283     }
3284   }
3285
3286 # If the "loaded" binary is missing, we cut out tests for ${dlfunc. It isn't
3287 # compiled on systems where we don't know how to. However, if Exim does not
3288 # have that functionality compiled, we needn't bother.
3289
3290 $dlfunc_deleted = 0;
3291 if (defined $parm_support{Expand_dlfunc} && !-e 'bin/loaded')
3292   {
3293   delete $parm_support{Expand_dlfunc};
3294   $dlfunc_deleted = 1;
3295   }
3296
3297
3298 ##################################################
3299 #          Find environmental details            #
3300 ##################################################
3301
3302 # Find the caller of this program.
3303
3304 ($parm_caller,$pwpw,$parm_caller_uid,$parm_caller_gid,$pwquota,$pwcomm,
3305  $parm_caller_gecos, $parm_caller_home) = getpwuid($>);
3306
3307 $pwpw = $pwpw;       # Kill Perl warnings
3308 $pwquota = $pwquota;
3309 $pwcomm = $pwcomm;
3310
3311 $parm_caller_group = getgrgid($parm_caller_gid);
3312
3313 print "Program caller is $parm_caller ($parm_caller_uid), whose group is $parm_caller_group ($parm_caller_gid)\n";
3314 print "Home directory is $parm_caller_home\n";
3315
3316 unless (defined $parm_eximgroup)
3317   {
3318   print "Unable to derive \$parm_eximgroup.\n";
3319   die "** ABANDONING.\n";
3320   }
3321
3322 if ($parm_caller_home eq $parm_cwd)
3323   {
3324   print "will confuse working dir with homedir; change homedir\n";
3325   die "** ABANDONING.\n";
3326   }
3327
3328 print "You need to be in the Exim group to run these tests. Checking ...";
3329
3330 if (`groups` =~ /\b\Q$parm_eximgroup\E\b/)
3331   {
3332   print " OK\n";
3333   }
3334 else
3335   {
3336   print "\nOh dear, you are not in the Exim group.\n";
3337   die "** Testing abandoned.\n";
3338   }
3339
3340 # Find this host's IP addresses - there may be many, of course, but we keep
3341 # one of each type (IPv4 and IPv6).
3342
3343 open(IFCONFIG, '-|', (grep { -x "$_/ip" } split /:/, $ENV{PATH}) ? 'ip address' : 'ifconfig -a')
3344   or die "** Cannot run 'ip address' or 'ifconfig -a'\n";
3345 while (not ($parm_ipv4 and $parm_ipv6) and defined($_ = <IFCONFIG>))
3346   {
3347   if (not $parm_ipv4 and /^\s*inet(?:\saddr)?:?\s?(\d+\.\d+\.\d+\.\d+)(?:\/\d+)?\s/i)
3348     {
3349     next if $1 =~ /^(?:127|10)\./;
3350     $parm_ipv4 = $1;
3351     }
3352
3353   if (not $parm_ipv6 and /^\s*inet6(?:\saddr)?:?\s?([abcdef\d:]+)(?:%[^ \/]+)?(?:\/\d+)?/i)
3354     {
3355     next if $1 eq '::1' or $1 =~ /^fe80/i;
3356     $parm_ipv6 = $1;
3357     }
3358   }
3359 close(IFCONFIG);
3360
3361 # Use private IP addresses if there are no public ones.
3362
3363 # If either type of IP address is missing, we need to set the value to
3364 # something other than empty, because that wrecks the substitutions. The value
3365 # is reflected, so use a meaningful string. Set appropriate options for the
3366 # "server" command. In practice, however, many tests assume 127.0.0.1 is
3367 # available, so things will go wrong if there is no IPv4 address. The lack
3368 # of IPV4 or IPv6 can be simulated by command options, which force $have_ipv4
3369 # and $have_ipv6 false.
3370
3371 if (not $parm_ipv4)
3372   {
3373   $have_ipv4 = 0;
3374   $parm_ipv4 = "<no IPv4 address found>";
3375   $server_opts .= " -noipv4";
3376   }
3377 elsif ($have_ipv4 == 0)
3378   {
3379   $parm_ipv4 = "<IPv4 testing disabled>";
3380   $server_opts .= " -noipv4";
3381   }
3382 else
3383   {
3384   $parm_running{IPv4} = " ";
3385   }
3386
3387 if (not $parm_ipv6)
3388   {
3389   $have_ipv6 = 0;
3390   $parm_ipv6 = "<no IPv6 address found>";
3391   $server_opts .= " -noipv6";
3392   delete($parm_support{IPv6});
3393   }
3394 elsif ($have_ipv6 == 0)
3395   {
3396   $parm_ipv6 = "<IPv6 testing disabled>";
3397   $server_opts .= " -noipv6";
3398   delete($parm_support{IPv6});
3399   }
3400 elsif (!defined $parm_support{IPv6})
3401   {
3402   $have_ipv6 = 0;
3403   $parm_ipv6 = "<no IPv6 support in Exim binary>";
3404   $server_opts .= " -noipv6";
3405   }
3406 else
3407   {
3408   $parm_running{IPv6} = " ";
3409   }
3410
3411 print "IPv4 address is $parm_ipv4\n";
3412 print "IPv6 address is $parm_ipv6\n";
3413 $parm_ipv6 =~ /^[^%\/]*/;
3414
3415 # For munging test output, we need the reversed IP addresses.
3416
3417 $parm_ipv4r = ($parm_ipv4 !~ /^\d/)? '' :
3418   join(".", reverse(split /\./, $parm_ipv4));
3419
3420 $parm_ipv6r = $parm_ipv6;             # Appropriate if not in use
3421 if ($parm_ipv6 =~ /^[\da-f]/)
3422   {
3423   my(@comps) = split /:/, $parm_ipv6;
3424   my(@nibbles);
3425   foreach $comp (@comps)
3426     {
3427     push @nibbles, sprintf("%lx", hex($comp) >> 8);
3428     push @nibbles, sprintf("%lx", hex($comp) & 0xff);
3429     }
3430   $parm_ipv6r = join(".", reverse(@nibbles));
3431   }
3432
3433 # Find the host name, fully qualified.
3434
3435 chomp($temp = `hostname`);
3436 die "'hostname' didn't return anything\n" unless defined $temp and length $temp;
3437 if ($temp =~ /\./)
3438   {
3439   $parm_hostname = $temp;
3440   }
3441 else
3442   {
3443   $parm_hostname = (gethostbyname($temp))[0];
3444   $parm_hostname = "no.host.name.found" unless defined $parm_hostname and length $parm_hostname;
3445   }
3446 print "Hostname is $parm_hostname\n";
3447
3448 if ($parm_hostname !~ /\./)
3449   {
3450   print "\n*** Host name is not fully qualified: this may cause problems ***\n\n";
3451   }
3452
3453 if ($parm_hostname =~ /[[:upper:]]/)
3454   {
3455   print "\n*** Host name has upper case characters: this may cause problems ***\n\n";
3456   }
3457
3458 if ($parm_hostname =~ /\.example\.com$/)
3459   {
3460   die "\n*** Host name ends in .example.com; this conflicts with the testsuite use of that domain.\n"
3461         . "    Please change the host's name (or comment out this check, and fail several testcases)\n";
3462   }
3463
3464
3465
3466 ##################################################
3467 #     Create a testing version of Exim           #
3468 ##################################################
3469
3470 # We want to be able to run Exim with a variety of configurations. Normally,
3471 # the use of -C to change configuration causes Exim to give up its root
3472 # privilege (unless the caller is exim or root). For these tests, we do not
3473 # want this to happen. Also, we want Exim to know that it is running in its
3474 # test harness.
3475
3476 # We achieve this by copying the binary and patching it as we go. The new
3477 # binary knows it is a testing copy, and it allows -C and -D without loss of
3478 # privilege. Clearly, this file is dangerous to have lying around on systems
3479 # where there are general users with login accounts. To protect against this,
3480 # we put the new binary in a special directory that is accessible only to the
3481 # caller of this script, who is known to have sudo root privilege from the test
3482 # that was done above. Furthermore, we ensure that the binary is deleted at the
3483 # end of the test. First ensure the directory exists.
3484
3485 if (-d "eximdir")
3486   { unlink "eximdir/exim"; }     # Just in case
3487 else
3488   {
3489   mkdir("eximdir", 0710) || die "** Unable to mkdir $parm_cwd/eximdir: $!\n";
3490   system("sudo chgrp $parm_eximgroup eximdir");
3491   }
3492
3493 # The construction of the patched binary must be done as root, so we use
3494 # a separate script. As well as indicating that this is a test-harness binary,
3495 # the version number is patched to "x.yz" so that its length is always the
3496 # same. Otherwise, when it appears in Received: headers, it affects the length
3497 # of the message, which breaks certain comparisons.
3498
3499 die "** Unable to make patched exim: $!\n"
3500   if (system("sudo ./patchexim $parm_exim") != 0);
3501
3502 # From this point on, exits from the program must go via the subroutine
3503 # tests_exit(), so that suitable cleaning up can be done when required.
3504 # Arrange to catch interrupting signals, to assist with this.
3505
3506 $SIG{INT} = \&inthandler;
3507 $SIG{PIPE} = \&pipehandler;
3508
3509 # For some tests, we need another copy of the binary that is setuid exim rather
3510 # than root.
3511
3512 system("sudo cp eximdir/exim eximdir/exim_exim;" .
3513        "sudo chown $parm_eximuser eximdir/exim_exim;" .
3514        "sudo chgrp $parm_eximgroup eximdir/exim_exim;" .
3515        "sudo chmod 06755 eximdir/exim_exim");
3516
3517 ##################################################
3518 #     Make copies of utilities we might need     #
3519 ##################################################
3520
3521 # Certain of the tests make use of some of Exim's utilities. We do not need
3522 # to be root to copy these.
3523
3524 ($parm_exim_dir) = $parm_exim =~ m?^(.*)/exim?;
3525
3526 $dbm_build_deleted = 0;
3527 if (defined $parm_lookups{dbm} &&
3528     system("cp $parm_exim_dir/exim_dbmbuild eximdir") != 0)
3529   {
3530   delete $parm_lookups{dbm};
3531   $dbm_build_deleted = 1;
3532   }
3533
3534 if (system("cp $parm_exim_dir/exim_dumpdb eximdir") != 0)
3535   {
3536   tests_exit(-1, "Failed to make a copy of exim_dumpdb: $!");
3537   }
3538
3539 if (system("cp $parm_exim_dir/exim_lock eximdir") != 0)
3540   {
3541   tests_exit(-1, "Failed to make a copy of exim_lock: $!");
3542   }
3543
3544 if (system("cp $parm_exim_dir/exinext eximdir") != 0)
3545   {
3546   tests_exit(-1, "Failed to make a copy of exinext: $!");
3547   }
3548
3549 if (system("cp $parm_exim_dir/exigrep eximdir") != 0)
3550   {
3551   tests_exit(-1, "Failed to make a copy of exigrep: $!");
3552   }
3553
3554 if (system("cp $parm_exim_dir/eximstats eximdir") != 0)
3555   {
3556   tests_exit(-1, "Failed to make a copy of eximstats: $!");
3557   }
3558
3559 # Collect some version information
3560 print '-' x 78, "\n";
3561 print "Perl version for runtest: $]\n";
3562 foreach (map { "./eximdir/$_" } qw(exigrep exinext eximstats)) {
3563   # fold (or unfold?) multiline output into a one-liner
3564   print join(', ', map { chomp; $_ } `$_ --version`), "\n";
3565 }
3566 print '-' x 78, "\n";
3567
3568
3569 ##################################################
3570 #    Check that the Exim user can access stuff   #
3571 ##################################################
3572
3573 # We delay this test till here so that we can check access to the actual test
3574 # binary. This will be needed when Exim re-exec's itself to do deliveries.
3575
3576 print "Exim user is $parm_eximuser ($parm_exim_uid)\n";
3577 print "Exim group is $parm_eximgroup ($parm_exim_gid)\n";
3578
3579 if ($parm_caller_uid eq $parm_exim_uid) {
3580   tests_exit(-1, "Exim user ($parm_eximuser,$parm_exim_uid) cannot be "
3581                 ."the same as caller ($parm_caller,$parm_caller_uid)");
3582 }
3583 if ($parm_caller_gid eq $parm_exim_gid) {
3584   tests_exit(-1, "Exim group ($parm_eximgroup,$parm_exim_gid) cannot be "
3585                 ."the same as caller's ($parm_caller) group as it confuses "
3586                 ."results analysis");
3587 }
3588
3589 print "The Exim user needs access to the test suite directory. Checking ...";
3590
3591 if (($rc = system("sudo bin/checkaccess $parm_cwd/eximdir/exim $parm_eximuser $parm_eximgroup")) != 0)
3592   {
3593   my($why) = "unknown failure $rc";
3594   $rc >>= 8;
3595   $why = "Couldn't find user \"$parm_eximuser\"" if $rc == 1;
3596   $why = "Couldn't find group \"$parm_eximgroup\"" if $rc == 2;
3597   $why = "Couldn't read auxiliary group list" if $rc == 3;
3598   $why = "Couldn't get rid of auxiliary groups" if $rc == 4;
3599   $why = "Couldn't set gid" if $rc == 5;
3600   $why = "Couldn't set uid" if $rc == 6;
3601   $why = "Couldn't open \"$parm_cwd/eximdir/exim\"" if $rc == 7;
3602   print "\n** $why\n";
3603   tests_exit(-1, "$parm_eximuser cannot access the test suite directory");
3604   }
3605 else
3606   {
3607   print " OK\n";
3608   }
3609
3610 tests_exit(-1, "Failed to unlink $log_summary_filename: $!")
3611   if not unlink($log_summary_filename) and -e $log_summary_filename;
3612
3613 ##################################################
3614 #        Create a list of available tests        #
3615 ##################################################
3616
3617 # The scripts directory contains a number of subdirectories whose names are
3618 # of the form 0000-xxxx, 1100-xxxx, 2000-xxxx, etc. Each set of tests apart
3619 # from the first requires certain optional features to be included in the Exim
3620 # binary. These requirements are contained in a file called "REQUIRES" within
3621 # the directory. We scan all these tests, discarding those that cannot be run
3622 # because the current binary does not support the right facilities, and also
3623 # those that are outside the numerical range selected.
3624
3625 printf "\nWill run %d tests between %d and %d for flavour %s\n",
3626   scalar(@wanted), $wanted[0], $wanted[-1], $flavour;
3627
3628 print "Omitting \${dlfunc expansion tests (loadable module not present)\n"
3629   if $dlfunc_deleted;
3630 print "Omitting dbm tests (unable to copy exim_dbmbuild)\n"
3631   if $dbm_build_deleted;
3632
3633
3634 my @test_dirs = grep { not /^CVS$/ } map { basename $_ } glob 'scripts/*'
3635   or die tests_exit(-1, "Failed to find test scripts in 'scripts/*`: $!");
3636
3637 # Scan for relevant tests
3638 # HS12: Needs to be reworked.
3639 DIR: for (my $i = 0; $i < @test_dirs; $i++)
3640   {
3641   my($testdir) = $test_dirs[$i];
3642   my($wantthis) = 1;
3643
3644   print ">>Checking $testdir\n" if $debug;
3645
3646   # Skip this directory if the first test is equal or greater than the first
3647   # test in the next directory.
3648
3649   next DIR if ($i < @test_dirs - 1) &&
3650           ($wanted[0] >= substr($test_dirs[$i+1], 0, 4));
3651
3652   # No need to carry on if the end test is less than the first test in this
3653   # subdirectory.
3654
3655   last DIR if $wanted[-1] < substr($testdir, 0, 4);
3656
3657   # Check requirements, if any.
3658
3659   if (open(my $requires, "scripts/$testdir/REQUIRES"))
3660     {
3661     while (<$requires>)
3662       {
3663       next if /^\s*$/;
3664       s/\s+$//;
3665       if (/^support (.*)$/)
3666         {
3667         if (!defined $parm_support{$1}) { $wantthis = 0; last; }
3668         }
3669       elsif (/^running (.*)$/)
3670         {
3671         if (!defined $parm_running{$1}) { $wantthis = 0; last; }
3672         }
3673       elsif (/^lookup (.*)$/)
3674         {
3675         if (!defined $parm_lookups{$1}) { $wantthis = 0; last; }
3676         }
3677       elsif (/^authenticators? (.*)$/)
3678         {
3679         if (!defined $parm_authenticators{$1}) { $wantthis = 0; last; }
3680         }
3681       elsif (/^router (.*)$/)
3682         {
3683         if (!defined $parm_routers{$1}) { $wantthis = 0; last; }
3684         }
3685       elsif (/^transport (.*)$/)
3686         {
3687         if (!defined $parm_transports{$1}) { $wantthis = 0; last; }
3688         }
3689       elsif (/^malware (.*)$/)
3690         {
3691         if (!defined $parm_malware{$1}) { $wantthis = 0; last; }
3692         }
3693       elsif (/^feature (.*)$/)
3694         {
3695         # move to a subroutine?
3696         my $eximinfo = "$parm_exim -C $parm_cwd/test-config -DDIR=$parm_cwd -bP macro $1";
3697
3698         open (IN, "$parm_cwd/confs/0000") ||
3699           tests_exit(-1, "Couldn't open $parm_cwd/confs/0000: $!\n");
3700         open (OUT, ">test-config") ||
3701           tests_exit(-1, "Couldn't open test-config: $!\n");
3702         while (<IN>)
3703           {
3704           do_substitute($testno);
3705           print OUT;
3706           }
3707         close(IN);
3708         close(OUT);
3709
3710         system($eximinfo . " >/dev/null 2>&1");
3711         if ($? != 0) {
3712           unlink("$parm_cwd/test-config");
3713           $wantthis = 0;
3714           $_ = "feature $1";
3715           last;
3716         }
3717         unlink("$parm_cwd/test-config");
3718         }
3719       else
3720         {
3721         tests_exit(-1, "Unknown line in \"scripts/$testdir/REQUIRES\": \"$_\"");
3722         }
3723       }
3724     }
3725   else
3726     {
3727     tests_exit(-1, "Failed to open \"scripts/$testdir/REQUIRES\": $!")
3728       unless $!{ENOENT};
3729     }
3730
3731   # Loop if we do not want the tests in this subdirectory.
3732
3733   if (!$wantthis)
3734     {
3735     chomp;
3736     print "Omitting tests in $testdir (missing $_)\n";
3737     }
3738
3739   # We want the tests from this subdirectory, provided they are in the
3740   # range that was selected.
3741
3742   @testlist = grep { $_ ~~ @wanted } grep { /^\d+(?:\.\d+)?$/ } map { basename $_ } glob "scripts/$testdir/*";
3743   tests_exit(-1, "Failed to read test scripts from `scripts/$testdir/*': $!")
3744     if not @testlist;
3745
3746   foreach $test (@testlist)
3747     {
3748     if (!$wantthis)
3749       {
3750       log_test($log_summary_filename, $test, '.');
3751       }
3752     else
3753       {
3754       push @test_list, "$testdir/$test";
3755       }
3756     }
3757   }
3758
3759 print ">>Test List:\n", join "\n", @test_list, '' if $debug;
3760
3761
3762 ##################################################
3763 #         Munge variable auxiliary data          #
3764 ##################################################
3765
3766 # Some of the auxiliary data files have to refer to the current testing
3767 # directory and other parameter data. The generic versions of these files are
3768 # stored in the aux-var-src directory. At this point, we copy each of them
3769 # to the aux-var directory, making appropriate substitutions. There aren't very
3770 # many of them, so it's easiest just to do this every time. Ensure the mode
3771 # is standardized, as this path is used as a test for the ${stat: expansion.
3772
3773 # A similar job has to be done for the files in the dnszones-src directory, to
3774 # make the fake DNS zones for testing. Most of the zone files are copied to
3775 # files of the same name, but db.ipv4.V4NET and db.ipv6.V6NET use the testing
3776 # networks that are defined by parameter.
3777
3778 foreach $basedir ("aux-var", "dnszones")
3779   {
3780   system("sudo rm -rf $parm_cwd/$basedir");
3781   mkdir("$parm_cwd/$basedir", 0777);
3782   chmod(0755, "$parm_cwd/$basedir");
3783
3784   opendir(AUX, "$parm_cwd/$basedir-src") ||
3785     tests_exit(-1, "Failed to opendir $parm_cwd/$basedir-src: $!");
3786   my(@filelist) = readdir(AUX);
3787   close(AUX);
3788
3789   foreach $file (@filelist)
3790     {
3791     my($outfile) = $file;
3792     next if $file =~ /^\./;
3793
3794     if ($file eq "db.ip4.V4NET")
3795       {
3796       $outfile = "db.ip4.$parm_ipv4_test_net";
3797       }
3798     elsif ($file eq "db.ip6.V6NET")
3799       {
3800       my(@nibbles) = reverse(split /\s*/, $parm_ipv6_test_net);
3801       $" = '.';
3802       $outfile = "db.ip6.@nibbles";
3803       $" = ' ';
3804       }
3805
3806     print ">>Copying $basedir-src/$file to $basedir/$outfile\n" if $debug;
3807     open(IN, "$parm_cwd/$basedir-src/$file") ||
3808       tests_exit(-1, "Failed to open $parm_cwd/$basedir-src/$file: $!");
3809     open(OUT, ">$parm_cwd/$basedir/$outfile") ||
3810       tests_exit(-1, "Failed to open $parm_cwd/$basedir/$outfile: $!");
3811     while (<IN>)
3812       {
3813       do_substitute(0);
3814       print OUT;
3815       }
3816     close(IN);
3817     close(OUT);
3818     }
3819   }
3820
3821 # Set a user's shell, distinguishable from /bin/sh
3822
3823 symlink('/bin/sh' => 'aux-var/sh');
3824 $ENV{SHELL} = $parm_shell = "$parm_cwd/aux-var/sh";
3825
3826 ##################################################
3827 #     Create fake DNS zones for this host        #
3828 ##################################################
3829
3830 # There are fixed zone files for 127.0.0.1 and ::1, but we also want to be
3831 # sure that there are forward and reverse registrations for this host, using
3832 # its real IP addresses. Dynamically created zone files achieve this.
3833
3834 if ($have_ipv4 || $have_ipv6)
3835   {
3836   my($shortname,$domain) = $parm_hostname =~ /^([^.]+)(.*)/;
3837   open(OUT, ">$parm_cwd/dnszones/db$domain") ||
3838     tests_exit(-1, "Failed to open $parm_cwd/dnszones/db$domain: $!");
3839   print OUT "; This is a dynamically constructed fake zone file.\n" .
3840     "; The following line causes fakens to return PASS_ON\n" .
3841     "; for queries that it cannot answer\n\n" .
3842     "PASS ON NOT FOUND\n\n";
3843   print OUT "$shortname  A     $parm_ipv4\n" if $have_ipv4;
3844   print OUT "$shortname  AAAA  $parm_ipv6\n" if $have_ipv6;
3845   print OUT "\n; End\n";
3846   close(OUT);
3847   }
3848
3849 if ($have_ipv4 && $parm_ipv4 ne "127.0.0.1")
3850   {
3851   my(@components) = $parm_ipv4 =~ /^(\d+)\.(\d+)\.(\d+)\.(\d+)/;
3852   open(OUT, ">$parm_cwd/dnszones/db.ip4.$components[0]") ||
3853     tests_exit(-1,
3854       "Failed  to open $parm_cwd/dnszones/db.ip4.$components[0]: $!");
3855   print OUT "; This is a dynamically constructed fake zone file.\n" .
3856     "; The zone is $components[0].in-addr.arpa.\n\n" .
3857     "$components[3].$components[2].$components[1]  PTR  $parm_hostname.\n\n" .
3858     "; End\n";
3859   close(OUT);
3860   }
3861
3862 if ($have_ipv6 && $parm_ipv6 ne "::1")
3863   {
3864   my($exp_v6) = $parm_ipv6;
3865   $exp_v6 =~ s/[^:]//g;
3866   if ( $parm_ipv6 =~ /^([^:].+)::$/ ) {
3867     $exp_v6 = $1 . ':0' x (9-length($exp_v6));
3868   } elsif ( $parm_ipv6 =~ /^(.+)::(.+)$/ ) {
3869     $exp_v6 = $1 . ':0' x (8-length($exp_v6)) . ':' . $2;
3870   } elsif ( $parm_ipv6 =~ /^::(.+[^:])$/ ) {
3871     $exp_v6 = '0:' x (9-length($exp_v6)) . $1;
3872   } else {
3873     $exp_v6 = $parm_ipv6;
3874   }
3875   my(@components) = split /:/, $exp_v6;
3876   my(@nibbles) = reverse (split /\s*/, shift @components);
3877   my($sep) =  '';
3878
3879   $" = ".";
3880   open(OUT, ">$parm_cwd/dnszones/db.ip6.@nibbles") ||
3881     tests_exit(-1,
3882       "Failed  to open $parm_cwd/dnszones/db.ip6.@nibbles: $!");
3883   print OUT "; This is a dynamically constructed fake zone file.\n" .
3884     "; The zone is @nibbles.ip6.arpa.\n\n";
3885
3886   @components = reverse @components;
3887   foreach $c (@components)
3888     {
3889     $c = "0$c" until $c =~ /^..../;
3890     @nibbles = reverse(split /\s*/, $c);
3891     print OUT "$sep@nibbles";
3892     $sep = ".";
3893     }
3894
3895   print OUT "  PTR  $parm_hostname.\n\n; End\n";
3896   close(OUT);
3897   $" = " ";
3898   }
3899
3900
3901
3902 ##################################################
3903 #    Create lists of mailboxes and message logs  #
3904 ##################################################
3905
3906 # We use these lists to check that a test has created the expected files. It
3907 # should be faster than looking for the file each time. For mailboxes, we have
3908 # to scan a complete subtree, in order to handle maildirs. For msglogs, there
3909 # is just a flat list of files.
3910
3911 @oldmails = list_files_below("mail");
3912 opendir(DIR, "msglog") || tests_exit(-1, "Failed to opendir msglog: $!");
3913 @oldmsglogs = readdir(DIR);
3914 closedir(DIR);
3915
3916
3917
3918 ##################################################
3919 #         Run the required tests                 #
3920 ##################################################
3921
3922 # Each test script contains a number of tests, separated by a line that
3923 # contains ****. We open input from the terminal so that we can read responses
3924 # to prompts.
3925
3926 if (not $force_continue) {
3927   # runtest needs to interact if we're not in continue
3928   # mode. It does so by communicate to /dev/tty
3929   open(T, '<', '/dev/tty') or tests_exit(-1, "Failed to open /dev/tty: $!");
3930   print "\nPress RETURN to run the tests: ";
3931   <T>;
3932 }
3933
3934
3935 foreach $test (@test_list)
3936   {
3937   state $lasttestdir = '';
3938
3939   local $lineno     = 0;
3940   local $commandno  = 0;
3941   local $subtestno  = 0;
3942   local $sortlog    = 0;
3943
3944   (local $testno = $test) =~ s|.*/||;
3945
3946   # Leaving traces in the process table and in the environment
3947   # gives us a chance to identify hanging processes (exim daemons)
3948   local $0 = "[runtest $testno]";
3949   local $ENV{EXIM_TEST_NUMBER} = $testno;
3950
3951   my $gnutls   = 0;
3952   my $docheck  = 1;
3953   my $thistestdir  = substr($test, 0, -5);
3954
3955   $dynamic_socket->close() if $dynamic_socket;
3956
3957   if ($lasttestdir ne $thistestdir)
3958     {
3959     $gnutls = 0;
3960     if (-s "scripts/$thistestdir/REQUIRES")
3961       {
3962       my $indent = '';
3963       print "\n>>> The following tests require: ";
3964       open(my $requires, '<', "scripts/$thistestdir/REQUIRES") ||
3965         tests_exit(-1, "Failed to open scripts/$thistestdir/REQUIRES: $!");
3966       while (<$requires>)
3967         {
3968         $gnutls = 1 if /^support GnuTLS/;
3969         print $indent, $_;
3970         $indent = ">>>                              ";
3971         }
3972       }
3973       $lasttestdir = $thistestdir;
3974     }
3975
3976   # Remove any debris in the spool directory and the test-mail directory
3977   # and also the files for collecting stdout and stderr. Then put back
3978   # the test-mail directory for appendfile deliveries.
3979
3980   system "sudo /bin/rm -rf spool test-*";
3981   system "mkdir test-mail 2>/dev/null";
3982
3983   # A privileged Exim will normally make its own spool directory, but some of
3984   # the tests run in unprivileged modes that don't always work if the spool
3985   # directory isn't already there. What is more, we want anybody to be able
3986   # to read it in order to find the daemon's pid.
3987
3988   system "mkdir spool; " .
3989          "sudo chown $parm_eximuser:$parm_eximgroup spool; " .
3990          "sudo chmod 0755 spool";
3991
3992   # Empty the cache that keeps track of things like message id mappings, and
3993   # set up the initial sequence strings.
3994
3995   undef %cache;
3996   $next_msgid = "aX";
3997   $next_pid = 1234;
3998   $next_port = 1111;
3999   $message_skip = 0;
4000   $msglog_skip = 0;
4001   $stderr_skip = 0;
4002   $stdout_skip = 0;
4003   $rmfiltertest = 0;
4004   $is_ipv6test = 0;
4005   $TEST_STATE->{munge} = '';
4006
4007   # Remove the associative arrays used to hold checked mail files and msglogs
4008
4009   undef %expected_mails;
4010   undef %expected_msglogs;
4011
4012   # Open the test's script
4013   open(SCRIPT, "scripts/$test") ||
4014     tests_exit(-1, "Failed to open \"scripts/$test\": $!");
4015   # Run through the script once to set variables which should be global
4016   while (<SCRIPT>)
4017     {
4018     if (/^no_message_check/) { $message_skip = 1; next; }
4019     if (/^no_msglog_check/)  { $msglog_skip = 1; next; }
4020     if (/^no_stderr_check/)  { $stderr_skip = 1; next; }
4021     if (/^no_stdout_check/)  { $stdout_skip = 1; next; }
4022     if (/^rmfiltertest/)     { $rmfiltertest = 1; next; }
4023     if (/^sortlog/)          { $sortlog = 1; next; }
4024     if (/\bPORT_DYNAMIC\b/)  { $dynamic_socket = Exim::Runtest::dynamic_socket(); next; }
4025     }
4026   # Reset to beginning of file for per test interpreting/processing
4027   seek(SCRIPT, 0, 0);
4028
4029   # The first line in the script must be a comment that is used to identify
4030   # the set of tests as a whole.
4031
4032   $_ = <SCRIPT>;
4033   $lineno++;
4034   tests_exit(-1, "Missing identifying comment at start of $test") if (!/^#/);
4035   printf("%s %s", (substr $test, 5), (substr $_, 2));
4036
4037   # Loop for each of the subtests within the script. The variable $server_pid
4038   # is used to remember the pid of a "server" process, for which we do not
4039   # wait until we have waited for a subsequent command.
4040
4041   local($server_pid) = 0;
4042   for ($commandno = 1; !eof SCRIPT; $commandno++)
4043     {
4044     # Skip further leading comments and blank lines, handle the flag setting
4045     # commands, and deal with tests for IP support.
4046
4047     while (<SCRIPT>)
4048       {
4049       $lineno++;
4050       # Could remove these variable settings because they are already
4051       # set above, but doesn't hurt to leave them here.
4052       if (/^no_message_check/) { $message_skip = 1; next; }
4053       if (/^no_msglog_check/)  { $msglog_skip = 1; next; }
4054       if (/^no_stderr_check/)  { $stderr_skip = 1; next; }
4055       if (/^no_stdout_check/)  { $stdout_skip = 1; next; }
4056       if (/^rmfiltertest/)     { $rmfiltertest = 1; next; }
4057       if (/^sortlog/)          { $sortlog = 1; next; }
4058
4059       if (/^need_largefiles/)
4060         {
4061         next if $have_largefiles;
4062         print ">>> Large file support is needed for test $testno, but is not available: skipping\n";
4063         $docheck = 0;      # don't check output
4064         undef $_;          # pretend EOF
4065         last;
4066         }
4067
4068       if (/^need_ipv4/)
4069         {
4070         next if $have_ipv4;
4071         print ">>> IPv4 is needed for test $testno, but is not available: skipping\n";
4072         $docheck = 0;      # don't check output
4073         undef $_;          # pretend EOF
4074         last;
4075         }
4076
4077       if (/^need_ipv6/)
4078         {
4079         if ($have_ipv6)
4080           {
4081           $is_ipv6test = 1;
4082           next;
4083           }
4084         print ">>> IPv6 is needed for test $testno, but is not available: skipping\n";
4085         $docheck = 0;      # don't check output
4086         undef $_;          # pretend EOF
4087         last;
4088         }
4089
4090       if (/^need_move_frozen_messages/)
4091         {
4092         next if defined $parm_support{move_frozen_messages};
4093         print ">>> move frozen message support is needed for test $testno, " .
4094           "but is not\n>>> available: skipping\n";
4095         $docheck = 0;      # don't check output
4096         undef $_;          # pretend EOF
4097         last;
4098         }
4099
4100       last unless /^(?:#(?!##\s)|\s*$)/;
4101       }
4102     last if !defined $_;  # Hit EOF
4103
4104     my($subtest_startline) = $lineno;
4105
4106     # Now run the command. The function returns 0 for an inline command,
4107     # 1 if a non-exim command was run and waited for, 2 if an exim
4108     # command was run and waited for, and 3 if a command
4109     # was run and not waited for (usually a daemon or server startup).
4110
4111     my($commandname) = '';
4112     my($expectrc) = 0;
4113     my($rc, $run_extra) = run_command($testno, \$subtestno, \$expectrc, \$commandname, $TEST_STATE);
4114     my($cmdrc) = $?;
4115
4116     if ($debug) {
4117       print ">> rc=$rc cmdrc=$cmdrc\n";
4118       if (defined $run_extra) {
4119         foreach my $k (keys %$run_extra) {
4120           my $v = defined $run_extra->{$k} ? qq!"$run_extra->{$k}"! : '<undef>';
4121           print ">>   $k -> $v\n";
4122         }
4123       }
4124     }
4125     $run_extra = {} unless defined $run_extra;
4126     foreach my $k (keys %$run_extra) {
4127       if (exists $TEST_STATE->{$k}) {
4128         my $nv = defined $run_extra->{$k} ? qq!"$run_extra->{$k}"! : 'removed';
4129         print ">> override of $k; was $TEST_STATE->{$k}, now $nv\n" if $debug;
4130       }
4131       if (defined $run_extra->{$k}) {
4132         $TEST_STATE->{$k} = $run_extra->{$k};
4133       } elsif (exists $TEST_STATE->{$k}) {
4134         delete $TEST_STATE->{$k};
4135       }
4136     }
4137
4138     # Hit EOF after an initial return code number
4139
4140     tests_exit(-1, "Unexpected EOF in script") if ($rc == 4);
4141
4142     # Carry on with the next command if we did not wait for this one. $rc == 0
4143     # if no subprocess was run; $rc == 3 if we started a process but did not
4144     # wait for it.
4145
4146     next if ($rc == 0 || $rc == 3);
4147
4148     # We ran and waited for a command. Check for the expected result unless
4149     # it died.
4150
4151     if ($cmdrc != $expectrc && !$sigpipehappened)
4152       {
4153       printf("** Command $commandno (\"$commandname\", starting at line $subtest_startline)\n");
4154       if (($cmdrc & 0xff) == 0)
4155         {
4156         printf("** Return code %d (expected %d)", $cmdrc/256, $expectrc/256);
4157         }
4158       elsif (($cmdrc & 0xff00) == 0)
4159         { printf("** Killed by signal %d", $cmdrc & 255); }
4160       else
4161         { printf("** Status %x", $cmdrc); }
4162
4163       for (;;)
4164         {
4165         print "\nshow stdErr, show stdOut, Retry, Continue (without file comparison), or Quit? [Q] ";
4166         $_ = $force_continue ? "c" : <T>;
4167         tests_exit(1) if /^q?$/i;
4168         if (/^c$/ && $force_continue) {
4169           log_failure($log_failed_filename, $testno, "exit code unexpected");
4170           log_test($log_summary_filename, $testno, 'F')
4171         }
4172         if ($force_continue)
4173           {
4174           print "\nstdout tail:\n";
4175           print "==================>\n";
4176           system("tail -20 test-stdout");
4177           print "===================\n";
4178           print "stderr tail:\n";
4179           print "==================>\n";
4180           system("tail -20 test-stderr");
4181           print "===================\n";
4182           print "... continue forced\n";
4183           }
4184
4185         last if /^[rc]$/i;
4186         if (/^e$/i)
4187           {
4188           system("$more test-stderr");
4189           }
4190         elsif (/^o$/i)
4191           {
4192           system("$more test-stdout");
4193           }
4194         }
4195
4196       $retry = 1 if /^r$/i;
4197       $docheck = 0;
4198       }
4199
4200     # If the command was exim, and a listening server is running, we can now
4201     # close its input, which causes us to wait for it to finish, which is why
4202     # we didn't close it earlier.
4203
4204     if ($rc == 2 && $server_pid != 0)
4205       {
4206       close SERVERCMD;
4207       $server_pid = 0;
4208       if ($? != 0)
4209         {
4210         if (($? & 0xff) == 0)
4211           { printf("Server return code %d for test %d starting line %d", $?/256,
4212                 $testno, $subtest_startline); }
4213         elsif (($? & 0xff00) == 0)
4214           { printf("Server killed by signal %d", $? & 255); }
4215         else
4216           { printf("Server status %x", $?); }
4217
4218         for (;;)
4219           {
4220           print "\nShow server stdout, Retry, Continue, or Quit? [Q] ";
4221           $_ = $force_continue ? "c" : <T>;
4222           tests_exit(1) if /^q?$/i;
4223           if (/^c$/ && $force_continue) {
4224             log_failure($log_failed_filename, $testno, "exit code unexpected");
4225             log_test($log_summary_filename, $testno, 'F')
4226           }
4227           print "... continue forced\n" if $force_continue;
4228           last if /^[rc]$/i;
4229
4230           if (/^s$/i)
4231             {
4232             open(S, "test-stdout-server") ||
4233               tests_exit(-1, "Failed to open test-stdout-server: $!");
4234             print while <S>;
4235             close(S);
4236             }
4237           }
4238         $retry = 1 if /^r$/i;
4239         }
4240       }
4241     }
4242
4243   close SCRIPT;
4244
4245   # The script has finished. Check the all the output that was generated. The
4246   # function returns 0 for a perfect pass, 1 if imperfect but ok, 2 if we should
4247   # rerun the test (the files # have been updated).
4248   # It does not return if the user responds Q to a prompt.
4249
4250   if ($retry)
4251     {
4252     $retry = '0';
4253     print (("#" x 79) . "\n");
4254     redo;
4255     }
4256
4257   if ($docheck)
4258     {
4259     sleep 1 if $slow;
4260     my $rc = check_output($TEST_STATE->{munge});
4261     log_test($log_summary_filename, $testno, 'P') if ($rc == 0);
4262     if ($rc < 2)
4263       {
4264       print ("  Script completed\n");
4265       }
4266     else
4267       {
4268       print (("#" x 79) . "\n");
4269       redo;
4270       }
4271     }
4272   }
4273
4274
4275 ##################################################
4276 #         Exit from the test script              #
4277 ##################################################
4278
4279 tests_exit(-1, "No runnable tests selected") if not @test_list;
4280 tests_exit(0);
4281
4282 __END__
4283
4284 =head1 NAME
4285
4286  runtest - run the exim testsuite
4287
4288 =head1 SYNOPSIS
4289
4290  runtest [exim-path] [options] [test0 [test1]]
4291
4292 =head1 DESCRIPTION
4293
4294 B<runtest> runs the Exim testsuite.
4295
4296 =head1 OPTIONS
4297
4298 For legacy reasons the options are not case sensitive.
4299
4300 =over
4301
4302 =item B<--continue>
4303
4304 Do not stop for user interaction or on errors. (default: off)
4305
4306 =item B<--debug>
4307
4308 This option enables the output of debug information when running the
4309 various test commands. (default: off)
4310
4311 =item B<--diff>
4312
4313 Use C<diff -u> for comparing the expected output with the produced
4314 output. (default: use a built-in routine)
4315
4316 =item B<--flavor>|B<--flavour> I<flavour>
4317
4318 Override the expected results for results for a specific (OS) flavour.
4319 (default: unused)
4320
4321 =item B<--[no]ipv4>
4322
4323 Skip IPv4 related setup and tests (default: use ipv4)
4324
4325 =item B<--[no]ipv6>
4326
4327 Skip IPv6 related setup and tests (default: use ipv6)
4328
4329 =item B<--keep>
4330
4331 Keep the various output files produced during a test run. (default: don't keep)
4332
4333 =item B<--range> I<n0> I<n1>
4334
4335 Run tests between (including) I<n0> and I<n1>. A "+" may be used to specify the "last
4336 test available".
4337
4338 =item B<--slow>
4339
4340 Insert some delays to compensate for a slow host system. (default: off)
4341
4342 =item B<--test> I<n>
4343
4344 Run the specified test. This option may used multiple times.
4345
4346 =item B<--update>
4347
4348 Automatically update the recorded (expected) data on mismatch. (default: off)
4349
4350 =item B<--valgrind>
4351
4352 Start Exim wrapped by I<valgrind>. (default: don't use valgrind)
4353
4354 =back
4355
4356 =cut
4357
4358
4359 # End of runtest script