test/runtest

   1 #! /usr/bin/env perl
   2 # We use env, because in some environments of our build farm
   3 # the Perl 5.010 interpreter is only reachable via $PATH
   4
   5 ###############################################################################
   6 # This is the controlling script for the "new" test suite for Exim. It should #
   7 # be possible to export this suite for running on a wide variety of hosts, in #
   8 # contrast to the old suite, which was very dependent on the environment of   #
   9 # Philip Hazel's desktop computer. This implementation inspects the version   #
  10 # of Exim that it finds, and tests only those features that are included. The #
  11 # surrounding environment is also tested to discover what is available. See   #
  12 # the README file for details of how it all works.                            #
  13 #                                                                             #
  14 # Implementation started: 03 August 2005 by Philip Hazel                      #
  15 # Placed in the Exim CVS: 06 February 2006                                    #
  16 ###############################################################################
  17
  18 #use strict;
  19 use 5.010;
  20 use warnings;
  21
  22 use Errno;
  23 use FileHandle;
  24 use IO::Socket::INET;
  25 use Socket;
  26 use Time::Local;
  27 use Cwd;
  28 use File::Basename;
  29 use if $ENV{DEBUG} && $ENV{DEBUG} =~ /\bruntest\b/ => ('Smart::Comments' => '####');
  30
  31
  32 # Start by initializing some global variables
  33
  34 $testversion = "4.80 (08-May-12)";
  35
  36 # This gets embedded in the D-H params filename, and the value comes
  37 # from asking GnuTLS for "normal", but there appears to be no way to
  38 # use certtool/... to ask what that value currently is.  *sigh*
  39 # We also clamp it because of NSS interop, see addition of tls_dh_max_bits.
  40 # This value is correct as of GnuTLS 2.12.18 as clamped by tls_dh_max_bits.
  41 # normal = 2432   tls_dh_max_bits = 2236
  42 $gnutls_dh_bits_normal = 2236;
  43
  44 $cf = "bin/cf -exact";
  45 $cr = "\r";
  46 $debug = 0;
  47 $flavour = 'FOO';
  48 $force_continue = 0;
  49 $force_update = 0;
  50 $log_failed_filename = "failed-summary.log";
  51 $more = "less -XF";
  52 $optargs = "";
  53 $save_output = 0;
  54 $server_opts = "";
  55 $valgrind = 0;
  56
  57 $have_ipv4 = 1;
  58 $have_ipv6 = 1;
  59 $have_largefiles = 0;
  60
  61 $test_start = 1;
  62 $test_end = $test_top = 8999;
  63 $test_special_top = 9999;
  64 @test_list = ();
  65 @test_dirs = ();
  66
  67
  68 # Networks to use for DNS tests. We need to choose some networks that will
  69 # never be used so that there is no chance that the host on which we are
  70 # running is actually in one of the test networks. Private networks such as
  71 # the IPv4 10.0.0.0/8 network are no good because hosts may well use them.
  72 # Rather than use some unassigned numbers (that might become assigned later),
  73 # I have chosen some multicast networks, in the belief that such addresses
  74 # won't ever be assigned to hosts. This is the only place where these numbers
  75 # are defined, so it is trivially possible to change them should that ever
  76 # become necessary.
  77
  78 $parm_ipv4_test_net = "224";
  79 $parm_ipv6_test_net = "ff00";
  80
  81 # Port numbers are currently hard-wired
  82
  83 $parm_port_n = 1223;         # Nothing listening on this port
  84 $parm_port_s = 1224;         # Used for the "server" command
  85 $parm_port_d = 1225;         # Used for the Exim daemon
  86 $parm_port_d2 = 1226;        # Additional for daemon
  87 $parm_port_d3 = 1227;        # Additional for daemon
  88 $parm_port_d4 = 1228;        # Additional for daemon
  89 my $dynamic_socket;          # allocated later for PORT_DYNAMIC
  90
  91 # Manually set locale
  92 $ENV{LC_ALL} = 'C';
  93
  94 # In some environments USER does not exists, but we
  95 # need it for some test(s)
  96 $ENV{USER} = getpwuid($>)
  97   if not exists $ENV{USER};
  98
  99 my ($parm_configure_owner, $parm_configure_group);
 100 my ($parm_ipv4, $parm_ipv6);
 101 my $parm_hostname;
 102
 103 ###############################################################################
 104 ###############################################################################
 105
 106 # Define a number of subroutines
 107
 108 ###############################################################################
 109 ###############################################################################
 110
 111
 112 ##################################################
 113 #              Handle signals                    #
 114 ##################################################
 115
 116 sub pipehandler { $sigpipehappened = 1; }
 117
 118 sub inthandler { print "\n"; tests_exit(-1, "Caught SIGINT"); }
 119
 120
 121 ##################################################
 122 #       Do global macro substitutions            #
 123 ##################################################
 124
 125 # This function is applied to configurations, command lines and data lines in
 126 # scripts, and to lines in the files of the aux-var-src and the dnszones-src
 127 # directory. It takes one argument: the current test number, or zero when
 128 # setting up files before running any tests.
 129
 130 sub do_substitute{
 131 s?\bCALLER\b?$parm_caller?g;
 132 s?\bCALLERGROUP\b?$parm_caller_group?g;
 133 s?\bCALLER_UID\b?$parm_caller_uid?g;
 134 s?\bCALLER_GID\b?$parm_caller_gid?g;
 135 s?\bCLAMSOCKET\b?$parm_clamsocket?g;
 136 s?\bDIR/?$parm_cwd/?g;
 137 s?\bEXIMGROUP\b?$parm_eximgroup?g;
 138 s?\bEXIMUSER\b?$parm_eximuser?g;
 139 s?\bHOSTIPV4\b?$parm_ipv4?g;
 140 s?\bHOSTIPV6\b?$parm_ipv6?g;
 141 s?\bHOSTNAME\b?$parm_hostname?g;
 142 s?\bPORT_D\b?$parm_port_d?g;
 143 s?\bPORT_D2\b?$parm_port_d2?g;
 144 s?\bPORT_D3\b?$parm_port_d3?g;
 145 s?\bPORT_D4\b?$parm_port_d4?g;
 146 s?\bPORT_N\b?$parm_port_n?g;
 147 s?\bPORT_S\b?$parm_port_s?g;
 148 s?\bTESTNUM\b?$_[0]?g;
 149 s?(\b|_)V4NET([\._])?$1$parm_ipv4_test_net$2?g;
 150 s?\bV6NET:?$parm_ipv6_test_net:?g;
 151 s?\bPORT_DYNAMIC\b?$dynamic_socket->sockport()?eg;
 152 }
 153
 154
 155 ##################################################
 156 #     Any state to be preserved across tests     #
 157 ##################################################
 158
 159 my $TEST_STATE = {};
 160
 161
 162 ##################################################
 163 #        Subroutine to tidy up and exit          #
 164 ##################################################
 165
 166 # In all cases, we check for any Exim daemons that have been left running, and
 167 # kill them. Then remove all the spool data, test output, and the modified Exim
 168 # binary if we are ending normally.
 169
 170 # Arguments:
 171 #    $_[0] = 0 for a normal exit; full cleanup done
 172 #    $_[0] > 0 for an error exit; no files cleaned up
 173 #    $_[0] < 0 for a "die" exit; $_[1] contains a message
 174
 175 sub tests_exit{
 176 my($rc) = $_[0];
 177 my($spool);
 178
 179 # Search for daemon pid files and kill the daemons. We kill with SIGINT rather
 180 # than SIGTERM to stop it outputting "Terminated" to the terminal when not in
 181 # the background.
 182
 183 if (exists $TEST_STATE->{exim_pid})
 184   {
 185   $pid = $TEST_STATE->{exim_pid};
 186   print "Tidyup: killing wait-mode daemon pid=$pid\n";
 187   system("sudo kill -INT $pid");
 188   }
 189
 190 if (opendir(DIR, "spool"))
 191   {
 192   my(@spools) = sort readdir(DIR);
 193   closedir(DIR);
 194   foreach $spool (@spools)
 195     {
 196     next if $spool !~ /^exim-daemon./;
 197     open(PID, "spool/$spool") || die "** Failed to open \"spool/$spool\": $!\n";
 198     chomp($pid = <PID>);
 199     close(PID);
 200     print "Tidyup: killing daemon pid=$pid\n";
 201     system("sudo rm -f spool/$spool; sudo kill -INT $pid");
 202     }
 203   }
 204 else
 205   { die "** Failed to opendir(\"spool\"): $!\n" unless $!{ENOENT}; }
 206
 207 # Close the terminal input and remove the test files if all went well, unless
 208 # the option to save them is set. Always remove the patched Exim binary. Then
 209 # exit normally, or die.
 210
 211 close(T);
 212 system("sudo /bin/rm -rf ./spool test-* ./dnszones/*")
 213   if ($rc == 0 && !$save_output);
 214
 215 system("sudo /bin/rm -rf ./eximdir/*")
 216   if (!$save_output);
 217
 218 print "\nYou were in test $test at the end there.\n\n" if defined $test;
 219 exit $rc if ($rc >= 0);
 220 die "** runtest error: $_[1]\n";
 221 }
 222
 223
 224
 225 ##################################################
 226 #   Subroutines used by the munging subroutine   #
 227 ##################################################
 228
 229 # This function is used for things like message ids, where we want to generate
 230 # more than one value, but keep a consistent mapping throughout.
 231 #
 232 # Arguments:
 233 #   $oldid        the value from the file
 234 #   $base         a base string into which we insert a sequence
 235 #   $sequence     the address of the current sequence counter
 236
 237 sub new_value {
 238 my($oldid, $base, $sequence) = @_;
 239 my($newid) = $cache{$oldid};
 240 if (! defined $newid)
 241   {
 242   $newid = sprintf($base, $$sequence++);
 243   $cache{$oldid} = $newid;
 244   }
 245 return $newid;
 246 }
 247
 248
 249 # This is used while munging the output from exim_dumpdb.
 250 # May go wrong across DST changes.
 251
 252 sub date_seconds {
 253 my($day,$month,$year,$hour,$min,$sec) =
 254   $_[0] =~ /^(\d\d)-(\w\w\w)-(\d{4})\s(\d\d):(\d\d):(\d\d)/;
 255 my($mon);
 256 if   ($month =~ /Jan/) {$mon = 0;}
 257 elsif($month =~ /Feb/) {$mon = 1;}
 258 elsif($month =~ /Mar/) {$mon = 2;}
 259 elsif($month =~ /Apr/) {$mon = 3;}
 260 elsif($month =~ /May/) {$mon = 4;}
 261 elsif($month =~ /Jun/) {$mon = 5;}
 262 elsif($month =~ /Jul/) {$mon = 6;}
 263 elsif($month =~ /Aug/) {$mon = 7;}
 264 elsif($month =~ /Sep/) {$mon = 8;}
 265 elsif($month =~ /Oct/) {$mon = 9;}
 266 elsif($month =~ /Nov/) {$mon = 10;}
 267 elsif($month =~ /Dec/) {$mon = 11;}
 268 return timelocal($sec,$min,$hour,$day,$mon,$year);
 269 }
 270
 271
 272 # This is a subroutine to sort maildir files into time-order. The second field
 273 # is the microsecond field, and may vary in length, so must be compared
 274 # numerically.
 275
 276 sub maildirsort {
 277 return $a cmp $b if ($a !~ /^\d+\.H\d/ || $b !~ /^\d+\.H\d/);
 278 my($x1,$y1) = $a =~ /^(\d+)\.H(\d+)/;
 279 my($x2,$y2) = $b =~ /^(\d+)\.H(\d+)/;
 280 return ($x1 != $x2)? ($x1 <=> $x2) : ($y1 <=> $y2);
 281 }
 282
 283
 284
 285 ##################################################
 286 #   Subroutine list files below a directory      #
 287 ##################################################
 288
 289 # This is used to build up a list of expected mail files below a certain path
 290 # in the directory tree. It has to be recursive in order to deal with multiple
 291 # maildir mailboxes.
 292
 293 sub list_files_below {
 294 my($dir) = $_[0];
 295 my(@yield) = ();
 296 my(@sublist, $file);
 297
 298 opendir(DIR, $dir) || tests_exit(-1, "Failed to open $dir: $!");
 299 @sublist = sort maildirsort readdir(DIR);
 300 closedir(DIR);
 301
 302 foreach $file (@sublist)
 303   {
 304   next if $file eq "." || $file eq ".." || $file eq "CVS";
 305   if (-d "$dir/$file")
 306     { @yield = (@yield, list_files_below("$dir/$file")); }
 307   else
 308     { push @yield, "$dir/$file"; }
 309   }
 310
 311 return @yield;
 312 }
 313
 314
 315
 316 ##################################################
 317 #         Munge a file before comparing          #
 318 ##################################################
 319
 320 # The pre-processing turns all dates, times, Exim versions, message ids, and so
 321 # on into standard values, so that the compare works. Perl's substitution with
 322 # an expression provides a neat way to do some of these changes.
 323
 324 # We keep a global associative array for repeatedly turning the same values
 325 # into the same standard values throughout the data from a single test.
 326 # Message ids get this treatment (can't be made reliable for times), and
 327 # times in dumped retry databases are also handled in a special way, as are
 328 # incoming port numbers.
 329
 330 # On entry to the subroutine, the file to write to is already opened with the
 331 # name MUNGED. The input file name is the only argument to the subroutine.
 332 # Certain actions are taken only when the name contains "stderr", "stdout",
 333 # or "log". The yield of the function is 1 if a line matching "*** truncated
 334 # ***" is encountered; otherwise it is 0.
 335
 336 sub munge {
 337 my($file) = $_[0];
 338 my($extra) = $_[1];
 339 my($yield) = 0;
 340 my(@saved) = ();
 341
 342 local $_;
 343
 344 open(IN, "$file") || tests_exit(-1, "Failed to open $file: $!");
 345
 346 my($is_log) = $file =~ /log/;
 347 my($is_stdout) = $file =~ /stdout/;
 348 my($is_stderr) = $file =~ /stderr/;
 349
 350 # Date pattern
 351
 352 $date = "\\d{2}-\\w{3}-\\d{4}\\s\\d{2}:\\d{2}:\\d{2}";
 353
 354 # Pattern for matching pids at start of stderr lines; initially something
 355 # that won't match.
 356
 357 $spid = "xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx";
 358
 359 # Scan the file and make the changes. Near the bottom there are some changes
 360 # that are specific to certain file types, though there are also some of those
 361 # inline too.
 362
 363 LINE: while(<IN>)
 364   {
 365 RESET_AFTER_EXTRA_LINE_READ:
 366   # Custom munges
 367   if ($extra)
 368     {
 369     next if $extra =~ m%^/%  &&  eval $extra;
 370     eval $extra if $extra =~ m/^s/;
 371     }
 372
 373   # Check for "*** truncated ***"
 374   $yield = 1 if /\*\*\* truncated \*\*\*/;
 375
 376   # Replace the name of this host
 377   s/\Q$parm_hostname\E/the.local.host.name/g;
 378
 379   # But convert "name=the.local.host address=127.0.0.1" to use "localhost"
 380   s/name=the\.local\.host address=127\.0\.0\.1/name=localhost address=127.0.0.1/g;
 381
 382   # The name of the shell may vary
 383   s/\s\Q$parm_shell\E\b/ ENV_SHELL/;
 384
 385   # Replace the path to the testsuite directory
 386   s?\Q$parm_cwd\E?TESTSUITE?g;
 387
 388   # Replace the Exim version number (may appear in various places)
 389   # patchexim should have fixed this for us
 390   #s/(Exim) \d+\.\d+[\w_-]*/$1 x.yz/i;
 391
 392   # Replace Exim message ids by a unique series
 393   s/((?:[^\W_]{6}-){2}[^\W_]{2})
 394     /new_value($1, "10Hm%s-0005vi-00", \$next_msgid)/egx;
 395
 396   # The names of lock files appear in some error and debug messages
 397   s/\.lock(\.[-\w]+)+(\.[\da-f]+){2}/.lock.test.ex.dddddddd.pppppppp/;
 398
 399   # Unless we are in an IPv6 test, replace IPv4 and/or IPv6 in "listening on
 400   # port" message, because it is not always the same.
 401   s/port (\d+) \([^)]+\)/port $1/g
 402     if !$is_ipv6test && m/listening for SMTP(S?) on port/;
 403
 404   # Challenges in SPA authentication
 405   s/TlRMTVNTUAACAAAAAAAAAAAoAAABgg[\w+\/]+/TlRMTVNTUAACAAAAAAAAAAAoAAABggAAAEbBRwqFwwIAAAAAAAAAAAAt1sgAAAAA/;
 406
 407   # PRVS values
 408   s?prvs=([^/]+)/[\da-f]{10}@?prvs=$1/xxxxxxxxxx@?g;    # Old form
 409   s?prvs=[\da-f]{10}=([^@]+)@?prvs=xxxxxxxxxx=$1@?g;    # New form
 410
 411   # Error lines on stdout from SSL contain process id values and file names.
 412   # They also contain a source file name and line number, which may vary from
 413   # release to release.
 414   s/^\d+:error:/pppp:error:/;
 415   s/:(?:\/[^\s:]+\/)?([^\/\s]+\.c):\d+:/:$1:dddd:/;
 416
 417   # There are differences in error messages between OpenSSL versions
 418   s/SSL_CTX_set_cipher_list/SSL_connect/;
 419
 420   # One error test in expansions mentions base 62 or 36
 421   s/is not a base (36|62) number/is not a base 36\/62 number/;
 422
 423   # This message sometimes has a different number of seconds
 424   s/forced fail after \d seconds/forced fail after d seconds/;
 425
 426   # This message may contain a different DBM library name
 427   s/Failed to open \S+( \([^\)]+\))? file/Failed to open DBM file/;
 428
 429   # The message for a non-listening FIFO varies
 430   s/:[^:]+: while opening named pipe/: Error: while opening named pipe/;
 431
 432   # Debugging output of lists of hosts may have different sort keys
 433   s/sort=\S+/sort=xx/ if /^\S+ (?:\d+\.){3}\d+ mx=\S+ sort=\S+/;
 434
 435   # Random local part in callout cache testing
 436   s/myhost.test.ex-\d+-testing/myhost.test.ex-dddddddd-testing/;
 437   s/the.local.host.name-\d+-testing/the.local.host.name-dddddddd-testing/;
 438
 439   # File descriptor numbers may vary
 440   s/^writing data block fd=\d+/writing data block fd=dddd/;
 441   s/(running as transport filter:) fd_write=\d+ fd_read=\d+/$1 fd_write=dddd fd_read=dddd/;
 442
 443
 444   # ======== Dumpdb output ========
 445   # This must be before the general date/date munging.
 446   # Time data lines, which look like this:
 447   # 25-Aug-2000 12:11:37  25-Aug-2000 12:11:37  26-Aug-2000 12:11:37
 448   if (/^($date)\s+($date)\s+($date)(\s+\*)?\s*$/)
 449     {
 450     my($date1,$date2,$date3,$expired) = ($1,$2,$3,$4);
 451     $expired = "" if !defined $expired;
 452     my($increment) = date_seconds($date3) - date_seconds($date2);
 453
 454     # We used to use globally unique replacement values, but timing
 455     # differences make this impossible. Just show the increment on the
 456     # last one.
 457
 458     printf MUNGED ("first failed = time last try = time2 next try = time2 + %s%s\n",
 459       $increment, $expired);
 460     next;
 461     }
 462
 463   # more_errno values in exim_dumpdb output which are times
 464   s/T:(\S+)\s-22\s(\S+)\s/T:$1 -22 xxxx /;
 465
 466
 467   # ======== Dates and times ========
 468
 469   # Dates and times are all turned into the same value - trying to turn
 470   # them into different ones cannot be done repeatedly because they are
 471   # real time stamps generated while running the test. The actual date and
 472   # time used was fixed when I first started running automatic Exim tests.
 473
 474   # Date/time in header lines and SMTP responses
 475   s/[A-Z][a-z]{2},\s\d\d?\s[A-Z][a-z]{2}\s\d\d\d\d\s\d\d\:\d\d:\d\d\s[-+]\d{4}
 476     /Tue, 2 Mar 1999 09:44:33 +0000/gx;
 477
 478   # Date/time in logs and in one instance of a filter test
 479   s/^\d{4}-\d\d-\d\d\s\d\d:\d\d:\d\d(\s[+-]\d\d\d\d)?/1999-03-02 09:44:33/gx;
 480   s/^Logwrite\s"\d{4}-\d\d-\d\d\s\d\d:\d\d:\d\d/Logwrite "1999-03-02 09:44:33/gx;
 481
 482   # Date/time in message separators
 483   s/(?:[A-Z][a-z]{2}\s){2}\d\d\s\d\d:\d\d:\d\d\s\d\d\d\d
 484     /Tue Mar 02 09:44:33 1999/gx;
 485
 486   # Date of message arrival in spool file as shown by -Mvh
 487   s/^\d{9,10}\s0$/ddddddddd 0/;
 488
 489   # Date/time in mbx mailbox files
 490   s/\d\d-\w\w\w-\d\d\d\d\s\d\d:\d\d:\d\d\s[-+]\d\d\d\d,/06-Sep-1999 15:52:48 +0100,/gx;
 491
 492   # Dates/times in debugging output for writing retry records
 493   if (/^  first failed=(\d+) last try=(\d+) next try=(\d+) (.*)$/)
 494     {
 495     my($next) = $3 - $2;
 496     $_ = "  first failed=dddd last try=dddd next try=+$next $4\n";
 497     }
 498   s/^(\s*)now=\d+ first_failed=\d+ next_try=\d+ expired=(\d)/$1now=tttt first_failed=tttt next_try=tttt expired=$2/;
 499   s/^(\s*)received_time=\d+ diff=\d+ timeout=(\d+)/$1received_time=tttt diff=tttt timeout=$2/;
 500
 501   # Time to retry may vary
 502   s/time to retry = \S+/time to retry = tttt/;
 503   s/retry record exists: age=\S+/retry record exists: age=ttt/;
 504   s/failing_interval=\S+ message_age=\S+/failing_interval=ttt message_age=ttt/;
 505
 506   # Date/time in exim -bV output
 507   s/\d\d-[A-Z][a-z]{2}-\d{4}\s\d\d:\d\d:\d\d/07-Mar-2000 12:21:52/g;
 508
 509   # Time on queue tolerance
 510   s/(QT|D)=1s/$1=0s/;
 511
 512   # Eximstats heading
 513   s/Exim\sstatistics\sfrom\s\d{4}-\d\d-\d\d\s\d\d:\d\d:\d\d\sto\s
 514     \d{4}-\d\d-\d\d\s\d\d:\d\d:\d\d/Exim statistics from <time> to <time>/x;
 515
 516   # Treat ECONNRESET the same as ECONNREFUSED.  At least some systems give
 517   # us the former on a new connection.
 518   s/(could not connect to .*: Connection) reset by peer$/$1 refused/;
 519
 520   # ======== TLS certificate algorithms ========
 521   # Test machines might have various different TLS library versions supporting
 522   # different protocols; can't rely upon TLS 1.2's AES256-GCM-SHA384, so we
 523   # treat the standard algorithms the same.
 524   # So far, have seen:
 525   #   TLSv1:AES128-GCM-SHA256:128
 526   #   TLSv1:AES256-SHA:256
 527   #   TLSv1.1:AES256-SHA:256
 528   #   TLSv1.2:AES256-GCM-SHA384:256
 529   #   TLSv1.2:DHE-RSA-AES256-SHA:256
 530   #   TLS1.2:DHE_RSA_AES_128_CBC_SHA1:128
 531   # We also need to handle the ciphersuite without the TLS part present, for
 532   # client-ssl's output.  We also see some older forced ciphersuites, but
 533   # negotiating TLS 1.2 instead of 1.0.
 534   # Mail headers (...), log-lines X=..., client-ssl output ...
 535   # (and \b doesn't match between ' ' and '(' )
 536
 537   s/( (?: (?:\b|\s) [\(=] ) | \s )TLSv1\.[12]:/$1TLSv1:/xg;
 538   s/\bAES128-GCM-SHA256:128\b/AES256-SHA:256/g;
 539   s/\bAES128-GCM-SHA256\b/AES256-SHA/g;
 540   s/\bAES256-GCM-SHA384\b/AES256-SHA/g;
 541   s/\bDHE-RSA-AES256-SHA\b/AES256-SHA/g;
 542
 543   # GnuTLS have seen:
 544   #   TLS1.2:ECDHE_RSA_AES_256_GCM_SHA384:256
 545   #   TLS1.2:ECDHE_RSA_AES_128_GCM_SHA256:128
 546   #   TLS1.2:RSA_AES_256_CBC_SHA1:256 (canonical)
 547   #   TLS1.2:DHE_RSA_AES_128_CBC_SHA1:128
 548   #
 549   #   X=TLS1.2:DHE_RSA_AES_256_CBC_SHA256:256
 550   #   X=TLS1.2:RSA_AES_256_CBC_SHA1:256
 551   #   X=TLS1.1:RSA_AES_256_CBC_SHA1:256
 552   #   X=TLS1.0:DHE_RSA_AES_256_CBC_SHA1:256
 553   # and as stand-alone cipher:
 554   #   ECDHE-RSA-AES256-SHA
 555   #   DHE-RSA-AES256-SHA256
 556   #   DHE-RSA-AES256-SHA
 557   # picking latter as canonical simply because regex easier that way.
 558   s/\bDHE_RSA_AES_128_CBC_SHA1:128/RSA_AES_256_CBC_SHA1:256/g;
 559   s/TLS1.[012]:((EC)?DHE_)?RSA_AES_(256|128)_(CBC|GCM)_SHA(1|256|384):(256|128)/TLS1.x:xxxxRSA_AES_256_CBC_SHAnnn:256/g;
 560   s/\b(ECDHE-RSA-AES256-SHA|DHE-RSA-AES256-SHA256)\b/AES256-SHA/g;
 561
 562   # GnuTLS library error message changes
 563   s/No certificate was found/The peer did not send any certificate/g;
 564 #(dodgy test?)  s/\(certificate verification failed\): invalid/\(gnutls_handshake\): The peer did not send any certificate./g;
 565   s/\(gnutls_priority_set\): No or insufficient priorities were set/\(gnutls_handshake\): Could not negotiate a supported cipher suite/g;
 566
 567   # (this new one is a generic channel-read error, but the testsuite
 568   # only hits it in one place)
 569   s/TLS error on connection \(gnutls_handshake\): Error in the pull function\./a TLS session is required but an attempt to start TLS failed/g;
 570
 571   # (replace old with new, hoping that old only happens in one situation)
 572   s/TLS error on connection to \d{1,3}(.\d{1,3}){3} \[\d{1,3}(.\d{1,3}){3}\] \(gnutls_handshake\): A TLS packet with unexpected length was received./a TLS session is required for ip4.ip4.ip4.ip4 [ip4.ip4.ip4.ip4], but an attempt to start TLS failed/g;
 573   s/TLS error on connection from \[127.0.0.1\] \(recv\): A TLS packet with unexpected length was received./TLS error on connection from [127.0.0.1] (recv): The TLS connection was non-properly terminated./g;
 574
 575   # signature algorithm names
 576   s/RSA-SHA1/RSA-SHA/;
 577
 578
 579   # ======== Caller's login, uid, gid, home, gecos ========
 580
 581   s/\Q$parm_caller_home\E/CALLER_HOME/g;   # NOTE: these must be done
 582   s/\b\Q$parm_caller\E\b/CALLER/g;         #       in this order!
 583   s/\b\Q$parm_caller_group\E\b/CALLER/g;   # In case group name different
 584
 585   s/\beuid=$parm_caller_uid\b/euid=CALLER_UID/g;
 586   s/\begid=$parm_caller_gid\b/egid=CALLER_GID/g;
 587
 588   s/\buid=$parm_caller_uid\b/uid=CALLER_UID/g;
 589   s/\bgid=$parm_caller_gid\b/gid=CALLER_GID/g;
 590
 591   s/\bname="?$parm_caller_gecos"?/name=CALLER_GECOS/g;
 592
 593   # When looking at spool files with -Mvh, we will find not only the caller
 594   # login, but also the uid and gid. It seems that $) in some Perls gives all
 595   # the auxiliary gids as well, so don't bother checking for that.
 596
 597   s/^CALLER $> \d+$/CALLER UID GID/;
 598
 599   # There is one case where the caller's login is forced to something else,
 600   # in order to test the processing of logins that contain spaces. Weird what
 601   # some people do, isn't it?
 602
 603   s/^spaced user $> \d+$/CALLER UID GID/;
 604
 605
 606   # ======== Exim's login ========
 607   # For messages received by the daemon, this is in the -H file, which some
 608   # tests inspect. For bounce messages, this will appear on the U= lines in
 609   # logs and also after Received: and in addresses. In one pipe test it appears
 610   # after "Running as:". It also appears in addresses, and in the names of lock
 611   # files.
 612
 613   s/U=$parm_eximuser/U=EXIMUSER/;
 614   s/user=$parm_eximuser/user=EXIMUSER/;
 615   s/login=$parm_eximuser/login=EXIMUSER/;
 616   s/Received: from $parm_eximuser /Received: from EXIMUSER /;
 617   s/Running as: $parm_eximuser/Running as: EXIMUSER/;
 618   s/\b$parm_eximuser@/EXIMUSER@/;
 619   s/\b$parm_eximuser\.lock\./EXIMUSER.lock./;
 620
 621   s/\beuid=$parm_exim_uid\b/euid=EXIM_UID/g;
 622   s/\begid=$parm_exim_gid\b/egid=EXIM_GID/g;
 623
 624   s/\buid=$parm_exim_uid\b/uid=EXIM_UID/g;
 625   s/\bgid=$parm_exim_gid\b/gid=EXIM_GID/g;
 626
 627   s/^$parm_eximuser $parm_exim_uid $parm_exim_gid/EXIMUSER EXIM_UID EXIM_GID/;
 628
 629
 630   # ======== General uids, gids, and pids ========
 631   # Note: this must come after munges for caller's and exim's uid/gid
 632
 633   # These are for systems where long int is 64
 634   s/\buid=4294967295/uid=-1/;
 635   s/\beuid=4294967295/euid=-1/;
 636   s/\bgid=4294967295/gid=-1/;
 637   s/\begid=4294967295/egid=-1/;
 638
 639   s/\bgid=\d+/gid=gggg/;
 640   s/\begid=\d+/egid=gggg/;
 641   s/\bpid=\d+/pid=pppp/;
 642   s/\buid=\d+/uid=uuuu/;
 643   s/\beuid=\d+/euid=uuuu/;
 644   s/set_process_info:\s+\d+/set_process_info: pppp/;
 645   s/queue run pid \d+/queue run pid ppppp/;
 646   s/process \d+ running as transport filter/process pppp running as transport filter/;
 647   s/process \d+ writing to transport filter/process pppp writing to transport filter/;
 648   s/reading pipe for subprocess \d+/reading pipe for subprocess pppp/;
 649   s/remote delivery process \d+ ended/remote delivery process pppp ended/;
 650
 651   # Pid in temp file in appendfile transport
 652   s"test-mail/temp\.\d+\."test-mail/temp.pppp.";
 653
 654   # Optional pid in log lines
 655   s/^(\d{4}-\d\d-\d\d\s\d\d:\d\d:\d\d)(\s[+-]\d\d\d\d|)(\s\[\d+\])/
 656     "$1$2 [" . new_value($3, "%s", \$next_pid) . "]"/gxe;
 657
 658   # Detect a daemon stderr line with a pid and save the pid for subsequent
 659   # removal from following lines.
 660   $spid = $1 if /^(\s*\d+) (?:listening|LOG: MAIN|(?:daemon_smtp_port|local_interfaces) overridden by)/;
 661   s/^$spid //;
 662
 663   # Queue runner waiting messages
 664   s/waiting for children of \d+/waiting for children of pppp/;
 665   s/waiting for (\S+) \(\d+\)/waiting for $1 (pppp)/;
 666
 667   # The spool header file name varies with PID
 668   s%^(Writing spool header file: .*/hdr).[0-9]{1,5}%$1.pppp%;
 669
 670   # ======== Port numbers ========
 671   # Incoming port numbers may vary, but not in daemon startup line.
 672
 673   s/^Port: (\d+)/"Port: " . new_value($1, "%s", \$next_port)/e;
 674   s/\(port=(\d+)/"(port=" . new_value($1, "%s", \$next_port)/e;
 675
 676   # This handles "connection from" and the like, when the port is given
 677   if (!/listening for SMTP on/ && !/Connecting to/ && !/=>/ && !/->/
 678       && !/\*>/ && !/Connection refused/)
 679     {
 680     s/\[([a-z\d:]+|\d+(?:\.\d+){3})\]:(\d+)/"[".$1."]:".new_value($2,"%s",\$next_port)/ie;
 681     }
 682
 683   # Port in host address in spool file output from -Mvh
 684   s/^-host_address (.*)\.\d+/-host_address $1.9999/;
 685
 686   if ($dynamic_socket and $dynamic_socket->opened and my $port = $dynamic_socket->sockport) {
 687     s/^Connecting to 127\.0\.0\.1 port \K$port/<dynamic port>/;
 688   }
 689
 690
 691   # ======== Local IP addresses ========
 692   # The amount of space between "host" and the address in verification output
 693   # depends on the length of the host name. We therefore reduce it to one space
 694   # for all of them.
 695   # Also, the length of space at the end of the host line is dependent
 696   # on the length of the longest line, so strip it also on otherwise
 697   # un-rewritten lines like localhost
 698
 699   s/^\s+host\s(\S+)\s+(\S+)/  host $1 $2/;
 700   s/^\s+(host\s\S+\s\S+)\s+(port=.*)/  host $1 $2/;
 701   s/^\s+(host\s\S+\s\S+)\s+(?=MX=)/  $1 /;
 702   s/host\s\Q$parm_ipv4\E\s\[\Q$parm_ipv4\E\]/host ipv4.ipv4.ipv4.ipv4 [ipv4.ipv4.ipv4.ipv4]/;
 703   s/host\s\Q$parm_ipv6\E\s\[\Q$parm_ipv6\E\]/host ip6:ip6:ip6:ip6:ip6:ip6:ip6:ip6 [ip6:ip6:ip6:ip6:ip6:ip6:ip6:ip6]/;
 704   s/\b\Q$parm_ipv4\E\b/ip4.ip4.ip4.ip4/g;
 705   s/(^|\W)\K\Q$parm_ipv6\E/ip6:ip6:ip6:ip6:ip6:ip6:ip6:ip6/g;
 706   s/\b\Q$parm_ipv4r\E\b/ip4-reverse/g;
 707   s/(^|\W)\K\Q$parm_ipv6r\E/ip6-reverse/g;
 708   s/^(\s+host\s\S+\s+\[\S+\]) +$/$1 /;
 709
 710
 711   # ======== Test network IP addresses ========
 712   s/(\b|_)\Q$parm_ipv4_test_net\E(?=\.\d+\.\d+\.\d+\b|_|\.rbl|\.in-addr|\.test\.again\.dns)/$1V4NET/g;
 713   s/\b\Q$parm_ipv6_test_net\E(?=:[\da-f]+:[\da-f]+:[\da-f]+)/V6NET/gi;
 714
 715
 716   # ======== IP error numbers and messages ========
 717   # These vary between operating systems
 718   s/Can't assign requested address/Network Error/;
 719   s/Cannot assign requested address/Network Error/;
 720   s/Operation timed out/Connection timed out/;
 721   s/Address family not supported by protocol family/Network Error/;
 722   s/Network is unreachable/Network Error/;
 723   s/Invalid argument/Network Error/;
 724
 725   s/\(\d+\): Network/(dd): Network/;
 726   s/\(\d+\): Connection refused/(dd): Connection refused/;
 727   s/\(\d+\): Connection timed out/(dd): Connection timed out/;
 728   s/\d+ 65 Connection refused/dd 65 Connection refused/;
 729   s/\d+ 321 Connection timed out/dd 321 Connection timed out/;
 730
 731
 732   # ======== Other error numbers ========
 733   s/errno=\d+/errno=dd/g;
 734
 735   # ======== System Error Messages ======
 736   # depending on the underlaying file system the error message seems to differ
 737   s/(?: is not a regular file)|(?: has too many links \(\d+\))/ not a regular file or too many links/;
 738
 739   # ======== Output from ls ========
 740   # Different operating systems use different spacing on long output
 741   #s/ +/ /g if /^[-rwd]{10} /;
 742   # (Bug 1226) SUSv3 allows a trailing printable char for modified access method control.
 743   # Handle only the Gnu and MacOS space, dot, plus and at-sign.  A full [[:graph:]]
 744   # unfortunately matches a non-ls linefull of dashes.
 745   # Allow the case where we've already picked out the file protection bits.
 746   if (s/^([-d](?:[-r][-w][-SsTtx]){3})[.+@]?( +|$)/$1$2/) {
 747     s/ +/ /g;
 748   }
 749
 750
 751   # ======== Message sizes =========
 752   # Message sizes vary, owing to different logins and host names that get
 753   # automatically inserted. I can't think of any way of even approximately
 754   # comparing these.
 755
 756   s/([\s,])S=\d+\b/$1S=sss/;
 757   s/:S\d+\b/:Ssss/;
 758   s/^(\s*\d+m\s+)\d+(\s+[a-z0-9-]{16} <)/$1sss$2/i if $is_stdout;
 759   s/\sSIZE=\d+\b/ SIZE=ssss/;
 760   s/\ssize=\d+\b/ size=sss/ if $is_stderr;
 761   s/old size = \d+\b/old size = sssss/;
 762   s/message size = \d+\b/message size = sss/;
 763   s/this message = \d+\b/this message = sss/;
 764   s/Size of headers = \d+/Size of headers = sss/;
 765   s/sum=(?!0)\d+/sum=dddd/;
 766   s/(?<=sum=dddd )count=\d+\b/count=dd/;
 767   s/(?<=sum=0 )count=\d+\b/count=dd/;
 768   s/,S is \d+\b/,S is ddddd/;
 769   s/\+0100,\d+;/+0100,ddd;/;
 770   s/\(\d+ bytes written\)/(ddd bytes written)/;
 771   s/added '\d+ 1'/added 'ddd 1'/;
 772   s/Received\s+\d+/Received               nnn/;
 773   s/Delivered\s+\d+/Delivered              nnn/;
 774
 775
 776   # ======== Values in spool space failure message ========
 777   s/space=\d+ inodes=[+-]?\d+/space=xxxxx inodes=xxxxx/;
 778
 779
 780   # ======== Filter sizes ========
 781   # The sizes of filter files may vary because of the substitution of local
 782   # filenames, logins, etc.
 783
 784   s/^\d+(?= bytes read from )/ssss/;
 785
 786
 787   # ======== OpenSSL error messages ========
 788   # Different releases of the OpenSSL libraries seem to give different error
 789   # numbers, or handle specific bad conditions in different ways, leading to
 790   # different wording in the error messages, so we cannot compare them.
 791
 792   s/(TLS error on connection (?:from .* )?\(SSL_\w+\): error:)(.*)/$1 <<detail omitted>>/;
 793   next if /SSL verify error: depth=0 error=certificate not trusted/;
 794
 795   # ======== Maildir things ========
 796   # timestamp output in maildir processing
 797   s/(timestamp=|\(timestamp_only\): )\d+/$1ddddddd/g;
 798
 799   # maildir delivery files appearing in log lines (in cases of error)
 800   s/writing to(?: file)? tmp\/\d+\.[^.]+\.(\S+)/writing to tmp\/MAILDIR.$1/;
 801
 802   s/renamed tmp\/\d+\.[^.]+\.(\S+) as new\/\d+\.[^.]+\.(\S+)/renamed tmp\/MAILDIR.$1 as new\/MAILDIR.$1/;
 803
 804   # Maildir file names in general
 805   s/\b\d+\.H\d+P\d+\b/dddddddddd.HddddddPddddd/;
 806
 807   # Maildirsize data
 808   while (/^\d+S,\d+C\s*$/)
 809     {
 810     print MUNGED;
 811     while (<IN>)
 812       {
 813       last if !/^\d+ \d+\s*$/;
 814       print MUNGED "ddd d\n";
 815       }
 816     last if !defined $_;
 817     }
 818   last if !defined $_;
 819
 820
 821   # ======== Output from the "fd" program about open descriptors ========
 822   # The statuses seem to be different on different operating systems, but
 823   # at least we'll still be checking the number of open fd's.
 824
 825   s/max fd = \d+/max fd = dddd/;
 826   s/status=0 RDONLY/STATUS/g;
 827   s/status=1 WRONLY/STATUS/g;
 828   s/status=2 RDWR/STATUS/g;
 829
 830
 831   # ======== Contents of spool files ========
 832   # A couple of tests dump the contents of the -H file. The length fields
 833   # will be wrong because of different user names, etc.
 834   s/^\d\d\d(?=[PFS*])/ddd/;
 835
 836
 837   # ========= Exim lookups ==================
 838   # Lookups have a char which depends on the number of lookup types compiled in,
 839   # in stderr output.  Replace with a "0".  Recognising this while avoiding
 840   # other output is fragile; perhaps the debug output should be revised instead.
 841   s%(?<!sqlite)(?<!lsearch\*@)(?<!lsearch\*)(?<!lsearch)[0-?]TESTSUITE/aux-fixed/%0TESTSUITE/aux-fixed/%g;
 842
 843   # ==========================================================
 844   # MIME boundaries in RFC3461 DSN messages
 845   s/\d{8,10}-eximdsn-\d+/NNNNNNNNNN-eximdsn-MMMMMMMMMM/;
 846
 847   # ==========================================================
 848   # Some munging is specific to the specific file types
 849
 850   # ======== stdout ========
 851
 852   if ($is_stdout)
 853     {
 854     # Skip translate_ip_address and use_classresources in -bP output because
 855     # they aren't always there.
 856
 857     next if /translate_ip_address =/;
 858     next if /use_classresources/;
 859
 860     # In certain filter tests, remove initial filter lines because they just
 861     # clog up by repetition.
 862
 863     if ($rmfiltertest)
 864       {
 865       next if /^(Sender\staken\sfrom|
 866                  Return-path\scopied\sfrom|
 867                  Sender\s+=|
 868                  Recipient\s+=)/x;
 869       if (/^Testing \S+ filter/)
 870         {
 871         $_ = <IN>;    # remove blank line
 872         next;
 873         }
 874       }
 875
 876     # openssl version variances
 877     next if /^SSL info: unknown state/;
 878     next if /^SSL info: SSLv2\/v3 write client hello A/;
 879     next if /^SSL info: SSLv3 read server key exchange A/;
 880     next if /SSL verify error: depth=0 error=certificate not trusted/;
 881     s/SSL3_READ_BYTES/ssl3_read_bytes/;
 882
 883     # gnutls version variances
 884     next if /^Error in the pull function./;
 885     }
 886
 887   # ======== stderr ========
 888
 889   elsif ($is_stderr)
 890     {
 891     # The very first line of debugging output will vary
 892
 893     s/^Exim version .*/Exim version x.yz ..../;
 894
 895     # Debugging lines for Exim terminations
 896
 897     s/(?<=^>>>>>>>>>>>>>>>> Exim pid=)\d+(?= terminating)/pppp/;
 898
 899     # IP address lookups use gethostbyname() when IPv6 is not supported,
 900     # and gethostbyname2() or getipnodebyname() when it is.
 901
 902     s/\b(gethostbyname2?|\bgetipnodebyname)(\(af=inet\))?/get[host|ipnode]byname[2]/;
 903
 904     # drop gnutls version strings
 905     next if /GnuTLS compile-time version: \d+[\.\d]+$/;
 906     next if /GnuTLS runtime version: \d+[\.\d]+$/;
 907
 908     # drop openssl version strings
 909     next if /OpenSSL compile-time version: OpenSSL \d+[\.\da-z]+/;
 910     next if /OpenSSL runtime version: OpenSSL \d+[\.\da-z]+/;
 911
 912     # drop lookups
 913     next if /^Lookups \(built-in\):/;
 914     next if /^Loading lookup modules from/;
 915     next if /^Loaded \d+ lookup modules/;
 916     next if /^Total \d+ lookups/;
 917
 918     # drop compiler information
 919     next if /^Compiler:/;
 920
 921     # and the ugly bit
 922     # different libraries will have different numbers (possibly 0) of follow-up
 923     # lines, indenting with more data
 924     if (/^Library version:/) {
 925       while (1) {
 926         $_ = <IN>;
 927         next if /^\s/;
 928         goto RESET_AFTER_EXTRA_LINE_READ;
 929       }
 930     }
 931
 932     # drop other build-time controls emitted for debugging
 933     next if /^WHITELIST_D_MACROS:/;
 934     next if /^TRUSTED_CONFIG_LIST:/;
 935
 936     # As of Exim 4.74, we log when a setgid fails; because we invoke Exim
 937     # with -be, privileges will have been dropped, so this will always
 938     # be the case
 939     next if /^changing group to \d+ failed: (Operation not permitted|Not owner)/;
 940
 941     # We might not keep this check; rather than change all the tests, just
 942     # ignore it as long as it succeeds; then we only need to change the
 943     # TLS tests where tls_require_ciphers has been set.
 944     if (m{^changed uid/gid: calling tls_validate_require_cipher}) {
 945       my $discard = <IN>;
 946       next;
 947     }
 948     next if /^tls_validate_require_cipher child \d+ ended: status=0x0/;
 949
 950     # We invoke Exim with -D, so we hit this new messag as of Exim 4.73:
 951     next if /^macros_trusted overridden to true by whitelisting/;
 952
 953     # We have to omit the localhost ::1 address so that all is well in
 954     # the IPv4-only case.
 955
 956     print MUNGED "MUNGED: ::1 will be omitted in what follows\n"
 957       if (/looked up these IP addresses/);
 958     next if /name=localhost address=::1/;
 959
 960     # drop pdkim debugging header
 961     next if /^PDKIM <<<<<<<<<<<<<<<<<<<<<<<<<<<<<+$/;
 962
 963     # Various other IPv6 lines must be omitted too
 964
 965     next if /using host_fake_gethostbyname for \S+ \(IPv6\)/;
 966     next if /get\[host\|ipnode\]byname\[2\]\(af=inet6\)/;
 967     next if /DNS lookup of \S+ \(AAAA\) using fakens/;
 968     next if / in dns_ipv4_lookup?/;
 969
 970     if (/DNS lookup of \S+ \(AAAA\) gave NO_DATA/)
 971       {
 972       $_= <IN>;     # Gets "returning DNS_NODATA"
 973       next;
 974       }
 975
 976     # Skip tls_advertise_hosts and hosts_require_tls checks when the options
 977     # are unset, because tls ain't always there.
 978
 979     next if /in\s(?:tls_advertise_hosts\?|hosts_require_tls\?)
 980                 \sno\s\((option\sunset|end\sof\slist)\)/x;
 981
 982     # Skip auxiliary group lists because they will vary.
 983
 984     next if /auxiliary group list:/;
 985
 986     # Skip "extracted from gecos field" because the gecos field varies
 987
 988     next if /extracted from gecos field/;
 989
 990     # Skip "waiting for data on socket" and "read response data: size=" lines
 991     # because some systems pack more stuff into packets than others.
 992
 993     next if /waiting for data on socket/;
 994     next if /read response data: size=/;
 995
 996     # If Exim is compiled with readline support but it can't find the library
 997     # to load, there will be an extra debug line. Omit it.
 998
 999     next if /failed to load readline:/;
1000
1001     # Some DBM libraries seem to make DBM files on opening with O_RDWR without
1002     # O_CREAT; other's don't. In the latter case there is some debugging output
1003     # which is not present in the former. Skip the relevant lines (there are
1004     # two of them).
1005
1006     if (/TESTSUITE\/spool\/db\/\S+ appears not to exist: trying to create/)
1007       {
1008       $_ = <IN>;
1009       next;
1010       }
1011
1012     # Some tests turn on +expand debugging to check on expansions.
1013     # Unfortunately, the Received: expansion varies, depending on whether TLS
1014     # is compiled or not. So we must remove the relevant debugging if it is.
1015
1016     if (/^condition: def:tls_cipher/)
1017       {
1018       while (<IN>) { last if /^condition: def:sender_address/; }
1019       }
1020     elsif (/^expanding: Received: /)
1021       {
1022       while (<IN>) { last if !/^\s/; }
1023       }
1024
1025     # remote port numbers vary
1026     s/(Connection request from 127.0.0.1 port) \d{1,5}/$1 sssss/;
1027
1028     # Skip hosts_require_dane checks when the options
1029     # are unset, because dane ain't always there.
1030
1031     next if /in\shosts_require_dane\?\sno\s\(option\sunset\)/x;
1032
1033     # SUPPORT_PROXY
1034     next if /host in hosts_proxy\?/;
1035
1036     # Experimental_International
1037     next if / in smtputf8_advertise_hosts\? no \(option unset\)/;
1038
1039     # Environment cleaning
1040     next if /\w+ in keep_environment\? (yes|no)/;
1041
1042     # Sizes vary with test hostname
1043     s/^cmd buf flush \d+ bytes$/cmd buf flush ddd bytes/;
1044
1045     # Spool filesystem free space changes on different systems.
1046     s/^((?:spool|log) directory space =) -?\d+K (inodes =)\s*-?\d+/$1 nnnnnK $2 nnnnn/;
1047
1048     # When Exim is checking the size of directories for maildir, it uses
1049     # the check_dir_size() function to scan directories. Of course, the order
1050     # of the files that are obtained using readdir() varies from system to
1051     # system. We therefore buffer up debugging lines from check_dir_size()
1052     # and sort them before outputting them.
1053
1054     if (/^check_dir_size:/ || /^skipping TESTSUITE\/test-mail\//)
1055       {
1056       push @saved, $_;
1057       }
1058     else
1059       {
1060       if (@saved > 0)
1061         {
1062         print MUNGED "MUNGED: the check_dir_size lines have been sorted " .
1063           "to ensure consistency\n";
1064         @saved = sort(@saved);
1065         print MUNGED @saved;
1066         @saved = ();
1067         }
1068
1069       # Skip some lines that Exim puts out at the start of debugging output
1070       # because they will be different in different binaries.
1071
1072       print MUNGED
1073         unless (/^Berkeley DB: / ||
1074                 /^Probably (?:Berkeley DB|ndbm|GDBM)/ ||
1075                 /^Authenticators:/ ||
1076                 /^Lookups:/ ||
1077                 /^Support for:/ ||
1078                 /^Routers:/ ||
1079                 /^Transports:/ ||
1080                 /^log selectors =/ ||
1081                 /^cwd=/ ||
1082                 /^Fixed never_users:/ ||
1083                 /^Configure owner:/ ||
1084                 /^Size of off_t:/
1085                 );
1086
1087
1088       }
1089
1090     next;
1091     }
1092
1093   # ======== log ========
1094
1095   elsif ($is_log)
1096     {
1097     # Berkeley DB version differences
1098     next if / Berkeley DB error: /;
1099     }
1100
1101   # ======== All files other than stderr ========
1102
1103   print MUNGED;
1104   }
1105
1106 close(IN);
1107 return $yield;
1108 }
1109
1110
1111
1112
1113 ##################################################
1114 #        Subroutine to interact with caller      #
1115 ##################################################
1116
1117 # Arguments: [0] the prompt string
1118 #            [1] if there is a U in the prompt and $force_update is true
1119 #            [2] if there is a C in the prompt and $force_continue is true
1120 # Returns:   returns the answer
1121
1122 sub interact{
1123 print $_[0];
1124 if ($_[1]) { $_ = "u"; print "... update forced\n"; }
1125   elsif ($_[2]) { $_ = "c"; print "... continue forced\n"; }
1126   else { $_ = <T>; }
1127 }
1128
1129
1130
1131 ##################################################
1132 #    Subroutine to log in force_continue mode    #
1133 ##################################################
1134
1135 # In force_continue mode, we just want a terse output to a statically
1136 # named logfile.  If multiple files in same batch (stdout, stderr, etc)
1137 # all have mismatches, it will log multiple times.
1138 #
1139 # Arguments: [0] the logfile to append to
1140 #            [1] the testno that failed
1141 # Returns:   nothing
1142
1143
1144
1145 sub log_failure {
1146   my $logfile = shift();
1147   my $testno  = shift();
1148   my $detail  = shift() || '';
1149   if ( open(my $fh, ">>", $logfile) ) {
1150     print $fh "Test $testno $detail failed\n";
1151     close $fh;
1152   }
1153 }
1154
1155
1156
1157 ##################################################
1158 #    Subroutine to compare one output file       #
1159 ##################################################
1160
1161 # When an Exim server is part of the test, its output is in separate files from
1162 # an Exim client. The server data is concatenated with the client data as part
1163 # of the munging operation.
1164 #
1165 # Arguments:  [0] the name of the main raw output file
1166 #             [1] the name of the server raw output file or undef
1167 #             [2] where to put the munged copy
1168 #             [3] the name of the saved file
1169 #             [4] TRUE if this is a log file whose deliveries must be sorted
1170 #             [5] optionally, a custom munge command
1171 #
1172 # Returns:    0 comparison succeeded or differences to be ignored
1173 #             1 comparison failed; files may have been updated (=> re-compare)
1174 #
1175 # Does not return if the user replies "Q" to a prompt.
1176
1177 sub check_file{
1178 my($rf,$rsf,$mf,$sf,$sortfile,$extra) = @_;
1179
1180 # If there is no saved file, the raw files must either not exist, or be
1181 # empty. The test ! -s is TRUE if the file does not exist or is empty.
1182
1183 # we check if there is a flavour specific file, but we remember
1184 # the original file name as "generic"
1185 $sf_generic = $sf;
1186 $sf_flavour = "$sf_generic.$flavour";
1187 $sf_current = -e $sf_flavour ? $sf_flavour : $sf_generic;
1188
1189 if (! -e $sf_current)
1190   {
1191   return 0 if (! -s $rf && (! defined $rsf || ! -s $rsf));
1192
1193   print "\n";
1194   print "** $rf is not empty\n" if (-s $rf);
1195   print "** $rsf is not empty\n" if (defined $rsf && -s $rsf);
1196
1197   for (;;)
1198     {
1199     print "Continue, Show, or Quit? [Q] ";
1200     $_ = $force_continue ? "c" : <T>;
1201     tests_exit(1) if /^q?$/i;
1202     log_failure($log_failed_filename, $testno, $rf) if (/^c$/i && $force_continue);
1203     return 0 if /^c$/i;
1204     last if (/^s$/);
1205     }
1206
1207   foreach $f ($rf, $rsf)
1208     {
1209     if (defined $f && -s $f)
1210       {
1211       print "\n";
1212       print "------------ $f -----------\n"
1213         if (defined $rf && -s $rf && defined $rsf && -s $rsf);
1214       system("$more '$f'");
1215       }
1216     }
1217
1218   print "\n";
1219   for (;;)
1220     {
1221     interact("Continue, Update & retry, Quit? [Q] ", $force_update, $force_continue);
1222     tests_exit(1) if /^q?$/i;
1223     log_failure($log_failed_filename, $testno, $rsf) if (/^c$/i && $force_continue);
1224     return 0 if /^c$/i;
1225     last if (/^u$/i);
1226     }
1227   }
1228
1229 #### $_
1230
1231 # Control reaches here if either (a) there is a saved file ($sf), or (b) there
1232 # was a request to create a saved file. First, create the munged file from any
1233 # data that does exist.
1234
1235 open(MUNGED, ">$mf") || tests_exit(-1, "Failed to open $mf: $!");
1236 my($truncated) = munge($rf, $extra) if -e $rf;
1237 if (defined $rsf && -e $rsf)
1238   {
1239   print MUNGED "\n******** SERVER ********\n";
1240   $truncated |= munge($rsf, $extra);
1241   }
1242 close(MUNGED);
1243
1244 # If a saved file exists, do the comparison. There are two awkward cases:
1245 #
1246 # If "*** truncated ***" was found in the new file, it means that a log line
1247 # was overlong, and truncated. The problem is that it may be truncated at
1248 # different points on different systems, because of different user name
1249 # lengths. We reload the file and the saved file, and remove lines from the new
1250 # file that precede "*** truncated ***" until we reach one that matches the
1251 # line that precedes it in the saved file.
1252 #
1253 # If $sortfile is set, we are dealing with a mainlog file where the deliveries
1254 # for an individual message might vary in their order from system to system, as
1255 # a result of parallel deliveries. We load the munged file and sort sequences
1256 # of delivery lines.
1257
1258 if (-e $sf_current)
1259   {
1260   # Deal with truncated text items
1261
1262   if ($truncated)
1263     {
1264     my(@munged, @saved, $i, $j, $k);
1265
1266     open(MUNGED, "$mf") || tests_exit(-1, "Failed to open $mf: $!");
1267     @munged = <MUNGED>;
1268     close(MUNGED);
1269     open(SAVED, $sf_current) || tests_exit(-1, "Failed to open $sf_current: $!");
1270     @saved = <SAVED>;
1271     close(SAVED);
1272
1273     $j = 0;
1274     for ($i = 0; $i < @munged; $i++)
1275       {
1276       if ($munged[$i] =~ /\*\*\* truncated \*\*\*/)
1277         {
1278         for (; $j < @saved; $j++)
1279           { last if $saved[$j] =~ /\*\*\* truncated \*\*\*/; }
1280         last if $j >= @saved;     # not found in saved
1281
1282         for ($k = $i - 1; $k >= 0; $k--)
1283           { last if $munged[$k] eq $saved[$j - 1]; }
1284
1285         last if $k <= 0;          # failed to find previous match
1286         splice @munged, $k + 1, $i - $k - 1;
1287         $i = $k + 1;
1288         }
1289       }
1290
1291     open(MUNGED, ">$mf") || tests_exit(-1, "Failed to open $mf: $!");
1292     for ($i = 0; $i < @munged; $i++)
1293       { print MUNGED $munged[$i]; }
1294     close(MUNGED);
1295     }
1296
1297   # Deal with log sorting
1298
1299   if ($sortfile)
1300     {
1301     my(@munged, $i, $j);
1302
1303     open(MUNGED, "$mf") || tests_exit(-1, "Failed to open $mf: $!");
1304     @munged = <MUNGED>;
1305     close(MUNGED);
1306
1307     for ($i = 0; $i < @munged; $i++)
1308       {
1309       if ($munged[$i] =~ /^[-\d]{10}\s[:\d]{8}\s[-A-Za-z\d]{16}\s[-=*]>/)
1310         {
1311         for ($j = $i + 1; $j < @munged; $j++)
1312           {
1313           last if $munged[$j] !~
1314             /^[-\d]{10}\s[:\d]{8}\s[-A-Za-z\d]{16}\s[-=*]>/;
1315           }
1316         @temp = splice(@munged, $i, $j - $i);
1317         @temp = sort(@temp);
1318         splice(@munged, $i, 0, @temp);
1319         }
1320       }
1321
1322     open(MUNGED, ">$mf") || tests_exit(-1, "Failed to open $mf: $!");
1323     print MUNGED "**NOTE: The delivery lines in this file have been sorted.\n";
1324     for ($i = 0; $i < @munged; $i++)
1325       { print MUNGED $munged[$i]; }
1326     close(MUNGED);
1327     }
1328
1329   # Do the comparison
1330
1331   return 0 if (system("$cf '$mf' '$sf_current' >test-cf") == 0);
1332
1333   # Handle comparison failure
1334
1335   print "** Comparison of $mf with $sf_current failed";
1336   system("$more test-cf");
1337
1338   print "\n";
1339   for (;;)
1340     {
1341     interact("Continue, Retry, Update current"
1342         . ($sf_current ne $sf_flavour  ? "/Save for flavour '$flavour'" : "")
1343         . " & retry, Quit? [Q] ", $force_update, $force_continue);
1344     tests_exit(1) if /^q?$/i;
1345     log_failure($log_failed_filename, $testno, $sf_current) if (/^c$/i && $force_continue);
1346     return 0 if /^c$/i;
1347     return 1 if /^r$/i;
1348     last if (/^[us]$/i);
1349     }
1350   }
1351
1352 # Update or delete the saved file, and give the appropriate return code.
1353
1354 if (-s $mf)
1355   {
1356         my $sf = /^u/i ? $sf_current : $sf_flavour;
1357                 tests_exit(-1, "Failed to cp $mf $sf") if system("cp '$mf' '$sf'") != 0;
1358   }
1359 else
1360   {
1361         # if we deal with a flavour file, we can't delete it, because next time the generic
1362         # file would be used again
1363         if ($sf_current eq $sf_flavour) {
1364                 open(FOO, ">$sf_current");
1365                 close(FOO);
1366         }
1367         else {
1368                 tests_exit(-1, "Failed to unlink $sf_current") if !unlink($sf_current);
1369         }
1370   }
1371
1372 return 1;
1373 }
1374
1375
1376
1377 ##################################################
1378 # Custom munges
1379 # keyed by name of munge; value is a ref to a hash
1380 # which is keyed by file, value a string to look for.
1381 # Usable files are:
1382 #  paniclog, rejectlog, mainlog, stdout, stderr, msglog, mail
1383 # Search strings starting with 's' do substitutions;
1384 # with '/' do line-skips.
1385 # Triggered by a scriptfile line "munge <name>"
1386 ##################################################
1387 $munges =
1388   { 'dnssec' =>
1389     { 'stderr' => '/^Reverse DNS security status: unverified\n/' },
1390
1391     'gnutls_unexpected' =>
1392     { 'mainlog' => '/\(recv\): A TLS packet with unexpected length was received./' },
1393
1394     'gnutls_handshake' =>
1395     { 'mainlog' => 's/\(gnutls_handshake\): Error in the push function/\(gnutls_handshake\): A TLS packet with unexpected length was received/' },
1396
1397     'optional_events' =>
1398     { 'stdout' => '/event_action =/' },
1399
1400     'optional_ocsp' =>
1401     { 'stderr' => '/127.0.0.1 in hosts_requ(ire|est)_ocsp/' },
1402
1403     'optional_cert_hostnames' =>
1404     { 'stderr' => '/in tls_verify_cert_hostnames\? no/' },
1405
1406     'loopback' =>
1407     { 'stdout' => 's/[[](127\.0\.0\.1|::1)]/[IP_LOOPBACK_ADDR]/' },
1408
1409     'scanfile_size' =>
1410     { 'stdout' => 's/(Content-length:) \d\d\d/$1 ddd/' },
1411
1412     'delay_1500' =>
1413     { 'stderr' => 's/(1[5-9]|23\d)\d\d msec/ssss msec/' },
1414
1415     'tls_anycipher' =>
1416     { 'mainlog' => 's/ X=TLS\S+ / X=TLS_proto_and_cipher /' },
1417
1418     'debug_pid' =>
1419     { 'stderr' => 's/(^\s{0,4}|(?<=Process )|(?<=child ))\d{1,5}/ppppp/g' },
1420
1421     'optional_dsn_info' =>
1422     { 'mail' => '/^(X-(Remote-MTA-(smtp-greeting|helo-response)|Exim-Diagnostic|(body|message)-linecount):|Remote-MTA: X-ip;)/'
1423     },
1424
1425     'optional_config' =>
1426     { 'stdout' => '/^(
1427                   dkim_(canon|domain|private_key|selector|sign_headers|strict)
1428                   |gnutls_require_(kx|mac|protocols)
1429                   |hosts_(requ(est|ire)|try)_(dane|ocsp)
1430                   |hosts_(avoid|nopass|require|verify_avoid)_tls
1431                   |socks_proxy
1432                   |tls_[^ ]*
1433                   )($|[ ]=)/x' },
1434
1435     'sys_bindir' =>
1436     { 'mainlog' => 's%/(usr/)?bin/%SYSBINDIR/%' },
1437
1438     'sync_check_data' =>
1439     { 'mainlog'   => 's/^(.* SMTP protocol synchronization error .* next input=.{8}).*$/$1<suppressed>/',
1440       'rejectlog' => 's/^(.* SMTP protocol synchronization error .* next input=.{8}).*$/$1<suppressed>/'},
1441
1442     'debuglog_stdout' =>
1443     { 'stdout' => 's/^\d\d:\d\d:\d\d\s+\d+ //;
1444                   s/Process \d+ is ready for new message/Process pppp is ready for new message/'
1445     },
1446   };
1447
1448
1449 ##################################################
1450 #    Subroutine to check the output of a test    #
1451 ##################################################
1452
1453 # This function is called when the series of subtests is complete. It makes
1454 # use of check_file(), whose arguments are:
1455 #
1456 #  [0] the name of the main raw output file
1457 #  [1] the name of the server raw output file or undef
1458 #  [2] where to put the munged copy
1459 #  [3] the name of the saved file
1460 #  [4] TRUE if this is a log file whose deliveries must be sorted
1461 #  [5] an optional custom munge command
1462 #
1463 # Arguments: Optionally, name of a single custom munge to run.
1464 # Returns:   0 if the output compared equal
1465 #            1 if re-run needed (files may have been updated)
1466
1467 sub check_output{
1468 my($mungename) = $_[0];
1469 my($yield) = 0;
1470 my($munge) = $munges->{$mungename} if defined $mungename;
1471
1472 $yield = 1 if check_file("spool/log/paniclog",
1473                        "spool/log/serverpaniclog",
1474                        "test-paniclog-munged",
1475                        "paniclog/$testno", 0,
1476                        $munge->{'paniclog'});
1477
1478 $yield = 1 if check_file("spool/log/rejectlog",
1479                        "spool/log/serverrejectlog",
1480                        "test-rejectlog-munged",
1481                        "rejectlog/$testno", 0,
1482                        $munge->{'rejectlog'});
1483
1484 $yield = 1 if check_file("spool/log/mainlog",
1485                        "spool/log/servermainlog",
1486                        "test-mainlog-munged",
1487                        "log/$testno", $sortlog,
1488                        $munge->{'mainlog'});
1489
1490 if (!$stdout_skip)
1491   {
1492   $yield = 1 if check_file("test-stdout",
1493                        "test-stdout-server",
1494                        "test-stdout-munged",
1495                        "stdout/$testno", 0,
1496                        $munge->{'stdout'});
1497   }
1498
1499 if (!$stderr_skip)
1500   {
1501   $yield = 1 if check_file("test-stderr",
1502                        "test-stderr-server",
1503                        "test-stderr-munged",
1504                        "stderr/$testno", 0,
1505                        $munge->{'stderr'});
1506   }
1507
1508 # Compare any delivered messages, unless this test is skipped.
1509
1510 if (! $message_skip)
1511   {
1512   my($msgno) = 0;
1513
1514   # Get a list of expected mailbox files for this script. We don't bother with
1515   # directories, just the files within them.
1516
1517   foreach $oldmail (@oldmails)
1518     {
1519     next unless $oldmail =~ /^mail\/$testno\./;
1520     print ">> EXPECT $oldmail\n" if $debug;
1521     $expected_mails{$oldmail} = 1;
1522     }
1523
1524   # If there are any files in test-mail, compare them. Note that "." and
1525   # ".." are automatically omitted by list_files_below().
1526
1527   @mails = list_files_below("test-mail");
1528
1529   foreach $mail (@mails)
1530     {
1531     next if $mail eq "test-mail/oncelog";
1532
1533     $saved_mail = substr($mail, 10);               # Remove "test-mail/"
1534     $saved_mail =~ s/^$parm_caller(\/|$)/CALLER/;  # Convert caller name
1535
1536     if ($saved_mail =~ /(\d+\.[^.]+\.)/)
1537       {
1538       $msgno++;
1539       $saved_mail =~ s/(\d+\.[^.]+\.)/$msgno./gx;
1540       }
1541
1542     print ">> COMPARE $mail mail/$testno.$saved_mail\n" if $debug;
1543     $yield = 1 if check_file($mail, undef, "test-mail-munged",
1544       "mail/$testno.$saved_mail", 0,
1545       $munge->{'mail'});
1546     delete $expected_mails{"mail/$testno.$saved_mail"};
1547     }
1548
1549   # Complain if not all expected mails have been found
1550
1551   if (scalar(keys %expected_mails) != 0)
1552     {
1553     foreach $key (keys %expected_mails)
1554       { print "** no test file found for $key\n"; }
1555
1556     for (;;)
1557       {
1558       interact("Continue, Update & retry, or Quit? [Q] ", $force_update, $force_continue);
1559       tests_exit(1) if /^q?$/i;
1560       log_failure($log_failed_filename, $testno, "missing email") if (/^c$/i && $force_continue);
1561       last if /^c$/i;
1562
1563       # For update, we not only have to unlink the file, but we must also
1564       # remove it from the @oldmails vector, as otherwise it will still be
1565       # checked for when we re-run the test.
1566
1567       if (/^u$/i)
1568         {
1569         foreach $key (keys %expected_mails)
1570           {
1571           my($i);
1572           tests_exit(-1, "Failed to unlink $key") if !unlink("$key");
1573           for ($i = 0; $i < @oldmails; $i++)
1574             {
1575             if ($oldmails[$i] eq $key)
1576               {
1577               splice @oldmails, $i, 1;
1578               last;
1579               }
1580             }
1581           }
1582         last;
1583         }
1584       }
1585     }
1586   }
1587
1588 # Compare any remaining message logs, unless this test is skipped.
1589
1590 if (! $msglog_skip)
1591   {
1592   # Get a list of expected msglog files for this test
1593
1594   foreach $oldmsglog (@oldmsglogs)
1595     {
1596     next unless $oldmsglog =~ /^$testno\./;
1597     $expected_msglogs{$oldmsglog} = 1;
1598     }
1599
1600   # If there are any files in spool/msglog, compare them. However, we have
1601   # to munge the file names because they are message ids, which are
1602   # time dependent.
1603
1604   if (opendir(DIR, "spool/msglog"))
1605     {
1606     @msglogs = sort readdir(DIR);
1607     closedir(DIR);
1608
1609     foreach $msglog (@msglogs)
1610       {
1611       next if ($msglog eq "." || $msglog eq ".." || $msglog eq "CVS");
1612       ($munged_msglog = $msglog) =~
1613         s/((?:[^\W_]{6}-){2}[^\W_]{2})
1614           /new_value($1, "10Hm%s-0005vi-00", \$next_msgid)/egx;
1615       $yield = 1 if check_file("spool/msglog/$msglog", undef,
1616         "test-msglog-munged", "msglog/$testno.$munged_msglog", 0,
1617         $munge->{'msglog'});
1618       delete $expected_msglogs{"$testno.$munged_msglog"};
1619       }
1620     }
1621
1622   # Complain if not all expected msglogs have been found
1623
1624   if (scalar(keys %expected_msglogs) != 0)
1625     {
1626     foreach $key (keys %expected_msglogs)
1627       {
1628       print "** no test msglog found for msglog/$key\n";
1629       ($msgid) = $key =~ /^\d+\.(.*)$/;
1630       foreach $cachekey (keys %cache)
1631         {
1632         if ($cache{$cachekey} eq $msgid)
1633           {
1634           print "** original msgid $cachekey\n";
1635           last;
1636           }
1637         }
1638       }
1639
1640     for (;;)
1641       {
1642       interact("Continue, Update, or Quit? [Q] ", $force_update, $force_continue);
1643       tests_exit(1) if /^q?$/i;
1644       log_failure($log_failed_filename, $testno, "missing msglog") if (/^c$/i && $force_continue);
1645       last if /^c$/i;
1646       if (/^u$/i)
1647         {
1648         foreach $key (keys %expected_msglogs)
1649           {
1650           tests_exit(-1, "Failed to unlink msglog/$key")
1651             if !unlink("msglog/$key");
1652           }
1653         last;
1654         }
1655       }
1656     }
1657   }
1658
1659 return $yield;
1660 }
1661
1662
1663
1664 ##################################################
1665 #     Subroutine to run one "system" command     #
1666 ##################################################
1667
1668 # We put this in a subroutine so that the command can be reflected when
1669 # debugging.
1670 #
1671 # Argument: the command to be run
1672 # Returns:  nothing
1673
1674 sub run_system {
1675 my($cmd) = $_[0];
1676 if ($debug)
1677   {
1678   my($prcmd) = $cmd;
1679   $prcmd =~ s/; /;\n>> /;
1680   print ">> $prcmd\n";
1681   }
1682 system("$cmd");
1683 }
1684
1685
1686
1687 ##################################################
1688 #      Subroutine to run one script command      #
1689 ##################################################
1690
1691 # The <SCRIPT> file is open for us to read an optional return code line,
1692 # followed by the command line and any following data lines for stdin. The
1693 # command line can be continued by the use of \. Data lines are not continued
1694 # in this way. In all lines, the following substutions are made:
1695 #
1696 # DIR    => the current directory
1697 # CALLER => the caller of this script
1698 #
1699 # Arguments: the current test number
1700 #            reference to the subtest number, holding previous value
1701 #            reference to the expected return code value
1702 #            reference to where to put the command name (for messages)
1703 #            auxilliary information returned from a previous run
1704 #
1705 # Returns:   0 the commmand was executed inline, no subprocess was run
1706 #            1 a non-exim command was run and waited for
1707 #            2 an exim command was run and waited for
1708 #            3 a command was run and not waited for (daemon, server, exim_lock)
1709 #            4 EOF was encountered after an initial return code line
1710 # Optionally alse a second parameter, a hash-ref, with auxilliary information:
1711 #            exim_pid: pid of a run process
1712 #            munge: name of a post-script results munger
1713
1714 sub run_command{
1715 my($testno) = $_[0];
1716 my($subtestref) = $_[1];
1717 my($commandnameref) = $_[3];
1718 my($aux_info) = $_[4];
1719 my($yield) = 1;
1720
1721 our %ENV = map { $_ => $ENV{$_} } grep { /^(?:USER|SHELL|PATH|TERM|EXIM_TEST_.*)$/ } keys %ENV;
1722
1723 if (/^(\d+)\s*$/)                # Handle unusual return code
1724   {
1725   my($r) = $_[2];
1726   $$r = $1 << 8;
1727   $_ = <SCRIPT>;
1728   return 4 if !defined $_;       # Missing command
1729   $lineno++;
1730   }
1731
1732 chomp;
1733 $wait_time = 0;
1734
1735 # Handle concatenated command lines
1736
1737 s/\s+$//;
1738 while (substr($_, -1) eq"\\")
1739   {
1740   my($temp);
1741   $_ = substr($_, 0, -1);
1742   chomp($temp = <SCRIPT>);
1743   if (defined $temp)
1744     {
1745     $lineno++;
1746     $temp =~ s/\s+$//;
1747     $temp =~ s/^\s+//;
1748     $_ .= $temp;
1749     }
1750   }
1751
1752 # Do substitutions
1753
1754 do_substitute($testno);
1755 if ($debug) { printf ">> $_\n"; }
1756
1757 # Pass back the command name (for messages)
1758
1759 ($$commandnameref) = /^(\S+)/;
1760
1761 # Here follows code for handling the various different commands that are
1762 # supported by this script. The first group of commands are all freestanding
1763 # in that they share no common code and are not followed by any data lines.
1764
1765
1766 ###################
1767 ###################
1768
1769 # The "dbmbuild" command runs exim_dbmbuild. This is used both to test the
1770 # utility and to make DBM files for testing DBM lookups.
1771
1772 if (/^dbmbuild\s+(\S+)\s+(\S+)/)
1773   {
1774   run_system("(./eximdir/exim_dbmbuild $parm_cwd/$1 $parm_cwd/$2;" .
1775          "echo exim_dbmbuild exit code = \$?)" .
1776          ">>test-stdout");
1777   return 1;
1778   }
1779
1780
1781 # The "dump" command runs exim_dumpdb. On different systems, the output for
1782 # some types of dump may appear in a different order because it's just hauled
1783 # out of the DBM file. We can solve this by sorting. Ignore the leading
1784 # date/time, as it will be flattened later during munging.
1785
1786 if (/^dump\s+(\S+)/)
1787   {
1788   my($which) = $1;
1789   my(@temp);
1790   print ">> ./eximdir/exim_dumpdb $parm_cwd/spool $which\n" if $debug;
1791   open(IN, "./eximdir/exim_dumpdb $parm_cwd/spool $which |");
1792   open(OUT, ">>test-stdout");
1793   print OUT "+++++++++++++++++++++++++++\n";
1794
1795   if ($which eq "retry")
1796     {
1797     $/ = "\n  ";
1798     @temp = <IN>;
1799     $/ = "\n";
1800
1801     @temp = sort {
1802                    my($aa) = split(' ', $a);
1803                    my($bb) = split(' ', $b);
1804                    return $aa cmp $bb;
1805                  } @temp;
1806
1807     foreach $item (@temp)
1808       {
1809       $item =~ s/^\s*(.*)\n(.*)\n?\s*$/$1\n$2/m;
1810       print OUT "  $item\n";
1811       }
1812     }
1813   else
1814     {
1815     @temp = <IN>;
1816     if ($which eq "callout")
1817       {
1818       @temp = sort {
1819                    my($aa) = substr $a, 21;
1820                    my($bb) = substr $b, 21;
1821                    return $aa cmp $bb;
1822                    } @temp;
1823       }
1824     print OUT @temp;
1825     }
1826
1827   close(IN);
1828   close(OUT);
1829   return 1;
1830   }
1831
1832
1833 # The "echo" command is a way of writing comments to the screen.
1834
1835 if (/^echo\s+(.*)$/)
1836   {
1837   print "$1\n";
1838   return 0;
1839   }
1840
1841
1842 # The "exim_lock" command runs exim_lock in the same manner as "server",
1843 # but it doesn't use any input.
1844
1845 if (/^exim_lock\s+(.*)$/)
1846   {
1847   $cmd = "./eximdir/exim_lock $1 >>test-stdout";
1848   $server_pid = open SERVERCMD, "|$cmd" ||
1849     tests_exit(-1, "Failed to run $cmd\n");
1850
1851   # This gives the process time to get started; otherwise the next
1852   # process may not find it there when it expects it.
1853
1854   select(undef, undef, undef, 0.1);
1855   return 3;
1856   }
1857
1858
1859 # The "exinext" command runs exinext
1860
1861 if (/^exinext\s+(.*)/)
1862   {
1863   run_system("(./eximdir/exinext " .
1864     "-DEXIM_PATH=$parm_cwd/eximdir/exim " .
1865     "-C $parm_cwd/test-config $1;" .
1866     "echo exinext exit code = \$?)" .
1867     ">>test-stdout");
1868   return 1;
1869   }
1870
1871
1872 # The "exigrep" command runs exigrep on the current mainlog
1873
1874 if (/^exigrep\s+(.*)/)
1875   {
1876   run_system("(./eximdir/exigrep " .
1877     "$1 $parm_cwd/spool/log/mainlog;" .
1878     "echo exigrep exit code = \$?)" .
1879     ">>test-stdout");
1880   return 1;
1881   }
1882
1883
1884 # The "eximstats" command runs eximstats on the current mainlog
1885
1886 if (/^eximstats\s+(.*)/)
1887   {
1888   run_system("(./eximdir/eximstats " .
1889     "$1 $parm_cwd/spool/log/mainlog;" .
1890     "echo eximstats exit code = \$?)" .
1891     ">>test-stdout");
1892   return 1;
1893   }
1894
1895
1896 # The "gnutls" command makes a copy of saved GnuTLS parameter data in the
1897 # spool directory, to save Exim from re-creating it each time.
1898
1899 if (/^gnutls/)
1900   {
1901   my $gen_fn = "spool/gnutls-params-$gnutls_dh_bits_normal";
1902   run_system "sudo cp -p aux-fixed/gnutls-params $gen_fn;" .
1903          "sudo chown $parm_eximuser:$parm_eximgroup $gen_fn;" .
1904          "sudo chmod 0400 $gen_fn";
1905   return 1;
1906   }
1907
1908
1909 # The "killdaemon" command should ultimately follow the starting of any Exim
1910 # daemon with the -bd option. We kill with SIGINT rather than SIGTERM to stop
1911 # it outputting "Terminated" to the terminal when not in the background.
1912
1913 if (/^killdaemon/)
1914   {
1915   my $return_extra = {};
1916   if (exists $aux_info->{exim_pid})
1917     {
1918     $pid = $aux_info->{exim_pid};
1919     $return_extra->{exim_pid} = undef;
1920     print ">> killdaemon: recovered pid $pid\n" if $debug;
1921     if ($pid)
1922       {
1923       run_system("sudo /bin/kill -INT $pid");
1924       wait;
1925       }
1926     } else {
1927     $pid = `cat $parm_cwd/spool/exim-daemon.*`;
1928     if ($pid)
1929       {
1930       run_system("sudo /bin/kill -INT $pid");
1931       close DAEMONCMD;                                   # Waits for process
1932       }
1933     }
1934     run_system("sudo /bin/rm -f spool/exim-daemon.*");
1935   return (1, $return_extra);
1936   }
1937
1938
1939 # The "millisleep" command is like "sleep" except that its argument is in
1940 # milliseconds, thus allowing for a subsecond sleep, which is, in fact, all it
1941 # is used for.
1942
1943 elsif (/^millisleep\s+(.*)$/)
1944   {
1945   select(undef, undef, undef, $1/1000);
1946   return 0;
1947   }
1948
1949
1950 # The "munge" command selects one of a hardwired set of test-result modifications
1951 # to be made before result compares are run agains the golden set.  This lets
1952 # us account for test-system dependent things which only affect a few, but known,
1953 # test-cases.
1954 # Currently only the last munge takes effect.
1955
1956 if (/^munge\s+(.*)$/)
1957   {
1958   return (0, { munge => $1 });
1959   }
1960
1961
1962 # The "sleep" command does just that. For sleeps longer than 1 second we
1963 # tell the user what's going on.
1964
1965 if (/^sleep\s+(.*)$/)
1966   {
1967   if ($1 == 1)
1968     {
1969     sleep(1);
1970     }
1971   else
1972     {
1973     printf("  Test %d sleep $1 ", $$subtestref);
1974     for (1..$1)
1975       {
1976       print ".";
1977       sleep(1);
1978       }
1979     printf("\r  Test %d                            $cr", $$subtestref);
1980     }
1981   return 0;
1982   }
1983
1984
1985 # Various Unix management commands are recognized
1986
1987 if (/^(ln|ls|du|mkdir|mkfifo|touch|cp|cat)\s/ ||
1988     /^sudo\s(rmdir|rm|mv|chown|chmod)\s/)
1989   {
1990   run_system("$_ >>test-stdout 2>>test-stderr");
1991   return 1;
1992   }
1993
1994
1995
1996 ###################
1997 ###################
1998
1999 # The next group of commands are also freestanding, but they are all followed
2000 # by data lines.
2001
2002
2003 # The "server" command starts up a script-driven server that runs in parallel
2004 # with the following exim command. Therefore, we want to run a subprocess and
2005 # not yet wait for it to complete. The waiting happens after the next exim
2006 # command, triggered by $server_pid being non-zero. The server sends its output
2007 # to a different file. The variable $server_opts, if not empty, contains
2008 # options to disable IPv4 or IPv6 if necessary.
2009 # This works because "server" swallows its stdin before waiting for a connection.
2010
2011 if (/^server\s+(.*)$/)
2012   {
2013   $pidfile = "$parm_cwd/aux-var/server-daemon.pid";
2014   $cmd = "./bin/server $server_opts -oP $pidfile $1 >>test-stdout-server";
2015   print ">> $cmd\n" if ($debug);
2016   $server_pid = open SERVERCMD, "|$cmd" || tests_exit(-1, "Failed to run $cmd");
2017   SERVERCMD->autoflush(1);
2018   print ">> Server pid is $server_pid\n" if $debug;
2019   while (<SCRIPT>)
2020     {
2021     $lineno++;
2022     last if /^\*{4}\s*$/;
2023     print SERVERCMD;
2024     }
2025   print SERVERCMD "++++\n"; # Send end to server; can't send EOF yet
2026                             # because close() waits for the process.
2027
2028   # Interlock the server startup; otherwise the next
2029   # process may not find it there when it expects it.
2030   while (! stat("$pidfile") ) { select(undef, undef, undef, 0.3); }
2031   return 3;
2032   }
2033
2034
2035 # The "write" command is a way of creating files of specific sizes for
2036 # buffering tests, or containing specific data lines from within the script
2037 # (rather than hold lots of little files). The "catwrite" command does the
2038 # same, but it also copies the lines to test-stdout.
2039
2040 if (/^(cat)?write\s+(\S+)(?:\s+(.*))?\s*$/)
2041   {
2042   my($cat) = defined $1;
2043   @sizes = ();
2044   @sizes = split /\s+/, $3 if defined $3;
2045   open FILE, ">$2" || tests_exit(-1, "Failed to open \"$2\": $!");
2046
2047   if ($cat)
2048     {
2049     open CAT, ">>test-stdout" ||
2050       tests_exit(-1, "Failed to open test-stdout: $!");
2051     print CAT "==========\n";
2052     }
2053
2054   if (scalar @sizes > 0)
2055     {
2056     # Pre-data
2057
2058     while (<SCRIPT>)
2059       {
2060       $lineno++;
2061       last if /^\+{4}\s*$/;
2062       print FILE;
2063       print CAT if $cat;
2064       }
2065
2066     # Sized data
2067
2068     while (scalar @sizes > 0)
2069       {
2070       ($count,$len,$leadin) = (shift @sizes) =~ /(\d+)x(\d+)(?:=(.*))?/;
2071       $leadin = "" if !defined $leadin;
2072       $leadin =~ s/_/ /g;
2073       $len -= length($leadin) + 1;
2074       while ($count-- > 0)
2075         {
2076         print FILE $leadin, "a" x $len, "\n";
2077         print CAT $leadin, "a" x $len, "\n" if $cat;
2078         }
2079       }
2080     }
2081
2082   # Post data, or only data if no sized data
2083
2084   while (<SCRIPT>)
2085     {
2086     $lineno++;
2087     last if /^\*{4}\s*$/;
2088     print FILE;
2089     print CAT if $cat;
2090     }
2091   close FILE;
2092
2093   if ($cat)
2094     {
2095     print CAT "==========\n";
2096     close CAT;
2097     }
2098
2099   return 0;
2100   }
2101
2102
2103 ###################
2104 ###################
2105
2106 # From this point on, script commands are implemented by setting up a shell
2107 # command in the variable $cmd. Shared code to run this command and handle its
2108 # input and output follows.
2109
2110 # The "client", "client-gnutls", and "client-ssl" commands run a script-driven
2111 # program that plays the part of an email client. We also have the availability
2112 # of running Perl for doing one-off special things. Note that all these
2113 # commands expect stdin data to be supplied.
2114
2115 if (/^client/ || /^(sudo\s+)?perl\b/)
2116   {
2117   s"client"./bin/client";
2118   $cmd = "$_ >>test-stdout 2>>test-stderr";
2119   }
2120
2121 # For the "exim" command, replace the text "exim" with the path for the test
2122 # binary, plus -D options to pass over various parameters, and a -C option for
2123 # the testing configuration file. When running in the test harness, Exim does
2124 # not drop privilege when -C and -D options are present. To run the exim
2125 # command as root, we use sudo.
2126
2127 elsif (/^((?i:[A-Z\d_]+=\S+\s+)+)?(\d+)?\s*(sudo(?:\s+-u\s+(\w+))?\s+)?exim(_\S+)?\s+(.*)$/)
2128   {
2129   $args = $6;
2130   my($envset) = (defined $1)? $1      : "";
2131   my($sudo)   = (defined $3)? "sudo " . (defined $4 ? "-u $4 ":"")  : "";
2132   my($special)= (defined $5)? $5      : "";
2133   $wait_time  = (defined $2)? $2      : 0;
2134
2135   # Return 2 rather than 1 afterwards
2136
2137   $yield = 2;
2138
2139   # Update the test number
2140
2141   $$subtestref = $$subtestref + 1;
2142   printf("  Test %d       $cr", $$subtestref);
2143
2144   # Copy the configuration file, making the usual substitutions.
2145
2146   open (IN, "$parm_cwd/confs/$testno") ||
2147     tests_exit(-1, "Couldn't open $parm_cwd/confs/$testno: $!\n");
2148   open (OUT, ">test-config") ||
2149     tests_exit(-1, "Couldn't open test-config: $!\n");
2150   while (<IN>)
2151     {
2152     do_substitute($testno);
2153     print OUT;
2154     }
2155   close(IN);
2156   close(OUT);
2157
2158   # The string $msg1 in args substitutes the message id of the first
2159   # message on the queue, and so on. */
2160
2161   if ($args =~ /\$msg/)
2162     {
2163     my($listcmd) = "$parm_cwd/eximdir/exim -bp " .
2164                    "-DEXIM_PATH=$parm_cwd/eximdir/exim " .
2165                    "-C $parm_cwd/test-config |";
2166     print ">> Getting queue list from:\n>>    $listcmd\n" if ($debug);
2167     open (QLIST, $listcmd) || tests_exit(-1, "Couldn't run \"exim -bp\": $!\n");
2168     my(@msglist) = ();
2169     while (<QLIST>) { push (@msglist, $1) if /^\s*\d+[smhdw]\s+\S+\s+(\S+)/; }
2170     close(QLIST);
2171
2172     # Done backwards just in case there are more than 9
2173
2174     for (my $i = @msglist; $i > 0; $i--) { $args =~ s/\$msg$i/$msglist[$i-1]/g; }
2175     if ( $args =~ /\$msg\d/ )
2176       {
2177       tests_exit(-1, "Not enough messages in spool, for test $testno line $lineno\n")
2178         unless $force_continue;
2179       }
2180     }
2181
2182   # If -d is specified in $optargs, remove it from $args; i.e. let
2183   # the command line for runtest override. Then run Exim.
2184
2185   $args =~ s/(?:^|\s)-d\S*// if $optargs =~ /(?:^|\s)-d/;
2186
2187   my $opt_valgrind = $valgrind ? "valgrind --leak-check=yes --suppressions=$parm_cwd/aux-fixed/valgrind.supp " : "";
2188
2189   $cmd = "$envset$sudo$opt_valgrind" .
2190          "$parm_cwd/eximdir/exim$special$optargs " .
2191          "-DEXIM_PATH=$parm_cwd/eximdir/exim$special " .
2192          "-C $parm_cwd/test-config $args " .
2193          ">>test-stdout 2>>test-stderr";
2194   # If the command is starting an Exim daemon, we run it in the same
2195   # way as the "server" command above, that is, we don't want to wait
2196   # for the process to finish. That happens when "killdaemon" is obeyed later
2197   # in the script. We also send the stderr output to test-stderr-server. The
2198   # daemon has its log files put in a different place too (by configuring with
2199   # log_file_path). This requires the  directory to be set up in advance.
2200   #
2201   # There are also times when we want to run a non-daemon version of Exim
2202   # (e.g. a queue runner) with the server configuration. In this case,
2203   # we also define -DNOTDAEMON.
2204
2205   if ($cmd =~ /\s-DSERVER=server\s/ && $cmd !~ /\s-DNOTDAEMON\s/)
2206     {
2207     $pidfile = "$parm_cwd/spool/exim-daemon.pid";
2208     if ($debug) { printf ">> daemon: $cmd\n"; }
2209     run_system("sudo mkdir spool/log 2>/dev/null");
2210     run_system("sudo chown $parm_eximuser:$parm_eximgroup spool/log");
2211
2212     # Before running the command, convert the -bd option into -bdf so that an
2213     # Exim daemon doesn't double fork. This means that when we wait close
2214     # DAEMONCMD, it waits for the correct process. Also, ensure that the pid
2215     # file is written to the spool directory, in case the Exim binary was
2216     # built with PID_FILE_PATH pointing somewhere else.
2217
2218     if ($cmd =~ /\s-oP\s/)
2219       {
2220       ($pidfile = $cmd) =~ s/^.*-oP ([^ ]+).*$/$1/;
2221       $cmd =~ s!\s-bd\s! -bdf !;
2222       }
2223     else
2224       {
2225       $pidfile = "$parm_cwd/spool/exim-daemon.pid";
2226       $cmd =~ s!\s-bd\s! -bdf -oP $pidfile !;
2227       }
2228     print ">> |${cmd}-server\n" if ($debug);
2229     open DAEMONCMD, "|${cmd}-server" || tests_exit(-1, "Failed to run $cmd");
2230     DAEMONCMD->autoflush(1);
2231     while (<SCRIPT>) { $lineno++; last if /^\*{4}\s*$/; }   # Ignore any input
2232
2233     # Interlock with daemon startup
2234     while (! stat("$pidfile") ) { select(undef, undef, undef, 0.3); }
2235     return 3;                                     # Don't wait
2236     }
2237   elsif ($cmd =~ /\s-DSERVER=wait:(\d+)\s/)
2238     {
2239
2240     # The port and the $dynamic_socket was already allocated while parsing the
2241     # script file, where -DSERVER=wait:PORT_DYNAMIC was encountered.
2242
2243     my $listen_port = $1;
2244     if ($debug) { printf ">> wait-mode daemon: $cmd\n"; }
2245     run_system("sudo mkdir spool/log 2>/dev/null");
2246     run_system("sudo chown $parm_eximuser:$parm_eximgroup spool/log");
2247
2248     my $pid = fork();
2249     if (not defined $pid) { die "** fork failed: $!\n" }
2250     if (not $pid) {
2251       close(STDIN);
2252       open(STDIN, '<&', $dynamic_socket) or die "** dup sock to stdin failed: $!\n";
2253       close($dynamic_socket);
2254       print "[$$]>> ${cmd}-server\n" if ($debug);
2255       exec "exec ${cmd}-server";
2256       die "Can't exec ${cmd}-server: $!\n";
2257     }
2258     while (<SCRIPT>) { $lineno++; last if /^\*{4}\s*$/; }   # Ignore any input
2259     select(undef, undef, undef, 0.3);             # Let the daemon get going
2260     return (3, { exim_pid => $pid });             # Don't wait
2261     }
2262   }
2263
2264 # The "background" command is run but not waited-for, like exim -DSERVER=server.
2265 # One script line is read and fork-exec'd.  The PID is stored for a later
2266 # killdaemon.
2267
2268 elsif (/^background$/)
2269   {
2270   my $line;
2271 #  $pidfile = "$parm_cwd/aux-var/server-daemon.pid";
2272
2273   $_ = <SCRIPT>; $lineno++;
2274   chomp;
2275   $line = $_;
2276   if ($debug) { printf ">> daemon: $line >>test-stdout 2>>test-stderr\n"; }
2277
2278   my $pid = fork();
2279   if (not defined $pid) { die "** fork failed: $!\n" }
2280   if (not $pid) {
2281     print "[$$]>> ${line}\n" if ($debug);
2282     close(STDIN);
2283     open(STDIN, "<", "test-stdout");
2284     close(STDOUT);
2285     open(STDOUT, ">>", "test-stdout");
2286     close(STDERR);
2287     open(STDERR, ">>", "test-stderr-server");
2288     exec "exec ${line}";
2289     exit(1);
2290   }
2291
2292 #  open(my $fh, ">", $pidfile) ||
2293 #      tests_exit(-1, "Failed to open $pidfile: $!");
2294 #  printf($fh, "%d\n", $pid);
2295 #  close($fh);
2296
2297   while (<SCRIPT>) { $lineno++; last if /^\*{4}\s*$/; }   # Ignore any input
2298   select(undef, undef, undef, 0.3);             # Let the daemon get going
2299   return (3, { exim_pid => $pid });             # Don't wait
2300   }
2301
2302
2303
2304 # Unknown command
2305
2306 else { tests_exit(-1, "Command unrecognized in line $lineno: $_"); }
2307
2308
2309 # Run the command, with stdin connected to a pipe, and write the stdin data
2310 # to it, with appropriate substitutions. If a line ends with \NONL\, chop off
2311 # the terminating newline (and the \NONL\). If the command contains
2312 # -DSERVER=server add "-server" to the command, where it will adjoin the name
2313 # for the stderr file. See comment above about the use of -DSERVER.
2314
2315 $stderrsuffix = ($cmd =~ /\s-DSERVER=server\s/)? "-server" : "";
2316 print ">> |${cmd}${stderrsuffix}\n" if ($debug);
2317 open CMD, "|${cmd}${stderrsuffix}" || tests_exit(1, "Failed to run $cmd");
2318
2319 CMD->autoflush(1);
2320 while (<SCRIPT>)
2321   {
2322   $lineno++;
2323   last if /^\*{4}\s*$/;
2324   do_substitute($testno);
2325   if (/^(.*)\\NONL\\\s*$/) { print CMD $1; } else { print CMD; }
2326   }
2327
2328 # For timeout tests, wait before closing the pipe; we expect a
2329 # SIGPIPE error in this case.
2330
2331 if ($wait_time > 0)
2332   {
2333   printf("  Test %d sleep $wait_time ", $$subtestref);
2334   while ($wait_time-- > 0)
2335     {
2336     print ".";
2337     sleep(1);
2338     }
2339   printf("\r  Test %d                                       $cr", $$subtestref);
2340   }
2341
2342 $sigpipehappened = 0;
2343 close CMD;                # Waits for command to finish
2344 return $yield;            # Ran command and waited
2345 }
2346
2347
2348
2349
2350 ###############################################################################
2351 ###############################################################################
2352
2353 # Here begins the Main Program ...
2354
2355 ###############################################################################
2356 ###############################################################################
2357
2358
2359 autoflush STDOUT 1;
2360 print "Exim tester $testversion\n";
2361
2362 # extend the PATH with .../sbin
2363 # we map all (.../bin) to (.../sbin:.../bin)
2364 $ENV{PATH} = do {
2365   my %seen = map { $_, 1 } split /:/, $ENV{PATH};
2366   join ':' => map { m{(.*)/bin$}
2367                 ? ( $seen{"$1/sbin"} ? () : ("$1/sbin"), $_)
2368                 : ($_) }
2369       split /:/, $ENV{PATH};
2370 };
2371
2372 ##################################################
2373 #      Some tests check created file modes       #
2374 ##################################################
2375
2376 umask 022;
2377
2378
2379 ##################################################
2380 #       Check for the "less" command             #
2381 ##################################################
2382
2383 $more = 'more' if system('which less >/dev/null 2>&1') != 0;
2384
2385
2386
2387 ##################################################
2388 #        Check for sudo access to root           #
2389 ##################################################
2390
2391 print "You need to have sudo access to root to run these tests. Checking ...\n";
2392 if (system('sudo true >/dev/null') != 0)
2393   {
2394   die "** Test for sudo failed: testing abandoned.\n";
2395   }
2396 else
2397   {
2398   print "Test for sudo OK\n";
2399   }
2400
2401
2402
2403 ##################################################
2404 #      See if an Exim binary has been given      #
2405 ##################################################
2406
2407 # If the first character of the first argument is '/', the argument is taken
2408 # as the path to the binary. If the first argument does not start with a
2409 # '/' but exists in the file system, it's assumed to be the Exim binary.
2410
2411 $parm_exim = (@ARGV > 0 && (-x $ARGV[0] or $ARGV[0] =~ m?^/?))? Cwd::abs_path(shift @ARGV) : "";
2412 print "Exim binary is $parm_exim\n" if $parm_exim ne "";
2413
2414
2415
2416 ##################################################
2417 # Sort out options and which tests are to be run #
2418 ##################################################
2419
2420 # There are a few possible options for the test script itself; after these, any
2421 # options are passed on to Exim calls within the tests. Typically, this is used
2422 # to turn on Exim debugging while setting up a test.
2423
2424 while (@ARGV > 0 && $ARGV[0] =~ /^-/)
2425   {
2426   my($arg) = shift @ARGV;
2427   if ($optargs eq "")
2428     {
2429     if ($arg eq "-DEBUG")  { $debug = 1; $cr = "\n"; next; }
2430     if ($arg eq "-DIFF")   { $cf = "diff -u"; next; }
2431     if ($arg eq "-CONTINUE"){$force_continue = 1;
2432                              $more = "cat";
2433                              next; }
2434     if ($arg eq "-UPDATE") { $force_update = 1; next; }
2435     if ($arg eq "-NOIPV4") { $have_ipv4 = 0; next; }
2436     if ($arg eq "-NOIPV6") { $have_ipv6 = 0; next; }
2437     if ($arg eq "-KEEP")   { $save_output = 1; next; }
2438     if ($arg eq "-VALGRIND")   { $valgrind = 1; next; }
2439     if ($arg =~ /^-FLAVOU?R$/) { $flavour = shift; next; }
2440     }
2441   $optargs .= " $arg";
2442   }
2443
2444 # Any subsequent arguments are a range of test numbers.
2445
2446 if (@ARGV > 0)
2447   {
2448   $test_end = $test_start = $ARGV[0];
2449   $test_end = $ARGV[1] if (@ARGV > 1);
2450   $test_end = ($test_start >= 9000)? $test_special_top : $test_top
2451     if $test_end eq "+";
2452   die "** Test numbers out of order\n" if ($test_end < $test_start);
2453   }
2454
2455
2456 ##################################################
2457 #      Make the command's directory current      #
2458 ##################################################
2459
2460 # After doing so, we find its absolute path name.
2461
2462 $cwd = $0;
2463 $cwd = '.' if ($cwd !~ s|/[^/]+$||);
2464 chdir($cwd) || die "** Failed to chdir to \"$cwd\": $!\n";
2465 $parm_cwd = Cwd::getcwd();
2466
2467
2468 ##################################################
2469 #     Search for an Exim binary to test          #
2470 ##################################################
2471
2472 # If an Exim binary hasn't been provided, try to find one. We can handle the
2473 # case where exim-testsuite is installed alongside Exim source directories. For
2474 # PH's private convenience, if there's a directory just called "exim4", that
2475 # takes precedence; otherwise exim-snapshot takes precedence over any numbered
2476 # releases.
2477
2478 if ($parm_exim eq "")
2479   {
2480   my($use_srcdir) = "";
2481
2482   opendir DIR, ".." || die "** Failed to opendir \"..\": $!\n";
2483   while ($f = readdir(DIR))
2484     {
2485     my($srcdir);
2486
2487     # Try this directory if it is "exim4" or if it is exim-snapshot or exim-n.m
2488     # possibly followed by -RCx where n.m is greater than any previously tried
2489     # directory. Thus, we should choose the highest version of Exim that has
2490     # been compiled.
2491
2492     if ($f eq "exim4" || $f eq "exim-snapshot" || $f eq 'src')
2493       { $srcdir = $f; }
2494     else
2495       { $srcdir = $f
2496         if ($f =~ /^exim-\d+\.\d+(-RC\d+)?$/ && $f gt $use_srcdir); }
2497
2498     # Look for a build directory with a binary in it. If we find a binary,
2499     # accept this source directory.
2500
2501     if ($srcdir)
2502       {
2503       opendir SRCDIR, "../$srcdir" ||
2504         die "** Failed to opendir \"$cwd/../$srcdir\": $!\n";
2505       while ($f = readdir(SRCDIR))
2506         {
2507         if ($f =~ /^build-/ && -e "../$srcdir/$f/exim")
2508           {
2509           $use_srcdir = $srcdir;
2510           $parm_exim = "$cwd/../$srcdir/$f/exim";
2511           $parm_exim =~ s'/[^/]+/\.\./'/';
2512           last;
2513           }
2514         }
2515       closedir(SRCDIR);
2516       }
2517
2518     # If we have found "exim4" or "exim-snapshot", that takes precedence.
2519     # Otherwise, continue to see if there's a later version.
2520
2521     last if $use_srcdir eq "exim4" || $use_srcdir eq "exim-snapshot";
2522     }
2523   closedir(DIR);
2524   print "Exim binary found in $parm_exim\n" if $parm_exim ne "";
2525   }
2526
2527 # If $parm_exim is still empty, ask the caller
2528
2529 if ($parm_exim eq "")
2530   {
2531   print "** Did not find an Exim binary to test\n";
2532   for ($i = 0; $i < 5; $i++)
2533     {
2534     my($trybin);
2535     print "** Enter pathname for Exim binary: ";
2536     chomp($trybin = <STDIN>);
2537     if (-e $trybin)
2538       {
2539       $parm_exim = $trybin;
2540       last;
2541       }
2542     else
2543       {
2544       print "** $trybin does not exist\n";
2545       }
2546     }
2547   die "** Too many tries\n" if $parm_exim eq "";
2548   }
2549
2550
2551
2552 ##################################################
2553 #          Find what is in the binary            #
2554 ##################################################
2555
2556 # deal with TRUSTED_CONFIG_LIST restrictions
2557 unlink("$parm_cwd/test-config") if -e "$parm_cwd/test-config";
2558 open (IN, "$parm_cwd/confs/0000") ||
2559   tests_exit(-1, "Couldn't open $parm_cwd/confs/0000: $!\n");
2560 open (OUT, ">test-config") ||
2561   tests_exit(-1, "Couldn't open test-config: $!\n");
2562 while (<IN>) { print OUT; }
2563 close(IN);
2564 close(OUT);
2565
2566 print("Probing with config file: $parm_cwd/test-config\n");
2567 open(EXIMINFO, "$parm_exim -d -C $parm_cwd/test-config -DDIR=$parm_cwd " .
2568                "-bP exim_user exim_group 2>&1|") ||
2569   die "** Cannot run $parm_exim: $!\n";
2570 while(<EXIMINFO>)
2571   {
2572   if (my ($version) = /^Exim version (\S+)/) {
2573     my $git = `git describe --dirty=-XX --match 'exim-4*'`;
2574     if (defined $git and $? == 0) {
2575       chomp $git;
2576       $version =~ s/^\d+\K\./_/;
2577       $git =~ s/^exim-//i;
2578       $git =~ s/.*-\Kg([[:xdigit:]]+(?:-XX)?)/$1/;
2579       print "\n*** Version mismatch (Exim: $version vs. GIT: $git). ***\n\n"
2580         if not $version eq $git;
2581     }
2582   }
2583   $parm_eximuser = $1 if /^exim_user = (.*)$/;
2584   $parm_eximgroup = $1 if /^exim_group = (.*)$/;
2585   $parm_trusted_config_list = $1 if /^TRUSTED_CONFIG_LIST:.*?"(.*?)"$/;
2586   ($parm_configure_owner, $parm_configure_group) = ($1, $2)
2587         if /^Configure owner:\s*(\d+):(\d+)/;
2588   print "$_" if /wrong owner/;
2589   }
2590 close(EXIMINFO);
2591
2592 if (defined $parm_eximuser)
2593   {
2594   if ($parm_eximuser =~ /^\d+$/) { $parm_exim_uid = $parm_eximuser; }
2595     else { $parm_exim_uid = getpwnam($parm_eximuser); }
2596   }
2597 else
2598   {
2599   print "Unable to extract exim_user from binary.\n";
2600   print "Check if Exim refused to run; if so, consider:\n";
2601   print "  TRUSTED_CONFIG_LIST ALT_CONFIG_PREFIX WHITELIST_D_MACROS\n";
2602   die "Failing to get information from binary.\n";
2603   }
2604
2605 if (defined $parm_eximgroup)
2606   {
2607   if ($parm_eximgroup =~ /^\d+$/) { $parm_exim_gid = $parm_eximgroup; }
2608     else { $parm_exim_gid = getgrnam($parm_eximgroup); }
2609   }
2610
2611 # check the permissions on the TRUSTED_CONFIG_LIST
2612 if (defined $parm_trusted_config_list)
2613   {
2614   die "TRUSTED_CONFIG_LIST: $parm_trusted_config_list: $!\n"
2615     if not -f $parm_trusted_config_list;
2616
2617   die "TRUSTED_CONFIG_LIST $parm_trusted_config_list must not be world writable!\n"
2618     if 02 & (stat _)[2];
2619
2620   die sprintf "TRUSTED_CONFIG_LIST: $parm_trusted_config_list %d is group writable, but not owned by group '%s' or '%s'.\n",
2621   (stat _)[1],
2622     scalar(getgrgid 0), scalar(getgrgid $>)
2623     if (020 & (stat _)[2]) and not ((stat _)[5] == $> or (stat _)[5] == 0);
2624
2625   die sprintf "TRUSTED_CONFIG_LIST: $parm_trusted_config_list is not owned by user '%s' or '%s'.\n",
2626   scalar(getpwuid 0), scalar(getpwuid $>)
2627      if (not (-o _ or (stat _)[4] == 0));
2628
2629   open(TCL, $parm_trusted_config_list) or die "Can't open $parm_trusted_config_list: $!\n";
2630   my $test_config = getcwd() . '/test-config';
2631   die "Can't find '$test_config' in TRUSTED_CONFIG_LIST $parm_trusted_config_list."
2632   if not grep { /^$test_config$/ } <TCL>;
2633   }
2634 else
2635   {
2636   die "Unable to check the TRUSTED_CONFIG_LIST, seems to be empty?\n";
2637   }
2638
2639 die "CONFIGURE_OWNER ($parm_configure_owner) does not match the user invoking $0 ($>)\n"
2640         if $parm_configure_owner != $>;
2641
2642 die "CONFIGURE_GROUP ($parm_configure_group) does not match the group invoking $0 ($))\n"
2643         if 0020 & (stat "$parm_cwd/test-config")[2]
2644         and $parm_configure_group != $);
2645
2646
2647 open(EXIMINFO, "$parm_exim -d-all+transport -bV -C $parm_cwd/test-config -DDIR=$parm_cwd |") ||
2648   die "** Cannot run $parm_exim: $!\n";
2649
2650 print "-" x 78, "\n";
2651
2652 while (<EXIMINFO>)
2653   {
2654   my(@temp);
2655
2656   if (/^(Exim|Library) version/) { print; }
2657
2658   elsif (/^Size of off_t: (\d+)/)
2659     {
2660     print;
2661     $have_largefiles = 1 if $1 > 4;
2662     die "** Size of off_t > 32 which seems improbable, not running tests\n"
2663         if ($1 > 32);
2664     }
2665
2666   elsif (/^Support for: (.*)/)
2667     {
2668     print;
2669     @temp = split /(\s+)/, $1;
2670     push(@temp, ' ');
2671     %parm_support = @temp;
2672     }
2673
2674   elsif (/^Lookups \(built-in\): (.*)/)
2675     {
2676     print;
2677     @temp = split /(\s+)/, $1;
2678     push(@temp, ' ');
2679     %parm_lookups = @temp;
2680     }
2681
2682   elsif (/^Authenticators: (.*)/)
2683     {
2684     print;
2685     @temp = split /(\s+)/, $1;
2686     push(@temp, ' ');
2687     %parm_authenticators = @temp;
2688     }
2689
2690   elsif (/^Routers: (.*)/)
2691     {
2692     print;
2693     @temp = split /(\s+)/, $1;
2694     push(@temp, ' ');
2695     %parm_routers = @temp;
2696     }
2697
2698   # Some transports have options, e.g. appendfile/maildir. For those, ensure
2699   # that the basic transport name is set, and then the name with each of the
2700   # options.
2701
2702   elsif (/^Transports: (.*)/)
2703     {
2704     print;
2705     @temp = split /(\s+)/, $1;
2706     my($i,$k);
2707     push(@temp, ' ');
2708     %parm_transports = @temp;
2709     foreach $k (keys %parm_transports)
2710       {
2711       if ($k =~ "/")
2712         {
2713         @temp = split /\//, $k;
2714         $parm_transports{"$temp[0]"} = " ";
2715         for ($i = 1; $i < @temp; $i++)
2716           { $parm_transports{"$temp[0]/$temp[$i]"} = " "; }
2717         }
2718       }
2719     }
2720   }
2721 close(EXIMINFO);
2722 print "-" x 78, "\n";
2723
2724 unlink("$parm_cwd/test-config");
2725
2726 ##################################################
2727 #    Check for SpamAssassin and ClamAV           #
2728 ##################################################
2729
2730 # These are crude tests. If they aren't good enough, we'll have to improve
2731 # them, for example by actually passing a message through spamc or clamscan.
2732
2733 if (defined $parm_support{'Content_Scanning'})
2734   {
2735   my $sock = new FileHandle;
2736
2737   if (system("spamc -h 2>/dev/null >/dev/null") == 0)
2738     {
2739     print "The spamc command works:\n";
2740
2741     # This test for an active SpamAssassin is courtesy of John Jetmore.
2742     # The tests are hard coded to localhost:783, so no point in making
2743     # this test flexible like the clamav test until the test scripts are
2744     # changed.  spamd doesn't have the nice PING/PONG protoccol that
2745     # clamd does, but it does respond to errors in an informative manner,
2746     # so use that.
2747
2748     my($sint,$sport) = ('127.0.0.1',783);
2749     eval
2750       {
2751       my $sin = sockaddr_in($sport, inet_aton($sint))
2752           or die "** Failed packing $sint:$sport\n";
2753       socket($sock, PF_INET, SOCK_STREAM, getprotobyname('tcp'))
2754           or die "** Unable to open socket $sint:$sport\n";
2755
2756       local $SIG{ALRM} =
2757           sub { die "** Timeout while connecting to socket $sint:$sport\n"; };
2758       alarm(5);
2759       connect($sock, $sin)
2760           or die "** Unable to connect to socket $sint:$sport\n";
2761       alarm(0);
2762
2763       select((select($sock), $| = 1)[0]);
2764       print $sock "bad command\r\n";
2765
2766       $SIG{ALRM} =
2767           sub { die "** Timeout while reading from socket $sint:$sport\n"; };
2768       alarm(10);
2769       my $res = <$sock>;
2770       alarm(0);
2771
2772       $res =~ m|^SPAMD/|
2773           or die "** Did not get SPAMD from socket $sint:$sport. "
2774                 ."It said: $res\n";
2775       };
2776     alarm(0);
2777     if($@)
2778       {
2779       print "  $@";
2780       print "  Assume SpamAssassin (spamd) is not running\n";
2781       }
2782     else
2783       {
2784       $parm_running{'SpamAssassin'} = ' ';
2785       print "  SpamAssassin (spamd) seems to be running\n";
2786       }
2787     }
2788   else
2789     {
2790     print "The spamc command failed: assume SpamAssassin (spamd) is not running\n";
2791     }
2792
2793   # For ClamAV, we need to find the clamd socket for use in the Exim
2794   # configuration. Search for the clamd configuration file.
2795
2796   if (system("clamscan -h 2>/dev/null >/dev/null") == 0)
2797     {
2798     my($f, $clamconf, $test_prefix);
2799
2800     print "The clamscan command works";
2801
2802     $test_prefix = $ENV{EXIM_TEST_PREFIX};
2803     $test_prefix = "" if !defined $test_prefix;
2804
2805     foreach $f ("$test_prefix/etc/clamd.conf",
2806                 "$test_prefix/usr/local/etc/clamd.conf",
2807                 "$test_prefix/etc/clamav/clamd.conf", "")
2808       {
2809       if (-e $f)
2810         {
2811         $clamconf = $f;
2812         last;
2813         }
2814       }
2815
2816     # Read the ClamAV configuration file and find the socket interface.
2817
2818     if ($clamconf ne "")
2819       {
2820       my $socket_domain;
2821       open(IN, "$clamconf") || die "\n** Unable to open $clamconf: $!\n";
2822       while (<IN>)
2823         {
2824         if (/^LocalSocket\s+(.*)/)
2825           {
2826           $parm_clamsocket = $1;
2827           $socket_domain = AF_UNIX;
2828           last;
2829           }
2830         if (/^TCPSocket\s+(\d+)/)
2831           {
2832           if (defined $parm_clamsocket)
2833             {
2834             $parm_clamsocket .= " $1";
2835             $socket_domain = AF_INET;
2836             last;
2837             }
2838           else
2839             {
2840             $parm_clamsocket = " $1";
2841             }
2842           }
2843         elsif (/^TCPAddr\s+(\S+)/)
2844           {
2845           if (defined $parm_clamsocket)
2846             {
2847             $parm_clamsocket = $1 . $parm_clamsocket;
2848             $socket_domain = AF_INET;
2849             last;
2850             }
2851           else
2852             {
2853             $parm_clamsocket = $1;
2854             }
2855           }
2856         }
2857       close(IN);
2858
2859       if (defined $socket_domain)
2860         {
2861         print ":\n  The clamd socket is $parm_clamsocket\n";
2862         # This test for an active ClamAV is courtesy of Daniel Tiefnig.
2863         eval
2864           {
2865           my $socket;
2866           if ($socket_domain == AF_UNIX)
2867             {
2868             $socket = sockaddr_un($parm_clamsocket) or die "** Failed packing '$parm_clamsocket'\n";
2869             }
2870           elsif ($socket_domain == AF_INET)
2871             {
2872             my ($ca_host, $ca_port) = split(/\s+/,$parm_clamsocket);
2873             my $ca_hostent = gethostbyname($ca_host) or die "** Failed to get raw address for host '$ca_host'\n";
2874             $socket = sockaddr_in($ca_port, $ca_hostent) or die "** Failed packing '$parm_clamsocket'\n";
2875             }
2876           else
2877             {
2878             die "** Unknown socket domain '$socket_domain' (should not happen)\n";
2879             }
2880           socket($sock, $socket_domain, SOCK_STREAM, 0) or die "** Unable to open socket '$parm_clamsocket'\n";
2881           local $SIG{ALRM} = sub { die "** Timeout while connecting to socket '$parm_clamsocket'\n"; };
2882           alarm(5);
2883           connect($sock, $socket) or die "** Unable to connect to socket '$parm_clamsocket'\n";
2884           alarm(0);
2885
2886           my $ofh = select $sock; $| = 1; select $ofh;
2887           print $sock "PING\n";
2888
2889           $SIG{ALRM} = sub { die "** Timeout while reading from socket '$parm_clamsocket'\n"; };
2890           alarm(10);
2891           my $res = <$sock>;
2892           alarm(0);
2893
2894           $res =~ /PONG/ or die "** Did not get PONG from socket '$parm_clamsocket'. It said: $res\n";
2895           };
2896         alarm(0);
2897
2898         if($@)
2899           {
2900           print "  $@";
2901           print "  Assume ClamAV is not running\n";
2902           }
2903         else
2904           {
2905           $parm_running{'ClamAV'} = ' ';
2906           print "  ClamAV seems to be running\n";
2907           }
2908         }
2909       else
2910         {
2911         print ", but the socket for clamd could not be determined\n";
2912         print "Assume ClamAV is not running\n";
2913         }
2914       }
2915
2916     else
2917       {
2918       print ", but I can't find a configuration for clamd\n";
2919       print "Assume ClamAV is not running\n";
2920       }
2921     }
2922   }
2923
2924
2925 ##################################################
2926 #       Check for redis                          #
2927 ##################################################
2928 if (defined $parm_lookups{'redis'})
2929   {
2930   if (system("redis-server -v 2>/dev/null >/dev/null") == 0)
2931     {
2932     print "The redis-server command works\n";
2933     $parm_running{'redis'} = ' ';
2934     }
2935   else
2936     {
2937     print "The redis-server command failed: assume Redis not installed\n";
2938     }
2939   }
2940
2941 ##################################################
2942 #         Test for the basic requirements        #
2943 ##################################################
2944
2945 # This test suite assumes that Exim has been built with at least the "usual"
2946 # set of routers, transports, and lookups. Ensure that this is so.
2947
2948 $missing = "";
2949
2950 $missing .= "     Lookup: lsearch\n" if (!defined $parm_lookups{'lsearch'});
2951
2952 $missing .= "     Router: accept\n" if (!defined $parm_routers{'accept'});
2953 $missing .= "     Router: dnslookup\n" if (!defined $parm_routers{'dnslookup'});
2954 $missing .= "     Router: manualroute\n" if (!defined $parm_routers{'manualroute'});
2955 $missing .= "     Router: redirect\n" if (!defined $parm_routers{'redirect'});
2956
2957 $missing .= "     Transport: appendfile\n" if (!defined $parm_transports{'appendfile'});
2958 $missing .= "     Transport: autoreply\n" if (!defined $parm_transports{'autoreply'});
2959 $missing .= "     Transport: pipe\n" if (!defined $parm_transports{'pipe'});
2960 $missing .= "     Transport: smtp\n" if (!defined $parm_transports{'smtp'});
2961
2962 if ($missing ne "")
2963   {
2964   print "\n";
2965   print "** Many features can be included or excluded from Exim binaries.\n";
2966   print "** This test suite requires that Exim is built to contain a certain\n";
2967   print "** set of basic facilities. It seems that some of these are missing\n";
2968   print "** from the binary that is under test, so the test cannot proceed.\n";
2969   print "** The missing facilities are:\n";
2970   print "$missing";
2971   die "** Test script abandoned\n";
2972   }
2973
2974
2975 ##################################################
2976 #      Check for the auxiliary programs          #
2977 ##################################################
2978
2979 # These are always required:
2980
2981 for $prog ("cf", "checkaccess", "client", "client-ssl", "client-gnutls",
2982            "fakens", "iefbr14", "server")
2983   {
2984   next if ($prog eq "client-ssl" && !defined $parm_support{'OpenSSL'});
2985   next if ($prog eq "client-gnutls" && !defined $parm_support{'GnuTLS'});
2986   if (!-e "bin/$prog")
2987     {
2988     print "\n";
2989     print "** bin/$prog does not exist. Have you run ./configure and make?\n";
2990     die "** Test script abandoned\n";
2991     }
2992   }
2993
2994 # If the "loaded" binary is missing, we cut out tests for ${dlfunc. It isn't
2995 # compiled on systems where we don't know how to. However, if Exim does not
2996 # have that functionality compiled, we needn't bother.
2997
2998 $dlfunc_deleted = 0;
2999 if (defined $parm_support{'Expand_dlfunc'} && !-e "bin/loaded")
3000   {
3001   delete $parm_support{'Expand_dlfunc'};
3002   $dlfunc_deleted = 1;
3003   }
3004
3005
3006 ##################################################
3007 #          Find environmental details            #
3008 ##################################################
3009
3010 # Find the caller of this program.
3011
3012 ($parm_caller,$pwpw,$parm_caller_uid,$parm_caller_gid,$pwquota,$pwcomm,
3013  $parm_caller_gecos, $parm_caller_home) = getpwuid($>);
3014
3015 $pwpw = $pwpw;       # Kill Perl warnings
3016 $pwquota = $pwquota;
3017 $pwcomm = $pwcomm;
3018
3019 $parm_caller_group = getgrgid($parm_caller_gid);
3020
3021 print "Program caller is $parm_caller ($parm_caller_uid), whose group is $parm_caller_group ($parm_caller_gid)\n";
3022 print "Home directory is $parm_caller_home\n";
3023
3024 unless (defined $parm_eximgroup)
3025   {
3026   print "Unable to derive \$parm_eximgroup.\n";
3027   die "** ABANDONING.\n";
3028   }
3029
3030 print "You need to be in the Exim group to run these tests. Checking ...";
3031
3032 if (`groups` =~ /\b\Q$parm_eximgroup\E\b/)
3033   {
3034   print " OK\n";
3035   }
3036 else
3037   {
3038   print "\nOh dear, you are not in the Exim group.\n";
3039   die "** Testing abandoned.\n";
3040   }
3041
3042 # Find this host's IP addresses - there may be many, of course, but we keep
3043 # one of each type (IPv4 and IPv6).
3044
3045 open(IFCONFIG, '-|', (grep { -x "$_/ip" } split /:/, $ENV{PATH}) ? 'ip address' : 'ifconfig -a')
3046   or die "** Cannot run 'ip address' or 'ifconfig -a'\n";
3047 while (not ($parm_ipv4 and $parm_ipv6) and defined($_ = <IFCONFIG>))
3048   {
3049   if (not $parm_ipv4 and /^\s*inet(?:\saddr)?:?\s?(\d+\.\d+\.\d+\.\d+)(?:\/\d+)?\s/i)
3050     {
3051     next if $1 =~ /^(?:127|10)\./;
3052     $parm_ipv4 = $1;
3053     }
3054
3055   if (not $parm_ipv6 and /^\s*inet6(?:\saddr)?:?\s?([abcdef\d:]+)(?:\/\d+)/i)
3056     {
3057     next if $1 eq '::1' or $1 =~ /^fe80/i;
3058     $parm_ipv6 = $1;
3059     }
3060   }
3061 close(IFCONFIG);
3062
3063 # Use private IP addresses if there are no public ones.
3064
3065 # If either type of IP address is missing, we need to set the value to
3066 # something other than empty, because that wrecks the substitutions. The value
3067 # is reflected, so use a meaningful string. Set appropriate options for the
3068 # "server" command. In practice, however, many tests assume 127.0.0.1 is
3069 # available, so things will go wrong if there is no IPv4 address. The lack
3070 # of IPV4 or IPv6 can be simulated by command options, which force $have_ipv4
3071 # and $have_ipv6 false.
3072
3073 if (not $parm_ipv4)
3074   {
3075   $have_ipv4 = 0;
3076   $parm_ipv4 = "<no IPv4 address found>";
3077   $server_opts .= " -noipv4";
3078   }
3079 elsif ($have_ipv4 == 0)
3080   {
3081   $parm_ipv4 = "<IPv4 testing disabled>";
3082   $server_opts .= " -noipv4";
3083   }
3084 else
3085   {
3086   $parm_running{"IPv4"} = " ";
3087   }
3088
3089 if (not $parm_ipv6)
3090   {
3091   $have_ipv6 = 0;
3092   $parm_ipv6 = "<no IPv6 address found>";
3093   $server_opts .= " -noipv6";
3094   delete($parm_support{"IPv6"});
3095   }
3096 elsif ($have_ipv6 == 0)
3097   {
3098   $parm_ipv6 = "<IPv6 testing disabled>";
3099   $server_opts .= " -noipv6";
3100   delete($parm_support{"IPv6"});
3101   }
3102 elsif (!defined $parm_support{'IPv6'})
3103   {
3104   $have_ipv6 = 0;
3105   $parm_ipv6 = "<no IPv6 support in Exim binary>";
3106   $server_opts .= " -noipv6";
3107   }
3108 else
3109   {
3110   $parm_running{"IPv6"} = " ";
3111   }
3112
3113 print "IPv4 address is $parm_ipv4\n";
3114 print "IPv6 address is $parm_ipv6\n";
3115
3116 # For munging test output, we need the reversed IP addresses.
3117
3118 $parm_ipv4r = ($parm_ipv4 !~ /^\d/)? "" :
3119   join(".", reverse(split /\./, $parm_ipv4));
3120
3121 $parm_ipv6r = $parm_ipv6;             # Appropriate if not in use
3122 if ($parm_ipv6 =~ /^[\da-f]/)
3123   {
3124   my(@comps) = split /:/, $parm_ipv6;
3125   my(@nibbles);
3126   foreach $comp (@comps)
3127     {
3128     push @nibbles, sprintf("%lx", hex($comp) >> 8);
3129     push @nibbles, sprintf("%lx", hex($comp) & 0xff);
3130     }
3131   $parm_ipv6r = join(".", reverse(@nibbles));
3132   }
3133
3134 # Find the host name, fully qualified.
3135
3136 chomp($temp = `hostname`);
3137 die "'hostname' didn't return anything\n" unless defined $temp and length $temp;
3138 $parm_hostname = (gethostbyname($temp))[0];
3139 $parm_hostname = "no.host.name.found" unless defined $parm_hostname and length $parm_hostname;
3140 print "Hostname is $parm_hostname\n";
3141
3142 if ($parm_hostname !~ /\./)
3143   {
3144   print "\n*** Host name is not fully qualified: this may cause problems ***\n\n";
3145   }
3146
3147 if ($parm_hostname =~ /[[:upper:]]/)
3148   {
3149   print "\n*** Host name has upper case characters: this may cause problems ***\n\n";
3150   }
3151
3152
3153
3154 ##################################################
3155 #     Create a testing version of Exim           #
3156 ##################################################
3157
3158 # We want to be able to run Exim with a variety of configurations. Normally,
3159 # the use of -C to change configuration causes Exim to give up its root
3160 # privilege (unless the caller is exim or root). For these tests, we do not
3161 # want this to happen. Also, we want Exim to know that it is running in its
3162 # test harness.
3163
3164 # We achieve this by copying the binary and patching it as we go. The new
3165 # binary knows it is a testing copy, and it allows -C and -D without loss of
3166 # privilege. Clearly, this file is dangerous to have lying around on systems
3167 # where there are general users with login accounts. To protect against this,
3168 # we put the new binary in a special directory that is accessible only to the
3169 # caller of this script, who is known to have sudo root privilege from the test
3170 # that was done above. Furthermore, we ensure that the binary is deleted at the
3171 # end of the test. First ensure the directory exists.
3172
3173 if (-d "eximdir")
3174   { unlink "eximdir/exim"; }     # Just in case
3175 else
3176   {
3177   mkdir("eximdir", 0710) || die "** Unable to mkdir $parm_cwd/eximdir: $!\n";
3178   system("sudo chgrp $parm_eximgroup eximdir");
3179   }
3180
3181 # The construction of the patched binary must be done as root, so we use
3182 # a separate script. As well as indicating that this is a test-harness binary,
3183 # the version number is patched to "x.yz" so that its length is always the
3184 # same. Otherwise, when it appears in Received: headers, it affects the length
3185 # of the message, which breaks certain comparisons.
3186
3187 die "** Unable to make patched exim: $!\n"
3188   if (system("sudo ./patchexim $parm_exim") != 0);
3189
3190 # From this point on, exits from the program must go via the subroutine
3191 # tests_exit(), so that suitable cleaning up can be done when required.
3192 # Arrange to catch interrupting signals, to assist with this.
3193
3194 $SIG{'INT'} = \&inthandler;
3195 $SIG{'PIPE'} = \&pipehandler;
3196
3197 # For some tests, we need another copy of the binary that is setuid exim rather
3198 # than root.
3199
3200 system("sudo cp eximdir/exim eximdir/exim_exim;" .
3201        "sudo chown $parm_eximuser eximdir/exim_exim;" .
3202        "sudo chgrp $parm_eximgroup eximdir/exim_exim;" .
3203        "sudo chmod 06755 eximdir/exim_exim");
3204
3205
3206 ##################################################
3207 #     Make copies of utilities we might need     #
3208 ##################################################
3209
3210 # Certain of the tests make use of some of Exim's utilities. We do not need
3211 # to be root to copy these.
3212
3213 ($parm_exim_dir) = $parm_exim =~ m?^(.*)/exim?;
3214
3215 $dbm_build_deleted = 0;
3216 if (defined $parm_lookups{'dbm'} &&
3217     system("cp $parm_exim_dir/exim_dbmbuild eximdir") != 0)
3218   {
3219   delete $parm_lookups{'dbm'};
3220   $dbm_build_deleted = 1;
3221   }
3222
3223 if (system("cp $parm_exim_dir/exim_dumpdb eximdir") != 0)
3224   {
3225   tests_exit(-1, "Failed to make a copy of exim_dumpdb: $!");
3226   }
3227
3228 if (system("cp $parm_exim_dir/exim_lock eximdir") != 0)
3229   {
3230   tests_exit(-1, "Failed to make a copy of exim_lock: $!");
3231   }
3232
3233 if (system("cp $parm_exim_dir/exinext eximdir") != 0)
3234   {
3235   tests_exit(-1, "Failed to make a copy of exinext: $!");
3236   }
3237
3238 if (system("cp $parm_exim_dir/exigrep eximdir") != 0)
3239   {
3240   tests_exit(-1, "Failed to make a copy of exigrep: $!");
3241   }
3242
3243 if (system("cp $parm_exim_dir/eximstats eximdir") != 0)
3244   {
3245   tests_exit(-1, "Failed to make a copy of eximstats: $!");
3246   }
3247
3248
3249 ##################################################
3250 #    Check that the Exim user can access stuff   #
3251 ##################################################
3252
3253 # We delay this test till here so that we can check access to the actual test
3254 # binary. This will be needed when Exim re-exec's itself to do deliveries.
3255
3256 print "Exim user is $parm_eximuser ($parm_exim_uid)\n";
3257 print "Exim group is $parm_eximgroup ($parm_exim_gid)\n";
3258
3259 if ($parm_caller_uid eq $parm_exim_uid) {
3260   tests_exit(-1, "Exim user ($parm_eximuser,$parm_exim_uid) cannot be "
3261                 ."the same as caller ($parm_caller,$parm_caller_uid)");
3262 }
3263 if ($parm_caller_gid eq $parm_exim_gid) {
3264   tests_exit(-1, "Exim group ($parm_eximgroup,$parm_exim_gid) cannot be "
3265                 ."the same as caller's ($parm_caller) group as it confuses "
3266                 ."results analysis");
3267 }
3268
3269 print "The Exim user needs access to the test suite directory. Checking ...";
3270
3271 if (($rc = system("sudo bin/checkaccess $parm_cwd/eximdir/exim $parm_eximuser $parm_eximgroup")) != 0)
3272   {
3273   my($why) = "unknown failure $rc";
3274   $rc >>= 8;
3275   $why = "Couldn't find user \"$parm_eximuser\"" if $rc == 1;
3276   $why = "Couldn't find group \"$parm_eximgroup\"" if $rc == 2;
3277   $why = "Couldn't read auxiliary group list" if $rc == 3;
3278   $why = "Couldn't get rid of auxiliary groups" if $rc == 4;
3279   $why = "Couldn't set gid" if $rc == 5;
3280   $why = "Couldn't set uid" if $rc == 6;
3281   $why = "Couldn't open \"$parm_cwd/eximdir/exim\"" if $rc == 7;
3282   print "\n** $why\n";
3283   tests_exit(-1, "$parm_eximuser cannot access the test suite directory");
3284   }
3285 else
3286   {
3287   print " OK\n";
3288   }
3289
3290
3291 ##################################################
3292 #        Create a list of available tests        #
3293 ##################################################
3294
3295 # The scripts directory contains a number of subdirectories whose names are
3296 # of the form 0000-xxxx, 1100-xxxx, 2000-xxxx, etc. Each set of tests apart
3297 # from the first requires certain optional features to be included in the Exim
3298 # binary. These requirements are contained in a file called "REQUIRES" within
3299 # the directory. We scan all these tests, discarding those that cannot be run
3300 # because the current binary does not support the right facilities, and also
3301 # those that are outside the numerical range selected.
3302
3303 print "\nTest range is $test_start to $test_end (flavour $flavour)\n";
3304 print "Omitting \${dlfunc expansion tests (loadable module not present)\n"
3305   if $dlfunc_deleted;
3306 print "Omitting dbm tests (unable to copy exim_dbmbuild)\n"
3307   if $dbm_build_deleted;
3308
3309 opendir(DIR, "scripts") || tests_exit(-1, "Failed to opendir(\"scripts\"): $!");
3310 @test_dirs = sort readdir(DIR);
3311 closedir(DIR);
3312
3313 # Remove . and .. and CVS from the list.
3314
3315 for ($i = 0; $i < @test_dirs; $i++)
3316   {
3317   my($d) = $test_dirs[$i];
3318   if ($d eq "." || $d eq ".." || $d eq "CVS")
3319     {
3320     splice @test_dirs, $i, 1;
3321     $i--;
3322     }
3323   }
3324
3325 # Scan for relevant tests
3326
3327 for ($i = 0; $i < @test_dirs; $i++)
3328   {
3329   my($testdir) = $test_dirs[$i];
3330   my($wantthis) = 1;
3331
3332   print ">>Checking $testdir\n" if $debug;
3333
3334   # Skip this directory if the first test is equal or greater than the first
3335   # test in the next directory.
3336
3337   next if ($i < @test_dirs - 1) &&
3338           ($test_start >= substr($test_dirs[$i+1], 0, 4));
3339
3340   # No need to carry on if the end test is less than the first test in this
3341   # subdirectory.
3342
3343   last if $test_end < substr($testdir, 0, 4);
3344
3345   # Check requirements, if any.
3346
3347   if (open(REQUIRES, "scripts/$testdir/REQUIRES"))
3348     {
3349     while (<REQUIRES>)
3350       {
3351       next if /^\s*$/;
3352       s/\s+$//;
3353       if (/^support (.*)$/)
3354         {
3355         if (!defined $parm_support{$1}) { $wantthis = 0; last; }
3356         }
3357       elsif (/^running (.*)$/)
3358         {
3359         if (!defined $parm_running{$1}) { $wantthis = 0; last; }
3360         }
3361       elsif (/^lookup (.*)$/)
3362         {
3363         if (!defined $parm_lookups{$1}) { $wantthis = 0; last; }
3364         }
3365       elsif (/^authenticators? (.*)$/)
3366         {
3367         if (!defined $parm_authenticators{$1}) { $wantthis = 0; last; }
3368         }
3369       elsif (/^router (.*)$/)
3370         {
3371         if (!defined $parm_routers{$1}) { $wantthis = 0; last; }
3372         }
3373       elsif (/^transport (.*)$/)
3374         {
3375         if (!defined $parm_transports{$1}) { $wantthis = 0; last; }
3376         }
3377       else
3378         {
3379         tests_exit(-1, "Unknown line in \"scripts/$testdir/REQUIRES\": \"$_\"");
3380         }
3381       }
3382     close(REQUIRES);
3383     }
3384   else
3385     {
3386     tests_exit(-1, "Failed to open \"scripts/$testdir/REQUIRES\": $!")
3387       unless $!{ENOENT};
3388     }
3389
3390   # Loop if we do not want the tests in this subdirectory.
3391
3392   if (!$wantthis)
3393     {
3394     chomp;
3395     print "Omitting tests in $testdir (missing $_)\n";
3396     next;
3397     }
3398
3399   # We want the tests from this subdirectory, provided they are in the
3400   # range that was selected.
3401
3402   opendir(SUBDIR, "scripts/$testdir") ||
3403     tests_exit(-1, "Failed to opendir(\"scripts/$testdir\"): $!");
3404   @testlist = sort readdir(SUBDIR);
3405   close(SUBDIR);
3406
3407   foreach $test (@testlist)
3408     {
3409     next if $test !~ /^\d{4}(?:\.\d+)?$/;
3410     next if $test < $test_start || $test > $test_end;
3411     push @test_list, "$testdir/$test";
3412     }
3413   }
3414
3415 print ">>Test List: @test_list\n", if $debug;
3416
3417
3418 ##################################################
3419 #         Munge variable auxiliary data          #
3420 ##################################################
3421
3422 # Some of the auxiliary data files have to refer to the current testing
3423 # directory and other parameter data. The generic versions of these files are
3424 # stored in the aux-var-src directory. At this point, we copy each of them
3425 # to the aux-var directory, making appropriate substitutions. There aren't very
3426 # many of them, so it's easiest just to do this every time. Ensure the mode
3427 # is standardized, as this path is used as a test for the ${stat: expansion.
3428
3429 # A similar job has to be done for the files in the dnszones-src directory, to
3430 # make the fake DNS zones for testing. Most of the zone files are copied to
3431 # files of the same name, but db.ipv4.V4NET and db.ipv6.V6NET use the testing
3432 # networks that are defined by parameter.
3433
3434 foreach $basedir ("aux-var", "dnszones")
3435   {
3436   system("sudo rm -rf $parm_cwd/$basedir");
3437   mkdir("$parm_cwd/$basedir", 0777);
3438   chmod(0755, "$parm_cwd/$basedir");
3439
3440   opendir(AUX, "$parm_cwd/$basedir-src") ||
3441     tests_exit(-1, "Failed to opendir $parm_cwd/$basedir-src: $!");
3442   my(@filelist) = readdir(AUX);
3443   close(AUX);
3444
3445   foreach $file (@filelist)
3446     {
3447     my($outfile) = $file;
3448     next if $file =~ /^\./;
3449
3450     if ($file eq "db.ip4.V4NET")
3451       {
3452       $outfile = "db.ip4.$parm_ipv4_test_net";
3453       }
3454     elsif ($file eq "db.ip6.V6NET")
3455       {
3456       my(@nibbles) = reverse(split /\s*/, $parm_ipv6_test_net);
3457       $" = '.';
3458       $outfile = "db.ip6.@nibbles";
3459       $" = ' ';
3460       }
3461
3462     print ">>Copying $basedir-src/$file to $basedir/$outfile\n" if $debug;
3463     open(IN, "$parm_cwd/$basedir-src/$file") ||
3464       tests_exit(-1, "Failed to open $parm_cwd/$basedir-src/$file: $!");
3465     open(OUT, ">$parm_cwd/$basedir/$outfile") ||
3466       tests_exit(-1, "Failed to open $parm_cwd/$basedir/$outfile: $!");
3467     while (<IN>)
3468       {
3469       do_substitute(0);
3470       print OUT;
3471       }
3472     close(IN);
3473     close(OUT);
3474     }
3475   }
3476
3477 # Set a user's shell, distinguishable from /bin/sh
3478
3479 symlink("/bin/sh","aux-var/sh");
3480 $ENV{'SHELL'} = $parm_shell = $parm_cwd . "/aux-var/sh";
3481
3482 ##################################################
3483 #     Create fake DNS zones for this host        #
3484 ##################################################
3485
3486 # There are fixed zone files for 127.0.0.1 and ::1, but we also want to be
3487 # sure that there are forward and reverse registrations for this host, using
3488 # its real IP addresses. Dynamically created zone files achieve this.
3489
3490 if ($have_ipv4 || $have_ipv6)
3491   {
3492   my($shortname,$domain) = $parm_hostname =~ /^([^.]+)(.*)/;
3493   open(OUT, ">$parm_cwd/dnszones/db$domain") ||
3494     tests_exit(-1, "Failed to open $parm_cwd/dnszones/db$domain: $!");
3495   print OUT "; This is a dynamically constructed fake zone file.\n" .
3496     "; The following line causes fakens to return PASS_ON\n" .
3497     "; for queries that it cannot answer\n\n" .
3498     "PASS ON NOT FOUND\n\n";
3499   print OUT "$shortname  A     $parm_ipv4\n" if $have_ipv4;
3500   print OUT "$shortname  AAAA  $parm_ipv6\n" if $have_ipv6;
3501   print OUT "\n; End\n";
3502   close(OUT);
3503   }
3504
3505 if ($have_ipv4 && $parm_ipv4 ne "127.0.0.1")
3506   {
3507   my(@components) = $parm_ipv4 =~ /^(\d+)\.(\d+)\.(\d+)\.(\d+)/;
3508   open(OUT, ">$parm_cwd/dnszones/db.ip4.$components[0]") ||
3509     tests_exit(-1,
3510       "Failed  to open $parm_cwd/dnszones/db.ip4.$components[0]: $!");
3511   print OUT "; This is a dynamically constructed fake zone file.\n" .
3512     "; The zone is $components[0].in-addr.arpa.\n\n" .
3513     "$components[3].$components[2].$components[1]  PTR  $parm_hostname.\n\n" .
3514     "; End\n";
3515   close(OUT);
3516   }
3517
3518 if ($have_ipv6 && $parm_ipv6 ne "::1")
3519   {
3520   my($exp_v6) = $parm_ipv6;
3521   $exp_v6 =~ s/[^:]//g;
3522   if ( $parm_ipv6 =~ /^([^:].+)::$/ ) {
3523     $exp_v6 = $1 . ':0' x (9-length($exp_v6));
3524   } elsif ( $parm_ipv6 =~ /^(.+)::(.+)$/ ) {
3525     $exp_v6 = $1 . ':0' x (8-length($exp_v6)) . ':' . $2;
3526   } elsif ( $parm_ipv6 =~ /^::(.+[^:])$/ ) {
3527     $exp_v6 = '0:' x (9-length($exp_v6)) . $1;
3528   } else {
3529     $exp_v6 = $parm_ipv6;
3530   }
3531   my(@components) = split /:/, $exp_v6;
3532   my(@nibbles) = reverse (split /\s*/, shift @components);
3533   my($sep) =  "";
3534
3535   $" = ".";
3536   open(OUT, ">$parm_cwd/dnszones/db.ip6.@nibbles") ||
3537     tests_exit(-1,
3538       "Failed  to open $parm_cwd/dnszones/db.ip6.@nibbles: $!");
3539   print OUT "; This is a dynamically constructed fake zone file.\n" .
3540     "; The zone is @nibbles.ip6.arpa.\n\n";
3541
3542   @components = reverse @components;
3543   foreach $c (@components)
3544     {
3545     $c = "0$c" until $c =~ /^..../;
3546     @nibbles = reverse(split /\s*/, $c);
3547     print OUT "$sep@nibbles";
3548     $sep = ".";
3549     }
3550
3551   print OUT "  PTR  $parm_hostname.\n\n; End\n";
3552   close(OUT);
3553   $" = " ";
3554   }
3555
3556
3557
3558 ##################################################
3559 #    Create lists of mailboxes and message logs  #
3560 ##################################################
3561
3562 # We use these lists to check that a test has created the expected files. It
3563 # should be faster than looking for the file each time. For mailboxes, we have
3564 # to scan a complete subtree, in order to handle maildirs. For msglogs, there
3565 # is just a flat list of files.
3566
3567 @oldmails = list_files_below("mail");
3568 opendir(DIR, "msglog") || tests_exit(-1, "Failed to opendir msglog: $!");
3569 @oldmsglogs = readdir(DIR);
3570 closedir(DIR);
3571
3572
3573
3574 ##################################################
3575 #         Run the required tests                 #
3576 ##################################################
3577
3578 # Each test script contains a number of tests, separated by a line that
3579 # contains ****. We open input from the terminal so that we can read responses
3580 # to prompts.
3581
3582 open(T, "/dev/tty") || tests_exit(-1, "Failed to open /dev/tty: $!");
3583
3584 print "\nPress RETURN to run the tests: ";
3585 $_ = $force_continue ? "c" : <T>;
3586 print "\n";
3587
3588 $lasttestdir = "";
3589
3590 foreach $test (@test_list)
3591   {
3592   local($lineno) = 0;
3593   local($commandno) = 0;
3594   local($subtestno) = 0;
3595   (local $testno = $test) =~ s|.*/||;
3596   local($sortlog) = 0;
3597
3598   my($gnutls) = 0;
3599   my($docheck) = 1;
3600   my($thistestdir) = substr($test, 0, -5);
3601
3602   $dynamic_socket->close() if $dynamic_socket;
3603
3604   if ($lasttestdir ne $thistestdir)
3605     {
3606     $gnutls = 0;
3607     if (-s "scripts/$thistestdir/REQUIRES")
3608       {
3609       my($indent) = "";
3610       print "\n>>> The following tests require: ";
3611       open(IN, "scripts/$thistestdir/REQUIRES") ||
3612         tests_exit(-1, "Failed to open scripts/$thistestdir/REQUIRES: $1");
3613       while (<IN>)
3614         {
3615         $gnutls = 1 if /^support GnuTLS/;
3616         print $indent, $_;
3617         $indent = ">>>                              ";
3618         }
3619       close(IN);
3620       }
3621     }
3622   $lasttestdir = $thistestdir;
3623
3624   # Remove any debris in the spool directory and the test-mail directory
3625   # and also the files for collecting stdout and stderr. Then put back
3626   # the test-mail directory for appendfile deliveries.
3627
3628   system "sudo /bin/rm -rf spool test-*";
3629   system "mkdir test-mail 2>/dev/null";
3630
3631   # A privileged Exim will normally make its own spool directory, but some of
3632   # the tests run in unprivileged modes that don't always work if the spool
3633   # directory isn't already there. What is more, we want anybody to be able
3634   # to read it in order to find the daemon's pid.
3635
3636   system "mkdir spool; " .
3637          "sudo chown $parm_eximuser:$parm_eximgroup spool; " .
3638          "sudo chmod 0755 spool";
3639
3640   # Empty the cache that keeps track of things like message id mappings, and
3641   # set up the initial sequence strings.
3642
3643   undef %cache;
3644   $next_msgid = "aX";
3645   $next_pid = 1234;
3646   $next_port = 1111;
3647   $message_skip = 0;
3648   $msglog_skip = 0;
3649   $stderr_skip = 0;
3650   $stdout_skip = 0;
3651   $rmfiltertest = 0;
3652   $is_ipv6test = 0;
3653   $TEST_STATE->{munge} = "";
3654
3655   # Remove the associative arrays used to hold checked mail files and msglogs
3656
3657   undef %expected_mails;
3658   undef %expected_msglogs;
3659
3660   # Open the test's script
3661   open(SCRIPT, "scripts/$test") ||
3662     tests_exit(-1, "Failed to open \"scripts/$test\": $!");
3663   # Run through the script once to set variables which should be global
3664   while (<SCRIPT>)
3665     {
3666     if (/^no_message_check/) { $message_skip = 1; next; }
3667     if (/^no_msglog_check/)  { $msglog_skip = 1; next; }
3668     if (/^no_stderr_check/)  { $stderr_skip = 1; next; }
3669     if (/^no_stdout_check/)  { $stdout_skip = 1; next; }
3670     if (/^rmfiltertest/)     { $rmfiltertest = 1; next; }
3671     if (/^sortlog/)          { $sortlog = 1; next; }
3672     if (/\bPORT_DYNAMIC\b/)  {
3673       for (my $port = 1024; $port < 65000; $port++) {
3674         $dynamic_socket = IO::Socket::INET->new(
3675           LocalHost => '127.0.0.1',
3676           LocalPort => $port,
3677           Listen => 10,
3678           ReuseAddr => 1,
3679         ) and last;
3680       }
3681       }
3682     }
3683   # Reset to beginning of file for per test interpreting/processing
3684   seek(SCRIPT, 0, 0);
3685
3686   # The first line in the script must be a comment that is used to identify
3687   # the set of tests as a whole.
3688
3689   $_ = <SCRIPT>;
3690   $lineno++;
3691   tests_exit(-1, "Missing identifying comment at start of $test") if (!/^#/);
3692   printf("%s %s", (substr $test, 5), (substr $_, 2));
3693
3694   # Loop for each of the subtests within the script. The variable $server_pid
3695   # is used to remember the pid of a "server" process, for which we do not
3696   # wait until we have waited for a subsequent command.
3697
3698   local($server_pid) = 0;
3699   for ($commandno = 1; !eof SCRIPT; $commandno++)
3700     {
3701     # Skip further leading comments and blank lines, handle the flag setting
3702     # commands, and deal with tests for IP support.
3703
3704     while (<SCRIPT>)
3705       {
3706       $lineno++;
3707       # Could remove these variable settings because they are already
3708       # set above, but doesn't hurt to leave them here.
3709       if (/^no_message_check/) { $message_skip = 1; next; }
3710       if (/^no_msglog_check/)  { $msglog_skip = 1; next; }
3711       if (/^no_stderr_check/)  { $stderr_skip = 1; next; }
3712       if (/^no_stdout_check/)  { $stdout_skip = 1; next; }
3713       if (/^rmfiltertest/)     { $rmfiltertest = 1; next; }
3714       if (/^sortlog/)          { $sortlog = 1; next; }
3715
3716       if (/^need_largefiles/)
3717         {
3718         next if $have_largefiles;
3719         print ">>> Large file support is needed for test $testno, but is not available: skipping\n";
3720         $docheck = 0;      # don't check output
3721         undef $_;          # pretend EOF
3722         last;
3723         }
3724
3725       if (/^need_ipv4/)
3726         {
3727         next if $have_ipv4;
3728         print ">>> IPv4 is needed for test $testno, but is not available: skipping\n";
3729         $docheck = 0;      # don't check output
3730         undef $_;          # pretend EOF
3731         last;
3732         }
3733
3734       if (/^need_ipv6/)
3735         {
3736         if ($have_ipv6)
3737           {
3738           $is_ipv6test = 1;
3739           next;
3740           }
3741         print ">>> IPv6 is needed for test $testno, but is not available: skipping\n";
3742         $docheck = 0;      # don't check output
3743         undef $_;          # pretend EOF
3744         last;
3745         }
3746
3747       if (/^need_move_frozen_messages/)
3748         {
3749         next if defined $parm_support{"move_frozen_messages"};
3750         print ">>> move frozen message support is needed for test $testno, " .
3751           "but is not\n>>> available: skipping\n";
3752         $docheck = 0;      # don't check output
3753         undef $_;          # pretend EOF
3754         last;
3755         }
3756
3757       last unless /^(#|\s*$)/;
3758       }
3759     last if !defined $_;  # Hit EOF
3760
3761     my($subtest_startline) = $lineno;
3762
3763     # Now run the command. The function returns 0 for an inline command,
3764     # 1 if a non-exim command was run and waited for, 2 if an exim
3765     # command was run and waited for, and 3 if a command
3766     # was run and not waited for (usually a daemon or server startup).
3767
3768     my($commandname) = "";
3769     my($expectrc) = 0;
3770     my($rc, $run_extra) = run_command($testno, \$subtestno, \$expectrc, \$commandname, $TEST_STATE);
3771     my($cmdrc) = $?;
3772
3773 $0 = "[runtest $testno]";
3774
3775     if ($debug) {
3776       print ">> rc=$rc cmdrc=$cmdrc\n";
3777       if (defined $run_extra) {
3778         foreach my $k (keys %$run_extra) {
3779           my $v = defined $run_extra->{$k} ? qq!"$run_extra->{$k}"! : '<undef>';
3780           print ">>   $k -> $v\n";
3781         }
3782       }
3783     }
3784     $run_extra = {} unless defined $run_extra;
3785     foreach my $k (keys %$run_extra) {
3786       if (exists $TEST_STATE->{$k}) {
3787         my $nv = defined $run_extra->{$k} ? qq!"$run_extra->{$k}"! : 'removed';
3788         print ">> override of $k; was $TEST_STATE->{$k}, now $nv\n" if $debug;
3789       }
3790       if (defined $run_extra->{$k}) {
3791         $TEST_STATE->{$k} = $run_extra->{$k};
3792       } elsif (exists $TEST_STATE->{$k}) {
3793         delete $TEST_STATE->{$k};
3794       }
3795     }
3796
3797     # Hit EOF after an initial return code number
3798
3799     tests_exit(-1, "Unexpected EOF in script") if ($rc == 4);
3800
3801     # Carry on with the next command if we did not wait for this one. $rc == 0
3802     # if no subprocess was run; $rc == 3 if we started a process but did not
3803     # wait for it.
3804
3805     next if ($rc == 0 || $rc == 3);
3806
3807     # We ran and waited for a command. Check for the expected result unless
3808     # it died.
3809
3810     if ($cmdrc != $expectrc && !$sigpipehappened)
3811       {
3812       printf("** Command $commandno (\"$commandname\", starting at line $subtest_startline)\n");
3813       if (($cmdrc & 0xff) == 0)
3814         {
3815         printf("** Return code %d (expected %d)", $cmdrc/256, $expectrc/256);
3816         }
3817       elsif (($cmdrc & 0xff00) == 0)
3818         { printf("** Killed by signal %d", $cmdrc & 255); }
3819       else
3820         { printf("** Status %x", $cmdrc); }
3821
3822       for (;;)
3823         {
3824         print "\nshow stdErr, show stdOut, Retry, Continue (without file comparison), or Quit? [Q] ";
3825         $_ = $force_continue ? "c" : <T>;
3826         tests_exit(1) if /^q?$/i;
3827         log_failure($log_failed_filename, $testno, "exit code unexpected") if (/^c$/i && $force_continue);
3828         if ($force_continue)
3829           {
3830           print "\nstderr tail:\n";
3831           print "===================\n";
3832           system("tail -20 test-stderr");
3833           print "===================\n";
3834           print "... continue forced\n";
3835           }
3836
3837         last if /^[rc]$/i;
3838         if (/^e$/i)
3839           {
3840           system("$more test-stderr");
3841           }
3842         elsif (/^o$/i)
3843           {
3844           system("$more test-stdout");
3845           }
3846         }
3847
3848       $retry = 1 if /^r$/i;
3849       $docheck = 0;
3850       }
3851
3852     # If the command was exim, and a listening server is running, we can now
3853     # close its input, which causes us to wait for it to finish, which is why
3854     # we didn't close it earlier.
3855
3856     if ($rc == 2 && $server_pid != 0)
3857       {
3858       close SERVERCMD;
3859       $server_pid = 0;
3860       if ($? != 0)
3861         {
3862         if (($? & 0xff) == 0)
3863           { printf("Server return code %d", $?/256); }
3864         elsif (($? & 0xff00) == 0)
3865           { printf("Server killed by signal %d", $? & 255); }
3866         else
3867           { printf("Server status %x", $?); }
3868
3869         for (;;)
3870           {
3871           print "\nShow server stdout, Retry, Continue, or Quit? [Q] ";
3872           $_ = $force_continue ? "c" : <T>;
3873           tests_exit(1) if /^q?$/i;
3874           log_failure($log_failed_filename, $testno, "exit code unexpected") if (/^c$/i && $force_continue);
3875           print "... continue forced\n" if $force_continue;
3876           last if /^[rc]$/i;
3877
3878           if (/^s$/i)
3879             {
3880             open(S, "test-stdout-server") ||
3881               tests_exit(-1, "Failed to open test-stdout-server: $!");
3882             print while <S>;
3883             close(S);
3884             }
3885           }
3886         $retry = 1 if /^r$/i;
3887         }
3888       }
3889     }
3890
3891   close SCRIPT;
3892
3893   # The script has finished. Check the all the output that was generated. The
3894   # function returns 0 if all is well, 1 if we should rerun the test (the files
3895   # function returns 0 if all is well, 1 if we should rerun the test (the files
3896   # have been updated). It does not return if the user responds Q to a prompt.
3897
3898   if ($retry)
3899     {
3900     $retry = '0';
3901     print (("#" x 79) . "\n");
3902     redo;
3903     }
3904
3905   if ($docheck)
3906     {
3907     if (check_output($TEST_STATE->{munge}) != 0)
3908       {
3909       print (("#" x 79) . "\n");
3910       redo;
3911       }
3912     else
3913       {
3914       print ("  Script completed\n");
3915       }
3916     }
3917   }
3918
3919
3920 ##################################################
3921 #         Exit from the test script              #
3922 ##################################################
3923
3924 tests_exit(-1, "No runnable tests selected") if @test_list == 0;
3925 tests_exit(0);
3926
3927 # End of runtest script