test/runtest

   1 #! /usr/bin/env perl
   2 # We use env, because in some environments of our build farm
   3 # the Perl 5.010 interpreter is only reachable via $PATH
   4
   5 ###############################################################################
   6 # This is the controlling script for the "new" test suite for Exim. It should #
   7 # be possible to export this suite for running on a wide variety of hosts, in #
   8 # contrast to the old suite, which was very dependent on the environment of   #
   9 # Philip Hazel's desktop computer. This implementation inspects the version   #
  10 # of Exim that it finds, and tests only those features that are included. The #
  11 # surrounding environment is also tested to discover what is available. See   #
  12 # the README file for details of how it all works.                            #
  13 #                                                                             #
  14 # Implementation started: 03 August 2005 by Philip Hazel                      #
  15 # Placed in the Exim CVS: 06 February 2006                                    #
  16 ###############################################################################
  17
  18 #use strict;
  19 use 5.010;
  20 use warnings;
  21
  22 use Errno;
  23 use FileHandle;
  24 use IO::Socket::INET;
  25 use Socket;
  26 use Time::Local;
  27 use Cwd;
  28 use File::Basename;
  29 use if $ENV{DEBUG} && $ENV{DEBUG} =~ /\bruntest\b/ => ('Smart::Comments' => '####');
  30
  31
  32 # Start by initializing some global variables
  33
  34 $testversion = "4.80 (08-May-12)";
  35
  36 # This gets embedded in the D-H params filename, and the value comes
  37 # from asking GnuTLS for "normal", but there appears to be no way to
  38 # use certtool/... to ask what that value currently is.  *sigh*
  39 # We also clamp it because of NSS interop, see addition of tls_dh_max_bits.
  40 # This value is correct as of GnuTLS 2.12.18 as clamped by tls_dh_max_bits.
  41 # normal = 2432   tls_dh_max_bits = 2236
  42 $gnutls_dh_bits_normal = 2236;
  43
  44 $cf = "bin/cf -exact";
  45 $cr = "\r";
  46 $debug = 0;
  47 $flavour = 'FOO';
  48 $force_continue = 0;
  49 $force_update = 0;
  50 $log_failed_filename = "failed-summary.log";
  51 $more = "less -XF";
  52 $optargs = "";
  53 $save_output = 0;
  54 $server_opts = "";
  55 $valgrind = 0;
  56
  57 $have_ipv4 = 1;
  58 $have_ipv6 = 1;
  59 $have_largefiles = 0;
  60
  61 $test_start = 1;
  62 $test_end = $test_top = 8999;
  63 $test_special_top = 9999;
  64 @test_list = ();
  65 @test_dirs = ();
  66
  67
  68 # Networks to use for DNS tests. We need to choose some networks that will
  69 # never be used so that there is no chance that the host on which we are
  70 # running is actually in one of the test networks. Private networks such as
  71 # the IPv4 10.0.0.0/8 network are no good because hosts may well use them.
  72 # Rather than use some unassigned numbers (that might become assigned later),
  73 # I have chosen some multicast networks, in the belief that such addresses
  74 # won't ever be assigned to hosts. This is the only place where these numbers
  75 # are defined, so it is trivially possible to change them should that ever
  76 # become necessary.
  77
  78 $parm_ipv4_test_net = "224";
  79 $parm_ipv6_test_net = "ff00";
  80
  81 # Port numbers are currently hard-wired
  82
  83 $parm_port_n = 1223;         # Nothing listening on this port
  84 $parm_port_s = 1224;         # Used for the "server" command
  85 $parm_port_d = 1225;         # Used for the Exim daemon
  86 $parm_port_d2 = 1226;        # Additional for daemon
  87 $parm_port_d3 = 1227;        # Additional for daemon
  88 $parm_port_d4 = 1228;        # Additional for daemon
  89 my $dynamic_socket;          # allocated later for PORT_DYNAMIC
  90
  91 # Manually set locale
  92 $ENV{LC_ALL} = 'C';
  93
  94 # In some environments USER does not exists, but we
  95 # need it for some test(s)
  96 $ENV{USER} = getpwuid($>)
  97   if not exists $ENV{USER};
  98
  99 my ($parm_configure_owner, $parm_configure_group);
 100 my ($parm_ipv4, $parm_ipv6);
 101 my $parm_hostname;
 102
 103 ###############################################################################
 104 ###############################################################################
 105
 106 # Define a number of subroutines
 107
 108 ###############################################################################
 109 ###############################################################################
 110
 111
 112 ##################################################
 113 #              Handle signals                    #
 114 ##################################################
 115
 116 sub pipehandler { $sigpipehappened = 1; }
 117
 118 sub inthandler { print "\n"; tests_exit(-1, "Caught SIGINT"); }
 119
 120
 121 ##################################################
 122 #       Do global macro substitutions            #
 123 ##################################################
 124
 125 # This function is applied to configurations, command lines and data lines in
 126 # scripts, and to lines in the files of the aux-var-src and the dnszones-src
 127 # directory. It takes one argument: the current test number, or zero when
 128 # setting up files before running any tests.
 129
 130 sub do_substitute{
 131 s?\bCALLER\b?$parm_caller?g;
 132 s?\bCALLERGROUP\b?$parm_caller_group?g;
 133 s?\bCALLER_UID\b?$parm_caller_uid?g;
 134 s?\bCALLER_GID\b?$parm_caller_gid?g;
 135 s?\bCLAMSOCKET\b?$parm_clamsocket?g;
 136 s?\bDIR/?$parm_cwd/?g;
 137 s?\bEXIMGROUP\b?$parm_eximgroup?g;
 138 s?\bEXIMUSER\b?$parm_eximuser?g;
 139 s?\bHOSTIPV4\b?$parm_ipv4?g;
 140 s?\bHOSTIPV6\b?$parm_ipv6?g;
 141 s?\bHOSTNAME\b?$parm_hostname?g;
 142 s?\bPORT_D\b?$parm_port_d?g;
 143 s?\bPORT_D2\b?$parm_port_d2?g;
 144 s?\bPORT_D3\b?$parm_port_d3?g;
 145 s?\bPORT_D4\b?$parm_port_d4?g;
 146 s?\bPORT_N\b?$parm_port_n?g;
 147 s?\bPORT_S\b?$parm_port_s?g;
 148 s?\bTESTNUM\b?$_[0]?g;
 149 s?(\b|_)V4NET([\._])?$1$parm_ipv4_test_net$2?g;
 150 s?\bV6NET:?$parm_ipv6_test_net:?g;
 151 s?\bPORT_DYNAMIC\b?$dynamic_socket->sockport()?eg;
 152 }
 153
 154
 155 ##################################################
 156 #     Any state to be preserved across tests     #
 157 ##################################################
 158
 159 my $TEST_STATE = {};
 160
 161
 162 ##################################################
 163 #        Subroutine to tidy up and exit          #
 164 ##################################################
 165
 166 # In all cases, we check for any Exim daemons that have been left running, and
 167 # kill them. Then remove all the spool data, test output, and the modified Exim
 168 # binary if we are ending normally.
 169
 170 # Arguments:
 171 #    $_[0] = 0 for a normal exit; full cleanup done
 172 #    $_[0] > 0 for an error exit; no files cleaned up
 173 #    $_[0] < 0 for a "die" exit; $_[1] contains a message
 174
 175 sub tests_exit{
 176 my($rc) = $_[0];
 177 my($spool);
 178
 179 # Search for daemon pid files and kill the daemons. We kill with SIGINT rather
 180 # than SIGTERM to stop it outputting "Terminated" to the terminal when not in
 181 # the background.
 182
 183 if (exists $TEST_STATE->{exim_pid})
 184   {
 185   $pid = $TEST_STATE->{exim_pid};
 186   print "Tidyup: killing wait-mode daemon pid=$pid\n";
 187   system("sudo kill -INT $pid");
 188   }
 189
 190 if (opendir(DIR, "spool"))
 191   {
 192   my(@spools) = sort readdir(DIR);
 193   closedir(DIR);
 194   foreach $spool (@spools)
 195     {
 196     next if $spool !~ /^exim-daemon./;
 197     open(PID, "spool/$spool") || die "** Failed to open \"spool/$spool\": $!\n";
 198     chomp($pid = <PID>);
 199     close(PID);
 200     print "Tidyup: killing daemon pid=$pid\n";
 201     system("sudo rm -f spool/$spool; sudo kill -INT $pid");
 202     }
 203   }
 204 else
 205   { die "** Failed to opendir(\"spool\"): $!\n" unless $!{ENOENT}; }
 206
 207 # Close the terminal input and remove the test files if all went well, unless
 208 # the option to save them is set. Always remove the patched Exim binary. Then
 209 # exit normally, or die.
 210
 211 close(T);
 212 system("sudo /bin/rm -rf ./spool test-* ./dnszones/*")
 213   if ($rc == 0 && !$save_output);
 214
 215 system("sudo /bin/rm -rf ./eximdir/*")
 216   if (!$save_output);
 217
 218 print "\nYou were in test $test at the end there.\n\n" if defined $test;
 219 exit $rc if ($rc >= 0);
 220 die "** runtest error: $_[1]\n";
 221 }
 222
 223
 224
 225 ##################################################
 226 #   Subroutines used by the munging subroutine   #
 227 ##################################################
 228
 229 # This function is used for things like message ids, where we want to generate
 230 # more than one value, but keep a consistent mapping throughout.
 231 #
 232 # Arguments:
 233 #   $oldid        the value from the file
 234 #   $base         a base string into which we insert a sequence
 235 #   $sequence     the address of the current sequence counter
 236
 237 sub new_value {
 238 my($oldid, $base, $sequence) = @_;
 239 my($newid) = $cache{$oldid};
 240 if (! defined $newid)
 241   {
 242   $newid = sprintf($base, $$sequence++);
 243   $cache{$oldid} = $newid;
 244   }
 245 return $newid;
 246 }
 247
 248
 249 # This is used while munging the output from exim_dumpdb.
 250 # May go wrong across DST changes.
 251
 252 sub date_seconds {
 253 my($day,$month,$year,$hour,$min,$sec) =
 254   $_[0] =~ /^(\d\d)-(\w\w\w)-(\d{4})\s(\d\d):(\d\d):(\d\d)/;
 255 my($mon);
 256 if   ($month =~ /Jan/) {$mon = 0;}
 257 elsif($month =~ /Feb/) {$mon = 1;}
 258 elsif($month =~ /Mar/) {$mon = 2;}
 259 elsif($month =~ /Apr/) {$mon = 3;}
 260 elsif($month =~ /May/) {$mon = 4;}
 261 elsif($month =~ /Jun/) {$mon = 5;}
 262 elsif($month =~ /Jul/) {$mon = 6;}
 263 elsif($month =~ /Aug/) {$mon = 7;}
 264 elsif($month =~ /Sep/) {$mon = 8;}
 265 elsif($month =~ /Oct/) {$mon = 9;}
 266 elsif($month =~ /Nov/) {$mon = 10;}
 267 elsif($month =~ /Dec/) {$mon = 11;}
 268 return timelocal($sec,$min,$hour,$day,$mon,$year);
 269 }
 270
 271
 272 # This is a subroutine to sort maildir files into time-order. The second field
 273 # is the microsecond field, and may vary in length, so must be compared
 274 # numerically.
 275
 276 sub maildirsort {
 277 return $a cmp $b if ($a !~ /^\d+\.H\d/ || $b !~ /^\d+\.H\d/);
 278 my($x1,$y1) = $a =~ /^(\d+)\.H(\d+)/;
 279 my($x2,$y2) = $b =~ /^(\d+)\.H(\d+)/;
 280 return ($x1 != $x2)? ($x1 <=> $x2) : ($y1 <=> $y2);
 281 }
 282
 283
 284
 285 ##################################################
 286 #   Subroutine list files below a directory      #
 287 ##################################################
 288
 289 # This is used to build up a list of expected mail files below a certain path
 290 # in the directory tree. It has to be recursive in order to deal with multiple
 291 # maildir mailboxes.
 292
 293 sub list_files_below {
 294 my($dir) = $_[0];
 295 my(@yield) = ();
 296 my(@sublist, $file);
 297
 298 opendir(DIR, $dir) || tests_exit(-1, "Failed to open $dir: $!");
 299 @sublist = sort maildirsort readdir(DIR);
 300 closedir(DIR);
 301
 302 foreach $file (@sublist)
 303   {
 304   next if $file eq "." || $file eq ".." || $file eq "CVS";
 305   if (-d "$dir/$file")
 306     { @yield = (@yield, list_files_below("$dir/$file")); }
 307   else
 308     { push @yield, "$dir/$file"; }
 309   }
 310
 311 return @yield;
 312 }
 313
 314
 315
 316 ##################################################
 317 #         Munge a file before comparing          #
 318 ##################################################
 319
 320 # The pre-processing turns all dates, times, Exim versions, message ids, and so
 321 # on into standard values, so that the compare works. Perl's substitution with
 322 # an expression provides a neat way to do some of these changes.
 323
 324 # We keep a global associative array for repeatedly turning the same values
 325 # into the same standard values throughout the data from a single test.
 326 # Message ids get this treatment (can't be made reliable for times), and
 327 # times in dumped retry databases are also handled in a special way, as are
 328 # incoming port numbers.
 329
 330 # On entry to the subroutine, the file to write to is already opened with the
 331 # name MUNGED. The input file name is the only argument to the subroutine.
 332 # Certain actions are taken only when the name contains "stderr", "stdout",
 333 # or "log". The yield of the function is 1 if a line matching "*** truncated
 334 # ***" is encountered; otherwise it is 0.
 335
 336 sub munge {
 337 my($file) = $_[0];
 338 my($extra) = $_[1];
 339 my($yield) = 0;
 340 my(@saved) = ();
 341
 342 local $_;
 343
 344 open(IN, "$file") || tests_exit(-1, "Failed to open $file: $!");
 345
 346 my($is_log) = $file =~ /log/;
 347 my($is_stdout) = $file =~ /stdout/;
 348 my($is_stderr) = $file =~ /stderr/;
 349
 350 # Date pattern
 351
 352 $date = "\\d{2}-\\w{3}-\\d{4}\\s\\d{2}:\\d{2}:\\d{2}";
 353
 354 # Pattern for matching pids at start of stderr lines; initially something
 355 # that won't match.
 356
 357 $spid = "xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx";
 358
 359 # Scan the file and make the changes. Near the bottom there are some changes
 360 # that are specific to certain file types, though there are also some of those
 361 # inline too.
 362
 363 LINE: while(<IN>)
 364   {
 365 RESET_AFTER_EXTRA_LINE_READ:
 366   # Custom munges
 367   if ($extra)
 368     {
 369     next if $extra =~ m%^/%  &&  eval $extra;
 370     eval $extra if $extra =~ m/^s/;
 371     }
 372
 373   # Check for "*** truncated ***"
 374   $yield = 1 if /\*\*\* truncated \*\*\*/;
 375
 376   # Replace the name of this host
 377   s/\Q$parm_hostname\E/the.local.host.name/g;
 378
 379   # But convert "name=the.local.host address=127.0.0.1" to use "localhost"
 380   s/name=the\.local\.host address=127\.0\.0\.1/name=localhost address=127.0.0.1/g;
 381
 382   # The name of the shell may vary
 383   s/\s\Q$parm_shell\E\b/ ENV_SHELL/;
 384
 385   # Replace the path to the testsuite directory
 386   s?\Q$parm_cwd\E?TESTSUITE?g;
 387
 388   # Replace the Exim version number (may appear in various places)
 389   # patchexim should have fixed this for us
 390   #s/(Exim) \d+\.\d+[\w_-]*/$1 x.yz/i;
 391
 392   # Replace Exim message ids by a unique series
 393   s/((?:[^\W_]{6}-){2}[^\W_]{2})
 394     /new_value($1, "10Hm%s-0005vi-00", \$next_msgid)/egx;
 395
 396   # The names of lock files appear in some error and debug messages
 397   s/\.lock(\.[-\w]+)+(\.[\da-f]+){2}/.lock.test.ex.dddddddd.pppppppp/;
 398
 399   # Unless we are in an IPv6 test, replace IPv4 and/or IPv6 in "listening on
 400   # port" message, because it is not always the same.
 401   s/port (\d+) \([^)]+\)/port $1/g
 402     if !$is_ipv6test && m/listening for SMTP(S?) on port/;
 403
 404   # Challenges in SPA authentication
 405   s/TlRMTVNTUAACAAAAAAAAAAAoAAABgg[\w+\/]+/TlRMTVNTUAACAAAAAAAAAAAoAAABggAAAEbBRwqFwwIAAAAAAAAAAAAt1sgAAAAA/;
 406
 407   # PRVS values
 408   s?prvs=([^/]+)/[\da-f]{10}@?prvs=$1/xxxxxxxxxx@?g;    # Old form
 409   s?prvs=[\da-f]{10}=([^@]+)@?prvs=xxxxxxxxxx=$1@?g;    # New form
 410
 411   # Error lines on stdout from SSL contain process id values and file names.
 412   # They also contain a source file name and line number, which may vary from
 413   # release to release.
 414   s/^\d+:error:/pppp:error:/;
 415   s/:(?:\/[^\s:]+\/)?([^\/\s]+\.c):\d+:/:$1:dddd:/;
 416
 417   # There are differences in error messages between OpenSSL versions
 418   s/SSL_CTX_set_cipher_list/SSL_connect/;
 419
 420   # One error test in expansions mentions base 62 or 36
 421   s/is not a base (36|62) number/is not a base 36\/62 number/;
 422
 423   # This message sometimes has a different number of seconds
 424   s/forced fail after \d seconds/forced fail after d seconds/;
 425
 426   # This message may contain a different DBM library name
 427   s/Failed to open \S+( \([^\)]+\))? file/Failed to open DBM file/;
 428
 429   # The message for a non-listening FIFO varies
 430   s/:[^:]+: while opening named pipe/: Error: while opening named pipe/;
 431
 432   # Debugging output of lists of hosts may have different sort keys
 433   s/sort=\S+/sort=xx/ if /^\S+ (?:\d+\.){3}\d+ mx=\S+ sort=\S+/;
 434
 435   # Random local part in callout cache testing
 436   s/myhost.test.ex-\d+-testing/myhost.test.ex-dddddddd-testing/;
 437   s/the.local.host.name-\d+-testing/the.local.host.name-dddddddd-testing/;
 438
 439   # File descriptor numbers may vary
 440   s/^writing data block fd=\d+/writing data block fd=dddd/;
 441   s/(running as transport filter:) fd_write=\d+ fd_read=\d+/$1 fd_write=dddd fd_read=dddd/;
 442
 443
 444   # ======== Dumpdb output ========
 445   # This must be before the general date/date munging.
 446   # Time data lines, which look like this:
 447   # 25-Aug-2000 12:11:37  25-Aug-2000 12:11:37  26-Aug-2000 12:11:37
 448   if (/^($date)\s+($date)\s+($date)(\s+\*)?\s*$/)
 449     {
 450     my($date1,$date2,$date3,$expired) = ($1,$2,$3,$4);
 451     $expired = "" if !defined $expired;
 452     my($increment) = date_seconds($date3) - date_seconds($date2);
 453
 454     # We used to use globally unique replacement values, but timing
 455     # differences make this impossible. Just show the increment on the
 456     # last one.
 457
 458     printf MUNGED ("first failed = time last try = time2 next try = time2 + %s%s\n",
 459       $increment, $expired);
 460     next;
 461     }
 462
 463   # more_errno values in exim_dumpdb output which are times
 464   s/T:(\S+)\s-22\s(\S+)\s/T:$1 -22 xxxx /;
 465
 466
 467   # ======== Dates and times ========
 468
 469   # Dates and times are all turned into the same value - trying to turn
 470   # them into different ones cannot be done repeatedly because they are
 471   # real time stamps generated while running the test. The actual date and
 472   # time used was fixed when I first started running automatic Exim tests.
 473
 474   # Date/time in header lines and SMTP responses
 475   s/[A-Z][a-z]{2},\s\d\d?\s[A-Z][a-z]{2}\s\d\d\d\d\s\d\d\:\d\d:\d\d\s[-+]\d{4}
 476     /Tue, 2 Mar 1999 09:44:33 +0000/gx;
 477
 478   # Date/time in logs and in one instance of a filter test
 479   s/^\d{4}-\d\d-\d\d\s\d\d:\d\d:\d\d(\s[+-]\d\d\d\d)?/1999-03-02 09:44:33/gx;
 480   s/^Logwrite\s"\d{4}-\d\d-\d\d\s\d\d:\d\d:\d\d/Logwrite "1999-03-02 09:44:33/gx;
 481
 482   # Date/time in message separators
 483   s/(?:[A-Z][a-z]{2}\s){2}\d\d\s\d\d:\d\d:\d\d\s\d\d\d\d
 484     /Tue Mar 02 09:44:33 1999/gx;
 485
 486   # Date of message arrival in spool file as shown by -Mvh
 487   s/^\d{9,10}\s0$/ddddddddd 0/;
 488
 489   # Date/time in mbx mailbox files
 490   s/\d\d-\w\w\w-\d\d\d\d\s\d\d:\d\d:\d\d\s[-+]\d\d\d\d,/06-Sep-1999 15:52:48 +0100,/gx;
 491
 492   # Dates/times in debugging output for writing retry records
 493   if (/^  first failed=(\d+) last try=(\d+) next try=(\d+) (.*)$/)
 494     {
 495     my($next) = $3 - $2;
 496     $_ = "  first failed=dddd last try=dddd next try=+$next $4\n";
 497     }
 498   s/^(\s*)now=\d+ first_failed=\d+ next_try=\d+ expired=(\d)/$1now=tttt first_failed=tttt next_try=tttt expired=$2/;
 499   s/^(\s*)received_time=\d+ diff=\d+ timeout=(\d+)/$1received_time=tttt diff=tttt timeout=$2/;
 500
 501   # Time to retry may vary
 502   s/time to retry = \S+/time to retry = tttt/;
 503   s/retry record exists: age=\S+/retry record exists: age=ttt/;
 504   s/failing_interval=\S+ message_age=\S+/failing_interval=ttt message_age=ttt/;
 505
 506   # Date/time in exim -bV output
 507   s/\d\d-[A-Z][a-z]{2}-\d{4}\s\d\d:\d\d:\d\d/07-Mar-2000 12:21:52/g;
 508
 509   # Time on queue tolerance
 510   s/(QT|D)=1s/$1=0s/;
 511
 512   # Eximstats heading
 513   s/Exim\sstatistics\sfrom\s\d{4}-\d\d-\d\d\s\d\d:\d\d:\d\d\sto\s
 514     \d{4}-\d\d-\d\d\s\d\d:\d\d:\d\d/Exim statistics from <time> to <time>/x;
 515
 516   # Treat ECONNRESET the same as ECONNREFUSED.  At least some systems give
 517   # us the former on a new connection.
 518   s/(could not connect to .*: Connection) reset by peer$/$1 refused/;
 519
 520   # ======== TLS certificate algorithms ========
 521   # Test machines might have various different TLS library versions supporting
 522   # different protocols; can't rely upon TLS 1.2's AES256-GCM-SHA384, so we
 523   # treat the standard algorithms the same.
 524   # So far, have seen:
 525   #   TLSv1:AES128-GCM-SHA256:128
 526   #   TLSv1:AES256-SHA:256
 527   #   TLSv1.1:AES256-SHA:256
 528   #   TLSv1.2:AES256-GCM-SHA384:256
 529   #   TLSv1.2:DHE-RSA-AES256-SHA:256
 530   #   TLS1.2:DHE_RSA_AES_128_CBC_SHA1:128
 531   # We also need to handle the ciphersuite without the TLS part present, for
 532   # client-ssl's output.  We also see some older forced ciphersuites, but
 533   # negotiating TLS 1.2 instead of 1.0.
 534   # Mail headers (...), log-lines X=..., client-ssl output ...
 535   # (and \b doesn't match between ' ' and '(' )
 536
 537   s/( (?: (?:\b|\s) [\(=] ) | \s )TLSv1\.[12]:/$1TLSv1:/xg;
 538   s/\bAES128-GCM-SHA256:128\b/AES256-SHA:256/g;
 539   s/\bAES128-GCM-SHA256\b/AES256-SHA/g;
 540   s/\bAES256-GCM-SHA384\b/AES256-SHA/g;
 541   s/\bDHE-RSA-AES256-SHA\b/AES256-SHA/g;
 542
 543   # GnuTLS have seen:
 544   #   TLS1.2:ECDHE_RSA_AES_256_GCM_SHA384:256
 545   #   TLS1.2:ECDHE_RSA_AES_128_GCM_SHA256:128
 546   #   TLS1.2:RSA_AES_256_CBC_SHA1:256 (canonical)
 547   #   TLS1.2:DHE_RSA_AES_128_CBC_SHA1:128
 548   #
 549   #   X=TLS1.2:DHE_RSA_AES_256_CBC_SHA256:256
 550   #   X=TLS1.2:RSA_AES_256_CBC_SHA1:256
 551   #   X=TLS1.1:RSA_AES_256_CBC_SHA1:256
 552   #   X=TLS1.0:DHE_RSA_AES_256_CBC_SHA1:256
 553   # and as stand-alone cipher:
 554   #   ECDHE-RSA-AES256-SHA
 555   #   DHE-RSA-AES256-SHA256
 556   #   DHE-RSA-AES256-SHA
 557   # picking latter as canonical simply because regex easier that way.
 558   s/\bDHE_RSA_AES_128_CBC_SHA1:128/RSA_AES_256_CBC_SHA1:256/g;
 559   s/TLS1.[012]:((EC)?DHE_)?RSA_AES_(256|128)_(CBC|GCM)_SHA(1|256|384):(256|128)/TLS1.x:xxxxRSA_AES_256_CBC_SHAnnn:256/g;
 560   s/\b(ECDHE-RSA-AES256-SHA|DHE-RSA-AES256-SHA256)\b/AES256-SHA/g;
 561
 562   # GnuTLS library error message changes
 563   s/No certificate was found/The peer did not send any certificate/g;
 564 #(dodgy test?)  s/\(certificate verification failed\): invalid/\(gnutls_handshake\): The peer did not send any certificate./g;
 565   s/\(gnutls_priority_set\): No or insufficient priorities were set/\(gnutls_handshake\): Could not negotiate a supported cipher suite/g;
 566
 567   # (this new one is a generic channel-read error, but the testsuite
 568   # only hits it in one place)
 569   s/TLS error on connection \(gnutls_handshake\): Error in the pull function\./a TLS session is required but an attempt to start TLS failed/g;
 570
 571   # (replace old with new, hoping that old only happens in one situation)
 572   s/TLS error on connection to \d{1,3}(.\d{1,3}){3} \[\d{1,3}(.\d{1,3}){3}\] \(gnutls_handshake\): A TLS packet with unexpected length was received./a TLS session is required for ip4.ip4.ip4.ip4 [ip4.ip4.ip4.ip4], but an attempt to start TLS failed/g;
 573   s/TLS error on connection from \[127.0.0.1\] \(recv\): A TLS packet with unexpected length was received./TLS error on connection from [127.0.0.1] (recv): The TLS connection was non-properly terminated./g;
 574
 575   # signature algorithm names
 576   s/RSA-SHA1/RSA-SHA/;
 577
 578
 579   # ======== Caller's login, uid, gid, home, gecos ========
 580
 581   s/\Q$parm_caller_home\E/CALLER_HOME/g;   # NOTE: these must be done
 582   s/\b\Q$parm_caller\E\b/CALLER/g;         #       in this order!
 583   s/\b\Q$parm_caller_group\E\b/CALLER/g;   # In case group name different
 584
 585   s/\beuid=$parm_caller_uid\b/euid=CALLER_UID/g;
 586   s/\begid=$parm_caller_gid\b/egid=CALLER_GID/g;
 587
 588   s/\buid=$parm_caller_uid\b/uid=CALLER_UID/g;
 589   s/\bgid=$parm_caller_gid\b/gid=CALLER_GID/g;
 590
 591   s/\bname="?$parm_caller_gecos"?/name=CALLER_GECOS/g;
 592
 593   # When looking at spool files with -Mvh, we will find not only the caller
 594   # login, but also the uid and gid. It seems that $) in some Perls gives all
 595   # the auxiliary gids as well, so don't bother checking for that.
 596
 597   s/^CALLER $> \d+$/CALLER UID GID/;
 598
 599   # There is one case where the caller's login is forced to something else,
 600   # in order to test the processing of logins that contain spaces. Weird what
 601   # some people do, isn't it?
 602
 603   s/^spaced user $> \d+$/CALLER UID GID/;
 604
 605
 606   # ======== Exim's login ========
 607   # For messages received by the daemon, this is in the -H file, which some
 608   # tests inspect. For bounce messages, this will appear on the U= lines in
 609   # logs and also after Received: and in addresses. In one pipe test it appears
 610   # after "Running as:". It also appears in addresses, and in the names of lock
 611   # files.
 612
 613   s/U=$parm_eximuser/U=EXIMUSER/;
 614   s/user=$parm_eximuser/user=EXIMUSER/;
 615   s/login=$parm_eximuser/login=EXIMUSER/;
 616   s/Received: from $parm_eximuser /Received: from EXIMUSER /;
 617   s/Running as: $parm_eximuser/Running as: EXIMUSER/;
 618   s/\b$parm_eximuser@/EXIMUSER@/;
 619   s/\b$parm_eximuser\.lock\./EXIMUSER.lock./;
 620
 621   s/\beuid=$parm_exim_uid\b/euid=EXIM_UID/g;
 622   s/\begid=$parm_exim_gid\b/egid=EXIM_GID/g;
 623
 624   s/\buid=$parm_exim_uid\b/uid=EXIM_UID/g;
 625   s/\bgid=$parm_exim_gid\b/gid=EXIM_GID/g;
 626
 627   s/^$parm_eximuser $parm_exim_uid $parm_exim_gid/EXIMUSER EXIM_UID EXIM_GID/;
 628
 629
 630   # ======== General uids, gids, and pids ========
 631   # Note: this must come after munges for caller's and exim's uid/gid
 632
 633   # These are for systems where long int is 64
 634   s/\buid=4294967295/uid=-1/;
 635   s/\beuid=4294967295/euid=-1/;
 636   s/\bgid=4294967295/gid=-1/;
 637   s/\begid=4294967295/egid=-1/;
 638
 639   s/\bgid=\d+/gid=gggg/;
 640   s/\begid=\d+/egid=gggg/;
 641   s/\bpid=\d+/pid=pppp/;
 642   s/\buid=\d+/uid=uuuu/;
 643   s/\beuid=\d+/euid=uuuu/;
 644   s/set_process_info:\s+\d+/set_process_info: pppp/;
 645   s/queue run pid \d+/queue run pid ppppp/;
 646   s/process \d+ running as transport filter/process pppp running as transport filter/;
 647   s/process \d+ writing to transport filter/process pppp writing to transport filter/;
 648   s/reading pipe for subprocess \d+/reading pipe for subprocess pppp/;
 649   s/remote delivery process \d+ ended/remote delivery process pppp ended/;
 650
 651   # Pid in temp file in appendfile transport
 652   s"test-mail/temp\.\d+\."test-mail/temp.pppp.";
 653
 654   # Optional pid in log lines
 655   s/^(\d{4}-\d\d-\d\d\s\d\d:\d\d:\d\d)(\s[+-]\d\d\d\d|)(\s\[\d+\])/
 656     "$1$2 [" . new_value($3, "%s", \$next_pid) . "]"/gxe;
 657
 658   # Detect a daemon stderr line with a pid and save the pid for subsequent
 659   # removal from following lines.
 660   $spid = $1 if /^(\s*\d+) (?:listening|LOG: MAIN|(?:daemon_smtp_port|local_interfaces) overridden by)/;
 661   s/^$spid //;
 662
 663   # Queue runner waiting messages
 664   s/waiting for children of \d+/waiting for children of pppp/;
 665   s/waiting for (\S+) \(\d+\)/waiting for $1 (pppp)/;
 666
 667   # The spool header file name varies with PID
 668   s%^(Writing spool header file: .*/hdr).[0-9]{1,5}%$1.pppp%;
 669
 670   # ======== Port numbers ========
 671   # Incoming port numbers may vary, but not in daemon startup line.
 672
 673   s/^Port: (\d+)/"Port: " . new_value($1, "%s", \$next_port)/e;
 674   s/\(port=(\d+)/"(port=" . new_value($1, "%s", \$next_port)/e;
 675
 676   # This handles "connection from" and the like, when the port is given
 677   if (!/listening for SMTP on/ && !/Connecting to/ && !/=>/ && !/->/
 678       && !/\*>/ && !/Connection refused/)
 679     {
 680     s/\[([a-z\d:]+|\d+(?:\.\d+){3})\]:(\d+)/"[".$1."]:".new_value($2,"%s",\$next_port)/ie;
 681     }
 682
 683   # Port in host address in spool file output from -Mvh
 684   s/^-host_address (.*)\.\d+/-host_address $1.9999/;
 685
 686   if ($dynamic_socket and $dynamic_socket->opened and my $port = $dynamic_socket->sockport) {
 687     s/^Connecting to 127\.0\.0\.1 port \K$port/<dynamic port>/;
 688   }
 689
 690
 691   # ======== Local IP addresses ========
 692   # The amount of space between "host" and the address in verification output
 693   # depends on the length of the host name. We therefore reduce it to one space
 694   # for all of them.
 695   # Also, the length of space at the end of the host line is dependent
 696   # on the length of the longest line, so strip it also on otherwise
 697   # un-rewritten lines like localhost
 698
 699   s/^\s+host\s(\S+)\s+(\S+)/  host $1 $2/;
 700   s/^\s+(host\s\S+\s\S+)\s+(port=.*)/  host $1 $2/;
 701   s/^\s+(host\s\S+\s\S+)\s+(?=MX=)/  $1 /;
 702   s/host\s\Q$parm_ipv4\E\s\[\Q$parm_ipv4\E\]/host ipv4.ipv4.ipv4.ipv4 [ipv4.ipv4.ipv4.ipv4]/;
 703   s/host\s\Q$parm_ipv6\E\s\[\Q$parm_ipv6\E\]/host ip6:ip6:ip6:ip6:ip6:ip6:ip6:ip6 [ip6:ip6:ip6:ip6:ip6:ip6:ip6:ip6]/;
 704   s/\b\Q$parm_ipv4\E\b/ip4.ip4.ip4.ip4/g;
 705   s/(^|\W)\K\Q$parm_ipv6\E/ip6:ip6:ip6:ip6:ip6:ip6:ip6:ip6/g;
 706   s/\b\Q$parm_ipv4r\E\b/ip4-reverse/g;
 707   s/(^|\W)\K\Q$parm_ipv6r\E/ip6-reverse/g;
 708   s/^(\s+host\s\S+\s+\[\S+\]) +$/$1 /;
 709
 710
 711   # ======== Test network IP addresses ========
 712   s/(\b|_)\Q$parm_ipv4_test_net\E(?=\.\d+\.\d+\.\d+\b|_|\.rbl|\.in-addr|\.test\.again\.dns)/$1V4NET/g;
 713   s/\b\Q$parm_ipv6_test_net\E(?=:[\da-f]+:[\da-f]+:[\da-f]+)/V6NET/gi;
 714
 715
 716   # ======== IP error numbers and messages ========
 717   # These vary between operating systems
 718   s/Can't assign requested address/Network Error/;
 719   s/Cannot assign requested address/Network Error/;
 720   s/Operation timed out/Connection timed out/;
 721   s/Address family not supported by protocol family/Network Error/;
 722   s/Network is unreachable/Network Error/;
 723   s/Invalid argument/Network Error/;
 724
 725   s/\(\d+\): Network/(dd): Network/;
 726   s/\(\d+\): Connection refused/(dd): Connection refused/;
 727   s/\(\d+\): Connection timed out/(dd): Connection timed out/;
 728   s/\d+ 65 Connection refused/dd 65 Connection refused/;
 729   s/\d+ 321 Connection timed out/dd 321 Connection timed out/;
 730
 731
 732   # ======== Other error numbers ========
 733   s/errno=\d+/errno=dd/g;
 734
 735   # ======== System Error Messages ======
 736   # depending on the underlaying file system the error message seems to differ
 737   s/(?: is not a regular file)|(?: has too many links \(\d+\))/ not a regular file or too many links/;
 738
 739   # ======== Output from ls ========
 740   # Different operating systems use different spacing on long output
 741   #s/ +/ /g if /^[-rwd]{10} /;
 742   # (Bug 1226) SUSv3 allows a trailing printable char for modified access method control.
 743   # Handle only the Gnu and MacOS space, dot, plus and at-sign.  A full [[:graph:]]
 744   # unfortunately matches a non-ls linefull of dashes.
 745   # Allow the case where we've already picked out the file protection bits.
 746   if (s/^([-d](?:[-r][-w][-SsTtx]){3})[.+@]?( +|$)/$1$2/) {
 747     s/ +/ /g;
 748   }
 749
 750
 751   # ======== Message sizes =========
 752   # Message sizes vary, owing to different logins and host names that get
 753   # automatically inserted. I can't think of any way of even approximately
 754   # comparing these.
 755
 756   s/([\s,])S=\d+\b/$1S=sss/;
 757   s/:S\d+\b/:Ssss/;
 758   s/^(\s*\d+m\s+)\d+(\s+[a-z0-9-]{16} <)/$1sss$2/i if $is_stdout;
 759   s/\sSIZE=\d+\b/ SIZE=ssss/;
 760   s/\ssize=\d+\b/ size=sss/ if $is_stderr;
 761   s/old size = \d+\b/old size = sssss/;
 762   s/message size = \d+\b/message size = sss/;
 763   s/this message = \d+\b/this message = sss/;
 764   s/Size of headers = \d+/Size of headers = sss/;
 765   s/sum=(?!0)\d+/sum=dddd/;
 766   s/(?<=sum=dddd )count=\d+\b/count=dd/;
 767   s/(?<=sum=0 )count=\d+\b/count=dd/;
 768   s/,S is \d+\b/,S is ddddd/;
 769   s/\+0100,\d+;/+0100,ddd;/;
 770   s/\(\d+ bytes written\)/(ddd bytes written)/;
 771   s/added '\d+ 1'/added 'ddd 1'/;
 772   s/Received\s+\d+/Received               nnn/;
 773   s/Delivered\s+\d+/Delivered              nnn/;
 774
 775
 776   # ======== Values in spool space failure message ========
 777   s/space=\d+ inodes=[+-]?\d+/space=xxxxx inodes=xxxxx/;
 778
 779
 780   # ======== Filter sizes ========
 781   # The sizes of filter files may vary because of the substitution of local
 782   # filenames, logins, etc.
 783
 784   s/^\d+(?= bytes read from )/ssss/;
 785
 786
 787   # ======== OpenSSL error messages ========
 788   # Different releases of the OpenSSL libraries seem to give different error
 789   # numbers, or handle specific bad conditions in different ways, leading to
 790   # different wording in the error messages, so we cannot compare them.
 791
 792   s/(TLS error on connection (?:from .* )?\(SSL_\w+\): error:)(.*)/$1 <<detail omitted>>/;
 793   next if /SSL verify error: depth=0 error=certificate not trusted/;
 794
 795   # ======== Maildir things ========
 796   # timestamp output in maildir processing
 797   s/(timestamp=|\(timestamp_only\): )\d+/$1ddddddd/g;
 798
 799   # maildir delivery files appearing in log lines (in cases of error)
 800   s/writing to(?: file)? tmp\/\d+\.[^.]+\.(\S+)/writing to tmp\/MAILDIR.$1/;
 801
 802   s/renamed tmp\/\d+\.[^.]+\.(\S+) as new\/\d+\.[^.]+\.(\S+)/renamed tmp\/MAILDIR.$1 as new\/MAILDIR.$1/;
 803
 804   # Maildir file names in general
 805   s/\b\d+\.H\d+P\d+\b/dddddddddd.HddddddPddddd/;
 806
 807   # Maildirsize data
 808   while (/^\d+S,\d+C\s*$/)
 809     {
 810     print MUNGED;
 811     while (<IN>)
 812       {
 813       last if !/^\d+ \d+\s*$/;
 814       print MUNGED "ddd d\n";
 815       }
 816     last if !defined $_;
 817     }
 818   last if !defined $_;
 819
 820
 821   # ======== Output from the "fd" program about open descriptors ========
 822   # The statuses seem to be different on different operating systems, but
 823   # at least we'll still be checking the number of open fd's.
 824
 825   s/max fd = \d+/max fd = dddd/;
 826   s/status=0 RDONLY/STATUS/g;
 827   s/status=1 WRONLY/STATUS/g;
 828   s/status=2 RDWR/STATUS/g;
 829
 830
 831   # ======== Contents of spool files ========
 832   # A couple of tests dump the contents of the -H file. The length fields
 833   # will be wrong because of different user names, etc.
 834   s/^\d\d\d(?=[PFS*])/ddd/;
 835
 836
 837   # ========= Exim lookups ==================
 838   # Lookups have a char which depends on the number of lookup types compiled in,
 839   # in stderr output.  Replace with a "0".  Recognising this while avoiding
 840   # other output is fragile; perhaps the debug output should be revised instead.
 841   s%(?<!sqlite)(?<!lsearch\*@)(?<!lsearch\*)(?<!lsearch)[0-?]TESTSUITE/aux-fixed/%0TESTSUITE/aux-fixed/%g;
 842
 843   # ==========================================================
 844   # MIME boundaries in RFC3461 DSN messages
 845   s/\d{8,10}-eximdsn-\d+/NNNNNNNNNN-eximdsn-MMMMMMMMMM/;
 846
 847   # ==========================================================
 848   # Some munging is specific to the specific file types
 849
 850   # ======== stdout ========
 851
 852   if ($is_stdout)
 853     {
 854     # Skip translate_ip_address and use_classresources in -bP output because
 855     # they aren't always there.
 856
 857     next if /translate_ip_address =/;
 858     next if /use_classresources/;
 859
 860     # In certain filter tests, remove initial filter lines because they just
 861     # clog up by repetition.
 862
 863     if ($rmfiltertest)
 864       {
 865       next if /^(Sender\staken\sfrom|
 866                  Return-path\scopied\sfrom|
 867                  Sender\s+=|
 868                  Recipient\s+=)/x;
 869       if (/^Testing \S+ filter/)
 870         {
 871         $_ = <IN>;    # remove blank line
 872         next;
 873         }
 874       }
 875
 876     # openssl version variances
 877     next if /^SSL info: unknown state/;
 878     next if /^SSL info: SSLv2\/v3 write client hello A/;
 879     next if /^SSL info: SSLv3 read server key exchange A/;
 880     next if /SSL verify error: depth=0 error=certificate not trusted/;
 881     s/SSL3_READ_BYTES/ssl3_read_bytes/;
 882
 883     # gnutls version variances
 884     next if /^Error in the pull function./;
 885     }
 886
 887   # ======== stderr ========
 888
 889   elsif ($is_stderr)
 890     {
 891     # The very first line of debugging output will vary
 892
 893     s/^Exim version .*/Exim version x.yz ..../;
 894
 895     # Debugging lines for Exim terminations
 896
 897     s/(?<=^>>>>>>>>>>>>>>>> Exim pid=)\d+(?= terminating)/pppp/;
 898
 899     # IP address lookups use gethostbyname() when IPv6 is not supported,
 900     # and gethostbyname2() or getipnodebyname() when it is.
 901
 902     s/\b(gethostbyname2?|\bgetipnodebyname)(\(af=inet\))?/get[host|ipnode]byname[2]/;
 903
 904     # drop gnutls version strings
 905     next if /GnuTLS compile-time version: \d+[\.\d]+$/;
 906     next if /GnuTLS runtime version: \d+[\.\d]+$/;
 907
 908     # drop openssl version strings
 909     next if /OpenSSL compile-time version: OpenSSL \d+[\.\da-z]+/;
 910     next if /OpenSSL runtime version: OpenSSL \d+[\.\da-z]+/;
 911
 912     # drop lookups
 913     next if /^Lookups \(built-in\):/;
 914     next if /^Loading lookup modules from/;
 915     next if /^Loaded \d+ lookup modules/;
 916     next if /^Total \d+ lookups/;
 917
 918     # drop compiler information
 919     next if /^Compiler:/;
 920
 921     # and the ugly bit
 922     # different libraries will have different numbers (possibly 0) of follow-up
 923     # lines, indenting with more data
 924     if (/^Library version:/) {
 925       while (1) {
 926         $_ = <IN>;
 927         next if /^\s/;
 928         goto RESET_AFTER_EXTRA_LINE_READ;
 929       }
 930     }
 931
 932     # drop other build-time controls emitted for debugging
 933     next if /^WHITELIST_D_MACROS:/;
 934     next if /^TRUSTED_CONFIG_LIST:/;
 935
 936     # As of Exim 4.74, we log when a setgid fails; because we invoke Exim
 937     # with -be, privileges will have been dropped, so this will always
 938     # be the case
 939     next if /^changing group to \d+ failed: (Operation not permitted|Not owner)/;
 940
 941     # We might not keep this check; rather than change all the tests, just
 942     # ignore it as long as it succeeds; then we only need to change the
 943     # TLS tests where tls_require_ciphers has been set.
 944     if (m{^changed uid/gid: calling tls_validate_require_cipher}) {
 945       my $discard = <IN>;
 946       next;
 947     }
 948     next if /^tls_validate_require_cipher child \d+ ended: status=0x0/;
 949
 950     # We invoke Exim with -D, so we hit this new messag as of Exim 4.73:
 951     next if /^macros_trusted overridden to true by whitelisting/;
 952
 953     # We have to omit the localhost ::1 address so that all is well in
 954     # the IPv4-only case.
 955
 956     print MUNGED "MUNGED: ::1 will be omitted in what follows\n"
 957       if (/looked up these IP addresses/);
 958     next if /name=localhost address=::1/;
 959
 960     # drop pdkim debugging header
 961     next if /^PDKIM <<<<<<<<<<<<<<<<<<<<<<<<<<<<<+$/;
 962
 963     # Various other IPv6 lines must be omitted too
 964
 965     next if /using host_fake_gethostbyname for \S+ \(IPv6\)/;
 966     next if /get\[host\|ipnode\]byname\[2\]\(af=inet6\)/;
 967     next if /DNS lookup of \S+ \(AAAA\) using fakens/;
 968     next if / in dns_ipv4_lookup?/;
 969
 970     if (/DNS lookup of \S+ \(AAAA\) gave NO_DATA/)
 971       {
 972       $_= <IN>;     # Gets "returning DNS_NODATA"
 973       next;
 974       }
 975
 976     # Skip tls_advertise_hosts and hosts_require_tls checks when the options
 977     # are unset, because tls ain't always there.
 978
 979     next if /in\s(?:tls_advertise_hosts\?|hosts_require_tls\?)
 980                 \sno\s\((option\sunset|end\sof\slist)\)/x;
 981
 982     # Skip auxiliary group lists because they will vary.
 983
 984     next if /auxiliary group list:/;
 985
 986     # Skip "extracted from gecos field" because the gecos field varies
 987
 988     next if /extracted from gecos field/;
 989
 990     # Skip "waiting for data on socket" and "read response data: size=" lines
 991     # because some systems pack more stuff into packets than others.
 992
 993     next if /waiting for data on socket/;
 994     next if /read response data: size=/;
 995
 996     # If Exim is compiled with readline support but it can't find the library
 997     # to load, there will be an extra debug line. Omit it.
 998
 999     next if /failed to load readline:/;
1000
1001     # Some DBM libraries seem to make DBM files on opening with O_RDWR without
1002     # O_CREAT; other's don't. In the latter case there is some debugging output
1003     # which is not present in the former. Skip the relevant lines (there are
1004     # two of them).
1005
1006     if (/TESTSUITE\/spool\/db\/\S+ appears not to exist: trying to create/)
1007       {
1008       $_ = <IN>;
1009       next;
1010       }
1011
1012     # Some tests turn on +expand debugging to check on expansions.
1013     # Unfortunately, the Received: expansion varies, depending on whether TLS
1014     # is compiled or not. So we must remove the relevant debugging if it is.
1015
1016     if (/^condition: def:tls_cipher/)
1017       {
1018       while (<IN>) { last if /^condition: def:sender_address/; }
1019       }
1020     elsif (/^expanding: Received: /)
1021       {
1022       while (<IN>) { last if !/^\s/; }
1023       }
1024
1025     # remote port numbers vary
1026     s/(Connection request from 127.0.0.1 port) \d{1,5}/$1 sssss/;
1027
1028     # Skip hosts_require_dane checks when the options
1029     # are unset, because dane ain't always there.
1030
1031     next if /in\shosts_require_dane\?\sno\s\(option\sunset\)/x;
1032
1033     # SUPPORT_PROXY
1034     next if /host in hosts_proxy\?/;
1035
1036     # Experimental_International
1037     next if / in smtputf8_advertise_hosts\? no \(option unset\)/;
1038
1039     # Environment cleaning
1040     next if /\w+ in keep_environment\? (yes|no)/;
1041
1042     # Sizes vary with test hostname
1043     s/^cmd buf flush \d+ bytes$/cmd buf flush ddd bytes/;
1044
1045     # Spool filesystem free space changes on different systems.
1046     s/^((?:spool|log) directory space =) -?\d+K (inodes =)\s*-?\d+/$1 nnnnnK $2 nnnnn/;
1047
1048     # Not all platforms support TCP Fast Open, and the compile omits the check
1049     if (/^((>>> )?Connecting to .* )in hosts_try_fastopen\? no \(option unset\)$/)
1050       {
1051       my $p = $1;
1052       $_ = <IN>;
1053       s/^/$p/;
1054       }
1055
1056     # When Exim is checking the size of directories for maildir, it uses
1057     # the check_dir_size() function to scan directories. Of course, the order
1058     # of the files that are obtained using readdir() varies from system to
1059     # system. We therefore buffer up debugging lines from check_dir_size()
1060     # and sort them before outputting them.
1061
1062     if (/^check_dir_size:/ || /^skipping TESTSUITE\/test-mail\//)
1063       {
1064       push @saved, $_;
1065       }
1066     else
1067       {
1068       if (@saved > 0)
1069         {
1070         print MUNGED "MUNGED: the check_dir_size lines have been sorted " .
1071           "to ensure consistency\n";
1072         @saved = sort(@saved);
1073         print MUNGED @saved;
1074         @saved = ();
1075         }
1076
1077       # Skip some lines that Exim puts out at the start of debugging output
1078       # because they will be different in different binaries.
1079
1080       print MUNGED
1081         unless (/^Berkeley DB: / ||
1082                 /^Probably (?:Berkeley DB|ndbm|GDBM)/ ||
1083                 /^Authenticators:/ ||
1084                 /^Lookups:/ ||
1085                 /^Support for:/ ||
1086                 /^Routers:/ ||
1087                 /^Transports:/ ||
1088                 /^log selectors =/ ||
1089                 /^cwd=/ ||
1090                 /^Fixed never_users:/ ||
1091                 /^Configure owner:/ ||
1092                 /^Size of off_t:/
1093                 );
1094
1095
1096       }
1097
1098     next;
1099     }
1100
1101   # ======== log ========
1102
1103   elsif ($is_log)
1104     {
1105     # Berkeley DB version differences
1106     next if / Berkeley DB error: /;
1107     }
1108
1109   # ======== All files other than stderr ========
1110
1111   print MUNGED;
1112   }
1113
1114 close(IN);
1115 return $yield;
1116 }
1117
1118
1119
1120
1121 ##################################################
1122 #        Subroutine to interact with caller      #
1123 ##################################################
1124
1125 # Arguments: [0] the prompt string
1126 #            [1] if there is a U in the prompt and $force_update is true
1127 #            [2] if there is a C in the prompt and $force_continue is true
1128 # Returns:   returns the answer
1129
1130 sub interact{
1131 print $_[0];
1132 if ($_[1]) { $_ = "u"; print "... update forced\n"; }
1133   elsif ($_[2]) { $_ = "c"; print "... continue forced\n"; }
1134   else { $_ = <T>; }
1135 }
1136
1137
1138
1139 ##################################################
1140 #    Subroutine to log in force_continue mode    #
1141 ##################################################
1142
1143 # In force_continue mode, we just want a terse output to a statically
1144 # named logfile.  If multiple files in same batch (stdout, stderr, etc)
1145 # all have mismatches, it will log multiple times.
1146 #
1147 # Arguments: [0] the logfile to append to
1148 #            [1] the testno that failed
1149 # Returns:   nothing
1150
1151
1152
1153 sub log_failure {
1154   my $logfile = shift();
1155   my $testno  = shift();
1156   my $detail  = shift() || '';
1157   if ( open(my $fh, ">>", $logfile) ) {
1158     print $fh "Test $testno $detail failed\n";
1159     close $fh;
1160   }
1161 }
1162
1163
1164
1165 ##################################################
1166 #    Subroutine to compare one output file       #
1167 ##################################################
1168
1169 # When an Exim server is part of the test, its output is in separate files from
1170 # an Exim client. The server data is concatenated with the client data as part
1171 # of the munging operation.
1172 #
1173 # Arguments:  [0] the name of the main raw output file
1174 #             [1] the name of the server raw output file or undef
1175 #             [2] where to put the munged copy
1176 #             [3] the name of the saved file
1177 #             [4] TRUE if this is a log file whose deliveries must be sorted
1178 #             [5] optionally, a custom munge command
1179 #
1180 # Returns:    0 comparison succeeded or differences to be ignored
1181 #             1 comparison failed; files may have been updated (=> re-compare)
1182 #
1183 # Does not return if the user replies "Q" to a prompt.
1184
1185 sub check_file{
1186 my($rf,$rsf,$mf,$sf,$sortfile,$extra) = @_;
1187
1188 # If there is no saved file, the raw files must either not exist, or be
1189 # empty. The test ! -s is TRUE if the file does not exist or is empty.
1190
1191 # we check if there is a flavour specific file, but we remember
1192 # the original file name as "generic"
1193 $sf_generic = $sf;
1194 $sf_flavour = "$sf_generic.$flavour";
1195 $sf_current = -e $sf_flavour ? $sf_flavour : $sf_generic;
1196
1197 if (! -e $sf_current)
1198   {
1199   return 0 if (! -s $rf && (! defined $rsf || ! -s $rsf));
1200
1201   print "\n";
1202   print "** $rf is not empty\n" if (-s $rf);
1203   print "** $rsf is not empty\n" if (defined $rsf && -s $rsf);
1204
1205   for (;;)
1206     {
1207     print "Continue, Show, or Quit? [Q] ";
1208     $_ = $force_continue ? "c" : <T>;
1209     tests_exit(1) if /^q?$/i;
1210     log_failure($log_failed_filename, $testno, $rf) if (/^c$/i && $force_continue);
1211     return 0 if /^c$/i;
1212     last if (/^s$/);
1213     }
1214
1215   foreach $f ($rf, $rsf)
1216     {
1217     if (defined $f && -s $f)
1218       {
1219       print "\n";
1220       print "------------ $f -----------\n"
1221         if (defined $rf && -s $rf && defined $rsf && -s $rsf);
1222       system("$more '$f'");
1223       }
1224     }
1225
1226   print "\n";
1227   for (;;)
1228     {
1229     interact("Continue, Update & retry, Quit? [Q] ", $force_update, $force_continue);
1230     tests_exit(1) if /^q?$/i;
1231     log_failure($log_failed_filename, $testno, $rsf) if (/^c$/i && $force_continue);
1232     return 0 if /^c$/i;
1233     last if (/^u$/i);
1234     }
1235   }
1236
1237 #### $_
1238
1239 # Control reaches here if either (a) there is a saved file ($sf), or (b) there
1240 # was a request to create a saved file. First, create the munged file from any
1241 # data that does exist.
1242
1243 open(MUNGED, ">$mf") || tests_exit(-1, "Failed to open $mf: $!");
1244 my($truncated) = munge($rf, $extra) if -e $rf;
1245 if (defined $rsf && -e $rsf)
1246   {
1247   print MUNGED "\n******** SERVER ********\n";
1248   $truncated |= munge($rsf, $extra);
1249   }
1250 close(MUNGED);
1251
1252 # If a saved file exists, do the comparison. There are two awkward cases:
1253 #
1254 # If "*** truncated ***" was found in the new file, it means that a log line
1255 # was overlong, and truncated. The problem is that it may be truncated at
1256 # different points on different systems, because of different user name
1257 # lengths. We reload the file and the saved file, and remove lines from the new
1258 # file that precede "*** truncated ***" until we reach one that matches the
1259 # line that precedes it in the saved file.
1260 #
1261 # If $sortfile is set, we are dealing with a mainlog file where the deliveries
1262 # for an individual message might vary in their order from system to system, as
1263 # a result of parallel deliveries. We load the munged file and sort sequences
1264 # of delivery lines.
1265
1266 if (-e $sf_current)
1267   {
1268   # Deal with truncated text items
1269
1270   if ($truncated)
1271     {
1272     my(@munged, @saved, $i, $j, $k);
1273
1274     open(MUNGED, "$mf") || tests_exit(-1, "Failed to open $mf: $!");
1275     @munged = <MUNGED>;
1276     close(MUNGED);
1277     open(SAVED, $sf_current) || tests_exit(-1, "Failed to open $sf_current: $!");
1278     @saved = <SAVED>;
1279     close(SAVED);
1280
1281     $j = 0;
1282     for ($i = 0; $i < @munged; $i++)
1283       {
1284       if ($munged[$i] =~ /\*\*\* truncated \*\*\*/)
1285         {
1286         for (; $j < @saved; $j++)
1287           { last if $saved[$j] =~ /\*\*\* truncated \*\*\*/; }
1288         last if $j >= @saved;     # not found in saved
1289
1290         for ($k = $i - 1; $k >= 0; $k--)
1291           { last if $munged[$k] eq $saved[$j - 1]; }
1292
1293         last if $k <= 0;          # failed to find previous match
1294         splice @munged, $k + 1, $i - $k - 1;
1295         $i = $k + 1;
1296         }
1297       }
1298
1299     open(MUNGED, ">$mf") || tests_exit(-1, "Failed to open $mf: $!");
1300     for ($i = 0; $i < @munged; $i++)
1301       { print MUNGED $munged[$i]; }
1302     close(MUNGED);
1303     }
1304
1305   # Deal with log sorting
1306
1307   if ($sortfile)
1308     {
1309     my(@munged, $i, $j);
1310
1311     open(MUNGED, "$mf") || tests_exit(-1, "Failed to open $mf: $!");
1312     @munged = <MUNGED>;
1313     close(MUNGED);
1314
1315     for ($i = 0; $i < @munged; $i++)
1316       {
1317       if ($munged[$i] =~ /^[-\d]{10}\s[:\d]{8}\s[-A-Za-z\d]{16}\s[-=*]>/)
1318         {
1319         for ($j = $i + 1; $j < @munged; $j++)
1320           {
1321           last if $munged[$j] !~
1322             /^[-\d]{10}\s[:\d]{8}\s[-A-Za-z\d]{16}\s[-=*]>/;
1323           }
1324         @temp = splice(@munged, $i, $j - $i);
1325         @temp = sort(@temp);
1326         splice(@munged, $i, 0, @temp);
1327         }
1328       }
1329
1330     open(MUNGED, ">$mf") || tests_exit(-1, "Failed to open $mf: $!");
1331     print MUNGED "**NOTE: The delivery lines in this file have been sorted.\n";
1332     for ($i = 0; $i < @munged; $i++)
1333       { print MUNGED $munged[$i]; }
1334     close(MUNGED);
1335     }
1336
1337   # Do the comparison
1338
1339   return 0 if (system("$cf '$mf' '$sf_current' >test-cf") == 0);
1340
1341   # Handle comparison failure
1342
1343   print "** Comparison of $mf with $sf_current failed";
1344   system("$more test-cf");
1345
1346   print "\n";
1347   for (;;)
1348     {
1349     interact("Continue, Retry, Update current"
1350         . ($sf_current ne $sf_flavour  ? "/Save for flavour '$flavour'" : "")
1351         . " & retry, Quit? [Q] ", $force_update, $force_continue);
1352     tests_exit(1) if /^q?$/i;
1353     log_failure($log_failed_filename, $testno, $sf_current) if (/^c$/i && $force_continue);
1354     return 0 if /^c$/i;
1355     return 1 if /^r$/i;
1356     last if (/^[us]$/i);
1357     }
1358   }
1359
1360 # Update or delete the saved file, and give the appropriate return code.
1361
1362 if (-s $mf)
1363   {
1364         my $sf = /^u/i ? $sf_current : $sf_flavour;
1365                 tests_exit(-1, "Failed to cp $mf $sf") if system("cp '$mf' '$sf'") != 0;
1366   }
1367 else
1368   {
1369         # if we deal with a flavour file, we can't delete it, because next time the generic
1370         # file would be used again
1371         if ($sf_current eq $sf_flavour) {
1372                 open(FOO, ">$sf_current");
1373                 close(FOO);
1374         }
1375         else {
1376                 tests_exit(-1, "Failed to unlink $sf_current") if !unlink($sf_current);
1377         }
1378   }
1379
1380 return 1;
1381 }
1382
1383
1384
1385 ##################################################
1386 # Custom munges
1387 # keyed by name of munge; value is a ref to a hash
1388 # which is keyed by file, value a string to look for.
1389 # Usable files are:
1390 #  paniclog, rejectlog, mainlog, stdout, stderr, msglog, mail
1391 # Search strings starting with 's' do substitutions;
1392 # with '/' do line-skips.
1393 # Triggered by a scriptfile line "munge <name>"
1394 ##################################################
1395 $munges =
1396   { 'dnssec' =>
1397     { 'stderr' => '/^Reverse DNS security status: unverified\n/' },
1398
1399     'gnutls_unexpected' =>
1400     { 'mainlog' => '/\(recv\): A TLS packet with unexpected length was received./' },
1401
1402     'gnutls_handshake' =>
1403     { 'mainlog' => 's/\(gnutls_handshake\): Error in the push function/\(gnutls_handshake\): A TLS packet with unexpected length was received/' },
1404
1405     'optional_events' =>
1406     { 'stdout' => '/event_action =/' },
1407
1408     'optional_ocsp' =>
1409     { 'stderr' => '/127.0.0.1 in hosts_requ(ire|est)_ocsp/' },
1410
1411     'optional_cert_hostnames' =>
1412     { 'stderr' => '/in tls_verify_cert_hostnames\? no/' },
1413
1414     'loopback' =>
1415     { 'stdout' => 's/[[](127\.0\.0\.1|::1)]/[IP_LOOPBACK_ADDR]/' },
1416
1417     'scanfile_size' =>
1418     { 'stdout' => 's/(Content-length:) \d\d\d/$1 ddd/' },
1419
1420     'delay_1500' =>
1421     { 'stderr' => 's/(1[5-9]|23\d)\d\d msec/ssss msec/' },
1422
1423     'tls_anycipher' =>
1424     { 'mainlog' => 's/ X=TLS\S+ / X=TLS_proto_and_cipher /' },
1425
1426     'debug_pid' =>
1427     { 'stderr' => 's/(^\s{0,4}|(?<=Process )|(?<=child ))\d{1,5}/ppppp/g' },
1428
1429     'optional_dsn_info' =>
1430     { 'mail' => '/^(X-(Remote-MTA-(smtp-greeting|helo-response)|Exim-Diagnostic|(body|message)-linecount):|Remote-MTA: X-ip;)/'
1431     },
1432
1433     'optional_config' =>
1434     { 'stdout' => '/^(
1435                   dkim_(canon|domain|private_key|selector|sign_headers|strict)
1436                   |gnutls_require_(kx|mac|protocols)
1437                   |hosts_(requ(est|ire)|try)_(dane|ocsp)
1438                   |hosts_(avoid|nopass|require|verify_avoid)_tls
1439                   |socks_proxy
1440                   |tls_[^ ]*
1441                   )($|[ ]=)/x' },
1442
1443     'sys_bindir' =>
1444     { 'mainlog' => 's%/(usr/)?bin/%SYSBINDIR/%' },
1445
1446     'sync_check_data' =>
1447     { 'mainlog'   => 's/^(.* SMTP protocol synchronization error .* next input=.{8}).*$/$1<suppressed>/',
1448       'rejectlog' => 's/^(.* SMTP protocol synchronization error .* next input=.{8}).*$/$1<suppressed>/'},
1449
1450     'debuglog_stdout' =>
1451     { 'stdout' => 's/^\d\d:\d\d:\d\d\s+\d+ //;
1452                   s/Process \d+ is ready for new message/Process pppp is ready for new message/'
1453     },
1454
1455     'timeout_errno' =>          # actual errno differs Solaris vs. Linux
1456     { 'mainlog' => 's/(host deferral .* errno) <\d+> /$1 <EEE> /' },
1457   };
1458
1459
1460 ##################################################
1461 #    Subroutine to check the output of a test    #
1462 ##################################################
1463
1464 # This function is called when the series of subtests is complete. It makes
1465 # use of check_file(), whose arguments are:
1466 #
1467 #  [0] the name of the main raw output file
1468 #  [1] the name of the server raw output file or undef
1469 #  [2] where to put the munged copy
1470 #  [3] the name of the saved file
1471 #  [4] TRUE if this is a log file whose deliveries must be sorted
1472 #  [5] an optional custom munge command
1473 #
1474 # Arguments: Optionally, name of a single custom munge to run.
1475 # Returns:   0 if the output compared equal
1476 #            1 if re-run needed (files may have been updated)
1477
1478 sub check_output{
1479 my($mungename) = $_[0];
1480 my($yield) = 0;
1481 my($munge) = $munges->{$mungename} if defined $mungename;
1482
1483 $yield = 1 if check_file("spool/log/paniclog",
1484                        "spool/log/serverpaniclog",
1485                        "test-paniclog-munged",
1486                        "paniclog/$testno", 0,
1487                        $munge->{'paniclog'});
1488
1489 $yield = 1 if check_file("spool/log/rejectlog",
1490                        "spool/log/serverrejectlog",
1491                        "test-rejectlog-munged",
1492                        "rejectlog/$testno", 0,
1493                        $munge->{'rejectlog'});
1494
1495 $yield = 1 if check_file("spool/log/mainlog",
1496                        "spool/log/servermainlog",
1497                        "test-mainlog-munged",
1498                        "log/$testno", $sortlog,
1499                        $munge->{'mainlog'});
1500
1501 if (!$stdout_skip)
1502   {
1503   $yield = 1 if check_file("test-stdout",
1504                        "test-stdout-server",
1505                        "test-stdout-munged",
1506                        "stdout/$testno", 0,
1507                        $munge->{'stdout'});
1508   }
1509
1510 if (!$stderr_skip)
1511   {
1512   $yield = 1 if check_file("test-stderr",
1513                        "test-stderr-server",
1514                        "test-stderr-munged",
1515                        "stderr/$testno", 0,
1516                        $munge->{'stderr'});
1517   }
1518
1519 # Compare any delivered messages, unless this test is skipped.
1520
1521 if (! $message_skip)
1522   {
1523   my($msgno) = 0;
1524
1525   # Get a list of expected mailbox files for this script. We don't bother with
1526   # directories, just the files within them.
1527
1528   foreach $oldmail (@oldmails)
1529     {
1530     next unless $oldmail =~ /^mail\/$testno\./;
1531     print ">> EXPECT $oldmail\n" if $debug;
1532     $expected_mails{$oldmail} = 1;
1533     }
1534
1535   # If there are any files in test-mail, compare them. Note that "." and
1536   # ".." are automatically omitted by list_files_below().
1537
1538   @mails = list_files_below("test-mail");
1539
1540   foreach $mail (@mails)
1541     {
1542     next if $mail eq "test-mail/oncelog";
1543
1544     $saved_mail = substr($mail, 10);               # Remove "test-mail/"
1545     $saved_mail =~ s/^$parm_caller(\/|$)/CALLER/;  # Convert caller name
1546
1547     if ($saved_mail =~ /(\d+\.[^.]+\.)/)
1548       {
1549       $msgno++;
1550       $saved_mail =~ s/(\d+\.[^.]+\.)/$msgno./gx;
1551       }
1552
1553     print ">> COMPARE $mail mail/$testno.$saved_mail\n" if $debug;
1554     $yield = 1 if check_file($mail, undef, "test-mail-munged",
1555       "mail/$testno.$saved_mail", 0,
1556       $munge->{'mail'});
1557     delete $expected_mails{"mail/$testno.$saved_mail"};
1558     }
1559
1560   # Complain if not all expected mails have been found
1561
1562   if (scalar(keys %expected_mails) != 0)
1563     {
1564     foreach $key (keys %expected_mails)
1565       { print "** no test file found for $key\n"; }
1566
1567     for (;;)
1568       {
1569       interact("Continue, Update & retry, or Quit? [Q] ", $force_update, $force_continue);
1570       tests_exit(1) if /^q?$/i;
1571       log_failure($log_failed_filename, $testno, "missing email") if (/^c$/i && $force_continue);
1572       last if /^c$/i;
1573
1574       # For update, we not only have to unlink the file, but we must also
1575       # remove it from the @oldmails vector, as otherwise it will still be
1576       # checked for when we re-run the test.
1577
1578       if (/^u$/i)
1579         {
1580         foreach $key (keys %expected_mails)
1581           {
1582           my($i);
1583           tests_exit(-1, "Failed to unlink $key") if !unlink("$key");
1584           for ($i = 0; $i < @oldmails; $i++)
1585             {
1586             if ($oldmails[$i] eq $key)
1587               {
1588               splice @oldmails, $i, 1;
1589               last;
1590               }
1591             }
1592           }
1593         last;
1594         }
1595       }
1596     }
1597   }
1598
1599 # Compare any remaining message logs, unless this test is skipped.
1600
1601 if (! $msglog_skip)
1602   {
1603   # Get a list of expected msglog files for this test
1604
1605   foreach $oldmsglog (@oldmsglogs)
1606     {
1607     next unless $oldmsglog =~ /^$testno\./;
1608     $expected_msglogs{$oldmsglog} = 1;
1609     }
1610
1611   # If there are any files in spool/msglog, compare them. However, we have
1612   # to munge the file names because they are message ids, which are
1613   # time dependent.
1614
1615   if (opendir(DIR, "spool/msglog"))
1616     {
1617     @msglogs = sort readdir(DIR);
1618     closedir(DIR);
1619
1620     foreach $msglog (@msglogs)
1621       {
1622       next if ($msglog eq "." || $msglog eq ".." || $msglog eq "CVS");
1623       ($munged_msglog = $msglog) =~
1624         s/((?:[^\W_]{6}-){2}[^\W_]{2})
1625           /new_value($1, "10Hm%s-0005vi-00", \$next_msgid)/egx;
1626       $yield = 1 if check_file("spool/msglog/$msglog", undef,
1627         "test-msglog-munged", "msglog/$testno.$munged_msglog", 0,
1628         $munge->{'msglog'});
1629       delete $expected_msglogs{"$testno.$munged_msglog"};
1630       }
1631     }
1632
1633   # Complain if not all expected msglogs have been found
1634
1635   if (scalar(keys %expected_msglogs) != 0)
1636     {
1637     foreach $key (keys %expected_msglogs)
1638       {
1639       print "** no test msglog found for msglog/$key\n";
1640       ($msgid) = $key =~ /^\d+\.(.*)$/;
1641       foreach $cachekey (keys %cache)
1642         {
1643         if ($cache{$cachekey} eq $msgid)
1644           {
1645           print "** original msgid $cachekey\n";
1646           last;
1647           }
1648         }
1649       }
1650
1651     for (;;)
1652       {
1653       interact("Continue, Update, or Quit? [Q] ", $force_update, $force_continue);
1654       tests_exit(1) if /^q?$/i;
1655       log_failure($log_failed_filename, $testno, "missing msglog") if (/^c$/i && $force_continue);
1656       last if /^c$/i;
1657       if (/^u$/i)
1658         {
1659         foreach $key (keys %expected_msglogs)
1660           {
1661           tests_exit(-1, "Failed to unlink msglog/$key")
1662             if !unlink("msglog/$key");
1663           }
1664         last;
1665         }
1666       }
1667     }
1668   }
1669
1670 return $yield;
1671 }
1672
1673
1674
1675 ##################################################
1676 #     Subroutine to run one "system" command     #
1677 ##################################################
1678
1679 # We put this in a subroutine so that the command can be reflected when
1680 # debugging.
1681 #
1682 # Argument: the command to be run
1683 # Returns:  nothing
1684
1685 sub run_system {
1686 my($cmd) = $_[0];
1687 if ($debug)
1688   {
1689   my($prcmd) = $cmd;
1690   $prcmd =~ s/; /;\n>> /;
1691   print ">> $prcmd\n";
1692   }
1693 system("$cmd");
1694 }
1695
1696
1697
1698 ##################################################
1699 #      Subroutine to run one script command      #
1700 ##################################################
1701
1702 # The <SCRIPT> file is open for us to read an optional return code line,
1703 # followed by the command line and any following data lines for stdin. The
1704 # command line can be continued by the use of \. Data lines are not continued
1705 # in this way. In all lines, the following substutions are made:
1706 #
1707 # DIR    => the current directory
1708 # CALLER => the caller of this script
1709 #
1710 # Arguments: the current test number
1711 #            reference to the subtest number, holding previous value
1712 #            reference to the expected return code value
1713 #            reference to where to put the command name (for messages)
1714 #            auxilliary information returned from a previous run
1715 #
1716 # Returns:   0 the commmand was executed inline, no subprocess was run
1717 #            1 a non-exim command was run and waited for
1718 #            2 an exim command was run and waited for
1719 #            3 a command was run and not waited for (daemon, server, exim_lock)
1720 #            4 EOF was encountered after an initial return code line
1721 # Optionally alse a second parameter, a hash-ref, with auxilliary information:
1722 #            exim_pid: pid of a run process
1723 #            munge: name of a post-script results munger
1724
1725 sub run_command{
1726 my($testno) = $_[0];
1727 my($subtestref) = $_[1];
1728 my($commandnameref) = $_[3];
1729 my($aux_info) = $_[4];
1730 my($yield) = 1;
1731
1732 our %ENV = map { $_ => $ENV{$_} } grep { /^(?:USER|SHELL|PATH|TERM|EXIM_TEST_.*)$/ } keys %ENV;
1733
1734 if (/^(\d+)\s*$/)                # Handle unusual return code
1735   {
1736   my($r) = $_[2];
1737   $$r = $1 << 8;
1738   $_ = <SCRIPT>;
1739   return 4 if !defined $_;       # Missing command
1740   $lineno++;
1741   }
1742
1743 chomp;
1744 $wait_time = 0;
1745
1746 # Handle concatenated command lines
1747
1748 s/\s+$//;
1749 while (substr($_, -1) eq"\\")
1750   {
1751   my($temp);
1752   $_ = substr($_, 0, -1);
1753   chomp($temp = <SCRIPT>);
1754   if (defined $temp)
1755     {
1756     $lineno++;
1757     $temp =~ s/\s+$//;
1758     $temp =~ s/^\s+//;
1759     $_ .= $temp;
1760     }
1761   }
1762
1763 # Do substitutions
1764
1765 do_substitute($testno);
1766 if ($debug) { printf ">> $_\n"; }
1767
1768 # Pass back the command name (for messages)
1769
1770 ($$commandnameref) = /^(\S+)/;
1771
1772 # Here follows code for handling the various different commands that are
1773 # supported by this script. The first group of commands are all freestanding
1774 # in that they share no common code and are not followed by any data lines.
1775
1776
1777 ###################
1778 ###################
1779
1780 # The "dbmbuild" command runs exim_dbmbuild. This is used both to test the
1781 # utility and to make DBM files for testing DBM lookups.
1782
1783 if (/^dbmbuild\s+(\S+)\s+(\S+)/)
1784   {
1785   run_system("(./eximdir/exim_dbmbuild $parm_cwd/$1 $parm_cwd/$2;" .
1786          "echo exim_dbmbuild exit code = \$?)" .
1787          ">>test-stdout");
1788   return 1;
1789   }
1790
1791
1792 # The "dump" command runs exim_dumpdb. On different systems, the output for
1793 # some types of dump may appear in a different order because it's just hauled
1794 # out of the DBM file. We can solve this by sorting. Ignore the leading
1795 # date/time, as it will be flattened later during munging.
1796
1797 if (/^dump\s+(\S+)/)
1798   {
1799   my($which) = $1;
1800   my(@temp);
1801   print ">> ./eximdir/exim_dumpdb $parm_cwd/spool $which\n" if $debug;
1802   open(IN, "./eximdir/exim_dumpdb $parm_cwd/spool $which |");
1803   open(OUT, ">>test-stdout");
1804   print OUT "+++++++++++++++++++++++++++\n";
1805
1806   if ($which eq "retry")
1807     {
1808     $/ = "\n  ";
1809     @temp = <IN>;
1810     $/ = "\n";
1811
1812     @temp = sort {
1813                    my($aa) = split(' ', $a);
1814                    my($bb) = split(' ', $b);
1815                    return $aa cmp $bb;
1816                  } @temp;
1817
1818     foreach $item (@temp)
1819       {
1820       $item =~ s/^\s*(.*)\n(.*)\n?\s*$/$1\n$2/m;
1821       print OUT "  $item\n";
1822       }
1823     }
1824   else
1825     {
1826     @temp = <IN>;
1827     if ($which eq "callout")
1828       {
1829       @temp = sort {
1830                    my($aa) = substr $a, 21;
1831                    my($bb) = substr $b, 21;
1832                    return $aa cmp $bb;
1833                    } @temp;
1834       }
1835     print OUT @temp;
1836     }
1837
1838   close(IN);
1839   close(OUT);
1840   return 1;
1841   }
1842
1843
1844 # The "echo" command is a way of writing comments to the screen.
1845
1846 if (/^echo\s+(.*)$/)
1847   {
1848   print "$1\n";
1849   return 0;
1850   }
1851
1852
1853 # The "exim_lock" command runs exim_lock in the same manner as "server",
1854 # but it doesn't use any input.
1855
1856 if (/^exim_lock\s+(.*)$/)
1857   {
1858   $cmd = "./eximdir/exim_lock $1 >>test-stdout";
1859   $server_pid = open SERVERCMD, "|$cmd" ||
1860     tests_exit(-1, "Failed to run $cmd\n");
1861
1862   # This gives the process time to get started; otherwise the next
1863   # process may not find it there when it expects it.
1864
1865   select(undef, undef, undef, 0.1);
1866   return 3;
1867   }
1868
1869
1870 # The "exinext" command runs exinext
1871
1872 if (/^exinext\s+(.*)/)
1873   {
1874   run_system("(./eximdir/exinext " .
1875     "-DEXIM_PATH=$parm_cwd/eximdir/exim " .
1876     "-C $parm_cwd/test-config $1;" .
1877     "echo exinext exit code = \$?)" .
1878     ">>test-stdout");
1879   return 1;
1880   }
1881
1882
1883 # The "exigrep" command runs exigrep on the current mainlog
1884
1885 if (/^exigrep\s+(.*)/)
1886   {
1887   run_system("(./eximdir/exigrep " .
1888     "$1 $parm_cwd/spool/log/mainlog;" .
1889     "echo exigrep exit code = \$?)" .
1890     ">>test-stdout");
1891   return 1;
1892   }
1893
1894
1895 # The "eximstats" command runs eximstats on the current mainlog
1896
1897 if (/^eximstats\s+(.*)/)
1898   {
1899   run_system("(./eximdir/eximstats " .
1900     "$1 $parm_cwd/spool/log/mainlog;" .
1901     "echo eximstats exit code = \$?)" .
1902     ">>test-stdout");
1903   return 1;
1904   }
1905
1906
1907 # The "gnutls" command makes a copy of saved GnuTLS parameter data in the
1908 # spool directory, to save Exim from re-creating it each time.
1909
1910 if (/^gnutls/)
1911   {
1912   my $gen_fn = "spool/gnutls-params-$gnutls_dh_bits_normal";
1913   run_system "sudo cp -p aux-fixed/gnutls-params $gen_fn;" .
1914          "sudo chown $parm_eximuser:$parm_eximgroup $gen_fn;" .
1915          "sudo chmod 0400 $gen_fn";
1916   return 1;
1917   }
1918
1919
1920 # The "killdaemon" command should ultimately follow the starting of any Exim
1921 # daemon with the -bd option. We kill with SIGINT rather than SIGTERM to stop
1922 # it outputting "Terminated" to the terminal when not in the background.
1923
1924 if (/^killdaemon/)
1925   {
1926   my $return_extra = {};
1927   if (exists $aux_info->{exim_pid})
1928     {
1929     $pid = $aux_info->{exim_pid};
1930     $return_extra->{exim_pid} = undef;
1931     print ">> killdaemon: recovered pid $pid\n" if $debug;
1932     if ($pid)
1933       {
1934       run_system("sudo /bin/kill -INT $pid");
1935       wait;
1936       }
1937     } else {
1938     $pid = `cat $parm_cwd/spool/exim-daemon.*`;
1939     if ($pid)
1940       {
1941       run_system("sudo /bin/kill -INT $pid");
1942       close DAEMONCMD;                                   # Waits for process
1943       }
1944     }
1945     run_system("sudo /bin/rm -f spool/exim-daemon.*");
1946   return (1, $return_extra);
1947   }
1948
1949
1950 # The "millisleep" command is like "sleep" except that its argument is in
1951 # milliseconds, thus allowing for a subsecond sleep, which is, in fact, all it
1952 # is used for.
1953
1954 elsif (/^millisleep\s+(.*)$/)
1955   {
1956   select(undef, undef, undef, $1/1000);
1957   return 0;
1958   }
1959
1960
1961 # The "munge" command selects one of a hardwired set of test-result modifications
1962 # to be made before result compares are run agains the golden set.  This lets
1963 # us account for test-system dependent things which only affect a few, but known,
1964 # test-cases.
1965 # Currently only the last munge takes effect.
1966
1967 if (/^munge\s+(.*)$/)
1968   {
1969   return (0, { munge => $1 });
1970   }
1971
1972
1973 # The "sleep" command does just that. For sleeps longer than 1 second we
1974 # tell the user what's going on.
1975
1976 if (/^sleep\s+(.*)$/)
1977   {
1978   if ($1 == 1)
1979     {
1980     sleep(1);
1981     }
1982   else
1983     {
1984     printf("  Test %d sleep $1 ", $$subtestref);
1985     for (1..$1)
1986       {
1987       print ".";
1988       sleep(1);
1989       }
1990     printf("\r  Test %d                            $cr", $$subtestref);
1991     }
1992   return 0;
1993   }
1994
1995
1996 # Various Unix management commands are recognized
1997
1998 if (/^(ln|ls|du|mkdir|mkfifo|touch|cp|cat)\s/ ||
1999     /^sudo\s(rmdir|rm|mv|chown|chmod)\s/)
2000   {
2001   run_system("$_ >>test-stdout 2>>test-stderr");
2002   return 1;
2003   }
2004
2005
2006
2007 ###################
2008 ###################
2009
2010 # The next group of commands are also freestanding, but they are all followed
2011 # by data lines.
2012
2013
2014 # The "server" command starts up a script-driven server that runs in parallel
2015 # with the following exim command. Therefore, we want to run a subprocess and
2016 # not yet wait for it to complete. The waiting happens after the next exim
2017 # command, triggered by $server_pid being non-zero. The server sends its output
2018 # to a different file. The variable $server_opts, if not empty, contains
2019 # options to disable IPv4 or IPv6 if necessary.
2020 # This works because "server" swallows its stdin before waiting for a connection.
2021
2022 if (/^server\s+(.*)$/)
2023   {
2024   $pidfile = "$parm_cwd/aux-var/server-daemon.pid";
2025   $cmd = "./bin/server $server_opts -oP $pidfile $1 >>test-stdout-server";
2026   print ">> $cmd\n" if ($debug);
2027   $server_pid = open SERVERCMD, "|$cmd" || tests_exit(-1, "Failed to run $cmd");
2028   SERVERCMD->autoflush(1);
2029   print ">> Server pid is $server_pid\n" if $debug;
2030   while (<SCRIPT>)
2031     {
2032     $lineno++;
2033     last if /^\*{4}\s*$/;
2034     print SERVERCMD;
2035     }
2036   print SERVERCMD "++++\n"; # Send end to server; can't send EOF yet
2037                             # because close() waits for the process.
2038
2039   # Interlock the server startup; otherwise the next
2040   # process may not find it there when it expects it.
2041   while (! stat("$pidfile") ) { select(undef, undef, undef, 0.3); }
2042   return 3;
2043   }
2044
2045
2046 # The "write" command is a way of creating files of specific sizes for
2047 # buffering tests, or containing specific data lines from within the script
2048 # (rather than hold lots of little files). The "catwrite" command does the
2049 # same, but it also copies the lines to test-stdout.
2050
2051 if (/^(cat)?write\s+(\S+)(?:\s+(.*))?\s*$/)
2052   {
2053   my($cat) = defined $1;
2054   @sizes = ();
2055   @sizes = split /\s+/, $3 if defined $3;
2056   open FILE, ">$2" || tests_exit(-1, "Failed to open \"$2\": $!");
2057
2058   if ($cat)
2059     {
2060     open CAT, ">>test-stdout" ||
2061       tests_exit(-1, "Failed to open test-stdout: $!");
2062     print CAT "==========\n";
2063     }
2064
2065   if (scalar @sizes > 0)
2066     {
2067     # Pre-data
2068
2069     while (<SCRIPT>)
2070       {
2071       $lineno++;
2072       last if /^\+{4}\s*$/;
2073       print FILE;
2074       print CAT if $cat;
2075       }
2076
2077     # Sized data
2078
2079     while (scalar @sizes > 0)
2080       {
2081       ($count,$len,$leadin) = (shift @sizes) =~ /(\d+)x(\d+)(?:=(.*))?/;
2082       $leadin = "" if !defined $leadin;
2083       $leadin =~ s/_/ /g;
2084       $len -= length($leadin) + 1;
2085       while ($count-- > 0)
2086         {
2087         print FILE $leadin, "a" x $len, "\n";
2088         print CAT $leadin, "a" x $len, "\n" if $cat;
2089         }
2090       }
2091     }
2092
2093   # Post data, or only data if no sized data
2094
2095   while (<SCRIPT>)
2096     {
2097     $lineno++;
2098     last if /^\*{4}\s*$/;
2099     print FILE;
2100     print CAT if $cat;
2101     }
2102   close FILE;
2103
2104   if ($cat)
2105     {
2106     print CAT "==========\n";
2107     close CAT;
2108     }
2109
2110   return 0;
2111   }
2112
2113
2114 ###################
2115 ###################
2116
2117 # From this point on, script commands are implemented by setting up a shell
2118 # command in the variable $cmd. Shared code to run this command and handle its
2119 # input and output follows.
2120
2121 # The "client", "client-gnutls", and "client-ssl" commands run a script-driven
2122 # program that plays the part of an email client. We also have the availability
2123 # of running Perl for doing one-off special things. Note that all these
2124 # commands expect stdin data to be supplied.
2125
2126 if (/^client/ || /^(sudo\s+)?perl\b/)
2127   {
2128   s"client"./bin/client";
2129   $cmd = "$_ >>test-stdout 2>>test-stderr";
2130   }
2131
2132 # For the "exim" command, replace the text "exim" with the path for the test
2133 # binary, plus -D options to pass over various parameters, and a -C option for
2134 # the testing configuration file. When running in the test harness, Exim does
2135 # not drop privilege when -C and -D options are present. To run the exim
2136 # command as root, we use sudo.
2137
2138 elsif (/^((?i:[A-Z\d_]+=\S+\s+)+)?(\d+)?\s*(sudo(?:\s+-u\s+(\w+))?\s+)?exim(_\S+)?\s+(.*)$/)
2139   {
2140   $args = $6;
2141   my($envset) = (defined $1)? $1      : "";
2142   my($sudo)   = (defined $3)? "sudo " . (defined $4 ? "-u $4 ":"")  : "";
2143   my($special)= (defined $5)? $5      : "";
2144   $wait_time  = (defined $2)? $2      : 0;
2145
2146   # Return 2 rather than 1 afterwards
2147
2148   $yield = 2;
2149
2150   # Update the test number
2151
2152   $$subtestref = $$subtestref + 1;
2153   printf("  Test %d       $cr", $$subtestref);
2154
2155   # Copy the configuration file, making the usual substitutions.
2156
2157   open (IN, "$parm_cwd/confs/$testno") ||
2158     tests_exit(-1, "Couldn't open $parm_cwd/confs/$testno: $!\n");
2159   open (OUT, ">test-config") ||
2160     tests_exit(-1, "Couldn't open test-config: $!\n");
2161   while (<IN>)
2162     {
2163     do_substitute($testno);
2164     print OUT;
2165     }
2166   close(IN);
2167   close(OUT);
2168
2169   # The string $msg1 in args substitutes the message id of the first
2170   # message on the queue, and so on. */
2171
2172   if ($args =~ /\$msg/)
2173     {
2174     my($listcmd) = "$parm_cwd/eximdir/exim -bp " .
2175                    "-DEXIM_PATH=$parm_cwd/eximdir/exim " .
2176                    "-C $parm_cwd/test-config |";
2177     print ">> Getting queue list from:\n>>    $listcmd\n" if ($debug);
2178     open (QLIST, $listcmd) || tests_exit(-1, "Couldn't run \"exim -bp\": $!\n");
2179     my(@msglist) = ();
2180     while (<QLIST>) { push (@msglist, $1) if /^\s*\d+[smhdw]\s+\S+\s+(\S+)/; }
2181     close(QLIST);
2182
2183     # Done backwards just in case there are more than 9
2184
2185     for (my $i = @msglist; $i > 0; $i--) { $args =~ s/\$msg$i/$msglist[$i-1]/g; }
2186     if ( $args =~ /\$msg\d/ )
2187       {
2188       tests_exit(-1, "Not enough messages in spool, for test $testno line $lineno\n")
2189         unless $force_continue;
2190       }
2191     }
2192
2193   # If -d is specified in $optargs, remove it from $args; i.e. let
2194   # the command line for runtest override. Then run Exim.
2195
2196   $args =~ s/(?:^|\s)-d\S*// if $optargs =~ /(?:^|\s)-d/;
2197
2198   my $opt_valgrind = $valgrind ? "valgrind --leak-check=yes --suppressions=$parm_cwd/aux-fixed/valgrind.supp " : "";
2199
2200   $cmd = "$envset$sudo$opt_valgrind" .
2201          "$parm_cwd/eximdir/exim$special$optargs " .
2202          "-DEXIM_PATH=$parm_cwd/eximdir/exim$special " .
2203          "-C $parm_cwd/test-config $args " .
2204          ">>test-stdout 2>>test-stderr";
2205   # If the command is starting an Exim daemon, we run it in the same
2206   # way as the "server" command above, that is, we don't want to wait
2207   # for the process to finish. That happens when "killdaemon" is obeyed later
2208   # in the script. We also send the stderr output to test-stderr-server. The
2209   # daemon has its log files put in a different place too (by configuring with
2210   # log_file_path). This requires the  directory to be set up in advance.
2211   #
2212   # There are also times when we want to run a non-daemon version of Exim
2213   # (e.g. a queue runner) with the server configuration. In this case,
2214   # we also define -DNOTDAEMON.
2215
2216   if ($cmd =~ /\s-DSERVER=server\s/ && $cmd !~ /\s-DNOTDAEMON\s/)
2217     {
2218     $pidfile = "$parm_cwd/spool/exim-daemon.pid";
2219     if ($debug) { printf ">> daemon: $cmd\n"; }
2220     run_system("sudo mkdir spool/log 2>/dev/null");
2221     run_system("sudo chown $parm_eximuser:$parm_eximgroup spool/log");
2222
2223     # Before running the command, convert the -bd option into -bdf so that an
2224     # Exim daemon doesn't double fork. This means that when we wait close
2225     # DAEMONCMD, it waits for the correct process. Also, ensure that the pid
2226     # file is written to the spool directory, in case the Exim binary was
2227     # built with PID_FILE_PATH pointing somewhere else.
2228
2229     if ($cmd =~ /\s-oP\s/)
2230       {
2231       ($pidfile = $cmd) =~ s/^.*-oP ([^ ]+).*$/$1/;
2232       $cmd =~ s!\s-bd\s! -bdf !;
2233       }
2234     else
2235       {
2236       $pidfile = "$parm_cwd/spool/exim-daemon.pid";
2237       $cmd =~ s!\s-bd\s! -bdf -oP $pidfile !;
2238       }
2239     print ">> |${cmd}-server\n" if ($debug);
2240     open DAEMONCMD, "|${cmd}-server" || tests_exit(-1, "Failed to run $cmd");
2241     DAEMONCMD->autoflush(1);
2242     while (<SCRIPT>) { $lineno++; last if /^\*{4}\s*$/; }   # Ignore any input
2243
2244     # Interlock with daemon startup
2245     while (! stat("$pidfile") ) { select(undef, undef, undef, 0.3); }
2246     return 3;                                     # Don't wait
2247     }
2248   elsif ($cmd =~ /\s-DSERVER=wait:(\d+)\s/)
2249     {
2250
2251     # The port and the $dynamic_socket was already allocated while parsing the
2252     # script file, where -DSERVER=wait:PORT_DYNAMIC was encountered.
2253
2254     my $listen_port = $1;
2255     if ($debug) { printf ">> wait-mode daemon: $cmd\n"; }
2256     run_system("sudo mkdir spool/log 2>/dev/null");
2257     run_system("sudo chown $parm_eximuser:$parm_eximgroup spool/log");
2258
2259     my $pid = fork();
2260     if (not defined $pid) { die "** fork failed: $!\n" }
2261     if (not $pid) {
2262       close(STDIN);
2263       open(STDIN, '<&', $dynamic_socket) or die "** dup sock to stdin failed: $!\n";
2264       close($dynamic_socket);
2265       print "[$$]>> ${cmd}-server\n" if ($debug);
2266       exec "exec ${cmd}-server";
2267       die "Can't exec ${cmd}-server: $!\n";
2268     }
2269     while (<SCRIPT>) { $lineno++; last if /^\*{4}\s*$/; }   # Ignore any input
2270     select(undef, undef, undef, 0.3);             # Let the daemon get going
2271     return (3, { exim_pid => $pid });             # Don't wait
2272     }
2273   }
2274
2275 # The "background" command is run but not waited-for, like exim -DSERVER=server.
2276 # One script line is read and fork-exec'd.  The PID is stored for a later
2277 # killdaemon.
2278
2279 elsif (/^background$/)
2280   {
2281   my $line;
2282 #  $pidfile = "$parm_cwd/aux-var/server-daemon.pid";
2283
2284   $_ = <SCRIPT>; $lineno++;
2285   chomp;
2286   $line = $_;
2287   if ($debug) { printf ">> daemon: $line >>test-stdout 2>>test-stderr\n"; }
2288
2289   my $pid = fork();
2290   if (not defined $pid) { die "** fork failed: $!\n" }
2291   if (not $pid) {
2292     print "[$$]>> ${line}\n" if ($debug);
2293     close(STDIN);
2294     open(STDIN, "<", "test-stdout");
2295     close(STDOUT);
2296     open(STDOUT, ">>", "test-stdout");
2297     close(STDERR);
2298     open(STDERR, ">>", "test-stderr-server");
2299     exec "exec ${line}";
2300     exit(1);
2301   }
2302
2303 #  open(my $fh, ">", $pidfile) ||
2304 #      tests_exit(-1, "Failed to open $pidfile: $!");
2305 #  printf($fh, "%d\n", $pid);
2306 #  close($fh);
2307
2308   while (<SCRIPT>) { $lineno++; last if /^\*{4}\s*$/; }   # Ignore any input
2309   select(undef, undef, undef, 0.3);             # Let the daemon get going
2310   return (3, { exim_pid => $pid });             # Don't wait
2311   }
2312
2313
2314
2315 # Unknown command
2316
2317 else { tests_exit(-1, "Command unrecognized in line $lineno: $_"); }
2318
2319
2320 # Run the command, with stdin connected to a pipe, and write the stdin data
2321 # to it, with appropriate substitutions. If a line ends with \NONL\, chop off
2322 # the terminating newline (and the \NONL\). If the command contains
2323 # -DSERVER=server add "-server" to the command, where it will adjoin the name
2324 # for the stderr file. See comment above about the use of -DSERVER.
2325
2326 $stderrsuffix = ($cmd =~ /\s-DSERVER=server\s/)? "-server" : "";
2327 print ">> |${cmd}${stderrsuffix}\n" if ($debug);
2328 open CMD, "|${cmd}${stderrsuffix}" || tests_exit(1, "Failed to run $cmd");
2329
2330 CMD->autoflush(1);
2331 while (<SCRIPT>)
2332   {
2333   $lineno++;
2334   last if /^\*{4}\s*$/;
2335   do_substitute($testno);
2336   if (/^(.*)\\NONL\\\s*$/) { print CMD $1; } else { print CMD; }
2337   }
2338
2339 # For timeout tests, wait before closing the pipe; we expect a
2340 # SIGPIPE error in this case.
2341
2342 if ($wait_time > 0)
2343   {
2344   printf("  Test %d sleep $wait_time ", $$subtestref);
2345   while ($wait_time-- > 0)
2346     {
2347     print ".";
2348     sleep(1);
2349     }
2350   printf("\r  Test %d                                       $cr", $$subtestref);
2351   }
2352
2353 $sigpipehappened = 0;
2354 close CMD;                # Waits for command to finish
2355 return $yield;            # Ran command and waited
2356 }
2357
2358
2359
2360
2361 ###############################################################################
2362 ###############################################################################
2363
2364 # Here begins the Main Program ...
2365
2366 ###############################################################################
2367 ###############################################################################
2368
2369
2370 autoflush STDOUT 1;
2371 print "Exim tester $testversion\n";
2372
2373 # extend the PATH with .../sbin
2374 # we map all (.../bin) to (.../sbin:.../bin)
2375 $ENV{PATH} = do {
2376   my %seen = map { $_, 1 } split /:/, $ENV{PATH};
2377   join ':' => map { m{(.*)/bin$}
2378                 ? ( $seen{"$1/sbin"} ? () : ("$1/sbin"), $_)
2379                 : ($_) }
2380       split /:/, $ENV{PATH};
2381 };
2382
2383 ##################################################
2384 #      Some tests check created file modes       #
2385 ##################################################
2386
2387 umask 022;
2388
2389
2390 ##################################################
2391 #       Check for the "less" command             #
2392 ##################################################
2393
2394 $more = 'more' if system('which less >/dev/null 2>&1') != 0;
2395
2396
2397
2398 ##################################################
2399 #        Check for sudo access to root           #
2400 ##################################################
2401
2402 print "You need to have sudo access to root to run these tests. Checking ...\n";
2403 if (system('sudo true >/dev/null') != 0)
2404   {
2405   die "** Test for sudo failed: testing abandoned.\n";
2406   }
2407 else
2408   {
2409   print "Test for sudo OK\n";
2410   }
2411
2412
2413
2414 ##################################################
2415 #      See if an Exim binary has been given      #
2416 ##################################################
2417
2418 # If the first character of the first argument is '/', the argument is taken
2419 # as the path to the binary. If the first argument does not start with a
2420 # '/' but exists in the file system, it's assumed to be the Exim binary.
2421
2422 $parm_exim = (@ARGV > 0 && (-x $ARGV[0] or $ARGV[0] =~ m?^/?))? Cwd::abs_path(shift @ARGV) : "";
2423 print "Exim binary is $parm_exim\n" if $parm_exim ne "";
2424
2425
2426
2427 ##################################################
2428 # Sort out options and which tests are to be run #
2429 ##################################################
2430
2431 # There are a few possible options for the test script itself; after these, any
2432 # options are passed on to Exim calls within the tests. Typically, this is used
2433 # to turn on Exim debugging while setting up a test.
2434
2435 while (@ARGV > 0 && $ARGV[0] =~ /^-/)
2436   {
2437   my($arg) = shift @ARGV;
2438   if ($optargs eq "")
2439     {
2440     if ($arg eq "-DEBUG")  { $debug = 1; $cr = "\n"; next; }
2441     if ($arg eq "-DIFF")   { $cf = "diff -u"; next; }
2442     if ($arg eq "-CONTINUE"){$force_continue = 1;
2443                              $more = "cat";
2444                              next; }
2445     if ($arg eq "-UPDATE") { $force_update = 1; next; }
2446     if ($arg eq "-NOIPV4") { $have_ipv4 = 0; next; }
2447     if ($arg eq "-NOIPV6") { $have_ipv6 = 0; next; }
2448     if ($arg eq "-KEEP")   { $save_output = 1; next; }
2449     if ($arg eq "-VALGRIND")   { $valgrind = 1; next; }
2450     if ($arg =~ /^-FLAVOU?R$/) { $flavour = shift; next; }
2451     }
2452   $optargs .= " $arg";
2453   }
2454
2455 # Any subsequent arguments are a range of test numbers.
2456
2457 if (@ARGV > 0)
2458   {
2459   $test_end = $test_start = $ARGV[0];
2460   $test_end = $ARGV[1] if (@ARGV > 1);
2461   $test_end = ($test_start >= 9000)? $test_special_top : $test_top
2462     if $test_end eq "+";
2463   die "** Test numbers out of order\n" if ($test_end < $test_start);
2464   }
2465
2466
2467 ##################################################
2468 #      Make the command's directory current      #
2469 ##################################################
2470
2471 # After doing so, we find its absolute path name.
2472
2473 $cwd = $0;
2474 $cwd = '.' if ($cwd !~ s|/[^/]+$||);
2475 chdir($cwd) || die "** Failed to chdir to \"$cwd\": $!\n";
2476 $parm_cwd = Cwd::getcwd();
2477
2478
2479 ##################################################
2480 #     Search for an Exim binary to test          #
2481 ##################################################
2482
2483 # If an Exim binary hasn't been provided, try to find one. We can handle the
2484 # case where exim-testsuite is installed alongside Exim source directories. For
2485 # PH's private convenience, if there's a directory just called "exim4", that
2486 # takes precedence; otherwise exim-snapshot takes precedence over any numbered
2487 # releases.
2488
2489 if ($parm_exim eq "")
2490   {
2491   my($use_srcdir) = "";
2492
2493   opendir DIR, ".." || die "** Failed to opendir \"..\": $!\n";
2494   while ($f = readdir(DIR))
2495     {
2496     my($srcdir);
2497
2498     # Try this directory if it is "exim4" or if it is exim-snapshot or exim-n.m
2499     # possibly followed by -RCx where n.m is greater than any previously tried
2500     # directory. Thus, we should choose the highest version of Exim that has
2501     # been compiled.
2502
2503     if ($f eq "exim4" || $f eq "exim-snapshot" || $f eq 'src')
2504       { $srcdir = $f; }
2505     else
2506       { $srcdir = $f
2507         if ($f =~ /^exim-\d+\.\d+(-RC\d+)?$/ && $f gt $use_srcdir); }
2508
2509     # Look for a build directory with a binary in it. If we find a binary,
2510     # accept this source directory.
2511
2512     if ($srcdir)
2513       {
2514       opendir SRCDIR, "../$srcdir" ||
2515         die "** Failed to opendir \"$cwd/../$srcdir\": $!\n";
2516       while ($f = readdir(SRCDIR))
2517         {
2518         if ($f =~ /^build-/ && -e "../$srcdir/$f/exim")
2519           {
2520           $use_srcdir = $srcdir;
2521           $parm_exim = "$cwd/../$srcdir/$f/exim";
2522           $parm_exim =~ s'/[^/]+/\.\./'/';
2523           last;
2524           }
2525         }
2526       closedir(SRCDIR);
2527       }
2528
2529     # If we have found "exim4" or "exim-snapshot", that takes precedence.
2530     # Otherwise, continue to see if there's a later version.
2531
2532     last if $use_srcdir eq "exim4" || $use_srcdir eq "exim-snapshot";
2533     }
2534   closedir(DIR);
2535   print "Exim binary found in $parm_exim\n" if $parm_exim ne "";
2536   }
2537
2538 # If $parm_exim is still empty, ask the caller
2539
2540 if ($parm_exim eq "")
2541   {
2542   print "** Did not find an Exim binary to test\n";
2543   for ($i = 0; $i < 5; $i++)
2544     {
2545     my($trybin);
2546     print "** Enter pathname for Exim binary: ";
2547     chomp($trybin = <STDIN>);
2548     if (-e $trybin)
2549       {
2550       $parm_exim = $trybin;
2551       last;
2552       }
2553     else
2554       {
2555       print "** $trybin does not exist\n";
2556       }
2557     }
2558   die "** Too many tries\n" if $parm_exim eq "";
2559   }
2560
2561
2562
2563 ##################################################
2564 #          Find what is in the binary            #
2565 ##################################################
2566
2567 # deal with TRUSTED_CONFIG_LIST restrictions
2568 unlink("$parm_cwd/test-config") if -e "$parm_cwd/test-config";
2569 open (IN, "$parm_cwd/confs/0000") ||
2570   tests_exit(-1, "Couldn't open $parm_cwd/confs/0000: $!\n");
2571 open (OUT, ">test-config") ||
2572   tests_exit(-1, "Couldn't open test-config: $!\n");
2573 while (<IN>) { print OUT; }
2574 close(IN);
2575 close(OUT);
2576
2577 print("Probing with config file: $parm_cwd/test-config\n");
2578 open(EXIMINFO, "$parm_exim -d -C $parm_cwd/test-config -DDIR=$parm_cwd " .
2579                "-bP exim_user exim_group 2>&1|") ||
2580   die "** Cannot run $parm_exim: $!\n";
2581 while(<EXIMINFO>)
2582   {
2583   if (my ($version) = /^Exim version (\S+)/) {
2584     my $git = `git describe --dirty=-XX --match 'exim-4*'`;
2585     if (defined $git and $? == 0) {
2586       chomp $git;
2587       $version =~ s/^\d+\K\./_/;
2588       $git =~ s/^exim-//i;
2589       $git =~ s/.*-\Kg([[:xdigit:]]+(?:-XX)?)/$1/;
2590       print "\n*** Version mismatch (Exim: $version vs. GIT: $git). ***\n\n"
2591         if not $version eq $git;
2592     }
2593   }
2594   $parm_eximuser = $1 if /^exim_user = (.*)$/;
2595   $parm_eximgroup = $1 if /^exim_group = (.*)$/;
2596   $parm_trusted_config_list = $1 if /^TRUSTED_CONFIG_LIST:.*?"(.*?)"$/;
2597   ($parm_configure_owner, $parm_configure_group) = ($1, $2)
2598         if /^Configure owner:\s*(\d+):(\d+)/;
2599   print "$_" if /wrong owner/;
2600   }
2601 close(EXIMINFO);
2602
2603 if (defined $parm_eximuser)
2604   {
2605   if ($parm_eximuser =~ /^\d+$/) { $parm_exim_uid = $parm_eximuser; }
2606     else { $parm_exim_uid = getpwnam($parm_eximuser); }
2607   }
2608 else
2609   {
2610   print "Unable to extract exim_user from binary.\n";
2611   print "Check if Exim refused to run; if so, consider:\n";
2612   print "  TRUSTED_CONFIG_LIST ALT_CONFIG_PREFIX WHITELIST_D_MACROS\n";
2613   print "If debug permission denied, are you in the exim group?\n";
2614   die "Failing to get information from binary.\n";
2615   }
2616
2617 if (defined $parm_eximgroup)
2618   {
2619   if ($parm_eximgroup =~ /^\d+$/) { $parm_exim_gid = $parm_eximgroup; }
2620     else { $parm_exim_gid = getgrnam($parm_eximgroup); }
2621   }
2622
2623 # check the permissions on the TRUSTED_CONFIG_LIST
2624 if (defined $parm_trusted_config_list)
2625   {
2626   die "TRUSTED_CONFIG_LIST: $parm_trusted_config_list: $!\n"
2627     if not -f $parm_trusted_config_list;
2628
2629   die "TRUSTED_CONFIG_LIST $parm_trusted_config_list must not be world writable!\n"
2630     if 02 & (stat _)[2];
2631
2632   die sprintf "TRUSTED_CONFIG_LIST: $parm_trusted_config_list %d is group writable, but not owned by group '%s' or '%s'.\n",
2633   (stat _)[1],
2634     scalar(getgrgid 0), scalar(getgrgid $>)
2635     if (020 & (stat _)[2]) and not ((stat _)[5] == $> or (stat _)[5] == 0);
2636
2637   die sprintf "TRUSTED_CONFIG_LIST: $parm_trusted_config_list is not owned by user '%s' or '%s'.\n",
2638   scalar(getpwuid 0), scalar(getpwuid $>)
2639      if (not (-o _ or (stat _)[4] == 0));
2640
2641   open(TCL, $parm_trusted_config_list) or die "Can't open $parm_trusted_config_list: $!\n";
2642   my $test_config = getcwd() . '/test-config';
2643   die "Can't find '$test_config' in TRUSTED_CONFIG_LIST $parm_trusted_config_list."
2644   if not grep { /^$test_config$/ } <TCL>;
2645   }
2646 else
2647   {
2648   die "Unable to check the TRUSTED_CONFIG_LIST, seems to be empty?\n";
2649   }
2650
2651 die "CONFIGURE_OWNER ($parm_configure_owner) does not match the user invoking $0 ($>)\n"
2652         if $parm_configure_owner != $>;
2653
2654 die "CONFIGURE_GROUP ($parm_configure_group) does not match the group invoking $0 ($))\n"
2655         if 0020 & (stat "$parm_cwd/test-config")[2]
2656         and $parm_configure_group != $);
2657
2658
2659 open(EXIMINFO, "$parm_exim -d-all+transport -bV -C $parm_cwd/test-config -DDIR=$parm_cwd |") ||
2660   die "** Cannot run $parm_exim: $!\n";
2661
2662 print "-" x 78, "\n";
2663
2664 while (<EXIMINFO>)
2665   {
2666   my(@temp);
2667
2668   if (/^(Exim|Library) version/) { print; }
2669
2670   elsif (/^Size of off_t: (\d+)/)
2671     {
2672     print;
2673     $have_largefiles = 1 if $1 > 4;
2674     die "** Size of off_t > 32 which seems improbable, not running tests\n"
2675         if ($1 > 32);
2676     }
2677
2678   elsif (/^Support for: (.*)/)
2679     {
2680     print;
2681     @temp = split /(\s+)/, $1;
2682     push(@temp, ' ');
2683     %parm_support = @temp;
2684     }
2685
2686   elsif (/^Lookups \(built-in\): (.*)/)
2687     {
2688     print;
2689     @temp = split /(\s+)/, $1;
2690     push(@temp, ' ');
2691     %parm_lookups = @temp;
2692     }
2693
2694   elsif (/^Authenticators: (.*)/)
2695     {
2696     print;
2697     @temp = split /(\s+)/, $1;
2698     push(@temp, ' ');
2699     %parm_authenticators = @temp;
2700     }
2701
2702   elsif (/^Routers: (.*)/)
2703     {
2704     print;
2705     @temp = split /(\s+)/, $1;
2706     push(@temp, ' ');
2707     %parm_routers = @temp;
2708     }
2709
2710   # Some transports have options, e.g. appendfile/maildir. For those, ensure
2711   # that the basic transport name is set, and then the name with each of the
2712   # options.
2713
2714   elsif (/^Transports: (.*)/)
2715     {
2716     print;
2717     @temp = split /(\s+)/, $1;
2718     my($i,$k);
2719     push(@temp, ' ');
2720     %parm_transports = @temp;
2721     foreach $k (keys %parm_transports)
2722       {
2723       if ($k =~ "/")
2724         {
2725         @temp = split /\//, $k;
2726         $parm_transports{"$temp[0]"} = " ";
2727         for ($i = 1; $i < @temp; $i++)
2728           { $parm_transports{"$temp[0]/$temp[$i]"} = " "; }
2729         }
2730       }
2731     }
2732   }
2733 close(EXIMINFO);
2734 print "-" x 78, "\n";
2735
2736 unlink("$parm_cwd/test-config");
2737
2738 ##################################################
2739 #    Check for SpamAssassin and ClamAV           #
2740 ##################################################
2741
2742 # These are crude tests. If they aren't good enough, we'll have to improve
2743 # them, for example by actually passing a message through spamc or clamscan.
2744
2745 if (defined $parm_support{'Content_Scanning'})
2746   {
2747   my $sock = new FileHandle;
2748
2749   if (system("spamc -h 2>/dev/null >/dev/null") == 0)
2750     {
2751     print "The spamc command works:\n";
2752
2753     # This test for an active SpamAssassin is courtesy of John Jetmore.
2754     # The tests are hard coded to localhost:783, so no point in making
2755     # this test flexible like the clamav test until the test scripts are
2756     # changed.  spamd doesn't have the nice PING/PONG protoccol that
2757     # clamd does, but it does respond to errors in an informative manner,
2758     # so use that.
2759
2760     my($sint,$sport) = ('127.0.0.1',783);
2761     eval
2762       {
2763       my $sin = sockaddr_in($sport, inet_aton($sint))
2764           or die "** Failed packing $sint:$sport\n";
2765       socket($sock, PF_INET, SOCK_STREAM, getprotobyname('tcp'))
2766           or die "** Unable to open socket $sint:$sport\n";
2767
2768       local $SIG{ALRM} =
2769           sub { die "** Timeout while connecting to socket $sint:$sport\n"; };
2770       alarm(5);
2771       connect($sock, $sin)
2772           or die "** Unable to connect to socket $sint:$sport\n";
2773       alarm(0);
2774
2775       select((select($sock), $| = 1)[0]);
2776       print $sock "bad command\r\n";
2777
2778       $SIG{ALRM} =
2779           sub { die "** Timeout while reading from socket $sint:$sport\n"; };
2780       alarm(10);
2781       my $res = <$sock>;
2782       alarm(0);
2783
2784       $res =~ m|^SPAMD/|
2785           or die "** Did not get SPAMD from socket $sint:$sport. "
2786                 ."It said: $res\n";
2787       };
2788     alarm(0);
2789     if($@)
2790       {
2791       print "  $@";
2792       print "  Assume SpamAssassin (spamd) is not running\n";
2793       }
2794     else
2795       {
2796       $parm_running{'SpamAssassin'} = ' ';
2797       print "  SpamAssassin (spamd) seems to be running\n";
2798       }
2799     }
2800   else
2801     {
2802     print "The spamc command failed: assume SpamAssassin (spamd) is not running\n";
2803     }
2804
2805   # For ClamAV, we need to find the clamd socket for use in the Exim
2806   # configuration. Search for the clamd configuration file.
2807
2808   if (system("clamscan -h 2>/dev/null >/dev/null") == 0)
2809     {
2810     my($f, $clamconf, $test_prefix);
2811
2812     print "The clamscan command works";
2813
2814     $test_prefix = $ENV{EXIM_TEST_PREFIX};
2815     $test_prefix = "" if !defined $test_prefix;
2816
2817     foreach $f ("$test_prefix/etc/clamd.conf",
2818                 "$test_prefix/usr/local/etc/clamd.conf",
2819                 "$test_prefix/etc/clamav/clamd.conf", "")
2820       {
2821       if (-e $f)
2822         {
2823         $clamconf = $f;
2824         last;
2825         }
2826       }
2827
2828     # Read the ClamAV configuration file and find the socket interface.
2829
2830     if ($clamconf ne "")
2831       {
2832       my $socket_domain;
2833       open(IN, "$clamconf") || die "\n** Unable to open $clamconf: $!\n";
2834       while (<IN>)
2835         {
2836         if (/^LocalSocket\s+(.*)/)
2837           {
2838           $parm_clamsocket = $1;
2839           $socket_domain = AF_UNIX;
2840           last;
2841           }
2842         if (/^TCPSocket\s+(\d+)/)
2843           {
2844           if (defined $parm_clamsocket)
2845             {
2846             $parm_clamsocket .= " $1";
2847             $socket_domain = AF_INET;
2848             last;
2849             }
2850           else
2851             {
2852             $parm_clamsocket = " $1";
2853             }
2854           }
2855         elsif (/^TCPAddr\s+(\S+)/)
2856           {
2857           if (defined $parm_clamsocket)
2858             {
2859             $parm_clamsocket = $1 . $parm_clamsocket;
2860             $socket_domain = AF_INET;
2861             last;
2862             }
2863           else
2864             {
2865             $parm_clamsocket = $1;
2866             }
2867           }
2868         }
2869       close(IN);
2870
2871       if (defined $socket_domain)
2872         {
2873         print ":\n  The clamd socket is $parm_clamsocket\n";
2874         # This test for an active ClamAV is courtesy of Daniel Tiefnig.
2875         eval
2876           {
2877           my $socket;
2878           if ($socket_domain == AF_UNIX)
2879             {
2880             $socket = sockaddr_un($parm_clamsocket) or die "** Failed packing '$parm_clamsocket'\n";
2881             }
2882           elsif ($socket_domain == AF_INET)
2883             {
2884             my ($ca_host, $ca_port) = split(/\s+/,$parm_clamsocket);
2885             my $ca_hostent = gethostbyname($ca_host) or die "** Failed to get raw address for host '$ca_host'\n";
2886             $socket = sockaddr_in($ca_port, $ca_hostent) or die "** Failed packing '$parm_clamsocket'\n";
2887             }
2888           else
2889             {
2890             die "** Unknown socket domain '$socket_domain' (should not happen)\n";
2891             }
2892           socket($sock, $socket_domain, SOCK_STREAM, 0) or die "** Unable to open socket '$parm_clamsocket'\n";
2893           local $SIG{ALRM} = sub { die "** Timeout while connecting to socket '$parm_clamsocket'\n"; };
2894           alarm(5);
2895           connect($sock, $socket) or die "** Unable to connect to socket '$parm_clamsocket'\n";
2896           alarm(0);
2897
2898           my $ofh = select $sock; $| = 1; select $ofh;
2899           print $sock "PING\n";
2900
2901           $SIG{ALRM} = sub { die "** Timeout while reading from socket '$parm_clamsocket'\n"; };
2902           alarm(10);
2903           my $res = <$sock>;
2904           alarm(0);
2905
2906           $res =~ /PONG/ or die "** Did not get PONG from socket '$parm_clamsocket'. It said: $res\n";
2907           };
2908         alarm(0);
2909
2910         if($@)
2911           {
2912           print "  $@";
2913           print "  Assume ClamAV is not running\n";
2914           }
2915         else
2916           {
2917           $parm_running{'ClamAV'} = ' ';
2918           print "  ClamAV seems to be running\n";
2919           }
2920         }
2921       else
2922         {
2923         print ", but the socket for clamd could not be determined\n";
2924         print "Assume ClamAV is not running\n";
2925         }
2926       }
2927
2928     else
2929       {
2930       print ", but I can't find a configuration for clamd\n";
2931       print "Assume ClamAV is not running\n";
2932       }
2933     }
2934   }
2935
2936
2937 ##################################################
2938 #       Check for redis                          #
2939 ##################################################
2940 if (defined $parm_lookups{'redis'})
2941   {
2942   if (system("redis-server -v 2>/dev/null >/dev/null") == 0)
2943     {
2944     print "The redis-server command works\n";
2945     $parm_running{'redis'} = ' ';
2946     }
2947   else
2948     {
2949     print "The redis-server command failed: assume Redis not installed\n";
2950     }
2951   }
2952
2953 ##################################################
2954 #         Test for the basic requirements        #
2955 ##################################################
2956
2957 # This test suite assumes that Exim has been built with at least the "usual"
2958 # set of routers, transports, and lookups. Ensure that this is so.
2959
2960 $missing = "";
2961
2962 $missing .= "     Lookup: lsearch\n" if (!defined $parm_lookups{'lsearch'});
2963
2964 $missing .= "     Router: accept\n" if (!defined $parm_routers{'accept'});
2965 $missing .= "     Router: dnslookup\n" if (!defined $parm_routers{'dnslookup'});
2966 $missing .= "     Router: manualroute\n" if (!defined $parm_routers{'manualroute'});
2967 $missing .= "     Router: redirect\n" if (!defined $parm_routers{'redirect'});
2968
2969 $missing .= "     Transport: appendfile\n" if (!defined $parm_transports{'appendfile'});
2970 $missing .= "     Transport: autoreply\n" if (!defined $parm_transports{'autoreply'});
2971 $missing .= "     Transport: pipe\n" if (!defined $parm_transports{'pipe'});
2972 $missing .= "     Transport: smtp\n" if (!defined $parm_transports{'smtp'});
2973
2974 if ($missing ne "")
2975   {
2976   print "\n";
2977   print "** Many features can be included or excluded from Exim binaries.\n";
2978   print "** This test suite requires that Exim is built to contain a certain\n";
2979   print "** set of basic facilities. It seems that some of these are missing\n";
2980   print "** from the binary that is under test, so the test cannot proceed.\n";
2981   print "** The missing facilities are:\n";
2982   print "$missing";
2983   die "** Test script abandoned\n";
2984   }
2985
2986
2987 ##################################################
2988 #      Check for the auxiliary programs          #
2989 ##################################################
2990
2991 # These are always required:
2992
2993 for $prog ("cf", "checkaccess", "client", "client-ssl", "client-gnutls",
2994            "fakens", "iefbr14", "server")
2995   {
2996   next if ($prog eq "client-ssl" && !defined $parm_support{'OpenSSL'});
2997   next if ($prog eq "client-gnutls" && !defined $parm_support{'GnuTLS'});
2998   if (!-e "bin/$prog")
2999     {
3000     print "\n";
3001     print "** bin/$prog does not exist. Have you run ./configure and make?\n";
3002     die "** Test script abandoned\n";
3003     }
3004   }
3005
3006 # If the "loaded" binary is missing, we cut out tests for ${dlfunc. It isn't
3007 # compiled on systems where we don't know how to. However, if Exim does not
3008 # have that functionality compiled, we needn't bother.
3009
3010 $dlfunc_deleted = 0;
3011 if (defined $parm_support{'Expand_dlfunc'} && !-e "bin/loaded")
3012   {
3013   delete $parm_support{'Expand_dlfunc'};
3014   $dlfunc_deleted = 1;
3015   }
3016
3017
3018 ##################################################
3019 #          Find environmental details            #
3020 ##################################################
3021
3022 # Find the caller of this program.
3023
3024 ($parm_caller,$pwpw,$parm_caller_uid,$parm_caller_gid,$pwquota,$pwcomm,
3025  $parm_caller_gecos, $parm_caller_home) = getpwuid($>);
3026
3027 $pwpw = $pwpw;       # Kill Perl warnings
3028 $pwquota = $pwquota;
3029 $pwcomm = $pwcomm;
3030
3031 $parm_caller_group = getgrgid($parm_caller_gid);
3032
3033 print "Program caller is $parm_caller ($parm_caller_uid), whose group is $parm_caller_group ($parm_caller_gid)\n";
3034 print "Home directory is $parm_caller_home\n";
3035
3036 unless (defined $parm_eximgroup)
3037   {
3038   print "Unable to derive \$parm_eximgroup.\n";
3039   die "** ABANDONING.\n";
3040   }
3041
3042 print "You need to be in the Exim group to run these tests. Checking ...";
3043
3044 if (`groups` =~ /\b\Q$parm_eximgroup\E\b/)
3045   {
3046   print " OK\n";
3047   }
3048 else
3049   {
3050   print "\nOh dear, you are not in the Exim group.\n";
3051   die "** Testing abandoned.\n";
3052   }
3053
3054 # Find this host's IP addresses - there may be many, of course, but we keep
3055 # one of each type (IPv4 and IPv6).
3056
3057 open(IFCONFIG, '-|', (grep { -x "$_/ip" } split /:/, $ENV{PATH}) ? 'ip address' : 'ifconfig -a')
3058   or die "** Cannot run 'ip address' or 'ifconfig -a'\n";
3059 while (not ($parm_ipv4 and $parm_ipv6) and defined($_ = <IFCONFIG>))
3060   {
3061   if (not $parm_ipv4 and /^\s*inet(?:\saddr)?:?\s?(\d+\.\d+\.\d+\.\d+)(?:\/\d+)?\s/i)
3062     {
3063     next if $1 =~ /^(?:127|10)\./;
3064     $parm_ipv4 = $1;
3065     }
3066
3067   if (not $parm_ipv6 and /^\s*inet6(?:\saddr)?:?\s?([abcdef\d:]+)(?:\/\d+)/i)
3068     {
3069     next if $1 eq '::1' or $1 =~ /^fe80/i;
3070     $parm_ipv6 = $1;
3071     }
3072   }
3073 close(IFCONFIG);
3074
3075 # Use private IP addresses if there are no public ones.
3076
3077 # If either type of IP address is missing, we need to set the value to
3078 # something other than empty, because that wrecks the substitutions. The value
3079 # is reflected, so use a meaningful string. Set appropriate options for the
3080 # "server" command. In practice, however, many tests assume 127.0.0.1 is
3081 # available, so things will go wrong if there is no IPv4 address. The lack
3082 # of IPV4 or IPv6 can be simulated by command options, which force $have_ipv4
3083 # and $have_ipv6 false.
3084
3085 if (not $parm_ipv4)
3086   {
3087   $have_ipv4 = 0;
3088   $parm_ipv4 = "<no IPv4 address found>";
3089   $server_opts .= " -noipv4";
3090   }
3091 elsif ($have_ipv4 == 0)
3092   {
3093   $parm_ipv4 = "<IPv4 testing disabled>";
3094   $server_opts .= " -noipv4";
3095   }
3096 else
3097   {
3098   $parm_running{"IPv4"} = " ";
3099   }
3100
3101 if (not $parm_ipv6)
3102   {
3103   $have_ipv6 = 0;
3104   $parm_ipv6 = "<no IPv6 address found>";
3105   $server_opts .= " -noipv6";
3106   delete($parm_support{"IPv6"});
3107   }
3108 elsif ($have_ipv6 == 0)
3109   {
3110   $parm_ipv6 = "<IPv6 testing disabled>";
3111   $server_opts .= " -noipv6";
3112   delete($parm_support{"IPv6"});
3113   }
3114 elsif (!defined $parm_support{'IPv6'})
3115   {
3116   $have_ipv6 = 0;
3117   $parm_ipv6 = "<no IPv6 support in Exim binary>";
3118   $server_opts .= " -noipv6";
3119   }
3120 else
3121   {
3122   $parm_running{"IPv6"} = " ";
3123   }
3124
3125 print "IPv4 address is $parm_ipv4\n";
3126 print "IPv6 address is $parm_ipv6\n";
3127
3128 # For munging test output, we need the reversed IP addresses.
3129
3130 $parm_ipv4r = ($parm_ipv4 !~ /^\d/)? "" :
3131   join(".", reverse(split /\./, $parm_ipv4));
3132
3133 $parm_ipv6r = $parm_ipv6;             # Appropriate if not in use
3134 if ($parm_ipv6 =~ /^[\da-f]/)
3135   {
3136   my(@comps) = split /:/, $parm_ipv6;
3137   my(@nibbles);
3138   foreach $comp (@comps)
3139     {
3140     push @nibbles, sprintf("%lx", hex($comp) >> 8);
3141     push @nibbles, sprintf("%lx", hex($comp) & 0xff);
3142     }
3143   $parm_ipv6r = join(".", reverse(@nibbles));
3144   }
3145
3146 # Find the host name, fully qualified.
3147
3148 chomp($temp = `hostname`);
3149 die "'hostname' didn't return anything\n" unless defined $temp and length $temp;
3150 $parm_hostname = (gethostbyname($temp))[0];
3151 $parm_hostname = "no.host.name.found" unless defined $parm_hostname and length $parm_hostname;
3152 print "Hostname is $parm_hostname\n";
3153
3154 if ($parm_hostname !~ /\./)
3155   {
3156   print "\n*** Host name is not fully qualified: this may cause problems ***\n\n";
3157   }
3158
3159 if ($parm_hostname =~ /[[:upper:]]/)
3160   {
3161   print "\n*** Host name has upper case characters: this may cause problems ***\n\n";
3162   }
3163
3164
3165
3166 ##################################################
3167 #     Create a testing version of Exim           #
3168 ##################################################
3169
3170 # We want to be able to run Exim with a variety of configurations. Normally,
3171 # the use of -C to change configuration causes Exim to give up its root
3172 # privilege (unless the caller is exim or root). For these tests, we do not
3173 # want this to happen. Also, we want Exim to know that it is running in its
3174 # test harness.
3175
3176 # We achieve this by copying the binary and patching it as we go. The new
3177 # binary knows it is a testing copy, and it allows -C and -D without loss of
3178 # privilege. Clearly, this file is dangerous to have lying around on systems
3179 # where there are general users with login accounts. To protect against this,
3180 # we put the new binary in a special directory that is accessible only to the
3181 # caller of this script, who is known to have sudo root privilege from the test
3182 # that was done above. Furthermore, we ensure that the binary is deleted at the
3183 # end of the test. First ensure the directory exists.
3184
3185 if (-d "eximdir")
3186   { unlink "eximdir/exim"; }     # Just in case
3187 else
3188   {
3189   mkdir("eximdir", 0710) || die "** Unable to mkdir $parm_cwd/eximdir: $!\n";
3190   system("sudo chgrp $parm_eximgroup eximdir");
3191   }
3192
3193 # The construction of the patched binary must be done as root, so we use
3194 # a separate script. As well as indicating that this is a test-harness binary,
3195 # the version number is patched to "x.yz" so that its length is always the
3196 # same. Otherwise, when it appears in Received: headers, it affects the length
3197 # of the message, which breaks certain comparisons.
3198
3199 die "** Unable to make patched exim: $!\n"
3200   if (system("sudo ./patchexim $parm_exim") != 0);
3201
3202 # From this point on, exits from the program must go via the subroutine
3203 # tests_exit(), so that suitable cleaning up can be done when required.
3204 # Arrange to catch interrupting signals, to assist with this.
3205
3206 $SIG{'INT'} = \&inthandler;
3207 $SIG{'PIPE'} = \&pipehandler;
3208
3209 # For some tests, we need another copy of the binary that is setuid exim rather
3210 # than root.
3211
3212 system("sudo cp eximdir/exim eximdir/exim_exim;" .
3213        "sudo chown $parm_eximuser eximdir/exim_exim;" .
3214        "sudo chgrp $parm_eximgroup eximdir/exim_exim;" .
3215        "sudo chmod 06755 eximdir/exim_exim");
3216
3217
3218 ##################################################
3219 #     Make copies of utilities we might need     #
3220 ##################################################
3221
3222 # Certain of the tests make use of some of Exim's utilities. We do not need
3223 # to be root to copy these.
3224
3225 ($parm_exim_dir) = $parm_exim =~ m?^(.*)/exim?;
3226
3227 $dbm_build_deleted = 0;
3228 if (defined $parm_lookups{'dbm'} &&
3229     system("cp $parm_exim_dir/exim_dbmbuild eximdir") != 0)
3230   {
3231   delete $parm_lookups{'dbm'};
3232   $dbm_build_deleted = 1;
3233   }
3234
3235 if (system("cp $parm_exim_dir/exim_dumpdb eximdir") != 0)
3236   {
3237   tests_exit(-1, "Failed to make a copy of exim_dumpdb: $!");
3238   }
3239
3240 if (system("cp $parm_exim_dir/exim_lock eximdir") != 0)
3241   {
3242   tests_exit(-1, "Failed to make a copy of exim_lock: $!");
3243   }
3244
3245 if (system("cp $parm_exim_dir/exinext eximdir") != 0)
3246   {
3247   tests_exit(-1, "Failed to make a copy of exinext: $!");
3248   }
3249
3250 if (system("cp $parm_exim_dir/exigrep eximdir") != 0)
3251   {
3252   tests_exit(-1, "Failed to make a copy of exigrep: $!");
3253   }
3254
3255 if (system("cp $parm_exim_dir/eximstats eximdir") != 0)
3256   {
3257   tests_exit(-1, "Failed to make a copy of eximstats: $!");
3258   }
3259
3260
3261 ##################################################
3262 #    Check that the Exim user can access stuff   #
3263 ##################################################
3264
3265 # We delay this test till here so that we can check access to the actual test
3266 # binary. This will be needed when Exim re-exec's itself to do deliveries.
3267
3268 print "Exim user is $parm_eximuser ($parm_exim_uid)\n";
3269 print "Exim group is $parm_eximgroup ($parm_exim_gid)\n";
3270
3271 if ($parm_caller_uid eq $parm_exim_uid) {
3272   tests_exit(-1, "Exim user ($parm_eximuser,$parm_exim_uid) cannot be "
3273                 ."the same as caller ($parm_caller,$parm_caller_uid)");
3274 }
3275 if ($parm_caller_gid eq $parm_exim_gid) {
3276   tests_exit(-1, "Exim group ($parm_eximgroup,$parm_exim_gid) cannot be "
3277                 ."the same as caller's ($parm_caller) group as it confuses "
3278                 ."results analysis");
3279 }
3280
3281 print "The Exim user needs access to the test suite directory. Checking ...";
3282
3283 if (($rc = system("sudo bin/checkaccess $parm_cwd/eximdir/exim $parm_eximuser $parm_eximgroup")) != 0)
3284   {
3285   my($why) = "unknown failure $rc";
3286   $rc >>= 8;
3287   $why = "Couldn't find user \"$parm_eximuser\"" if $rc == 1;
3288   $why = "Couldn't find group \"$parm_eximgroup\"" if $rc == 2;
3289   $why = "Couldn't read auxiliary group list" if $rc == 3;
3290   $why = "Couldn't get rid of auxiliary groups" if $rc == 4;
3291   $why = "Couldn't set gid" if $rc == 5;
3292   $why = "Couldn't set uid" if $rc == 6;
3293   $why = "Couldn't open \"$parm_cwd/eximdir/exim\"" if $rc == 7;
3294   print "\n** $why\n";
3295   tests_exit(-1, "$parm_eximuser cannot access the test suite directory");
3296   }
3297 else
3298   {
3299   print " OK\n";
3300   }
3301
3302
3303 ##################################################
3304 #        Create a list of available tests        #
3305 ##################################################
3306
3307 # The scripts directory contains a number of subdirectories whose names are
3308 # of the form 0000-xxxx, 1100-xxxx, 2000-xxxx, etc. Each set of tests apart
3309 # from the first requires certain optional features to be included in the Exim
3310 # binary. These requirements are contained in a file called "REQUIRES" within
3311 # the directory. We scan all these tests, discarding those that cannot be run
3312 # because the current binary does not support the right facilities, and also
3313 # those that are outside the numerical range selected.
3314
3315 print "\nTest range is $test_start to $test_end (flavour $flavour)\n";
3316 print "Omitting \${dlfunc expansion tests (loadable module not present)\n"
3317   if $dlfunc_deleted;
3318 print "Omitting dbm tests (unable to copy exim_dbmbuild)\n"
3319   if $dbm_build_deleted;
3320
3321 opendir(DIR, "scripts") || tests_exit(-1, "Failed to opendir(\"scripts\"): $!");
3322 @test_dirs = sort readdir(DIR);
3323 closedir(DIR);
3324
3325 # Remove . and .. and CVS from the list.
3326
3327 for ($i = 0; $i < @test_dirs; $i++)
3328   {
3329   my($d) = $test_dirs[$i];
3330   if ($d eq "." || $d eq ".." || $d eq "CVS")
3331     {
3332     splice @test_dirs, $i, 1;
3333     $i--;
3334     }
3335   }
3336
3337 # Scan for relevant tests
3338
3339 for ($i = 0; $i < @test_dirs; $i++)
3340   {
3341   my($testdir) = $test_dirs[$i];
3342   my($wantthis) = 1;
3343
3344   print ">>Checking $testdir\n" if $debug;
3345
3346   # Skip this directory if the first test is equal or greater than the first
3347   # test in the next directory.
3348
3349   next if ($i < @test_dirs - 1) &&
3350           ($test_start >= substr($test_dirs[$i+1], 0, 4));
3351
3352   # No need to carry on if the end test is less than the first test in this
3353   # subdirectory.
3354
3355   last if $test_end < substr($testdir, 0, 4);
3356
3357   # Check requirements, if any.
3358
3359   if (open(REQUIRES, "scripts/$testdir/REQUIRES"))
3360     {
3361     while (<REQUIRES>)
3362       {
3363       next if /^\s*$/;
3364       s/\s+$//;
3365       if (/^support (.*)$/)
3366         {
3367         if (!defined $parm_support{$1}) { $wantthis = 0; last; }
3368         }
3369       elsif (/^running (.*)$/)
3370         {
3371         if (!defined $parm_running{$1}) { $wantthis = 0; last; }
3372         }
3373       elsif (/^lookup (.*)$/)
3374         {
3375         if (!defined $parm_lookups{$1}) { $wantthis = 0; last; }
3376         }
3377       elsif (/^authenticators? (.*)$/)
3378         {
3379         if (!defined $parm_authenticators{$1}) { $wantthis = 0; last; }
3380         }
3381       elsif (/^router (.*)$/)
3382         {
3383         if (!defined $parm_routers{$1}) { $wantthis = 0; last; }
3384         }
3385       elsif (/^transport (.*)$/)
3386         {
3387         if (!defined $parm_transports{$1}) { $wantthis = 0; last; }
3388         }
3389       else
3390         {
3391         tests_exit(-1, "Unknown line in \"scripts/$testdir/REQUIRES\": \"$_\"");
3392         }
3393       }
3394     close(REQUIRES);
3395     }
3396   else
3397     {
3398     tests_exit(-1, "Failed to open \"scripts/$testdir/REQUIRES\": $!")
3399       unless $!{ENOENT};
3400     }
3401
3402   # Loop if we do not want the tests in this subdirectory.
3403
3404   if (!$wantthis)
3405     {
3406     chomp;
3407     print "Omitting tests in $testdir (missing $_)\n";
3408     next;
3409     }
3410
3411   # We want the tests from this subdirectory, provided they are in the
3412   # range that was selected.
3413
3414   opendir(SUBDIR, "scripts/$testdir") ||
3415     tests_exit(-1, "Failed to opendir(\"scripts/$testdir\"): $!");
3416   @testlist = sort readdir(SUBDIR);
3417   close(SUBDIR);
3418
3419   foreach $test (@testlist)
3420     {
3421     next if $test !~ /^\d{4}(?:\.\d+)?$/;
3422     next if $test < $test_start || $test > $test_end;
3423     push @test_list, "$testdir/$test";
3424     }
3425   }
3426
3427 print ">>Test List: @test_list\n", if $debug;
3428
3429
3430 ##################################################
3431 #         Munge variable auxiliary data          #
3432 ##################################################
3433
3434 # Some of the auxiliary data files have to refer to the current testing
3435 # directory and other parameter data. The generic versions of these files are
3436 # stored in the aux-var-src directory. At this point, we copy each of them
3437 # to the aux-var directory, making appropriate substitutions. There aren't very
3438 # many of them, so it's easiest just to do this every time. Ensure the mode
3439 # is standardized, as this path is used as a test for the ${stat: expansion.
3440
3441 # A similar job has to be done for the files in the dnszones-src directory, to
3442 # make the fake DNS zones for testing. Most of the zone files are copied to
3443 # files of the same name, but db.ipv4.V4NET and db.ipv6.V6NET use the testing
3444 # networks that are defined by parameter.
3445
3446 foreach $basedir ("aux-var", "dnszones")
3447   {
3448   system("sudo rm -rf $parm_cwd/$basedir");
3449   mkdir("$parm_cwd/$basedir", 0777);
3450   chmod(0755, "$parm_cwd/$basedir");
3451
3452   opendir(AUX, "$parm_cwd/$basedir-src") ||
3453     tests_exit(-1, "Failed to opendir $parm_cwd/$basedir-src: $!");
3454   my(@filelist) = readdir(AUX);
3455   close(AUX);
3456
3457   foreach $file (@filelist)
3458     {
3459     my($outfile) = $file;
3460     next if $file =~ /^\./;
3461
3462     if ($file eq "db.ip4.V4NET")
3463       {
3464       $outfile = "db.ip4.$parm_ipv4_test_net";
3465       }
3466     elsif ($file eq "db.ip6.V6NET")
3467       {
3468       my(@nibbles) = reverse(split /\s*/, $parm_ipv6_test_net);
3469       $" = '.';
3470       $outfile = "db.ip6.@nibbles";
3471       $" = ' ';
3472       }
3473
3474     print ">>Copying $basedir-src/$file to $basedir/$outfile\n" if $debug;
3475     open(IN, "$parm_cwd/$basedir-src/$file") ||
3476       tests_exit(-1, "Failed to open $parm_cwd/$basedir-src/$file: $!");
3477     open(OUT, ">$parm_cwd/$basedir/$outfile") ||
3478       tests_exit(-1, "Failed to open $parm_cwd/$basedir/$outfile: $!");
3479     while (<IN>)
3480       {
3481       do_substitute(0);
3482       print OUT;
3483       }
3484     close(IN);
3485     close(OUT);
3486     }
3487   }
3488
3489 # Set a user's shell, distinguishable from /bin/sh
3490
3491 symlink("/bin/sh","aux-var/sh");
3492 $ENV{'SHELL'} = $parm_shell = $parm_cwd . "/aux-var/sh";
3493
3494 ##################################################
3495 #     Create fake DNS zones for this host        #
3496 ##################################################
3497
3498 # There are fixed zone files for 127.0.0.1 and ::1, but we also want to be
3499 # sure that there are forward and reverse registrations for this host, using
3500 # its real IP addresses. Dynamically created zone files achieve this.
3501
3502 if ($have_ipv4 || $have_ipv6)
3503   {
3504   my($shortname,$domain) = $parm_hostname =~ /^([^.]+)(.*)/;
3505   open(OUT, ">$parm_cwd/dnszones/db$domain") ||
3506     tests_exit(-1, "Failed to open $parm_cwd/dnszones/db$domain: $!");
3507   print OUT "; This is a dynamically constructed fake zone file.\n" .
3508     "; The following line causes fakens to return PASS_ON\n" .
3509     "; for queries that it cannot answer\n\n" .
3510     "PASS ON NOT FOUND\n\n";
3511   print OUT "$shortname  A     $parm_ipv4\n" if $have_ipv4;
3512   print OUT "$shortname  AAAA  $parm_ipv6\n" if $have_ipv6;
3513   print OUT "\n; End\n";
3514   close(OUT);
3515   }
3516
3517 if ($have_ipv4 && $parm_ipv4 ne "127.0.0.1")
3518   {
3519   my(@components) = $parm_ipv4 =~ /^(\d+)\.(\d+)\.(\d+)\.(\d+)/;
3520   open(OUT, ">$parm_cwd/dnszones/db.ip4.$components[0]") ||
3521     tests_exit(-1,
3522       "Failed  to open $parm_cwd/dnszones/db.ip4.$components[0]: $!");
3523   print OUT "; This is a dynamically constructed fake zone file.\n" .
3524     "; The zone is $components[0].in-addr.arpa.\n\n" .
3525     "$components[3].$components[2].$components[1]  PTR  $parm_hostname.\n\n" .
3526     "; End\n";
3527   close(OUT);
3528   }
3529
3530 if ($have_ipv6 && $parm_ipv6 ne "::1")
3531   {
3532   my($exp_v6) = $parm_ipv6;
3533   $exp_v6 =~ s/[^:]//g;
3534   if ( $parm_ipv6 =~ /^([^:].+)::$/ ) {
3535     $exp_v6 = $1 . ':0' x (9-length($exp_v6));
3536   } elsif ( $parm_ipv6 =~ /^(.+)::(.+)$/ ) {
3537     $exp_v6 = $1 . ':0' x (8-length($exp_v6)) . ':' . $2;
3538   } elsif ( $parm_ipv6 =~ /^::(.+[^:])$/ ) {
3539     $exp_v6 = '0:' x (9-length($exp_v6)) . $1;
3540   } else {
3541     $exp_v6 = $parm_ipv6;
3542   }
3543   my(@components) = split /:/, $exp_v6;
3544   my(@nibbles) = reverse (split /\s*/, shift @components);
3545   my($sep) =  "";
3546
3547   $" = ".";
3548   open(OUT, ">$parm_cwd/dnszones/db.ip6.@nibbles") ||
3549     tests_exit(-1,
3550       "Failed  to open $parm_cwd/dnszones/db.ip6.@nibbles: $!");
3551   print OUT "; This is a dynamically constructed fake zone file.\n" .
3552     "; The zone is @nibbles.ip6.arpa.\n\n";
3553
3554   @components = reverse @components;
3555   foreach $c (@components)
3556     {
3557     $c = "0$c" until $c =~ /^..../;
3558     @nibbles = reverse(split /\s*/, $c);
3559     print OUT "$sep@nibbles";
3560     $sep = ".";
3561     }
3562
3563   print OUT "  PTR  $parm_hostname.\n\n; End\n";
3564   close(OUT);
3565   $" = " ";
3566   }
3567
3568
3569
3570 ##################################################
3571 #    Create lists of mailboxes and message logs  #
3572 ##################################################
3573
3574 # We use these lists to check that a test has created the expected files. It
3575 # should be faster than looking for the file each time. For mailboxes, we have
3576 # to scan a complete subtree, in order to handle maildirs. For msglogs, there
3577 # is just a flat list of files.
3578
3579 @oldmails = list_files_below("mail");
3580 opendir(DIR, "msglog") || tests_exit(-1, "Failed to opendir msglog: $!");
3581 @oldmsglogs = readdir(DIR);
3582 closedir(DIR);
3583
3584
3585
3586 ##################################################
3587 #         Run the required tests                 #
3588 ##################################################
3589
3590 # Each test script contains a number of tests, separated by a line that
3591 # contains ****. We open input from the terminal so that we can read responses
3592 # to prompts.
3593
3594 open(T, "/dev/tty") || tests_exit(-1, "Failed to open /dev/tty: $!");
3595
3596 print "\nPress RETURN to run the tests: ";
3597 $_ = $force_continue ? "c" : <T>;
3598 print "\n";
3599
3600 $lasttestdir = "";
3601
3602 foreach $test (@test_list)
3603   {
3604   local($lineno) = 0;
3605   local($commandno) = 0;
3606   local($subtestno) = 0;
3607   (local $testno = $test) =~ s|.*/||;
3608   local($sortlog) = 0;
3609
3610   my($gnutls) = 0;
3611   my($docheck) = 1;
3612   my($thistestdir) = substr($test, 0, -5);
3613
3614   $dynamic_socket->close() if $dynamic_socket;
3615
3616   if ($lasttestdir ne $thistestdir)
3617     {
3618     $gnutls = 0;
3619     if (-s "scripts/$thistestdir/REQUIRES")
3620       {
3621       my($indent) = "";
3622       print "\n>>> The following tests require: ";
3623       open(IN, "scripts/$thistestdir/REQUIRES") ||
3624         tests_exit(-1, "Failed to open scripts/$thistestdir/REQUIRES: $1");
3625       while (<IN>)
3626         {
3627         $gnutls = 1 if /^support GnuTLS/;
3628         print $indent, $_;
3629         $indent = ">>>                              ";
3630         }
3631       close(IN);
3632       }
3633     }
3634   $lasttestdir = $thistestdir;
3635
3636   # Remove any debris in the spool directory and the test-mail directory
3637   # and also the files for collecting stdout and stderr. Then put back
3638   # the test-mail directory for appendfile deliveries.
3639
3640   system "sudo /bin/rm -rf spool test-*";
3641   system "mkdir test-mail 2>/dev/null";
3642
3643   # A privileged Exim will normally make its own spool directory, but some of
3644   # the tests run in unprivileged modes that don't always work if the spool
3645   # directory isn't already there. What is more, we want anybody to be able
3646   # to read it in order to find the daemon's pid.
3647
3648   system "mkdir spool; " .
3649          "sudo chown $parm_eximuser:$parm_eximgroup spool; " .
3650          "sudo chmod 0755 spool";
3651
3652   # Empty the cache that keeps track of things like message id mappings, and
3653   # set up the initial sequence strings.
3654
3655   undef %cache;
3656   $next_msgid = "aX";
3657   $next_pid = 1234;
3658   $next_port = 1111;
3659   $message_skip = 0;
3660   $msglog_skip = 0;
3661   $stderr_skip = 0;
3662   $stdout_skip = 0;
3663   $rmfiltertest = 0;
3664   $is_ipv6test = 0;
3665   $TEST_STATE->{munge} = "";
3666
3667   # Remove the associative arrays used to hold checked mail files and msglogs
3668
3669   undef %expected_mails;
3670   undef %expected_msglogs;
3671
3672   # Open the test's script
3673   open(SCRIPT, "scripts/$test") ||
3674     tests_exit(-1, "Failed to open \"scripts/$test\": $!");
3675   # Run through the script once to set variables which should be global
3676   while (<SCRIPT>)
3677     {
3678     if (/^no_message_check/) { $message_skip = 1; next; }
3679     if (/^no_msglog_check/)  { $msglog_skip = 1; next; }
3680     if (/^no_stderr_check/)  { $stderr_skip = 1; next; }
3681     if (/^no_stdout_check/)  { $stdout_skip = 1; next; }
3682     if (/^rmfiltertest/)     { $rmfiltertest = 1; next; }
3683     if (/^sortlog/)          { $sortlog = 1; next; }
3684     if (/\bPORT_DYNAMIC\b/)  {
3685       for (my $port = 1024; $port < 65000; $port++) {
3686         $dynamic_socket = IO::Socket::INET->new(
3687           LocalHost => '127.0.0.1',
3688           LocalPort => $port,
3689           Listen => 10,
3690           ReuseAddr => 1,
3691         ) and last;
3692       }
3693       }
3694     }
3695   # Reset to beginning of file for per test interpreting/processing
3696   seek(SCRIPT, 0, 0);
3697
3698   # The first line in the script must be a comment that is used to identify
3699   # the set of tests as a whole.
3700
3701   $_ = <SCRIPT>;
3702   $lineno++;
3703   tests_exit(-1, "Missing identifying comment at start of $test") if (!/^#/);
3704   printf("%s %s", (substr $test, 5), (substr $_, 2));
3705
3706   # Loop for each of the subtests within the script. The variable $server_pid
3707   # is used to remember the pid of a "server" process, for which we do not
3708   # wait until we have waited for a subsequent command.
3709
3710   local($server_pid) = 0;
3711   for ($commandno = 1; !eof SCRIPT; $commandno++)
3712     {
3713     # Skip further leading comments and blank lines, handle the flag setting
3714     # commands, and deal with tests for IP support.
3715
3716     while (<SCRIPT>)
3717       {
3718       $lineno++;
3719       # Could remove these variable settings because they are already
3720       # set above, but doesn't hurt to leave them here.
3721       if (/^no_message_check/) { $message_skip = 1; next; }
3722       if (/^no_msglog_check/)  { $msglog_skip = 1; next; }
3723       if (/^no_stderr_check/)  { $stderr_skip = 1; next; }
3724       if (/^no_stdout_check/)  { $stdout_skip = 1; next; }
3725       if (/^rmfiltertest/)     { $rmfiltertest = 1; next; }
3726       if (/^sortlog/)          { $sortlog = 1; next; }
3727
3728       if (/^need_largefiles/)
3729         {
3730         next if $have_largefiles;
3731         print ">>> Large file support is needed for test $testno, but is not available: skipping\n";
3732         $docheck = 0;      # don't check output
3733         undef $_;          # pretend EOF
3734         last;
3735         }
3736
3737       if (/^need_ipv4/)
3738         {
3739         next if $have_ipv4;
3740         print ">>> IPv4 is needed for test $testno, but is not available: skipping\n";
3741         $docheck = 0;      # don't check output
3742         undef $_;          # pretend EOF
3743         last;
3744         }
3745
3746       if (/^need_ipv6/)
3747         {
3748         if ($have_ipv6)
3749           {
3750           $is_ipv6test = 1;
3751           next;
3752           }
3753         print ">>> IPv6 is needed for test $testno, but is not available: skipping\n";
3754         $docheck = 0;      # don't check output
3755         undef $_;          # pretend EOF
3756         last;
3757         }
3758
3759       if (/^need_move_frozen_messages/)
3760         {
3761         next if defined $parm_support{"move_frozen_messages"};
3762         print ">>> move frozen message support is needed for test $testno, " .
3763           "but is not\n>>> available: skipping\n";
3764         $docheck = 0;      # don't check output
3765         undef $_;          # pretend EOF
3766         last;
3767         }
3768
3769       last unless /^(#|\s*$)/;
3770       }
3771     last if !defined $_;  # Hit EOF
3772
3773     my($subtest_startline) = $lineno;
3774
3775     # Now run the command. The function returns 0 for an inline command,
3776     # 1 if a non-exim command was run and waited for, 2 if an exim
3777     # command was run and waited for, and 3 if a command
3778     # was run and not waited for (usually a daemon or server startup).
3779
3780     my($commandname) = "";
3781     my($expectrc) = 0;
3782     my($rc, $run_extra) = run_command($testno, \$subtestno, \$expectrc, \$commandname, $TEST_STATE);
3783     my($cmdrc) = $?;
3784
3785 $0 = "[runtest $testno]";
3786
3787     if ($debug) {
3788       print ">> rc=$rc cmdrc=$cmdrc\n";
3789       if (defined $run_extra) {
3790         foreach my $k (keys %$run_extra) {
3791           my $v = defined $run_extra->{$k} ? qq!"$run_extra->{$k}"! : '<undef>';
3792           print ">>   $k -> $v\n";
3793         }
3794       }
3795     }
3796     $run_extra = {} unless defined $run_extra;
3797     foreach my $k (keys %$run_extra) {
3798       if (exists $TEST_STATE->{$k}) {
3799         my $nv = defined $run_extra->{$k} ? qq!"$run_extra->{$k}"! : 'removed';
3800         print ">> override of $k; was $TEST_STATE->{$k}, now $nv\n" if $debug;
3801       }
3802       if (defined $run_extra->{$k}) {
3803         $TEST_STATE->{$k} = $run_extra->{$k};
3804       } elsif (exists $TEST_STATE->{$k}) {
3805         delete $TEST_STATE->{$k};
3806       }
3807     }
3808
3809     # Hit EOF after an initial return code number
3810
3811     tests_exit(-1, "Unexpected EOF in script") if ($rc == 4);
3812
3813     # Carry on with the next command if we did not wait for this one. $rc == 0
3814     # if no subprocess was run; $rc == 3 if we started a process but did not
3815     # wait for it.
3816
3817     next if ($rc == 0 || $rc == 3);
3818
3819     # We ran and waited for a command. Check for the expected result unless
3820     # it died.
3821
3822     if ($cmdrc != $expectrc && !$sigpipehappened)
3823       {
3824       printf("** Command $commandno (\"$commandname\", starting at line $subtest_startline)\n");
3825       if (($cmdrc & 0xff) == 0)
3826         {
3827         printf("** Return code %d (expected %d)", $cmdrc/256, $expectrc/256);
3828         }
3829       elsif (($cmdrc & 0xff00) == 0)
3830         { printf("** Killed by signal %d", $cmdrc & 255); }
3831       else
3832         { printf("** Status %x", $cmdrc); }
3833
3834       for (;;)
3835         {
3836         print "\nshow stdErr, show stdOut, Retry, Continue (without file comparison), or Quit? [Q] ";
3837         $_ = $force_continue ? "c" : <T>;
3838         tests_exit(1) if /^q?$/i;
3839         log_failure($log_failed_filename, $testno, "exit code unexpected") if (/^c$/i && $force_continue);
3840         if ($force_continue)
3841           {
3842           print "\nstderr tail:\n";
3843           print "===================\n";
3844           system("tail -20 test-stderr");
3845           print "===================\n";
3846           print "... continue forced\n";
3847           }
3848
3849         last if /^[rc]$/i;
3850         if (/^e$/i)
3851           {
3852           system("$more test-stderr");
3853           }
3854         elsif (/^o$/i)
3855           {
3856           system("$more test-stdout");
3857           }
3858         }
3859
3860       $retry = 1 if /^r$/i;
3861       $docheck = 0;
3862       }
3863
3864     # If the command was exim, and a listening server is running, we can now
3865     # close its input, which causes us to wait for it to finish, which is why
3866     # we didn't close it earlier.
3867
3868     if ($rc == 2 && $server_pid != 0)
3869       {
3870       close SERVERCMD;
3871       $server_pid = 0;
3872       if ($? != 0)
3873         {
3874         if (($? & 0xff) == 0)
3875           { printf("Server return code %d", $?/256); }
3876         elsif (($? & 0xff00) == 0)
3877           { printf("Server killed by signal %d", $? & 255); }
3878         else
3879           { printf("Server status %x", $?); }
3880
3881         for (;;)
3882           {
3883           print "\nShow server stdout, Retry, Continue, or Quit? [Q] ";
3884           $_ = $force_continue ? "c" : <T>;
3885           tests_exit(1) if /^q?$/i;
3886           log_failure($log_failed_filename, $testno, "exit code unexpected") if (/^c$/i && $force_continue);
3887           print "... continue forced\n" if $force_continue;
3888           last if /^[rc]$/i;
3889
3890           if (/^s$/i)
3891             {
3892             open(S, "test-stdout-server") ||
3893               tests_exit(-1, "Failed to open test-stdout-server: $!");
3894             print while <S>;
3895             close(S);
3896             }
3897           }
3898         $retry = 1 if /^r$/i;
3899         }
3900       }
3901     }
3902
3903   close SCRIPT;
3904
3905   # The script has finished. Check the all the output that was generated. The
3906   # function returns 0 if all is well, 1 if we should rerun the test (the files
3907   # function returns 0 if all is well, 1 if we should rerun the test (the files
3908   # have been updated). It does not return if the user responds Q to a prompt.
3909
3910   if ($retry)
3911     {
3912     $retry = '0';
3913     print (("#" x 79) . "\n");
3914     redo;
3915     }
3916
3917   if ($docheck)
3918     {
3919     if (check_output($TEST_STATE->{munge}) != 0)
3920       {
3921       print (("#" x 79) . "\n");
3922       redo;
3923       }
3924     else
3925       {
3926       print ("  Script completed\n");
3927       }
3928     }
3929   }
3930
3931
3932 ##################################################
3933 #         Exit from the test script              #
3934 ##################################################
3935
3936 tests_exit(-1, "No runnable tests selected") if @test_list == 0;
3937 tests_exit(0);
3938
3939 # End of runtest script