test/runtest

   1 #! /usr/bin/perl -w
   2
   3 ###############################################################################
   4 # This is the controlling script for the "new" test suite for Exim. It should #
   5 # be possible to export this suite for running on a wide variety of hosts, in #
   6 # contrast to the old suite, which was very dependent on the environment of   #
   7 # Philip Hazel's desktop computer. This implementation inspects the version   #
   8 # of Exim that it finds, and tests only those features that are included. The #
   9 # surrounding environment is also tested to discover what is available. See   #
  10 # the README file for details of how it all works.                            #
  11 #                                                                             #
  12 # Implementation started: 03 August 2005 by Philip Hazel                      #
  13 # Placed in the Exim CVS: 06 February 2006                                    #
  14 ###############################################################################
  15
  16 #use strict;
  17 require Cwd;
  18 use Errno;
  19 use FileHandle;
  20 use Socket;
  21 use Time::Local;
  22
  23
  24 # Start by initializing some global variables
  25
  26 $testversion = "4.80 (08-May-12)";
  27
  28 # This gets embedded in the D-H params filename, and the value comes
  29 # from asking GnuTLS for "normal", but there appears to be no way to
  30 # use certtool/... to ask what that value currently is.  *sigh*
  31 # We also clamp it because of NSS interop, see addition of tls_dh_max_bits.
  32 # This value is correct as of GnuTLS 2.12.18 as clamped by tls_dh_max_bits.
  33 # normal = 2432   tls_dh_max_bits = 2236
  34 $gnutls_dh_bits_normal = 2236;
  35
  36 $cf = "bin/cf -exact";
  37 $cr = "\r";
  38 $debug = 0;
  39 $force_update = 0;
  40 $more = "less -XF";
  41 $optargs = "";
  42 $save_output = 0;
  43 $server_opts = "";
  44
  45 $have_ipv4 = 1;
  46 $have_ipv6 = 1;
  47 $have_largefiles = 0;
  48
  49 $test_start = 1;
  50 $test_end = $test_top = 8999;
  51 $test_special_top = 9999;
  52 @test_list = ();
  53 @test_dirs = ();
  54
  55
  56 # Networks to use for DNS tests. We need to choose some networks that will
  57 # never be used so that there is no chance that the host on which we are
  58 # running is actually in one of the test networks. Private networks such as
  59 # the IPv4 10.0.0.0/8 network are no good because hosts may well use them.
  60 # Rather than use some unassigned numbers (that might become assigned later),
  61 # I have chosen some multicast networks, in the belief that such addresses
  62 # won't ever be assigned to hosts. This is the only place where these numbers
  63 # are defined, so it is trivially possible to change them should that ever
  64 # become necessary.
  65
  66 $parm_ipv4_test_net = "224";
  67 $parm_ipv6_test_net = "ff00";
  68
  69 # Port numbers are currently hard-wired
  70
  71 $parm_port_n = 1223;         # Nothing listening on this port
  72 $parm_port_s = 1224;         # Used for the "server" command
  73 $parm_port_d = 1225;         # Used for the Exim daemon
  74 $parm_port_d2 = 1226;        # Additional for daemon
  75 $parm_port_d3 = 1227;        # Additional for daemon
  76 $parm_port_d4 = 1228;        # Additional for daemon
  77
  78 # Manually set locale
  79 $ENV{'LC_ALL'} = 'C';
  80
  81
  82
  83 ###############################################################################
  84 ###############################################################################
  85
  86 # Define a number of subroutines
  87
  88 ###############################################################################
  89 ###############################################################################
  90
  91
  92 ##################################################
  93 #              Handle signals                    #
  94 ##################################################
  95
  96 sub pipehandler { $sigpipehappened = 1; }
  97
  98 sub inthandler { print "\n"; tests_exit(-1, "Caught SIGINT"); }
  99
 100
 101 ##################################################
 102 #       Do global macro substitutions            #
 103 ##################################################
 104
 105 # This function is applied to configurations, command lines and data lines in
 106 # scripts, and to lines in the files of the aux-var-src and the dnszones-src
 107 # directory. It takes one argument: the current test number, or zero when
 108 # setting up files before running any tests.
 109
 110 sub do_substitute{
 111 s?\bCALLER\b?$parm_caller?g;
 112 s?\bCALLERGROUP\b?$parm_caller_group?g;
 113 s?\bCALLER_UID\b?$parm_caller_uid?g;
 114 s?\bCALLER_GID\b?$parm_caller_gid?g;
 115 s?\bCLAMSOCKET\b?$parm_clamsocket?g;
 116 s?\bDIR/?$parm_cwd/?g;
 117 s?\bEXIMGROUP\b?$parm_eximgroup?g;
 118 s?\bEXIMUSER\b?$parm_eximuser?g;
 119 s?\bHOSTIPV4\b?$parm_ipv4?g;
 120 s?\bHOSTIPV6\b?$parm_ipv6?g;
 121 s?\bHOSTNAME\b?$parm_hostname?g;
 122 s?\bPORT_D\b?$parm_port_d?g;
 123 s?\bPORT_D2\b?$parm_port_d2?g;
 124 s?\bPORT_D3\b?$parm_port_d3?g;
 125 s?\bPORT_D4\b?$parm_port_d4?g;
 126 s?\bPORT_N\b?$parm_port_n?g;
 127 s?\bPORT_S\b?$parm_port_s?g;
 128 s?\bTESTNUM\b?$_[0]?g;
 129 s?(\b|_)V4NET([\._])?$1$parm_ipv4_test_net$2?g;
 130 s?\bV6NET:?$parm_ipv6_test_net:?g;
 131 }
 132
 133
 134 ##################################################
 135 #     Any state to be preserved across tests     #
 136 ##################################################
 137
 138 my $TEST_STATE = {};
 139
 140
 141 ##################################################
 142 #        Subroutine to tidy up and exit          #
 143 ##################################################
 144
 145 # In all cases, we check for any Exim daemons that have been left running, and
 146 # kill them. Then remove all the spool data, test output, and the modified Exim
 147 # binary if we are ending normally.
 148
 149 # Arguments:
 150 #    $_[0] = 0 for a normal exit; full cleanup done
 151 #    $_[0] > 0 for an error exit; no files cleaned up
 152 #    $_[0] < 0 for a "die" exit; $_[1] contains a message
 153
 154 sub tests_exit{
 155 my($rc) = $_[0];
 156 my($spool);
 157
 158 # Search for daemon pid files and kill the daemons. We kill with SIGINT rather
 159 # than SIGTERM to stop it outputting "Terminated" to the terminal when not in
 160 # the background.
 161
 162 if (exists $TEST_STATE->{exim_pid})
 163   {
 164   $pid = $TEST_STATE->{exim_pid};
 165   print "Tidyup: killing wait-mode daemon pid=$pid\n";
 166   system("sudo kill -SIGINT $pid");
 167   }
 168
 169 if (opendir(DIR, "spool"))
 170   {
 171   my(@spools) = sort readdir(DIR);
 172   closedir(DIR);
 173   foreach $spool (@spools)
 174     {
 175     next if $spool !~ /^exim-daemon./;
 176     open(PID, "spool/$spool") || die "** Failed to open \"spool/$spool\": $!\n";
 177     chomp($pid = <PID>);
 178     close(PID);
 179     print "Tidyup: killing daemon pid=$pid\n";
 180     system("sudo rm -f spool/$spool; sudo kill -SIGINT $pid");
 181     }
 182   }
 183 else
 184   { die "** Failed to opendir(\"spool\"): $!\n" unless $!{ENOENT}; }
 185
 186 # Close the terminal input and remove the test files if all went well, unless
 187 # the option to save them is set. Always remove the patched Exim binary. Then
 188 # exit normally, or die.
 189
 190 close(T);
 191 system("sudo /bin/rm -rf ./spool test-* ./dnszones/*")
 192   if ($rc == 0 && !$save_output);
 193
 194 system("sudo /bin/rm -rf ./eximdir/*");
 195
 196 print "\nYou were in test $test at the end there.\n\n" if defined $test;
 197 exit $rc if ($rc >= 0);
 198 die "** runtest error: $_[1]\n";
 199 }
 200
 201
 202
 203 ##################################################
 204 #   Subroutines used by the munging subroutine   #
 205 ##################################################
 206
 207 # This function is used for things like message ids, where we want to generate
 208 # more than one value, but keep a consistent mapping throughout.
 209 #
 210 # Arguments:
 211 #   $oldid        the value from the file
 212 #   $base         a base string into which we insert a sequence
 213 #   $sequence     the address of the current sequence counter
 214
 215 sub new_value {
 216 my($oldid, $base, $sequence) = @_;
 217 my($newid) = $cache{$oldid};
 218 if (! defined $newid)
 219   {
 220   $newid = sprintf($base, $$sequence++);
 221   $cache{$oldid} = $newid;
 222   }
 223 return $newid;
 224 }
 225
 226
 227 # This is used while munging the output from exim_dumpdb.
 228 # May go wrong across DST changes.
 229
 230 sub date_seconds {
 231 my($day,$month,$year,$hour,$min,$sec) =
 232   $_[0] =~ /^(\d\d)-(\w\w\w)-(\d{4})\s(\d\d):(\d\d):(\d\d)/;
 233 my($mon);
 234 if   ($month =~ /Jan/) {$mon = 0;}
 235 elsif($month =~ /Feb/) {$mon = 1;}
 236 elsif($month =~ /Mar/) {$mon = 2;}
 237 elsif($month =~ /Apr/) {$mon = 3;}
 238 elsif($month =~ /May/) {$mon = 4;}
 239 elsif($month =~ /Jun/) {$mon = 5;}
 240 elsif($month =~ /Jul/) {$mon = 6;}
 241 elsif($month =~ /Aug/) {$mon = 7;}
 242 elsif($month =~ /Sep/) {$mon = 8;}
 243 elsif($month =~ /Oct/) {$mon = 9;}
 244 elsif($month =~ /Nov/) {$mon = 10;}
 245 elsif($month =~ /Dec/) {$mon = 11;}
 246 return timelocal($sec,$min,$hour,$day,$mon,$year);
 247 }
 248
 249
 250 # This is a subroutine to sort maildir files into time-order. The second field
 251 # is the microsecond field, and may vary in length, so must be compared
 252 # numerically.
 253
 254 sub maildirsort {
 255 return $a cmp $b if ($a !~ /^\d+\.H\d/ || $b !~ /^\d+\.H\d/);
 256 my($x1,$y1) = $a =~ /^(\d+)\.H(\d+)/;
 257 my($x2,$y2) = $b =~ /^(\d+)\.H(\d+)/;
 258 return ($x1 != $x2)? ($x1 <=> $x2) : ($y1 <=> $y2);
 259 }
 260
 261
 262
 263 ##################################################
 264 #   Subroutine list files below a directory      #
 265 ##################################################
 266
 267 # This is used to build up a list of expected mail files below a certain path
 268 # in the directory tree. It has to be recursive in order to deal with multiple
 269 # maildir mailboxes.
 270
 271 sub list_files_below {
 272 my($dir) = $_[0];
 273 my(@yield) = ();
 274 my(@sublist, $file);
 275
 276 opendir(DIR, $dir) || tests_exit(-1, "Failed to open $dir: $!");
 277 @sublist = sort maildirsort readdir(DIR);
 278 closedir(DIR);
 279
 280 foreach $file (@sublist)
 281   {
 282   next if $file eq "." || $file eq ".." || $file eq "CVS";
 283   if (-d "$dir/$file")
 284     { @yield = (@yield, list_files_below("$dir/$file")); }
 285   else
 286     { push @yield, "$dir/$file"; }
 287   }
 288
 289 return @yield;
 290 }
 291
 292
 293
 294 ##################################################
 295 #         Munge a file before comparing          #
 296 ##################################################
 297
 298 # The pre-processing turns all dates, times, Exim versions, message ids, and so
 299 # on into standard values, so that the compare works. Perl's substitution with
 300 # an expression provides a neat way to do some of these changes.
 301
 302 # We keep a global associative array for repeatedly turning the same values
 303 # into the same standard values throughout the data from a single test.
 304 # Message ids get this treatment (can't be made reliable for times), and
 305 # times in dumped retry databases are also handled in a special way, as are
 306 # incoming port numbers.
 307
 308 # On entry to the subroutine, the file to write to is already opened with the
 309 # name MUNGED. The input file name is the only argument to the subroutine.
 310 # Certain actions are taken only when the name contains "stderr", "stdout",
 311 # or "log". The yield of the function is 1 if a line matching "*** truncated
 312 # ***" is encountered; otherwise it is 0.
 313
 314 sub munge {
 315 my($file) = $_[0];
 316 my($extra) = $_[1];
 317 my($yield) = 0;
 318 my(@saved) = ();
 319
 320 open(IN, "$file") || tests_exit(-1, "Failed to open $file: $!");
 321
 322 my($is_log) = $file =~ /log/;
 323 my($is_stdout) = $file =~ /stdout/;
 324 my($is_stderr) = $file =~ /stderr/;
 325
 326 # Date pattern
 327
 328 $date = "\\d{2}-\\w{3}-\\d{4}\\s\\d{2}:\\d{2}:\\d{2}";
 329
 330 # Pattern for matching pids at start of stderr lines; initially something
 331 # that won't match.
 332
 333 $spid = "xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx";
 334
 335 # Scan the file and make the changes. Near the bottom there are some changes
 336 # that are specific to certain file types, though there are also some of those
 337 # inline too.
 338
 339 while(<IN>)
 340   {
 341 RESET_AFTER_EXTRA_LINE_READ:
 342   # Custom munges
 343   if ($extra)
 344     {
 345     next if $extra =~ m%^/%  &&  eval $extra;
 346     eval $extra if $extra =~ m/^s/;
 347     }
 348
 349   # Check for "*** truncated ***"
 350   $yield = 1 if /\*\*\* truncated \*\*\*/;
 351
 352   # Replace the name of this host
 353   s/\Q$parm_hostname\E/the.local.host.name/g;
 354
 355   # But convert "name=the.local.host address=127.0.0.1" to use "localhost"
 356   s/name=the\.local\.host address=127\.0\.0\.1/name=localhost address=127.0.0.1/g;
 357
 358   # The name of the shell may vary
 359   s/\s\Q$parm_shell\E\b/ ENV_SHELL/;
 360
 361   # Replace the path to the testsuite directory
 362   s?\Q$parm_cwd\E?TESTSUITE?g;
 363
 364   # Replace the Exim version number (may appear in various places)
 365   # patchexim should have fixed this for us
 366   #s/(Exim) \d+\.\d+[\w_-]*/$1 x.yz/i;
 367
 368   # Replace Exim message ids by a unique series
 369   s/((?:[^\W_]{6}-){2}[^\W_]{2})
 370     /new_value($1, "10Hm%s-0005vi-00", \$next_msgid)/egx;
 371
 372   # The names of lock files appear in some error and debug messages
 373   s/\.lock(\.[-\w]+)+(\.[\da-f]+){2}/.lock.test.ex.dddddddd.pppppppp/;
 374
 375   # Unless we are in an IPv6 test, replace IPv4 and/or IPv6 in "listening on
 376   # port" message, because it is not always the same.
 377   s/port (\d+) \([^)]+\)/port $1/g
 378     if !$is_ipv6test && m/listening for SMTP(S?) on port/;
 379
 380   # Challenges in SPA authentication
 381   s/TlRMTVNTUAACAAAAAAAAAAAoAAABgg[\w+\/]+/TlRMTVNTUAACAAAAAAAAAAAoAAABggAAAEbBRwqFwwIAAAAAAAAAAAAt1sgAAAAA/;
 382
 383   # PRVS values
 384   s?prvs=([^/]+)/[\da-f]{10}@?prvs=$1/xxxxxxxxxx@?g;    # Old form
 385   s?prvs=[\da-f]{10}=([^@]+)@?prvs=xxxxxxxxxx=$1@?g;    # New form
 386
 387   # Error lines on stdout from SSL contain process id values and file names.
 388   # They also contain a source file name and line number, which may vary from
 389   # release to release.
 390   s/^\d+:error:/pppp:error:/;
 391   s/:(?:\/[^\s:]+\/)?([^\/\s]+\.c):\d+:/:$1:dddd:/;
 392
 393   # There are differences in error messages between OpenSSL versions
 394   s/SSL_CTX_set_cipher_list/SSL_connect/;
 395
 396   # One error test in expansions mentions base 62 or 36
 397   s/is not a base (36|62) number/is not a base 36\/62 number/;
 398
 399   # This message sometimes has a different number of seconds
 400   s/forced fail after \d seconds/forced fail after d seconds/;
 401
 402   # This message may contain a different DBM library name
 403   s/Failed to open \S+( \([^\)]+\))? file/Failed to open DBM file/;
 404
 405   # The message for a non-listening FIFO varies
 406   s/:[^:]+: while opening named pipe/: Error: while opening named pipe/;
 407
 408   # Debugging output of lists of hosts may have different sort keys
 409   s/sort=\S+/sort=xx/ if /^\S+ (?:\d+\.){3}\d+ mx=\S+ sort=\S+/;
 410
 411   # Random local part in callout cache testing
 412   s/myhost.test.ex-\d+-testing/myhost.test.ex-dddddddd-testing/;
 413
 414   # File descriptor numbers may vary
 415   s/^writing data block fd=\d+/writing data block fd=dddd/;
 416   s/running as transport filter: write=\d+ read=\d+/running as transport filter: write=dddd read=dddd/;
 417
 418
 419   # ======== Dumpdb output ========
 420   # This must be before the general date/date munging.
 421   # Time data lines, which look like this:
 422   # 25-Aug-2000 12:11:37  25-Aug-2000 12:11:37  26-Aug-2000 12:11:37
 423   if (/^($date)\s+($date)\s+($date)(\s+\*)?\s*$/)
 424     {
 425     my($date1,$date2,$date3,$expired) = ($1,$2,$3,$4);
 426     $expired = "" if !defined $expired;
 427     my($increment) = date_seconds($date3) - date_seconds($date2);
 428
 429     # We used to use globally unique replacement values, but timing
 430     # differences make this impossible. Just show the increment on the
 431     # last one.
 432
 433     printf MUNGED ("first failed = time last try = time2 next try = time2 + %s%s\n",
 434       $increment, $expired);
 435     next;
 436     }
 437
 438   # more_errno values in exim_dumpdb output which are times
 439   s/T:(\S+)\s-22\s(\S+)\s/T:$1 -22 xxxx /;
 440
 441
 442   # ======== Dates and times ========
 443
 444   # Dates and times are all turned into the same value - trying to turn
 445   # them into different ones cannot be done repeatedly because they are
 446   # real time stamps generated while running the test. The actual date and
 447   # time used was fixed when I first started running automatic Exim tests.
 448
 449   # Date/time in header lines and SMTP responses
 450   s/[A-Z][a-z]{2},\s\d\d?\s[A-Z][a-z]{2}\s\d\d\d\d\s\d\d\:\d\d:\d\d\s[-+]\d{4}
 451     /Tue, 2 Mar 1999 09:44:33 +0000/gx;
 452
 453   # Date/time in logs and in one instance of a filter test
 454   s/^\d{4}-\d\d-\d\d\s\d\d:\d\d:\d\d(\s[+-]\d\d\d\d)?/1999-03-02 09:44:33/gx;
 455   s/^Logwrite\s"\d{4}-\d\d-\d\d\s\d\d:\d\d:\d\d/Logwrite "1999-03-02 09:44:33/gx;
 456
 457   # Date/time in message separators
 458   s/(?:[A-Z][a-z]{2}\s){2}\d\d\s\d\d:\d\d:\d\d\s\d\d\d\d
 459     /Tue Mar 02 09:44:33 1999/gx;
 460
 461   # Date of message arrival in spool file as shown by -Mvh
 462   s/^\d{9,10}\s0$/ddddddddd 0/;
 463
 464   # Date/time in mbx mailbox files
 465   s/\d\d-\w\w\w-\d\d\d\d\s\d\d:\d\d:\d\d\s[-+]\d\d\d\d,/06-Sep-1999 15:52:48 +0100,/gx;
 466
 467   # Dates/times in debugging output for writing retry records
 468   if (/^  first failed=(\d+) last try=(\d+) next try=(\d+) (.*)$/)
 469     {
 470     my($next) = $3 - $2;
 471     $_ = "  first failed=dddd last try=dddd next try=+$next $4\n";
 472     }
 473   s/^(\s*)now=\d+ first_failed=\d+ next_try=\d+ expired=(\d)/$1now=tttt first_failed=tttt next_try=tttt expired=$2/;
 474   s/^(\s*)received_time=\d+ diff=\d+ timeout=(\d+)/$1received_time=tttt diff=tttt timeout=$2/;
 475
 476   # Time to retry may vary
 477   s/time to retry = \S+/time to retry = tttt/;
 478   s/retry record exists: age=\S+/retry record exists: age=ttt/;
 479   s/failing_interval=\S+ message_age=\S+/failing_interval=ttt message_age=ttt/;
 480
 481   # Date/time in exim -bV output
 482   s/\d\d-[A-Z][a-z]{2}-\d{4}\s\d\d:\d\d:\d\d/07-Mar-2000 12:21:52/g;
 483
 484   # Time on queue tolerance
 485   s/QT=1s/QT=0s/;
 486
 487   # Eximstats heading
 488   s/Exim\sstatistics\sfrom\s\d{4}-\d\d-\d\d\s\d\d:\d\d:\d\d\sto\s
 489     \d{4}-\d\d-\d\d\s\d\d:\d\d:\d\d/Exim statistics from <time> to <time>/x;
 490
 491
 492   # ======== TLS certificate algorithms ========
 493   # Test machines might have various different TLS library versions supporting
 494   # different protocols; can't rely upon TLS 1.2's AES256-GCM-SHA384, so we
 495   # treat the standard algorithms the same.
 496   # So far, have seen:
 497   #   TLSv1:AES256-SHA:256
 498   #   TLSv1.2:AES256-GCM-SHA384:256
 499   #   TLSv1.2:DHE-RSA-AES256-SHA:256
 500   #   TLS1.2:DHE_RSA_AES_128_CBC_SHA1:128
 501   # We also need to handle the ciphersuite without the TLS part present, for
 502   # client-ssl's output.  We also see some older forced ciphersuites, but
 503   # negotiating TLS 1.2 instead of 1.0.
 504   # Mail headers (...), log-lines X=..., client-ssl output ...
 505   # (and \b doesn't match between ' ' and '(' )
 506
 507   s/( (?: (?:\b|\s) [\(=] ) | \s )TLSv1\.2:/$1TLSv1:/xg;
 508   s/\bAES256-GCM-SHA384\b/AES256-SHA/g;
 509   s/\bDHE-RSA-AES256-SHA\b/AES256-SHA/g;
 510
 511   # GnuTLS have seen:
 512   #   TLS1.2:RSA_AES_256_CBC_SHA1:256 (canonical)
 513   #   TLS1.2:DHE_RSA_AES_128_CBC_SHA1:128
 514   #
 515   #   X=TLS1.2:DHE_RSA_AES_256_CBC_SHA256:256
 516   #   X=TLS1.2:RSA_AES_256_CBC_SHA1:256
 517   #   X=TLS1.1:RSA_AES_256_CBC_SHA1:256
 518   #   X=TLS1.0:DHE_RSA_AES_256_CBC_SHA1:256
 519   # and as stand-alone cipher:
 520   #   DHE-RSA-AES256-SHA256
 521   #   DHE-RSA-AES256-SHA
 522   # picking latter as canonical simply because regex easier that way.
 523   s/\bDHE_RSA_AES_128_CBC_SHA1:128/RSA_AES_256_CBC_SHA1:256/g;
 524   s/TLS1.[012]:(DHE_)?RSA_AES_256_CBC_SHA(1|256):256/TLS1.x:xxxxRSA_AES_256_CBC_SHAnnn:256/g;
 525   s/\bDHE-RSA-AES256-SHA256\b/DHE-RSA-AES256-SHA/g;
 526
 527
 528   # ======== Caller's login, uid, gid, home, gecos ========
 529
 530   s/\Q$parm_caller_home\E/CALLER_HOME/g;   # NOTE: these must be done
 531   s/\b\Q$parm_caller\E\b/CALLER/g;         #       in this order!
 532   s/\b\Q$parm_caller_group\E\b/CALLER/g;   # In case group name different
 533
 534   s/\beuid=$parm_caller_uid\b/euid=CALLER_UID/g;
 535   s/\begid=$parm_caller_gid\b/egid=CALLER_GID/g;
 536
 537   s/\buid=$parm_caller_uid\b/uid=CALLER_UID/g;
 538   s/\bgid=$parm_caller_gid\b/gid=CALLER_GID/g;
 539
 540   s/\bname=$parm_caller_gecos\b/name=CALLER_GECOS/g;
 541
 542   # When looking at spool files with -Mvh, we will find not only the caller
 543   # login, but also the uid and gid. It seems that $) in some Perls gives all
 544   # the auxiliary gids as well, so don't bother checking for that.
 545
 546   s/^CALLER $> \d+$/CALLER UID GID/;
 547
 548   # There is one case where the caller's login is forced to something else,
 549   # in order to test the processing of logins that contain spaces. Weird what
 550   # some people do, isn't it?
 551
 552   s/^spaced user $> \d+$/CALLER UID GID/;
 553
 554
 555   # ======== Exim's login ========
 556   # For messages received by the daemon, this is in the -H file, which some
 557   # tests inspect. For bounce messages, this will appear on the U= lines in
 558   # logs and also after Received: and in addresses. In one pipe test it appears
 559   # after "Running as:". It also appears in addresses, and in the names of lock
 560   # files.
 561
 562   s/U=$parm_eximuser/U=EXIMUSER/;
 563   s/user=$parm_eximuser/user=EXIMUSER/;
 564   s/login=$parm_eximuser/login=EXIMUSER/;
 565   s/Received: from $parm_eximuser /Received: from EXIMUSER /;
 566   s/Running as: $parm_eximuser/Running as: EXIMUSER/;
 567   s/\b$parm_eximuser@/EXIMUSER@/;
 568   s/\b$parm_eximuser\.lock\./EXIMUSER.lock./;
 569
 570   s/\beuid=$parm_exim_uid\b/euid=EXIM_UID/g;
 571   s/\begid=$parm_exim_gid\b/egid=EXIM_GID/g;
 572
 573   s/\buid=$parm_exim_uid\b/uid=EXIM_UID/g;
 574   s/\bgid=$parm_exim_gid\b/gid=EXIM_GID/g;
 575
 576   s/^$parm_eximuser $parm_exim_uid $parm_exim_gid/EXIMUSER EXIM_UID EXIM_GID/;
 577
 578
 579   # ======== General uids, gids, and pids ========
 580   # Note: this must come after munges for caller's and exim's uid/gid
 581
 582   # These are for systems where long int is 64
 583   s/\buid=4294967295/uid=-1/;
 584   s/\beuid=4294967295/euid=-1/;
 585   s/\bgid=4294967295/gid=-1/;
 586   s/\begid=4294967295/egid=-1/;
 587
 588   s/\bgid=\d+/gid=gggg/;
 589   s/\begid=\d+/egid=gggg/;
 590   s/\bpid=\d+/pid=pppp/;
 591   s/\buid=\d+/uid=uuuu/;
 592   s/\beuid=\d+/euid=uuuu/;
 593   s/set_process_info:\s+\d+/set_process_info: pppp/;
 594   s/queue run pid \d+/queue run pid ppppp/;
 595   s/process \d+ running as transport filter/process pppp running as transport filter/;
 596   s/process \d+ writing to transport filter/process pppp writing to transport filter/;
 597   s/reading pipe for subprocess \d+/reading pipe for subprocess pppp/;
 598   s/remote delivery process \d+ ended/remote delivery process pppp ended/;
 599
 600   # Pid in temp file in appendfile transport
 601   s"test-mail/temp\.\d+\."test-mail/temp.pppp.";
 602
 603   # Optional pid in log lines
 604   s/^(\d{4}-\d\d-\d\d\s\d\d:\d\d:\d\d)(\s[+-]\d\d\d\d|)(\s\[\d+\])/
 605     "$1$2 [" . new_value($3, "%s", \$next_pid) . "]"/gxe;
 606
 607   # Detect a daemon stderr line with a pid and save the pid for subsequent
 608   # removal from following lines.
 609   $spid = $1 if /^(\s*\d+) (?:listening|LOG: MAIN|(?:daemon_smtp_port|local_interfaces) overridden by)/;
 610   s/^$spid //;
 611
 612   # Queue runner waiting messages
 613   s/waiting for children of \d+/waiting for children of pppp/;
 614   s/waiting for (\S+) \(\d+\)/waiting for $1 (pppp)/;
 615
 616   # ======== Port numbers ========
 617   # Incoming port numbers may vary, but not in daemon startup line.
 618
 619   s/^Port: (\d+)/"Port: " . new_value($1, "%s", \$next_port)/e;
 620   s/\(port=(\d+)/"(port=" . new_value($1, "%s", \$next_port)/e;
 621
 622   # This handles "connection from" and the like, when the port is given
 623   if (!/listening for SMTP on/ && !/Connecting to/ && !/=>/ && !/->/
 624       && !/\*>/ && !/Connection refused/)
 625     {
 626     s/\[([a-z\d:]+|\d+(?:\.\d+){3})\]:(\d+)/"[".$1."]:".new_value($2,"%s",\$next_port)/ie;
 627     }
 628
 629   # Port in host address in spool file output from -Mvh
 630   s/^-host_address (.*)\.\d+/-host_address $1.9999/;
 631
 632
 633   # ======== Local IP addresses ========
 634   # The amount of space between "host" and the address in verification output
 635   # depends on the length of the host name. We therefore reduce it to one space
 636   # for all of them.
 637   # Also, the length of space at the end of the host line is dependent
 638   # on the length of the longest line, so strip it also on otherwise
 639   # un-rewritten lines like localhost
 640
 641   s/^\s+host\s(\S+)\s+(\S+)/  host $1 $2/;
 642   s/^\s+(host\s\S+\s\S+)\s+(port=.*)/  host $1 $2/;
 643   s/^\s+(host\s\S+\s\S+)\s+(?=MX=)/  $1 /;
 644   s/host\s\Q$parm_ipv4\E\s\[\Q$parm_ipv4\E\]/host ipv4.ipv4.ipv4.ipv4 [ipv4.ipv4.ipv4.ipv4]/;
 645   s/host\s\Q$parm_ipv6\E\s\[\Q$parm_ipv6\E\]/host ip6:ip6:ip6:ip6:ip6:ip6:ip6:ip6 [ip6:ip6:ip6:ip6:ip6:ip6:ip6:ip6]/;
 646   s/\b\Q$parm_ipv4\E\b/ip4.ip4.ip4.ip4/g;
 647   s/(^|\W)\K\Q$parm_ipv6\E/ip6:ip6:ip6:ip6:ip6:ip6:ip6:ip6/g;
 648   s/\b\Q$parm_ipv4r\E\b/ip4-reverse/g;
 649   s/(^|\W)\K\Q$parm_ipv6r\E/ip6-reverse/g;
 650   s/^(\s+host\s\S+\s+\[\S+\]) +$/$1 /;
 651
 652
 653   # ======== Test network IP addresses ========
 654   s/(\b|_)\Q$parm_ipv4_test_net\E(?=\.\d+\.\d+\.\d+\b|_|\.rbl|\.in-addr|\.test\.again\.dns)/$1V4NET/g;
 655   s/\b\Q$parm_ipv6_test_net\E(?=:[\da-f]+:[\da-f]+:[\da-f]+)/V6NET/gi;
 656
 657
 658   # ======== IP error numbers and messages ========
 659   # These vary between operating systems
 660   s/Can't assign requested address/Network Error/;
 661   s/Cannot assign requested address/Network Error/;
 662   s/Operation timed out/Connection timed out/;
 663   s/Address family not supported by protocol family/Network Error/;
 664   s/Network is unreachable/Network Error/;
 665   s/Invalid argument/Network Error/;
 666
 667   s/\(\d+\): Network/(dd): Network/;
 668   s/\(\d+\): Connection refused/(dd): Connection refused/;
 669   s/\(\d+\): Connection timed out/(dd): Connection timed out/;
 670   s/\d+ 65 Connection refused/dd 65 Connection refused/;
 671   s/\d+ 321 Connection timed out/dd 321 Connection timed out/;
 672
 673
 674   # ======== Other error numbers ========
 675   s/errno=\d+/errno=dd/g;
 676
 677
 678   # ======== Output from ls ========
 679   # Different operating systems use different spacing on long output
 680   #s/ +/ /g if /^[-rwd]{10} /;
 681   # (Bug 1226) SUSv3 allows a trailing printable char for modified access method control.
 682   # Handle only the Gnu and MacOS space, dot, plus and at-sign.  A full [[:graph:]]
 683   # unfortunately matches a non-ls linefull of dashes.
 684   # Allow the case where we've already picked out the file protection bits.
 685   if (s/^([-d](?:[-r][-w][-SsTtx]){3})[.+@]?( +|$)/$1$2/) {
 686     s/ +/ /g;
 687   }
 688
 689
 690   # ======== Message sizes =========
 691   # Message sizes vary, owing to different logins and host names that get
 692   # automatically inserted. I can't think of any way of even approximately
 693   # comparing these.
 694
 695   s/([\s,])S=\d+\b/$1S=sss/;
 696   s/:S\d+\b/:Ssss/;
 697   s/^(\s*\d+m\s+)\d+(\s+[a-z0-9-]{16} <)/$1sss$2/i if $is_stdout;
 698   s/\sSIZE=\d+\b/ SIZE=ssss/;
 699   s/\ssize=\d+\b/ size=sss/ if $is_stderr;
 700   s/old size = \d+\b/old size = sssss/;
 701   s/message size = \d+\b/message size = sss/;
 702   s/this message = \d+\b/this message = sss/;
 703   s/Size of headers = \d+/Size of headers = sss/;
 704   s/sum=(?!0)\d+/sum=dddd/;
 705   s/(?<=sum=dddd )count=(?!0)\d+\b/count=dd/;
 706   s/(?<=sum=0 )count=(?!0)\d+\b/count=dd/;
 707   s/,S is \d+\b/,S is ddddd/;
 708   s/\+0100,\d+;/+0100,ddd;/;
 709   s/\(\d+ bytes written\)/(ddd bytes written)/;
 710   s/added '\d+ 1'/added 'ddd 1'/;
 711   s/Received\s+\d+/Received               nnn/;
 712   s/Delivered\s+\d+/Delivered              nnn/;
 713
 714
 715   # ======== Values in spool space failure message ========
 716   s/space=\d+ inodes=[+-]?\d+/space=xxxxx inodes=xxxxx/;
 717
 718
 719   # ======== Filter sizes ========
 720   # The sizes of filter files may vary because of the substitution of local
 721   # filenames, logins, etc.
 722
 723   s/^\d+(?= bytes read from )/ssss/;
 724
 725
 726   # ======== OpenSSL error messages ========
 727   # Different releases of the OpenSSL libraries seem to give different error
 728   # numbers, or handle specific bad conditions in different ways, leading to
 729   # different wording in the error messages, so we cannot compare them.
 730
 731   s/(TLS error on connection (?:from|to) .*? \(SSL_\w+\): error:)(.*)/$1 <<detail omitted>>/;
 732
 733   # ======== Maildir things ========
 734   # timestamp output in maildir processing
 735   s/(timestamp=|\(timestamp_only\): )\d+/$1ddddddd/g;
 736
 737   # maildir delivery files appearing in log lines (in cases of error)
 738   s/writing to(?: file)? tmp\/\d+\.[^.]+\.(\S+)/writing to tmp\/MAILDIR.$1/;
 739
 740   s/renamed tmp\/\d+\.[^.]+\.(\S+) as new\/\d+\.[^.]+\.(\S+)/renamed tmp\/MAILDIR.$1 as new\/MAILDIR.$1/;
 741
 742   # Maildir file names in general
 743   s/\b\d+\.H\d+P\d+\b/dddddddddd.HddddddPddddd/;
 744
 745   # Maildirsize data
 746   while (/^\d+S,\d+C\s*$/)
 747     {
 748     print MUNGED;
 749     while (<IN>)
 750       {
 751       last if !/^\d+ \d+\s*$/;
 752       print MUNGED "ddd d\n";
 753       }
 754     last if !defined $_;
 755     }
 756   last if !defined $_;
 757
 758
 759   # ======== Output from the "fd" program about open descriptors ========
 760   # The statuses seem to be different on different operating systems, but
 761   # at least we'll still be checking the number of open fd's.
 762
 763   s/max fd = \d+/max fd = dddd/;
 764   s/status=0 RDONLY/STATUS/g;
 765   s/status=1 WRONLY/STATUS/g;
 766   s/status=2 RDWR/STATUS/g;
 767
 768
 769   # ======== Contents of spool files ========
 770   # A couple of tests dump the contents of the -H file. The length fields
 771   # will be wrong because of different user names, etc.
 772   s/^\d\d\d(?=[PFS*])/ddd/;
 773
 774
 775   # ========= Exim lookups ==================
 776   # Lookups have a char which depends on the number of lookup types compiled in,
 777   # in stderr output.  Replace with a "0".  Recognising this while avoiding
 778   # other output is fragile; perhaps the debug output should be revised instead.
 779   s%(?<!sqlite)(?<!lsearch\*@)(?<!lsearch\*)(?<!lsearch)[0-?]TESTSUITE/aux-fixed/%0TESTSUITE/aux-fixed/%g;
 780
 781   # ==========================================================
 782   # Some munging is specific to the specific file types
 783
 784   # ======== stdout ========
 785
 786   if ($is_stdout)
 787     {
 788     # Skip translate_ip_address and use_classresources in -bP output because
 789     # they aren't always there.
 790
 791     next if /translate_ip_address =/;
 792     next if /use_classresources/;
 793
 794     # In certain filter tests, remove initial filter lines because they just
 795     # clog up by repetition.
 796
 797     if ($rmfiltertest)
 798       {
 799       next if /^(Sender\staken\sfrom|
 800                  Return-path\scopied\sfrom|
 801                  Sender\s+=|
 802                  Recipient\s+=)/x;
 803       if (/^Testing \S+ filter/)
 804         {
 805         $_ = <IN>;    # remove blank line
 806         next;
 807         }
 808       }
 809     }
 810
 811   # ======== stderr ========
 812
 813   elsif ($is_stderr)
 814     {
 815     # The very first line of debugging output will vary
 816
 817     s/^Exim version .*/Exim version x.yz ..../;
 818
 819     # Debugging lines for Exim terminations
 820
 821     s/(?<=^>>>>>>>>>>>>>>>> Exim pid=)\d+(?= terminating)/pppp/;
 822
 823     # IP address lookups use gethostbyname() when IPv6 is not supported,
 824     # and gethostbyname2() or getipnodebyname() when it is.
 825
 826     s/\bgethostbyname2?|\bgetipnodebyname/get[host|ipnode]byname[2]/;
 827
 828     # drop gnutls version strings
 829     next if /GnuTLS compile-time version: \d+[\.\d]+$/;
 830     next if /GnuTLS runtime version: \d+[\.\d]+$/;
 831
 832     # drop openssl version strings
 833     next if /OpenSSL compile-time version: OpenSSL \d+[\.\da-z]+/;
 834     next if /OpenSSL runtime version: OpenSSL \d+[\.\da-z]+/;
 835
 836     # drop lookups
 837     next if /^Lookups \(built-in\):/;
 838     next if /^Loading lookup modules from/;
 839     next if /^Loaded \d+ lookup modules/;
 840     next if /^Total \d+ lookups/;
 841
 842     # drop compiler information
 843     next if /^Compiler:/;
 844
 845     # and the ugly bit
 846     # different libraries will have different numbers (possibly 0) of follow-up
 847     # lines, indenting with more data
 848     if (/^Library version:/) {
 849       while (1) {
 850         $_ = <IN>;
 851         next if /^\s/;
 852         goto RESET_AFTER_EXTRA_LINE_READ;
 853       }
 854     }
 855
 856     # drop other build-time controls emitted for debugging
 857     next if /^WHITELIST_D_MACROS:/;
 858     next if /^TRUSTED_CONFIG_LIST:/;
 859
 860     # As of Exim 4.74, we log when a setgid fails; because we invoke Exim
 861     # with -be, privileges will have been dropped, so this will always
 862     # be the case
 863     next if /^changing group to \d+ failed: Operation not permitted/;
 864
 865     # We might not keep this check; rather than change all the tests, just
 866     # ignore it as long as it succeeds; then we only need to change the
 867     # TLS tests where tls_require_ciphers has been set.
 868     if (m{^changed uid/gid: calling tls_validate_require_cipher}) {
 869       my $discard = <IN>;
 870       next;
 871     }
 872     next if /^tls_validate_require_cipher child \d+ ended: status=0x0/;
 873
 874     # We invoke Exim with -D, so we hit this new messag as of Exim 4.73:
 875     next if /^macros_trusted overridden to true by whitelisting/;
 876
 877     # We have to omit the localhost ::1 address so that all is well in
 878     # the IPv4-only case.
 879
 880     print MUNGED "MUNGED: ::1 will be omitted in what follows\n"
 881       if (/looked up these IP addresses/);
 882     next if /name=localhost address=::1/;
 883
 884     # drop pdkim debugging header
 885     next if /^PDKIM <<<<<<<<<<<<<<<<<<<<<<<<<<<<<+$/;
 886
 887     # Various other IPv6 lines must be omitted too
 888
 889     next if /using host_fake_gethostbyname for \S+ \(IPv6\)/;
 890     next if /get\[host\|ipnode\]byname\[2\]\(af=inet6\)/;
 891     next if /DNS lookup of \S+ \(AAAA\) using fakens/;
 892     next if / in dns_ipv4_lookup?/;
 893
 894     if (/DNS lookup of \S+ \(AAAA\) gave NO_DATA/)
 895       {
 896       $_= <IN>;     # Gets "returning DNS_NODATA"
 897       next;
 898       }
 899
 900     # Skip tls_advertise_hosts and hosts_require_tls checks when the options
 901     # are unset, because tls ain't always there.
 902
 903     next if /in\s(?:tls_advertise_hosts\?|hosts_require_tls\?)
 904                 \sno\s\(option\sunset\)/x;
 905
 906     # Skip auxiliary group lists because they will vary.
 907
 908     next if /auxiliary group list:/;
 909
 910     # Skip "extracted from gecos field" because the gecos field varies
 911
 912     next if /extracted from gecos field/;
 913
 914     # Skip "waiting for data on socket" and "read response data: size=" lines
 915     # because some systems pack more stuff into packets than others.
 916
 917     next if /waiting for data on socket/;
 918     next if /read response data: size=/;
 919
 920     # If Exim is compiled with readline support but it can't find the library
 921     # to load, there will be an extra debug line. Omit it.
 922
 923     next if /failed to load readline:/;
 924
 925     # Some DBM libraries seem to make DBM files on opening with O_RDWR without
 926     # O_CREAT; other's don't. In the latter case there is some debugging output
 927     # which is not present in the former. Skip the relevant lines (there are
 928     # two of them).
 929
 930     if (/TESTSUITE\/spool\/db\/\S+ appears not to exist: trying to create/)
 931       {
 932       $_ = <IN>;
 933       next;
 934       }
 935
 936     # Some tests turn on +expand debugging to check on expansions.
 937     # Unfortunately, the Received: expansion varies, depending on whether TLS
 938     # is compiled or not. So we must remove the relevant debugging if it is.
 939
 940     if (/^condition: def:tls_cipher/)
 941       {
 942       while (<IN>) { last if /^condition: def:sender_address/; }
 943       }
 944     elsif (/^expanding: Received: /)
 945       {
 946       while (<IN>) { last if !/^\s/; }
 947       }
 948
 949     # When Exim is checking the size of directories for maildir, it uses
 950     # the check_dir_size() function to scan directories. Of course, the order
 951     # of the files that are obtained using readdir() varies from system to
 952     # system. We therefore buffer up debugging lines from check_dir_size()
 953     # and sort them before outputting them.
 954
 955     if (/^check_dir_size:/ || /^skipping TESTSUITE\/test-mail\//)
 956       {
 957       push @saved, $_;
 958       }
 959     else
 960       {
 961       if (@saved > 0)
 962         {
 963         print MUNGED "MUNGED: the check_dir_size lines have been sorted " .
 964           "to ensure consistency\n";
 965         @saved = sort(@saved);
 966         print MUNGED @saved;
 967         @saved = ();
 968         }
 969
 970       # Skip some lines that Exim puts out at the start of debugging output
 971       # because they will be different in different binaries.
 972
 973       print MUNGED
 974         unless (/^Berkeley DB: / ||
 975                 /^Probably (?:Berkeley DB|ndbm|GDBM)/ ||
 976                 /^Authenticators:/ ||
 977                 /^Lookups:/ ||
 978                 /^Support for:/ ||
 979                 /^Routers:/ ||
 980                 /^Transports:/ ||
 981                 /^log selectors =/ ||
 982                 /^cwd=/ ||
 983                 /^Fixed never_users:/ ||
 984                 /^Size of off_t:/
 985                 );
 986       }
 987
 988     next;
 989     }
 990
 991   # ======== All files other than stderr ========
 992
 993   print MUNGED;
 994   }
 995
 996 close(IN);
 997 return $yield;
 998 }
 999
1000
1001
1002
1003 ##################################################
1004 #        Subroutine to interact with caller      #
1005 ##################################################
1006
1007 # Arguments: [0] the prompt string
1008 #            [1] if there is a U in the prompt and $force_update is true
1009 # Returns:   nothing (it sets $_)
1010
1011 sub interact{
1012 print $_[0];
1013 if ($_[1]) { $_ = "u"; print "... update forced\n"; }
1014   else { $_ = <T>; }
1015 }
1016
1017
1018
1019
1020 ##################################################
1021 #    Subroutine to compare one output file       #
1022 ##################################################
1023
1024 # When an Exim server is part of the test, its output is in separate files from
1025 # an Exim client. The server data is concatenated with the client data as part
1026 # of the munging operation.
1027 #
1028 # Arguments:  [0] the name of the main raw output file
1029 #             [1] the name of the server raw output file or undef
1030 #             [2] where to put the munged copy
1031 #             [3] the name of the saved file
1032 #             [4] TRUE if this is a log file whose deliveries must be sorted
1033 #             [5] optionally, a custom munge command
1034 #
1035 # Returns:    0 comparison succeeded or differences to be ignored
1036 #             1 comparison failed; files may have been updated (=> re-compare)
1037 #
1038 # Does not return if the user replies "Q" to a prompt.
1039
1040 sub check_file{
1041 my($rf,$rsf,$mf,$sf,$sortfile,$extra) = @_;
1042
1043 # If there is no saved file, the raw files must either not exist, or be
1044 # empty. The test ! -s is TRUE if the file does not exist or is empty.
1045
1046 if (! -e $sf)
1047   {
1048   return 0 if (! -s $rf && (! defined $rsf || ! -s $rsf));
1049
1050   print "\n";
1051   print "** $rf is not empty\n" if (-s $rf);
1052   print "** $rsf is not empty\n" if (defined $rsf && -s $rsf);
1053
1054   for (;;)
1055     {
1056     print "Continue, Show, or Quit? [Q] ";
1057     $_ = <T>;
1058     tests_exit(1) if /^q?$/i;
1059     return 0 if /^c$/i;
1060     last if (/^s$/);
1061     }
1062
1063   foreach $f ($rf, $rsf)
1064     {
1065     if (defined $f && -s $f)
1066       {
1067       print "\n";
1068       print "------------ $f -----------\n"
1069         if (defined $rf && -s $rf && defined $rsf && -s $rsf);
1070       system("$more '$f'");
1071       }
1072     }
1073
1074   print "\n";
1075   for (;;)
1076     {
1077     interact("Continue, Update & retry, Quit? [Q] ", $force_update);
1078     tests_exit(1) if /^q?$/i;
1079     return 0 if /^c$/i;
1080     last if (/^u$/i);
1081     }
1082   }
1083
1084 # Control reaches here if either (a) there is a saved file ($sf), or (b) there
1085 # was a request to create a saved file. First, create the munged file from any
1086 # data that does exist.
1087
1088 open(MUNGED, ">$mf") || tests_exit(-1, "Failed to open $mf: $!");
1089 my($truncated) = munge($rf, $extra) if -e $rf;
1090 if (defined $rsf && -e $rsf)
1091   {
1092   print MUNGED "\n******** SERVER ********\n";
1093   $truncated |= munge($rsf, $extra);
1094   }
1095 close(MUNGED);
1096
1097 # If a saved file exists, do the comparison. There are two awkward cases:
1098 #
1099 # If "*** truncated ***" was found in the new file, it means that a log line
1100 # was overlong, and truncated. The problem is that it may be truncated at
1101 # different points on different systems, because of different user name
1102 # lengths. We reload the file and the saved file, and remove lines from the new
1103 # file that precede "*** truncated ***" until we reach one that matches the
1104 # line that precedes it in the saved file.
1105 #
1106 # If $sortfile is set, we are dealing with a mainlog file where the deliveries
1107 # for an individual message might vary in their order from system to system, as
1108 # a result of parallel deliveries. We load the munged file and sort sequences
1109 # of delivery lines.
1110
1111 if (-e $sf)
1112   {
1113   # Deal with truncated text items
1114
1115   if ($truncated)
1116     {
1117     my(@munged, @saved, $i, $j, $k);
1118
1119     open(MUNGED, "$mf") || tests_exit(-1, "Failed to open $mf: $!");
1120     @munged = <MUNGED>;
1121     close(MUNGED);
1122     open(SAVED, "$sf") || tests_exit(-1, "Failed to open $sf: $!");
1123     @saved = <SAVED>;
1124     close(SAVED);
1125
1126     $j = 0;
1127     for ($i = 0; $i < @munged; $i++)
1128       {
1129       if ($munged[$i] =~ /\*\*\* truncated \*\*\*/)
1130         {
1131         for (; $j < @saved; $j++)
1132           { last if $saved[$j] =~ /\*\*\* truncated \*\*\*/; }
1133         last if $j >= @saved;     # not found in saved
1134
1135         for ($k = $i - 1; $k >= 0; $k--)
1136           { last if $munged[$k] eq $saved[$j - 1]; }
1137
1138         last if $k <= 0;          # failed to find previous match
1139         splice @munged, $k + 1, $i - $k - 1;
1140         $i = $k + 1;
1141         }
1142       }
1143
1144     open(MUNGED, ">$mf") || tests_exit(-1, "Failed to open $mf: $!");
1145     for ($i = 0; $i < @munged; $i++)
1146       { print MUNGED $munged[$i]; }
1147     close(MUNGED);
1148     }
1149
1150   # Deal with log sorting
1151
1152   if ($sortfile)
1153     {
1154     my(@munged, $i, $j);
1155
1156     open(MUNGED, "$mf") || tests_exit(-1, "Failed to open $mf: $!");
1157     @munged = <MUNGED>;
1158     close(MUNGED);
1159
1160     for ($i = 0; $i < @munged; $i++)
1161       {
1162       if ($munged[$i] =~ /^[-\d]{10}\s[:\d]{8}\s[-A-Za-z\d]{16}\s[-=*]>/)
1163         {
1164         for ($j = $i + 1; $j < @munged; $j++)
1165           {
1166           last if $munged[$j] !~
1167             /^[-\d]{10}\s[:\d]{8}\s[-A-Za-z\d]{16}\s[-=*]>/;
1168           }
1169         @temp = splice(@munged, $i, $j - $i);
1170         @temp = sort(@temp);
1171         splice(@munged, $i, 0, @temp);
1172         }
1173       }
1174
1175     open(MUNGED, ">$mf") || tests_exit(-1, "Failed to open $mf: $!");
1176     print MUNGED "**NOTE: The delivery lines in this file have been sorted.\n";
1177     for ($i = 0; $i < @munged; $i++)
1178       { print MUNGED $munged[$i]; }
1179     close(MUNGED);
1180     }
1181
1182   # Do the comparison
1183
1184   return 0 if (system("$cf '$mf' '$sf' >test-cf") == 0);
1185
1186   # Handle comparison failure
1187
1188   print "** Comparison of $mf with $sf failed";
1189   system("$more test-cf");
1190
1191   print "\n";
1192   for (;;)
1193     {
1194     interact("Continue, Retry, Update & retry, Quit? [Q] ", $force_update);
1195     tests_exit(1) if /^q?$/i;
1196     return 0 if /^c$/i;
1197     return 1 if /^r$/i;
1198     last if (/^u$/i);
1199     }
1200   }
1201
1202 # Update or delete the saved file, and give the appropriate return code.
1203
1204 if (-s $mf)
1205   { tests_exit(-1, "Failed to cp $mf $sf") if system("cp '$mf' '$sf'") != 0; }
1206 else
1207   { tests_exit(-1, "Failed to unlink $sf") if !unlink($sf); }
1208
1209 return 1;
1210 }
1211
1212
1213
1214 ##################################################
1215 # Custom munges
1216 # keyed by name of munge; value is a ref to a hash
1217 # which is keyed by file, value a string to look for.
1218 # Usable files are:
1219 #  paniclog, rejectlog, mainlog, stdout, stderr, msglog, mail
1220 # Search strings starting with 's' do substitutions;
1221 # with '/' do line-skips.
1222 ##################################################
1223 $munges =
1224   { 'dnssec' =>
1225     { 'stderr' => '/^Reverse DNS security status: unverified\n/', },
1226
1227     'gnutls_unexpected' =>
1228     { 'mainlog' => '/\(recv\): A TLS packet with unexpected length was received./', },
1229
1230     'gnutls_handshake' =>
1231     { 'mainlog' => 's/\(gnutls_handshake\): Error in the push function/\(gnutls_handshake\): A TLS packet with unexpected length was received/', },
1232
1233   };
1234
1235
1236 ##################################################
1237 #    Subroutine to check the output of a test    #
1238 ##################################################
1239
1240 # This function is called when the series of subtests is complete. It makes
1241 # use of check_file(), whose arguments are:
1242 #
1243 #  [0] the name of the main raw output file
1244 #  [1] the name of the server raw output file or undef
1245 #  [2] where to put the munged copy
1246 #  [3] the name of the saved file
1247 #  [4] TRUE if this is a log file whose deliveries must be sorted
1248 #  [5] an optional custom munge command
1249 #
1250 # Arguments: Optionally, name of a custom munge to run.
1251 # Returns:   0 if the output compared equal
1252 #            1 if re-run needed (files may have been updated)
1253
1254 sub check_output{
1255 my($mungename) = $_[0];
1256 my($yield) = 0;
1257 my($munge) = $munges->{$mungename} if defined $mungename;
1258
1259 $yield = 1 if check_file("spool/log/paniclog",
1260                        "spool/log/serverpaniclog",
1261                        "test-paniclog-munged",
1262                        "paniclog/$testno", 0,
1263                        $munge->{'paniclog'});
1264
1265 $yield = 1 if check_file("spool/log/rejectlog",
1266                        "spool/log/serverrejectlog",
1267                        "test-rejectlog-munged",
1268                        "rejectlog/$testno", 0,
1269                        $munge->{'rejectlog'});
1270
1271 $yield = 1 if check_file("spool/log/mainlog",
1272                        "spool/log/servermainlog",
1273                        "test-mainlog-munged",
1274                        "log/$testno", $sortlog,
1275                        $munge->{'mainlog'});
1276
1277 if (!$stdout_skip)
1278   {
1279   $yield = 1 if check_file("test-stdout",
1280                        "test-stdout-server",
1281                        "test-stdout-munged",
1282                        "stdout/$testno", 0,
1283                        $munge->{'stdout'});
1284   }
1285
1286 if (!$stderr_skip)
1287   {
1288   $yield = 1 if check_file("test-stderr",
1289                        "test-stderr-server",
1290                        "test-stderr-munged",
1291                        "stderr/$testno", 0,
1292                        $munge->{'stderr'});
1293   }
1294
1295 # Compare any delivered messages, unless this test is skipped.
1296
1297 if (! $message_skip)
1298   {
1299   my($msgno) = 0;
1300
1301   # Get a list of expected mailbox files for this script. We don't bother with
1302   # directories, just the files within them.
1303
1304   foreach $oldmail (@oldmails)
1305     {
1306     next unless $oldmail =~ /^mail\/$testno\./;
1307     print ">> EXPECT $oldmail\n" if $debug;
1308     $expected_mails{$oldmail} = 1;
1309     }
1310
1311   # If there are any files in test-mail, compare them. Note that "." and
1312   # ".." are automatically omitted by list_files_below().
1313
1314   @mails = list_files_below("test-mail");
1315
1316   foreach $mail (@mails)
1317     {
1318     next if $mail eq "test-mail/oncelog";
1319
1320     $saved_mail = substr($mail, 10);               # Remove "test-mail/"
1321     $saved_mail =~ s/^$parm_caller(\/|$)/CALLER/;  # Convert caller name
1322
1323     if ($saved_mail =~ /(\d+\.[^.]+\.)/)
1324       {
1325       $msgno++;
1326       $saved_mail =~ s/(\d+\.[^.]+\.)/$msgno./gx;
1327       }
1328
1329     print ">> COMPARE $mail mail/$testno.$saved_mail\n" if $debug;
1330     $yield = 1 if check_file($mail, undef, "test-mail-munged",
1331       "mail/$testno.$saved_mail", 0,
1332       $munge->{'mail'});
1333     delete $expected_mails{"mail/$testno.$saved_mail"};
1334     }
1335
1336   # Complain if not all expected mails have been found
1337
1338   if (scalar(keys %expected_mails) != 0)
1339     {
1340     foreach $key (keys %expected_mails)
1341       { print "** no test file found for $key\n"; }
1342
1343     for (;;)
1344       {
1345       interact("Continue, Update & retry, or Quit? [Q] ", $force_update);
1346       tests_exit(1) if /^q?$/i;
1347       last if /^c$/i;
1348
1349       # For update, we not only have to unlink the file, but we must also
1350       # remove it from the @oldmails vector, as otherwise it will still be
1351       # checked for when we re-run the test.
1352
1353       if (/^u$/i)
1354         {
1355         foreach $key (keys %expected_mails)
1356           {
1357           my($i);
1358           tests_exit(-1, "Failed to unlink $key") if !unlink("$key");
1359           for ($i = 0; $i < @oldmails; $i++)
1360             {
1361             if ($oldmails[$i] eq $key)
1362               {
1363               splice @oldmails, $i, 1;
1364               last;
1365               }
1366             }
1367           }
1368         last;
1369         }
1370       }
1371     }
1372   }
1373
1374 # Compare any remaining message logs, unless this test is skipped.
1375
1376 if (! $msglog_skip)
1377   {
1378   # Get a list of expected msglog files for this test
1379
1380   foreach $oldmsglog (@oldmsglogs)
1381     {
1382     next unless $oldmsglog =~ /^$testno\./;
1383     $expected_msglogs{$oldmsglog} = 1;
1384     }
1385
1386   # If there are any files in spool/msglog, compare them. However, we have
1387   # to munge the file names because they are message ids, which are
1388   # time dependent.
1389
1390   if (opendir(DIR, "spool/msglog"))
1391     {
1392     @msglogs = sort readdir(DIR);
1393     closedir(DIR);
1394
1395     foreach $msglog (@msglogs)
1396       {
1397       next if ($msglog eq "." || $msglog eq ".." || $msglog eq "CVS");
1398       ($munged_msglog = $msglog) =~
1399         s/((?:[^\W_]{6}-){2}[^\W_]{2})
1400           /new_value($1, "10Hm%s-0005vi-00", \$next_msgid)/egx;
1401       $yield = 1 if check_file("spool/msglog/$msglog", undef,
1402         "test-msglog-munged", "msglog/$testno.$munged_msglog", 0,
1403         $munge->{'msglog'});
1404       delete $expected_msglogs{"$testno.$munged_msglog"};
1405       }
1406     }
1407
1408   # Complain if not all expected msglogs have been found
1409
1410   if (scalar(keys %expected_msglogs) != 0)
1411     {
1412     foreach $key (keys %expected_msglogs)
1413       {
1414       print "** no test msglog found for msglog/$key\n";
1415       ($msgid) = $key =~ /^\d+\.(.*)$/;
1416       foreach $cachekey (keys %cache)
1417         {
1418         if ($cache{$cachekey} eq $msgid)
1419           {
1420           print "** original msgid $cachekey\n";
1421           last;
1422           }
1423         }
1424       }
1425
1426     for (;;)
1427       {
1428       interact("Continue, Update, or Quit? [Q] ", $force_update);
1429       tests_exit(1) if /^q?$/i;
1430       last if /^c$/i;
1431       if (/^u$/i)
1432         {
1433         foreach $key (keys %expected_msglogs)
1434           {
1435           tests_exit(-1, "Failed to unlink msglog/$key")
1436             if !unlink("msglog/$key");
1437           }
1438         last;
1439         }
1440       }
1441     }
1442   }
1443
1444 return $yield;
1445 }
1446
1447
1448
1449 ##################################################
1450 #     Subroutine to run one "system" command     #
1451 ##################################################
1452
1453 # We put this in a subroutine so that the command can be reflected when
1454 # debugging.
1455 #
1456 # Argument: the command to be run
1457 # Returns:  nothing
1458
1459 sub run_system {
1460 my($cmd) = $_[0];
1461 if ($debug)
1462   {
1463   my($prcmd) = $cmd;
1464   $prcmd =~ s/; /;\n>> /;
1465   print ">> $prcmd\n";
1466   }
1467 system("$cmd");
1468 }
1469
1470
1471
1472 ##################################################
1473 #      Subroutine to run one script command      #
1474 ##################################################
1475
1476 # The <SCRIPT> file is open for us to read an optional return code line,
1477 # followed by the command line and any following data lines for stdin. The
1478 # command line can be continued by the use of \. Data lines are not continued
1479 # in this way. In all lines, the following substutions are made:
1480 #
1481 # DIR    => the current directory
1482 # CALLER => the caller of this script
1483 #
1484 # Arguments: the current test number
1485 #            reference to the subtest number, holding previous value
1486 #            reference to the expected return code value
1487 #            reference to where to put the command name (for messages)
1488 #            auxilliary information returned from a previous run
1489 #
1490 # Returns:   0 the commmand was executed inline, no subprocess was run
1491 #            1 a non-exim command was run and waited for
1492 #            2 an exim command was run and waited for
1493 #            3 a command was run and not waited for (daemon, server, exim_lock)
1494 #            4 EOF was encountered after an initial return code line
1495 # Optionally alse a second parameter, a hash-ref, with auxilliary information:
1496 #            exim_pid: pid of a run process
1497 #            munge: name of a post-script results munger
1498
1499 sub run_command{
1500 my($testno) = $_[0];
1501 my($subtestref) = $_[1];
1502 my($commandnameref) = $_[3];
1503 my($aux_info) = $_[4];
1504 my($yield) = 1;
1505
1506 if (/^(\d+)\s*$/)                # Handle unusual return code
1507   {
1508   my($r) = $_[2];
1509   $$r = $1 << 8;
1510   $_ = <SCRIPT>;
1511   return 4 if !defined $_;       # Missing command
1512   $lineno++;
1513   }
1514
1515 chomp;
1516 $wait_time = 0;
1517
1518 # Handle concatenated command lines
1519
1520 s/\s+$//;
1521 while (substr($_, -1) eq"\\")
1522   {
1523   my($temp);
1524   $_ = substr($_, 0, -1);
1525   chomp($temp = <SCRIPT>);
1526   if (defined $temp)
1527     {
1528     $lineno++;
1529     $temp =~ s/\s+$//;
1530     $temp =~ s/^\s+//;
1531     $_ .= $temp;
1532     }
1533   }
1534
1535 # Do substitutions
1536
1537 do_substitute($testno);
1538 if ($debug) { printf ">> $_\n"; }
1539
1540 # Pass back the command name (for messages)
1541
1542 ($$commandnameref) = /^(\S+)/;
1543
1544 # Here follows code for handling the various different commands that are
1545 # supported by this script. The first group of commands are all freestanding
1546 # in that they share no common code and are not followed by any data lines.
1547
1548
1549 ###################
1550 ###################
1551
1552 # The "dbmbuild" command runs exim_dbmbuild. This is used both to test the
1553 # utility and to make DBM files for testing DBM lookups.
1554
1555 if (/^dbmbuild\s+(\S+)\s+(\S+)/)
1556   {
1557   run_system("(./eximdir/exim_dbmbuild $parm_cwd/$1 $parm_cwd/$2;" .
1558          "echo exim_dbmbuild exit code = \$?)" .
1559          ">>test-stdout");
1560   return 1;
1561   }
1562
1563
1564 # The "dump" command runs exim_dumpdb. On different systems, the output for
1565 # some types of dump may appear in a different order because it's just hauled
1566 # out of the DBM file. We can solve this by sorting. Ignore the leading
1567 # date/time, as it will be flattened later during munging.
1568
1569 if (/^dump\s+(\S+)/)
1570   {
1571   my($which) = $1;
1572   my(@temp);
1573   print ">> ./eximdir/exim_dumpdb $parm_cwd/spool $which\n" if $debug;
1574   open(IN, "./eximdir/exim_dumpdb $parm_cwd/spool $which |");
1575   @temp = <IN>;
1576   close(IN);
1577   if ($which eq "callout")
1578     {
1579     @temp = sort {
1580                  my($aa) = substr $a, 21;
1581                  my($bb) = substr $b, 21;
1582                  return $aa cmp $bb;
1583                  } @temp;
1584     }
1585   open(OUT, ">>test-stdout");
1586   print OUT "+++++++++++++++++++++++++++\n";
1587   print OUT @temp;
1588   close(OUT);
1589   return 1;
1590   }
1591
1592
1593 # The "echo" command is a way of writing comments to the screen.
1594
1595 if (/^echo\s+(.*)$/)
1596   {
1597   print "$1\n";
1598   return 0;
1599   }
1600
1601
1602 # The "exim_lock" command runs exim_lock in the same manner as "server",
1603 # but it doesn't use any input.
1604
1605 if (/^exim_lock\s+(.*)$/)
1606   {
1607   $cmd = "./eximdir/exim_lock $1 >>test-stdout";
1608   $server_pid = open SERVERCMD, "|$cmd" ||
1609     tests_exit(-1, "Failed to run $cmd\n");
1610
1611   # This gives the process time to get started; otherwise the next
1612   # process may not find it there when it expects it.
1613
1614   select(undef, undef, undef, 0.1);
1615   return 3;
1616   }
1617
1618
1619 # The "exinext" command runs exinext
1620
1621 if (/^exinext\s+(.*)/)
1622   {
1623   run_system("(./eximdir/exinext " .
1624     "-DEXIM_PATH=$parm_cwd/eximdir/exim " .
1625     "-C $parm_cwd/test-config $1;" .
1626     "echo exinext exit code = \$?)" .
1627     ">>test-stdout");
1628   return 1;
1629   }
1630
1631
1632 # The "exigrep" command runs exigrep on the current mainlog
1633
1634 if (/^exigrep\s+(.*)/)
1635   {
1636   run_system("(./eximdir/exigrep " .
1637     "$1 $parm_cwd/spool/log/mainlog;" .
1638     "echo exigrep exit code = \$?)" .
1639     ">>test-stdout");
1640   return 1;
1641   }
1642
1643
1644 # The "eximstats" command runs eximstats on the current mainlog
1645
1646 if (/^eximstats\s+(.*)/)
1647   {
1648   run_system("(./eximdir/eximstats " .
1649     "$1 $parm_cwd/spool/log/mainlog;" .
1650     "echo eximstats exit code = \$?)" .
1651     ">>test-stdout");
1652   return 1;
1653   }
1654
1655
1656 # The "gnutls" command makes a copy of saved GnuTLS parameter data in the
1657 # spool directory, to save Exim from re-creating it each time.
1658
1659 if (/^gnutls/)
1660   {
1661   my $gen_fn = "spool/gnutls-params-$gnutls_dh_bits_normal";
1662   run_system "sudo cp -p aux-fixed/gnutls-params $gen_fn;" .
1663          "sudo chown $parm_eximuser:$parm_eximgroup $gen_fn;" .
1664          "sudo chmod 0400 $gen_fn";
1665   return 1;
1666   }
1667
1668
1669 # The "killdaemon" command should ultimately follow the starting of any Exim
1670 # daemon with the -bd option. We kill with SIGINT rather than SIGTERM to stop
1671 # it outputting "Terminated" to the terminal when not in the background.
1672
1673 if (/^killdaemon/)
1674   {
1675   my $return_extra = {};
1676   if (exists $aux_info->{exim_pid})
1677     {
1678     $pid = $aux_info->{exim_pid};
1679     $return_extra->{exim_pid} = undef;
1680     print ">> killdaemon: recovered pid $pid\n" if $debug;
1681     if ($pid)
1682       {
1683       run_system("sudo /bin/kill -SIGINT $pid");
1684       wait;
1685       }
1686     } else {
1687     $pid = `cat $parm_cwd/spool/exim-daemon.*`;
1688     if ($pid)
1689       {
1690       run_system("sudo /bin/kill -SIGINT $pid");
1691       close DAEMONCMD;                                   # Waits for process
1692       }
1693     }
1694     run_system("sudo /bin/rm -f spool/exim-daemon.*");
1695   return (1, $return_extra);
1696   }
1697
1698
1699 # The "millisleep" command is like "sleep" except that its argument is in
1700 # milliseconds, thus allowing for a subsecond sleep, which is, in fact, all it
1701 # is used for.
1702
1703 elsif (/^millisleep\s+(.*)$/)
1704   {
1705   select(undef, undef, undef, $1/1000);
1706   return 0;
1707   }
1708
1709
1710 # The "munge" command selects one of a hardwired set of test-result modifications
1711 # to be made before result compares are run agains the golden set.  This lets
1712 # us account for test-system dependent things which only affect a few, but known,
1713 # test-cases.
1714 # Currently only the last munge takes effect.
1715
1716 if (/^munge\s+(.*)$/)
1717   {
1718   return (0, { munge => $1 });
1719   }
1720
1721
1722 # The "sleep" command does just that. For sleeps longer than 1 second we
1723 # tell the user what's going on.
1724
1725 if (/^sleep\s+(.*)$/)
1726   {
1727   if ($1 == 1)
1728     {
1729     sleep(1);
1730     }
1731   else
1732     {
1733     printf("  Test %d sleep $1 ", $$subtestref);
1734     for (1..$1)
1735       {
1736       print ".";
1737       sleep(1);
1738       }
1739     printf("\r  Test %d                            $cr", $$subtestref);
1740     }
1741   return 0;
1742   }
1743
1744
1745 # Various Unix management commands are recognized
1746
1747 if (/^(ln|ls|du|mkdir|mkfifo|touch|cp|cat)\s/ ||
1748     /^sudo (rmdir|rm|chown|chmod)\s/)
1749   {
1750   run_system("$_ >>test-stdout 2>>test-stderr");
1751   return 1;
1752   }
1753
1754
1755
1756 ###################
1757 ###################
1758
1759 # The next group of commands are also freestanding, but they are all followed
1760 # by data lines.
1761
1762
1763 # The "server" command starts up a script-driven server that runs in parallel
1764 # with the following exim command. Therefore, we want to run a subprocess and
1765 # not yet wait for it to complete. The waiting happens after the next exim
1766 # command, triggered by $server_pid being non-zero. The server sends its output
1767 # to a different file. The variable $server_opts, if not empty, contains
1768 # options to disable IPv4 or IPv6 if necessary.
1769
1770 if (/^server\s+(.*)$/)
1771   {
1772   $cmd = "./bin/server $server_opts $1 >>test-stdout-server";
1773   print ">> $cmd\n" if ($debug);
1774   $server_pid = open SERVERCMD, "|$cmd" || tests_exit(-1, "Failed to run $cmd");
1775   SERVERCMD->autoflush(1);
1776   print ">> Server pid is $server_pid\n" if $debug;
1777   while (<SCRIPT>)
1778     {
1779     $lineno++;
1780     last if /^\*{4}\s*$/;
1781     print SERVERCMD;
1782     }
1783   print SERVERCMD "++++\n"; # Send end to server; can't send EOF yet
1784                             # because close() waits for the process.
1785
1786   # This gives the server time to get started; otherwise the next
1787   # process may not find it there when it expects it.
1788
1789   select(undef, undef, undef, 0.5);
1790   return 3;
1791   }
1792
1793
1794 # The "write" command is a way of creating files of specific sizes for
1795 # buffering tests, or containing specific data lines from within the script
1796 # (rather than hold lots of little files). The "catwrite" command does the
1797 # same, but it also copies the lines to test-stdout.
1798
1799 if (/^(cat)?write\s+(\S+)(?:\s+(.*))?\s*$/)
1800   {
1801   my($cat) = defined $1;
1802   @sizes = ();
1803   @sizes = split /\s+/, $3 if defined $3;
1804   open FILE, ">$2" || tests_exit(-1, "Failed to open \"$2\": $!");
1805
1806   if ($cat)
1807     {
1808     open CAT, ">>test-stdout" ||
1809       tests_exit(-1, "Failed to open test-stdout: $!");
1810     print CAT "==========\n";
1811     }
1812
1813   if (scalar @sizes > 0)
1814     {
1815     # Pre-data
1816
1817     while (<SCRIPT>)
1818       {
1819       $lineno++;
1820       last if /^\+{4}\s*$/;
1821       print FILE;
1822       print CAT if $cat;
1823       }
1824
1825     # Sized data
1826
1827     while (scalar @sizes > 0)
1828       {
1829       ($count,$len,$leadin) = (shift @sizes) =~ /(\d+)x(\d+)(?:=(.*))?/;
1830       $leadin = "" if !defined $leadin;
1831       $leadin =~ s/_/ /g;
1832       $len -= length($leadin) + 1;
1833       while ($count-- > 0)
1834         {
1835         print FILE $leadin, "a" x $len, "\n";
1836         print CAT $leadin, "a" x $len, "\n" if $cat;
1837         }
1838       }
1839     }
1840
1841   # Post data, or only data if no sized data
1842
1843   while (<SCRIPT>)
1844     {
1845     $lineno++;
1846     last if /^\*{4}\s*$/;
1847     print FILE;
1848     print CAT if $cat;
1849     }
1850   close FILE;
1851
1852   if ($cat)
1853     {
1854     print CAT "==========\n";
1855     close CAT;
1856     }
1857
1858   return 0;
1859   }
1860
1861
1862 ###################
1863 ###################
1864
1865 # From this point on, script commands are implemented by setting up a shell
1866 # command in the variable $cmd. Shared code to run this command and handle its
1867 # input and output follows.
1868
1869 # The "client", "client-gnutls", and "client-ssl" commands run a script-driven
1870 # program that plays the part of an email client. We also have the availability
1871 # of running Perl for doing one-off special things. Note that all these
1872 # commands expect stdin data to be supplied.
1873
1874 if (/^client/ || /^(sudo\s+)?perl\b/)
1875   {
1876   s"client"./bin/client";
1877   $cmd = "$_ >>test-stdout 2>>test-stderr";
1878   }
1879
1880 # For the "exim" command, replace the text "exim" with the path for the test
1881 # binary, plus -D options to pass over various parameters, and a -C option for
1882 # the testing configuration file. When running in the test harness, Exim does
1883 # not drop privilege when -C and -D options are present. To run the exim
1884 # command as root, we use sudo.
1885
1886 elsif (/^([A-Z_]+=\S+\s+)?(\d+)?\s*(sudo\s+)?exim(_\S+)?\s+(.*)$/)
1887   {
1888   $args = $5;
1889   my($envset) = (defined $1)? $1      : "";
1890   my($sudo)   = (defined $3)? "sudo " : "";
1891   my($special)= (defined $4)? $4      : "";
1892   $wait_time  = (defined $2)? $2      : 0;
1893
1894   # Return 2 rather than 1 afterwards
1895
1896   $yield = 2;
1897
1898   # Update the test number
1899
1900   $$subtestref = $$subtestref + 1;
1901   printf("  Test %d       $cr", $$subtestref);
1902
1903   # Copy the configuration file, making the usual substitutions.
1904
1905   open (IN, "$parm_cwd/confs/$testno") ||
1906     tests_exit(-1, "Couldn't open $parm_cwd/confs/$testno: $!\n");
1907   open (OUT, ">test-config") ||
1908     tests_exit(-1, "Couldn't open test-config: $!\n");
1909   while (<IN>)
1910     {
1911     do_substitute($testno);
1912     print OUT;
1913     }
1914   close(IN);
1915   close(OUT);
1916
1917   # The string $msg1 in args substitutes the message id of the first
1918   # message on the queue, and so on. */
1919
1920   if ($args =~ /\$msg/)
1921     {
1922     my($listcmd) = "$parm_cwd/eximdir/exim -bp " .
1923                    "-DEXIM_PATH=$parm_cwd/eximdir/exim " .
1924                    "-C $parm_cwd/test-config |";
1925     print ">> Getting queue list from:\n>>    $listcmd\n" if ($debug);
1926     open (QLIST, $listcmd) || tests_exit(-1, "Couldn't run \"exim -bp\": $!\n");
1927     my(@msglist) = ();
1928     while (<QLIST>) { push (@msglist, $1) if /^\s*\d+[smhdw]\s+\S+\s+(\S+)/; }
1929     close(QLIST);
1930
1931     # Done backwards just in case there are more than 9
1932
1933     my($i);
1934     for ($i = @msglist; $i > 0; $i--) { $args =~ s/\$msg$i/$msglist[$i-1]/g; }
1935     if ( $args =~ /\$msg\d/ )
1936       {
1937       tests_exit(-1, "Not enough messages in spool, for test $testno line $lineno\n");
1938       }
1939     }
1940
1941   # If -d is specified in $optargs, remove it from $args; i.e. let
1942   # the command line for runtest override. Then run Exim.
1943
1944   $args =~ s/(?:^|\s)-d\S*// if $optargs =~ /(?:^|\s)-d/;
1945
1946   $cmd = "$envset$sudo$parm_cwd/eximdir/exim$special$optargs " .
1947          "-DEXIM_PATH=$parm_cwd/eximdir/exim$special " .
1948          "-C $parm_cwd/test-config $args " .
1949          ">>test-stdout 2>>test-stderr";
1950
1951   # If the command is starting an Exim daemon, we run it in the same
1952   # way as the "server" command above, that is, we don't want to wait
1953   # for the process to finish. That happens when "killdaemon" is obeyed later
1954   # in the script. We also send the stderr output to test-stderr-server. The
1955   # daemon has its log files put in a different place too (by configuring with
1956   # log_file_path). This requires the  directory to be set up in advance.
1957   #
1958   # There are also times when we want to run a non-daemon version of Exim
1959   # (e.g. a queue runner) with the server configuration. In this case,
1960   # we also define -DNOTDAEMON.
1961
1962   if ($cmd =~ /\s-DSERVER=server\s/ && $cmd !~ /\s-DNOTDAEMON\s/)
1963     {
1964     if ($debug) { printf ">> daemon: $cmd\n"; }
1965     run_system("sudo mkdir spool/log 2>/dev/null");
1966     run_system("sudo chown $parm_eximuser:$parm_eximgroup spool/log");
1967
1968     # Before running the command, convert the -bd option into -bdf so that an
1969     # Exim daemon doesn't double fork. This means that when we wait close
1970     # DAEMONCMD, it waits for the correct process. Also, ensure that the pid
1971     # file is written to the spool directory, in case the Exim binary was
1972     # built with PID_FILE_PATH pointing somewhere else.
1973
1974     $cmd =~ s!\s-bd\s! -bdf -oP $parm_cwd/spool/exim-daemon.pid !;
1975     print ">> |${cmd}-server\n" if ($debug);
1976     open DAEMONCMD, "|${cmd}-server" || tests_exit(-1, "Failed to run $cmd");
1977     DAEMONCMD->autoflush(1);
1978     while (<SCRIPT>) { $lineno++; last if /^\*{4}\s*$/; }   # Ignore any input
1979     select(undef, undef, undef, 0.3);             # Let the daemon get going
1980     return 3;                                     # Don't wait
1981     }
1982   elsif ($cmd =~ /\s-DSERVER=wait:(\d+)\s/)
1983     {
1984     my $listen_port = $1;
1985     my $waitmode_sock = new FileHandle;
1986     if ($debug) { printf ">> wait-mode daemon: $cmd\n"; }
1987     run_system("sudo mkdir spool/log 2>/dev/null");
1988     run_system("sudo chown $parm_eximuser:$parm_eximgroup spool/log");
1989
1990     my ($s_ip,$s_port) = ('127.0.0.1', $listen_port);
1991     my $sin = sockaddr_in($s_port, inet_aton($s_ip))
1992         or die "** Failed packing $s_ip:$s_port\n";
1993     socket($waitmode_sock, PF_INET, SOCK_STREAM, getprotobyname('tcp'))
1994         or die "** Unable to open socket $s_ip:$s_port: $!\n";
1995     setsockopt($waitmode_sock, SOL_SOCKET, SO_REUSEADDR, 1)
1996         or die "** Unable to setsockopt(SO_REUSEADDR): $!\n";
1997     bind($waitmode_sock, $sin)
1998         or die "** Unable to bind socket ($s_port): $!\n";
1999     listen($waitmode_sock, 5);
2000     my $pid = fork();
2001     if (not defined $pid) { die "** fork failed: $!\n" }
2002     if (not $pid) {
2003       close(STDIN);
2004       open(STDIN, "<&", $waitmode_sock) or die "** dup sock to stdin failed: $!\n";
2005       close($waitmode_sock);
2006       print "[$$]>> ${cmd}-server\n" if ($debug);
2007       exec "exec ${cmd}-server";
2008       exit(1);
2009     }
2010     while (<SCRIPT>) { $lineno++; last if /^\*{4}\s*$/; }   # Ignore any input
2011     select(undef, undef, undef, 0.3);             # Let the daemon get going
2012     return (3, { exim_pid => $pid });             # Don't wait
2013     }
2014   }
2015
2016
2017 # Unknown command
2018
2019 else { tests_exit(-1, "Command unrecognized in line $lineno: $_"); }
2020
2021
2022 # Run the command, with stdin connected to a pipe, and write the stdin data
2023 # to it, with appropriate substitutions. If a line ends with \NONL\, chop off
2024 # the terminating newline (and the \NONL\). If the command contains
2025 # -DSERVER=server add "-server" to the command, where it will adjoin the name
2026 # for the stderr file. See comment above about the use of -DSERVER.
2027
2028 $stderrsuffix = ($cmd =~ /\s-DSERVER=server\s/)? "-server" : "";
2029 print ">> |${cmd}${stderrsuffix}\n" if ($debug);
2030 open CMD, "|${cmd}${stderrsuffix}" || tests_exit(1, "Failed to run $cmd");
2031
2032 CMD->autoflush(1);
2033 while (<SCRIPT>)
2034   {
2035   $lineno++;
2036   last if /^\*{4}\s*$/;
2037   do_substitute($testno);
2038   if (/^(.*)\\NONL\\\s*$/) { print CMD $1; } else { print CMD; }
2039   }
2040
2041 # For timeout tests, wait before closing the pipe; we expect a
2042 # SIGPIPE error in this case.
2043
2044 if ($wait_time > 0)
2045   {
2046   printf("  Test %d sleep $wait_time ", $$subtestref);
2047   while ($wait_time-- > 0)
2048     {
2049     print ".";
2050     sleep(1);
2051     }
2052   printf("\r  Test %d                                       $cr", $$subtestref);
2053   }
2054
2055 $sigpipehappened = 0;
2056 close CMD;                # Waits for command to finish
2057 return $yield;            # Ran command and waited
2058 }
2059
2060
2061
2062
2063 ###############################################################################
2064 ###############################################################################
2065
2066 # Here beginneth the Main Program ...
2067
2068 ###############################################################################
2069 ###############################################################################
2070
2071
2072 autoflush STDOUT 1;
2073 print "Exim tester $testversion\n";
2074
2075
2076 ##################################################
2077 #      Some tests check created file modes       #
2078 ##################################################
2079
2080 umask 022;
2081
2082
2083 ##################################################
2084 #       Check for the "less" command             #
2085 ##################################################
2086
2087 $more = "more" if system("which less >/dev/null 2>&1") != 0;
2088
2089
2090
2091 ##################################################
2092 #        Check for sudo access to root           #
2093 ##################################################
2094
2095 print "You need to have sudo access to root to run these tests. Checking ...\n";
2096 if (system("sudo date >/dev/null") != 0)
2097   {
2098   die "** Test for sudo failed: testing abandoned.\n";
2099   }
2100 else
2101   {
2102   print "Test for sudo OK\n";
2103   }
2104
2105
2106
2107 ##################################################
2108 #      See if an Exim binary has been given      #
2109 ##################################################
2110
2111 # If the first character of the first argument is '/', the argument is taken
2112 # as the path to the binary.
2113
2114 $parm_exim = (@ARGV > 0 && $ARGV[0] =~ m?^/?)? shift @ARGV : "";
2115 print "Exim binary is $parm_exim\n" if $parm_exim ne "";
2116
2117
2118
2119 ##################################################
2120 # Sort out options and which tests are to be run #
2121 ##################################################
2122
2123 # There are a few possible options for the test script itself; after these, any
2124 # options are passed on to Exim calls within the tests. Typically, this is used
2125 # to turn on Exim debugging while setting up a test.
2126
2127 while (@ARGV > 0 && $ARGV[0] =~ /^-/)
2128   {
2129   my($arg) = shift @ARGV;
2130   if ($optargs eq "")
2131     {
2132     if ($arg eq "-DEBUG")  { $debug = 1; $cr = "\n"; next; }
2133     if ($arg eq "-DIFF")   { $cf = "diff -u"; next; }
2134     if ($arg eq "-UPDATE") { $force_update = 1; next; }
2135     if ($arg eq "-NOIPV4") { $have_ipv4 = 0; next; }
2136     if ($arg eq "-NOIPV6") { $have_ipv6 = 0; next; }
2137     if ($arg eq "-KEEP")   { $save_output = 1; next; }
2138     }
2139   $optargs .= " $arg";
2140   }
2141
2142 # Any subsequent arguments are a range of test numbers.
2143
2144 if (@ARGV > 0)
2145   {
2146   $test_end = $test_start = $ARGV[0];
2147   $test_end = $ARGV[1] if (@ARGV > 1);
2148   $test_end = ($test_start >= 9000)? $test_special_top : $test_top
2149     if $test_end eq "+";
2150   die "** Test numbers out of order\n" if ($test_end < $test_start);
2151   }
2152
2153
2154 ##################################################
2155 #      Make the command's directory current      #
2156 ##################################################
2157
2158 # After doing so, we find its absolute path name.
2159
2160 $cwd = $0;
2161 $cwd = '.' if ($cwd !~ s|/[^/]+$||);
2162 chdir($cwd) || die "** Failed to chdir to \"$cwd\": $!\n";
2163 $parm_cwd = Cwd::getcwd();
2164
2165
2166 ##################################################
2167 #     Search for an Exim binary to test          #
2168 ##################################################
2169
2170 # If an Exim binary hasn't been provided, try to find one. We can handle the
2171 # case where exim-testsuite is installed alongside Exim source directories. For
2172 # PH's private convenience, if there's a directory just called "exim4", that
2173 # takes precedence; otherwise exim-snapshot takes precedence over any numbered
2174 # releases.
2175
2176 if ($parm_exim eq "")
2177   {
2178   my($use_srcdir) = "";
2179
2180   opendir DIR, ".." || die "** Failed to opendir \"..\": $!\n";
2181   while ($f = readdir(DIR))
2182     {
2183     my($srcdir);
2184
2185     # Try this directory if it is "exim4" or if it is exim-snapshot or exim-n.m
2186     # possibly followed by -RCx where n.m is greater than any previously tried
2187     # directory. Thus, we should choose the highest version of Exim that has
2188     # been compiled.
2189
2190     if ($f eq "exim4" || $f eq "exim-snapshot")
2191       { $srcdir = $f; }
2192     else
2193       { $srcdir = $f
2194         if ($f =~ /^exim-\d+\.\d+(-RC\d+)?$/ && $f gt $use_srcdir); }
2195
2196     # Look for a build directory with a binary in it. If we find a binary,
2197     # accept this source directory.
2198
2199     if ($srcdir)
2200       {
2201       opendir SRCDIR, "../$srcdir" ||
2202         die "** Failed to opendir \"$cwd/../$srcdir\": $!\n";
2203       while ($f = readdir(SRCDIR))
2204         {
2205         if ($f =~ /^build-/ && -e "../$srcdir/$f/exim")
2206           {
2207           $use_srcdir = $srcdir;
2208           $parm_exim = "$cwd/../$srcdir/$f/exim";
2209           $parm_exim =~ s'/[^/]+/\.\./'/';
2210           last;
2211           }
2212         }
2213       closedir(SRCDIR);
2214       }
2215
2216     # If we have found "exim4" or "exim-snapshot", that takes precedence.
2217     # Otherwise, continue to see if there's a later version.
2218
2219     last if $use_srcdir eq "exim4" || $use_srcdir eq "exim-snapshot";
2220     }
2221   closedir(DIR);
2222   print "Exim binary found in $parm_exim\n" if $parm_exim ne "";
2223   }
2224
2225 # If $parm_exim is still empty, ask the caller
2226
2227 if ($parm_exim eq "")
2228   {
2229   print "** Did not find an Exim binary to test\n";
2230   for ($i = 0; $i < 5; $i++)
2231     {
2232     my($trybin);
2233     print "** Enter pathname for Exim binary: ";
2234     chomp($trybin = <STDIN>);
2235     if (-e $trybin)
2236       {
2237       $parm_exim = $trybin;
2238       last;
2239       }
2240     else
2241       {
2242       print "** $trybin does not exist\n";
2243       }
2244     }
2245   die "** Too many tries\n" if $parm_exim eq "";
2246   }
2247
2248
2249
2250 ##################################################
2251 #          Find what is in the binary            #
2252 ##################################################
2253
2254 # deal with TRUSTED_CONFIG_LIST restrictions
2255 unlink("$parm_cwd/test-config") if -e "$parm_cwd/test-config";
2256 symlink("$parm_cwd/confs/0000", "$parm_cwd/test-config")
2257   or die "Unable to link initial config into place: $!\n";
2258
2259 print("Probing with config file: $parm_cwd/test-config\n");
2260 open(EXIMINFO, "$parm_exim -d -C $parm_cwd/test-config -DDIR=$parm_cwd " .
2261                "-bP exim_user exim_group|") ||
2262   die "** Cannot run $parm_exim: $!\n";
2263 while(<EXIMINFO>)
2264   {
2265   $parm_eximuser = $1 if /^exim_user = (.*)$/;
2266   $parm_eximgroup = $1 if /^exim_group = (.*)$/;
2267   }
2268 close(EXIMINFO);
2269
2270 if (defined $parm_eximuser)
2271   {
2272   if ($parm_eximuser =~ /^\d+$/) { $parm_exim_uid = $parm_eximuser; }
2273     else { $parm_exim_uid = getpwnam($parm_eximuser); }
2274   }
2275 else
2276   {
2277   print "Unable to extract exim_user from binary.\n";
2278   print "Check if Exim refused to run; if so, consider:\n";
2279   print "  TRUSTED_CONFIG_LIST ALT_CONFIG_PREFIX WHITELIST_D_MACROS\n";
2280   die "Failing to get information from binary.\n";
2281   }
2282
2283 if (defined $parm_eximgroup)
2284   {
2285   if ($parm_eximgroup =~ /^\d+$/) { $parm_exim_gid = $parm_eximgroup; }
2286     else { $parm_exim_gid = getgrnam($parm_eximgroup); }
2287   }
2288
2289 open(EXIMINFO, "$parm_exim -bV -C $parm_cwd/test-config -DDIR=$parm_cwd |") ||
2290   die "** Cannot run $parm_exim: $!\n";
2291
2292 print "-" x 78, "\n";
2293
2294 while (<EXIMINFO>)
2295   {
2296   my(@temp);
2297
2298   if (/^Exim version/) { print; }
2299
2300   elsif (/^Size of off_t: (\d+)/)
2301     {
2302     print;
2303     $have_largefiles = 1 if $1 > 4;
2304     die "** Size of off_t > 32 which seems improbable, not running tests\n"
2305         if ($1 > 32);
2306     }
2307
2308   elsif (/^Support for: (.*)/)
2309     {
2310     print;
2311     @temp = split /(\s+)/, $1;
2312     push(@temp, ' ');
2313     %parm_support = @temp;
2314     }
2315
2316   elsif (/^Lookups \(built-in\): (.*)/)
2317     {
2318     print;
2319     @temp = split /(\s+)/, $1;
2320     push(@temp, ' ');
2321     %parm_lookups = @temp;
2322     }
2323
2324   elsif (/^Authenticators: (.*)/)
2325     {
2326     print;
2327     @temp = split /(\s+)/, $1;
2328     push(@temp, ' ');
2329     %parm_authenticators = @temp;
2330     }
2331
2332   elsif (/^Routers: (.*)/)
2333     {
2334     print;
2335     @temp = split /(\s+)/, $1;
2336     push(@temp, ' ');
2337     %parm_routers = @temp;
2338     }
2339
2340   # Some transports have options, e.g. appendfile/maildir. For those, ensure
2341   # that the basic transport name is set, and then the name with each of the
2342   # options.
2343
2344   elsif (/^Transports: (.*)/)
2345     {
2346     print;
2347     @temp = split /(\s+)/, $1;
2348     my($i,$k);
2349     push(@temp, ' ');
2350     %parm_transports = @temp;
2351     foreach $k (keys %parm_transports)
2352       {
2353       if ($k =~ "/")
2354         {
2355         @temp = split /\//, $k;
2356         $parm_transports{"$temp[0]"} = " ";
2357         for ($i = 1; $i < @temp; $i++)
2358           { $parm_transports{"$temp[0]/$temp[$i]"} = " "; }
2359         }
2360       }
2361     }
2362   }
2363 close(EXIMINFO);
2364 print "-" x 78, "\n";
2365
2366 unlink("$parm_cwd/test-config");
2367
2368 ##################################################
2369 #    Check for SpamAssassin and ClamAV           #
2370 ##################################################
2371
2372 # These are crude tests. If they aren't good enough, we'll have to improve
2373 # them, for example by actually passing a message through spamc or clamscan.
2374
2375 if (defined $parm_support{'Content_Scanning'})
2376   {
2377   my $sock = new FileHandle;
2378
2379   if (system("spamc -h 2>/dev/null >/dev/null") == 0)
2380     {
2381     print "The spamc command works:\n";
2382
2383     # This test for an active SpamAssassin is courtesy of John Jetmore.
2384     # The tests are hard coded to localhost:783, so no point in making
2385     # this test flexible like the clamav test until the test scripts are
2386     # changed.  spamd doesn't have the nice PING/PONG protoccol that
2387     # clamd does, but it does respond to errors in an informative manner,
2388     # so use that.
2389
2390     my($sint,$sport) = ('127.0.0.1',783);
2391     eval
2392       {
2393       my $sin = sockaddr_in($sport, inet_aton($sint))
2394           or die "** Failed packing $sint:$sport\n";
2395       socket($sock, PF_INET, SOCK_STREAM, getprotobyname('tcp'))
2396           or die "** Unable to open socket $sint:$sport\n";
2397
2398       local $SIG{ALRM} =
2399           sub { die "** Timeout while connecting to socket $sint:$sport\n"; };
2400       alarm(5);
2401       connect($sock, $sin)
2402           or die "** Unable to connect to socket $sint:$sport\n";
2403       alarm(0);
2404
2405       select((select($sock), $| = 1)[0]);
2406       print $sock "bad command\r\n";
2407
2408       $SIG{ALRM} =
2409           sub { die "** Timeout while reading from socket $sint:$sport\n"; };
2410       alarm(10);
2411       my $res = <$sock>;
2412       alarm(0);
2413
2414       $res =~ m|^SPAMD/|
2415           or die "** Did not get SPAMD from socket $sint:$sport. "
2416                 ."It said: $res\n";
2417       };
2418     alarm(0);
2419     if($@)
2420       {
2421       print "  $@";
2422       print "  Assume SpamAssassin (spamd) is not running\n";
2423       }
2424     else
2425       {
2426       $parm_running{'SpamAssassin'} = ' ';
2427       print "  SpamAssassin (spamd) seems to be running\n";
2428       }
2429     }
2430   else
2431     {
2432     print "The spamc command failed: assume SpamAssassin (spamd) is not running\n";
2433     }
2434
2435   # For ClamAV, we need to find the clamd socket for use in the Exim
2436   # configuration. Search for the clamd configuration file.
2437
2438   if (system("clamscan -h 2>/dev/null >/dev/null") == 0)
2439     {
2440     my($f, $clamconf, $test_prefix);
2441
2442     print "The clamscan command works";
2443
2444     $test_prefix = $ENV{EXIM_TEST_PREFIX};
2445     $test_prefix = "" if !defined $test_prefix;
2446
2447     foreach $f ("$test_prefix/etc/clamd.conf",
2448                 "$test_prefix/usr/local/etc/clamd.conf",
2449                 "$test_prefix/etc/clamav/clamd.conf", "")
2450       {
2451       if (-e $f)
2452         {
2453         $clamconf = $f;
2454         last;
2455         }
2456       }
2457
2458     # Read the ClamAV configuration file and find the socket interface.
2459
2460     if ($clamconf ne "")
2461       {
2462       my $socket_domain;
2463       open(IN, "$clamconf") || die "\n** Unable to open $clamconf: $!\n";
2464       while (<IN>)
2465         {
2466         if (/^LocalSocket\s+(.*)/)
2467           {
2468           $parm_clamsocket = $1;
2469           $socket_domain = AF_UNIX;
2470           last;
2471           }
2472         if (/^TCPSocket\s+(\d+)/)
2473           {
2474           if (defined $parm_clamsocket)
2475             {
2476             $parm_clamsocket .= " $1";
2477             $socket_domain = AF_INET;
2478             last;
2479             }
2480           else
2481             {
2482             $parm_clamsocket = " $1";
2483             }
2484           }
2485         elsif (/^TCPAddr\s+(\S+)/)
2486           {
2487           if (defined $parm_clamsocket)
2488             {
2489             $parm_clamsocket = $1 . $parm_clamsocket;
2490             $socket_domain = AF_INET;
2491             last;
2492             }
2493           else
2494             {
2495             $parm_clamsocket = $1;
2496             }
2497           }
2498         }
2499       close(IN);
2500
2501       if (defined $socket_domain)
2502         {
2503         print ":\n  The clamd socket is $parm_clamsocket\n";
2504         # This test for an active ClamAV is courtesy of Daniel Tiefnig.
2505         eval
2506           {
2507           my $socket;
2508           if ($socket_domain == AF_UNIX)
2509             {
2510             $socket = sockaddr_un($parm_clamsocket) or die "** Failed packing '$parm_clamsocket'\n";
2511             }
2512           elsif ($socket_domain == AF_INET)
2513             {
2514             my ($ca_host, $ca_port) = split(/\s+/,$parm_clamsocket);
2515             my $ca_hostent = gethostbyname($ca_host) or die "** Failed to get raw address for host '$ca_host'\n";
2516             $socket = sockaddr_in($ca_port, $ca_hostent) or die "** Failed packing '$parm_clamsocket'\n";
2517             }
2518           else
2519             {
2520             die "** Unknown socket domain '$socket_domain' (should not happen)\n";
2521             }
2522           socket($sock, $socket_domain, SOCK_STREAM, 0) or die "** Unable to open socket '$parm_clamsocket'\n";
2523           local $SIG{ALRM} = sub { die "** Timeout while connecting to socket '$parm_clamsocket'\n"; };
2524           alarm(5);
2525           connect($sock, $socket) or die "** Unable to connect to socket '$parm_clamsocket'\n";
2526           alarm(0);
2527
2528           my $ofh = select $sock; $| = 1; select $ofh;
2529           print $sock "PING\n";
2530
2531           $SIG{ALRM} = sub { die "** Timeout while reading from socket '$parm_clamsocket'\n"; };
2532           alarm(10);
2533           my $res = <$sock>;
2534           alarm(0);
2535
2536           $res =~ /PONG/ or die "** Did not get PONG from socket '$parm_clamsocket'. It said: $res\n";
2537           };
2538         alarm(0);
2539
2540         if($@)
2541           {
2542           print "  $@";
2543           print "  Assume ClamAV is not running\n";
2544           }
2545         else
2546           {
2547           $parm_running{'ClamAV'} = ' ';
2548           print "  ClamAV seems to be running\n";
2549           }
2550         }
2551       else
2552         {
2553         print ", but the socket for clamd could not be determined\n";
2554         print "Assume ClamAV is not running\n";
2555         }
2556       }
2557
2558     else
2559       {
2560       print ", but I can't find a configuration for clamd\n";
2561       print "Assume ClamAV is not running\n";
2562       }
2563     }
2564   }
2565
2566
2567 ##################################################
2568 #         Test for the basic requirements        #
2569 ##################################################
2570
2571 # This test suite assumes that Exim has been built with at least the "usual"
2572 # set of routers, transports, and lookups. Ensure that this is so.
2573
2574 $missing = "";
2575
2576 $missing .= "     Lookup: lsearch\n" if (!defined $parm_lookups{'lsearch'});
2577
2578 $missing .= "     Router: accept\n" if (!defined $parm_routers{'accept'});
2579 $missing .= "     Router: dnslookup\n" if (!defined $parm_routers{'dnslookup'});
2580 $missing .= "     Router: manualroute\n" if (!defined $parm_routers{'manualroute'});
2581 $missing .= "     Router: redirect\n" if (!defined $parm_routers{'redirect'});
2582
2583 $missing .= "     Transport: appendfile\n" if (!defined $parm_transports{'appendfile'});
2584 $missing .= "     Transport: autoreply\n" if (!defined $parm_transports{'autoreply'});
2585 $missing .= "     Transport: pipe\n" if (!defined $parm_transports{'pipe'});
2586 $missing .= "     Transport: smtp\n" if (!defined $parm_transports{'smtp'});
2587
2588 if ($missing ne "")
2589   {
2590   print "\n";
2591   print "** Many features can be included or excluded from Exim binaries.\n";
2592   print "** This test suite requires that Exim is built to contain a certain\n";
2593   print "** set of basic facilities. It seems that some of these are missing\n";
2594   print "** from the binary that is under test, so the test cannot proceed.\n";
2595   print "** The missing facilities are:\n";
2596   print "$missing";
2597   die "** Test script abandoned\n";
2598   }
2599
2600
2601 ##################################################
2602 #      Check for the auxiliary programs          #
2603 ##################################################
2604
2605 # These are always required:
2606
2607 for $prog ("cf", "checkaccess", "client", "client-ssl", "client-gnutls",
2608            "fakens", "iefbr14", "server")
2609   {
2610   next if ($prog eq "client-ssl" && !defined $parm_support{'OpenSSL'});
2611   next if ($prog eq "client-gnutls" && !defined $parm_support{'GnuTLS'});
2612   if (!-e "bin/$prog")
2613     {
2614     print "\n";
2615     print "** bin/$prog does not exist. Have you run ./configure and make?\n";
2616     die "** Test script abandoned\n";
2617     }
2618   }
2619
2620 # If the "loaded" binary is missing, we cut out tests for ${dlfunc. It isn't
2621 # compiled on systems where we don't know how to. However, if Exim does not
2622 # have that functionality compiled, we needn't bother.
2623
2624 $dlfunc_deleted = 0;
2625 if (defined $parm_support{'Expand_dlfunc'} && !-e "bin/loaded")
2626   {
2627   delete $parm_support{'Expand_dlfunc'};
2628   $dlfunc_deleted = 1;
2629   }
2630
2631
2632 ##################################################
2633 #          Find environmental details            #
2634 ##################################################
2635
2636 # Find the caller of this program.
2637
2638 ($parm_caller,$pwpw,$parm_caller_uid,$parm_caller_gid,$pwquota,$pwcomm,
2639  $parm_caller_gecos, $parm_caller_home) = getpwuid($>);
2640
2641 $pwpw = $pwpw;       # Kill Perl warnings
2642 $pwquota = $pwquota;
2643 $pwcomm = $pwcomm;
2644
2645 $parm_caller_group = getgrgid($parm_caller_gid);
2646
2647 print "Program caller is $parm_caller, whose group is $parm_caller_group\n";
2648 print "Home directory is $parm_caller_home\n";
2649
2650 unless (defined $parm_eximgroup)
2651   {
2652   print "Unable to derive \$parm_eximgroup.\n";
2653   die "** ABANDONING.\n";
2654   }
2655
2656 print "You need to be in the Exim group to run these tests. Checking ...";
2657
2658 if (`groups` =~ /\b\Q$parm_eximgroup\E\b/)
2659   {
2660   print " OK\n";
2661   }
2662 else
2663   {
2664   print "\nOh dear, you are not in the Exim group.\n";
2665   die "** Testing abandoned.\n";
2666   }
2667
2668 # Find this host's IP addresses - there may be many, of course, but we keep
2669 # one of each type (IPv4 and IPv6).
2670
2671 $parm_ipv4 = "";
2672 $parm_ipv6 = "";
2673
2674 $local_ipv4 = "";
2675 $local_ipv6 = "";
2676
2677 open(IFCONFIG, "ifconfig -a|") || die "** Cannot run \"ifconfig\": $!\n";
2678 while (($parm_ipv4 eq "" || $parm_ipv6 eq "") && ($_ = <IFCONFIG>))
2679   {
2680   my($ip);
2681   if ($parm_ipv4 eq "" &&
2682       $_ =~ /^\s*inet(?:\saddr)?:?\s?(\d+\.\d+\.\d+\.\d+)\s/i)
2683     {
2684     $ip = $1;
2685     next if ($ip eq "127.0.0.1");
2686     $parm_ipv4 = $ip;
2687     }
2688
2689   if ($parm_ipv6 eq "" &&
2690       $_ =~ /^\s*inet6(?:\saddr)?:?\s?([abcdef\d:]+)/i)
2691     {
2692     $ip = $1;
2693     next if ($ip eq "::1" || $ip =~ /^fe80/i);
2694     $parm_ipv6 = $ip;
2695     }
2696   }
2697 close(IFCONFIG);
2698
2699 # Use private IP addresses if there are no public ones.
2700
2701 $parm_ipv4 = $local_ipv4 if ($parm_ipv4 eq "");
2702 $parm_ipv6 = $local_ipv6 if ($parm_ipv6 eq "");
2703
2704 # If either type of IP address is missing, we need to set the value to
2705 # something other than empty, because that wrecks the substitutions. The value
2706 # is reflected, so use a meaningful string. Set appropriate options for the
2707 # "server" command. In practice, however, many tests assume 127.0.0.1 is
2708 # available, so things will go wrong if there is no IPv4 address. The lack
2709 # of IPV4 or IPv6 can be simulated by command options, which force $have_ipv4
2710 # and $have_ipv6 false.
2711
2712 if ($parm_ipv4 eq "")
2713   {
2714   $have_ipv4 = 0;
2715   $parm_ipv4 = "<no IPv4 address found>";
2716   $server_opts .= " -noipv4";
2717   }
2718 elsif ($have_ipv4 == 0)
2719   {
2720   $parm_ipv4 = "<IPv4 testing disabled>";
2721   $server_opts .= " -noipv4";
2722   }
2723 else
2724   {
2725   $parm_running{"IPv4"} = " ";
2726   }
2727
2728 if ($parm_ipv6 eq "")
2729   {
2730   $have_ipv6 = 0;
2731   $parm_ipv6 = "<no IPv6 address found>";
2732   $server_opts .= " -noipv6";
2733   delete($parm_support{"IPv6"});
2734   }
2735 elsif ($have_ipv6 == 0)
2736   {
2737   $parm_ipv6 = "<IPv6 testing disabled>";
2738   $server_opts .= " -noipv6";
2739   delete($parm_support{"IPv6"});
2740   }
2741 elsif (!defined $parm_support{'IPv6'})
2742   {
2743   $have_ipv6 = 0;
2744   $parm_ipv6 = "<no IPv6 support in Exim binary>";
2745   $server_opts .= " -noipv6";
2746   }
2747 else
2748   {
2749   $parm_running{"IPv6"} = " ";
2750   }
2751
2752 print "IPv4 address is $parm_ipv4\n";
2753 print "IPv6 address is $parm_ipv6\n";
2754
2755 # For munging test output, we need the reversed IP addresses.
2756
2757 $parm_ipv4r = ($parm_ipv4 !~ /^\d/)? "" :
2758   join(".", reverse(split /\./, $parm_ipv4));
2759
2760 $parm_ipv6r = $parm_ipv6;             # Appropriate if not in use
2761 if ($parm_ipv6 =~ /^[\da-f]/)
2762   {
2763   my(@comps) = split /:/, $parm_ipv6;
2764   my(@nibbles);
2765   foreach $comp (@comps)
2766     {
2767     push @nibbles, sprintf("%lx", hex($comp) >> 8);
2768     push @nibbles, sprintf("%lx", hex($comp) & 0xff);
2769     }
2770   $parm_ipv6r = join(".", reverse(@nibbles));
2771   }
2772
2773 # Find the host name, fully qualified.
2774
2775 chomp($temp = `hostname`);
2776 $parm_hostname = (gethostbyname($temp))[0];
2777 $parm_hostname = "no.host.name.found" if $parm_hostname eq "";
2778 print "Hostname is $parm_hostname\n";
2779
2780 if ($parm_hostname !~ /\./)
2781   {
2782   print "\n*** Host name is not fully qualified: this may cause problems ***\n\n";
2783   }
2784
2785 if ($parm_hostname =~ /[[:upper:]]/)
2786   {
2787   print "\n*** Host name has upper case characters: this may cause problems ***\n\n";
2788   }
2789
2790
2791
2792 ##################################################
2793 #     Create a testing version of Exim           #
2794 ##################################################
2795
2796 # We want to be able to run Exim with a variety of configurations. Normally,
2797 # the use of -C to change configuration causes Exim to give up its root
2798 # privilege (unless the caller is exim or root). For these tests, we do not
2799 # want this to happen. Also, we want Exim to know that it is running in its
2800 # test harness.
2801
2802 # We achieve this by copying the binary and patching it as we go. The new
2803 # binary knows it is a testing copy, and it allows -C and -D without loss of
2804 # privilege. Clearly, this file is dangerous to have lying around on systems
2805 # where there are general users with login accounts. To protect against this,
2806 # we put the new binary in a special directory that is accessible only to the
2807 # caller of this script, who is known to have sudo root privilege from the test
2808 # that was done above. Furthermore, we ensure that the binary is deleted at the
2809 # end of the test. First ensure the directory exists.
2810
2811 if (-d "eximdir")
2812   { unlink "eximdir/exim"; }     # Just in case
2813 else
2814   {
2815   mkdir("eximdir", 0710) || die "** Unable to mkdir $parm_cwd/eximdir: $!\n";
2816   system("sudo chgrp $parm_eximgroup eximdir");
2817   }
2818
2819 # The construction of the patched binary must be done as root, so we use
2820 # a separate script. As well as indicating that this is a test-harness binary,
2821 # the version number is patched to "x.yz" so that its length is always the
2822 # same. Otherwise, when it appears in Received: headers, it affects the length
2823 # of the message, which breaks certain comparisons.
2824
2825 die "** Unable to make patched exim: $!\n"
2826   if (system("sudo ./patchexim $parm_exim") != 0);
2827
2828 # From this point on, exits from the program must go via the subroutine
2829 # tests_exit(), so that suitable cleaning up can be done when required.
2830 # Arrange to catch interrupting signals, to assist with this.
2831
2832 $SIG{'INT'} = \&inthandler;
2833 $SIG{'PIPE'} = \&pipehandler;
2834
2835 # For some tests, we need another copy of the binary that is setuid exim rather
2836 # than root.
2837
2838 system("sudo cp eximdir/exim eximdir/exim_exim;" .
2839        "sudo chown $parm_eximuser eximdir/exim_exim;" .
2840        "sudo chgrp $parm_eximgroup eximdir/exim_exim;" .
2841        "sudo chmod 06755 eximdir/exim_exim");
2842
2843
2844 ##################################################
2845 #     Make copies of utilities we might need     #
2846 ##################################################
2847
2848 # Certain of the tests make use of some of Exim's utilities. We do not need
2849 # to be root to copy these.
2850
2851 ($parm_exim_dir) = $parm_exim =~ m?^(.*)/exim?;
2852
2853 $dbm_build_deleted = 0;
2854 if (defined $parm_lookups{'dbm'} &&
2855     system("cp $parm_exim_dir/exim_dbmbuild eximdir") != 0)
2856   {
2857   delete $parm_lookups{'dbm'};
2858   $dbm_build_deleted = 1;
2859   }
2860
2861 if (system("cp $parm_exim_dir/exim_dumpdb eximdir") != 0)
2862   {
2863   tests_exit(-1, "Failed to make a copy of exim_dumpdb: $!");
2864   }
2865
2866 if (system("cp $parm_exim_dir/exim_lock eximdir") != 0)
2867   {
2868   tests_exit(-1, "Failed to make a copy of exim_lock: $!");
2869   }
2870
2871 if (system("cp $parm_exim_dir/exinext eximdir") != 0)
2872   {
2873   tests_exit(-1, "Failed to make a copy of exinext: $!");
2874   }
2875
2876 if (system("cp $parm_exim_dir/exigrep eximdir") != 0)
2877   {
2878   tests_exit(-1, "Failed to make a copy of exigrep: $!");
2879   }
2880
2881 if (system("cp $parm_exim_dir/eximstats eximdir") != 0)
2882   {
2883   tests_exit(-1, "Failed to make a copy of eximstats: $!");
2884   }
2885
2886
2887 ##################################################
2888 #    Check that the Exim user can access stuff   #
2889 ##################################################
2890
2891 # We delay this test till here so that we can check access to the actual test
2892 # binary. This will be needed when Exim re-exec's itself to do deliveries.
2893
2894 print "Exim user is $parm_eximuser ($parm_exim_uid)\n";
2895 print "Exim group is $parm_eximgroup ($parm_exim_gid)\n";
2896
2897 if ($parm_caller_uid eq $parm_exim_uid) {
2898   tests_exit(-1, "Exim user ($parm_eximuser,$parm_exim_uid) cannot be "
2899                 ."the same as caller ($parm_caller,$parm_caller_uid)");
2900 }
2901
2902 print "The Exim user needs access to the test suite directory. Checking ...";
2903
2904 if (($rc = system("sudo bin/checkaccess $parm_cwd/eximdir/exim $parm_eximuser $parm_eximgroup")) != 0)
2905   {
2906   my($why) = "unknown failure $rc";
2907   $rc >>= 8;
2908   $why = "Couldn't find user \"$parm_eximuser\"" if $rc == 1;
2909   $why = "Couldn't find group \"$parm_eximgroup\"" if $rc == 2;
2910   $why = "Couldn't read auxiliary group list" if $rc == 3;
2911   $why = "Couldn't get rid of auxiliary groups" if $rc == 4;
2912   $why = "Couldn't set gid" if $rc == 5;
2913   $why = "Couldn't set uid" if $rc == 6;
2914   $why = "Couldn't open \"$parm_cwd/eximdir/exim\"" if $rc == 7;
2915   print "\n** $why\n";
2916   tests_exit(-1, "$parm_eximuser cannot access the test suite directory");
2917   }
2918 else
2919   {
2920   print " OK\n";
2921   }
2922
2923
2924 ##################################################
2925 #        Create a list of available tests        #
2926 ##################################################
2927
2928 # The scripts directory contains a number of subdirectories whose names are
2929 # of the form 0000-xxxx, 1100-xxxx, 2000-xxxx, etc. Each set of tests apart
2930 # from the first requires certain optional features to be included in the Exim
2931 # binary. These requirements are contained in a file called "REQUIRES" within
2932 # the directory. We scan all these tests, discarding those that cannot be run
2933 # because the current binary does not support the right facilities, and also
2934 # those that are outside the numerical range selected.
2935
2936 print "\nTest range is $test_start to $test_end\n";
2937 print "Omitting \${dlfunc expansion tests (loadable module not present)\n"
2938   if $dlfunc_deleted;
2939 print "Omitting dbm tests (unable to copy exim_dbmbuild)\n"
2940   if $dbm_build_deleted;
2941
2942 opendir(DIR, "scripts") || tests_exit(-1, "Failed to opendir(\"scripts\"): $!");
2943 @test_dirs = sort readdir(DIR);
2944 closedir(DIR);
2945
2946 # Remove . and .. and CVS from the list.
2947
2948 for ($i = 0; $i < @test_dirs; $i++)
2949   {
2950   my($d) = $test_dirs[$i];
2951   if ($d eq "." || $d eq ".." || $d eq "CVS")
2952     {
2953     splice @test_dirs, $i, 1;
2954     $i--;
2955     }
2956   }
2957
2958 # Scan for relevant tests
2959
2960 for ($i = 0; $i < @test_dirs; $i++)
2961   {
2962   my($testdir) = $test_dirs[$i];
2963   my($wantthis) = 1;
2964
2965   print ">>Checking $testdir\n" if $debug;
2966
2967   # Skip this directory if the first test is equal or greater than the first
2968   # test in the next directory.
2969
2970   next if ($i < @test_dirs - 1) &&
2971           ($test_start >= substr($test_dirs[$i+1], 0, 4));
2972
2973   # No need to carry on if the end test is less than the first test in this
2974   # subdirectory.
2975
2976   last if $test_end < substr($testdir, 0, 4);
2977
2978   # Check requirements, if any.
2979
2980   if (open(REQUIRES, "scripts/$testdir/REQUIRES"))
2981     {
2982     while (<REQUIRES>)
2983       {
2984       next if /^\s*$/;
2985       s/\s+$//;
2986       if (/^support (.*)$/)
2987         {
2988         if (!defined $parm_support{$1}) { $wantthis = 0; last; }
2989         }
2990       elsif (/^running (.*)$/)
2991         {
2992         if (!defined $parm_running{$1}) { $wantthis = 0; last; }
2993         }
2994       elsif (/^lookup (.*)$/)
2995         {
2996         if (!defined $parm_lookups{$1}) { $wantthis = 0; last; }
2997         }
2998       elsif (/^authenticators? (.*)$/)
2999         {
3000         if (!defined $parm_authenticators{$1}) { $wantthis = 0; last; }
3001         }
3002       elsif (/^router (.*)$/)
3003         {
3004         if (!defined $parm_routers{$1}) { $wantthis = 0; last; }
3005         }
3006       elsif (/^transport (.*)$/)
3007         {
3008         if (!defined $parm_transports{$1}) { $wantthis = 0; last; }
3009         }
3010       else
3011         {
3012         tests_exit(-1, "Unknown line in \"scripts/$testdir/REQUIRES\": \"$_\"");
3013         }
3014       }
3015     close(REQUIRES);
3016     }
3017   else
3018     {
3019     tests_exit(-1, "Failed to open \"scripts/$testdir/REQUIRES\": $!")
3020       unless $!{ENOENT};
3021     }
3022
3023   # Loop if we do not want the tests in this subdirectory.
3024
3025   if (!$wantthis)
3026     {
3027     chomp;
3028     print "Omitting tests in $testdir (missing $_)\n";
3029     next;
3030     }
3031
3032   # We want the tests from this subdirectory, provided they are in the
3033   # range that was selected.
3034
3035   opendir(SUBDIR, "scripts/$testdir") ||
3036     tests_exit(-1, "Failed to opendir(\"scripts/$testdir\"): $!");
3037   @testlist = sort readdir(SUBDIR);
3038   close(SUBDIR);
3039
3040   foreach $test (@testlist)
3041     {
3042     next if $test !~ /^\d{4}$/;
3043     next if $test < $test_start || $test > $test_end;
3044     push @test_list, "$testdir/$test";
3045     }
3046   }
3047
3048 print ">>Test List: @test_list\n", if $debug;
3049
3050
3051 ##################################################
3052 #         Munge variable auxiliary data          #
3053 ##################################################
3054
3055 # Some of the auxiliary data files have to refer to the current testing
3056 # directory and other parameter data. The generic versions of these files are
3057 # stored in the aux-var-src directory. At this point, we copy each of them
3058 # to the aux-var directory, making appropriate substitutions. There aren't very
3059 # many of them, so it's easiest just to do this every time. Ensure the mode
3060 # is standardized, as this path is used as a test for the ${stat: expansion.
3061
3062 # A similar job has to be done for the files in the dnszones-src directory, to
3063 # make the fake DNS zones for testing. Most of the zone files are copied to
3064 # files of the same name, but db.ipv4.V4NET and db.ipv6.V6NET use the testing
3065 # networks that are defined by parameter.
3066
3067 foreach $basedir ("aux-var", "dnszones")
3068   {
3069   system("sudo rm -rf $parm_cwd/$basedir");
3070   mkdir("$parm_cwd/$basedir", 0777);
3071   chmod(0755, "$parm_cwd/$basedir");
3072
3073   opendir(AUX, "$parm_cwd/$basedir-src") ||
3074     tests_exit(-1, "Failed to opendir $parm_cwd/$basedir-src: $!");
3075   my(@filelist) = readdir(AUX);
3076   close(AUX);
3077
3078   foreach $file (@filelist)
3079     {
3080     my($outfile) = $file;
3081     next if $file =~ /^\./;
3082
3083     if ($file eq "db.ip4.V4NET")
3084       {
3085       $outfile = "db.ip4.$parm_ipv4_test_net";
3086       }
3087     elsif ($file eq "db.ip6.V6NET")
3088       {
3089       my(@nibbles) = reverse(split /\s*/, $parm_ipv6_test_net);
3090       $" = '.';
3091       $outfile = "db.ip6.@nibbles";
3092       $" = ' ';
3093       }
3094
3095     print ">>Copying $basedir-src/$file to $basedir/$outfile\n" if $debug;
3096     open(IN, "$parm_cwd/$basedir-src/$file") ||
3097       tests_exit(-1, "Failed to open $parm_cwd/$basedir-src/$file: $!");
3098     open(OUT, ">$parm_cwd/$basedir/$outfile") ||
3099       tests_exit(-1, "Failed to open $parm_cwd/$basedir/$outfile: $!");
3100     while (<IN>)
3101       {
3102       do_substitute(0);
3103       print OUT;
3104       }
3105     close(IN);
3106     close(OUT);
3107     }
3108   }
3109
3110 # Set a user's shell, distinguishable from /bin/sh
3111
3112 symlink("/bin/sh","aux-var/sh");
3113 $ENV{'SHELL'} = $parm_shell = $parm_cwd . "/aux-var/sh";
3114
3115 ##################################################
3116 #     Create fake DNS zones for this host        #
3117 ##################################################
3118
3119 # There are fixed zone files for 127.0.0.1 and ::1, but we also want to be
3120 # sure that there are forward and reverse registrations for this host, using
3121 # its real IP addresses. Dynamically created zone files achieve this.
3122
3123 if ($have_ipv4 || $have_ipv6)
3124   {
3125   my($shortname,$domain) = $parm_hostname =~ /^([^.]+)(.*)/;
3126   open(OUT, ">$parm_cwd/dnszones/db$domain") ||
3127     tests_exit(-1, "Failed to open $parm_cwd/dnszones/db$domain: $!");
3128   print OUT "; This is a dynamically constructed fake zone file.\n" .
3129     "; The following line causes fakens to return PASS_ON\n" .
3130     "; for queries that it cannot answer\n\n" .
3131     "PASS ON NOT FOUND\n\n";
3132   print OUT "$shortname  A     $parm_ipv4\n" if $have_ipv4;
3133   print OUT "$shortname  AAAA  $parm_ipv6\n" if $have_ipv6;
3134   print OUT "\n; End\n";
3135   close(OUT);
3136   }
3137
3138 if ($have_ipv4 && $parm_ipv4 ne "127.0.0.1")
3139   {
3140   my(@components) = $parm_ipv4 =~ /^(\d+)\.(\d+)\.(\d+)\.(\d+)/;
3141   open(OUT, ">$parm_cwd/dnszones/db.ip4.$components[0]") ||
3142     tests_exit(-1,
3143       "Failed  to open $parm_cwd/dnszones/db.ip4.$components[0]: $!");
3144   print OUT "; This is a dynamically constructed fake zone file.\n" .
3145     "; The zone is $components[0].in-addr.arpa.\n\n" .
3146     "$components[3].$components[2].$components[1]  PTR  $parm_hostname.\n\n" .
3147     "; End\n";
3148   close(OUT);
3149   }
3150
3151 if ($have_ipv6 && $parm_ipv6 ne "::1")
3152   {
3153   my($exp_v6) = $parm_ipv6;
3154   $exp_v6 =~ s/[^:]//g;
3155   if ( $parm_ipv6 =~ /^([^:].+)::$/ ) {
3156     $exp_v6 = $1 . ':0' x (9-length($exp_v6));
3157   } elsif ( $parm_ipv6 =~ /^(.+)::(.+)$/ ) {
3158     $exp_v6 = $1 . ':0' x (8-length($exp_v6)) . ':' . $2;
3159   } elsif ( $parm_ipv6 =~ /^::(.+[^:])$/ ) {
3160     $exp_v6 = '0:' x (9-length($exp_v6)) . $1;
3161   } else {
3162     $exp_v6 = $parm_ipv6;
3163   }
3164   my(@components) = split /:/, $exp_v6;
3165   my(@nibbles) = reverse (split /\s*/, shift @components);
3166   my($sep) =  "";
3167
3168   $" = ".";
3169   open(OUT, ">$parm_cwd/dnszones/db.ip6.@nibbles") ||
3170     tests_exit(-1,
3171       "Failed  to open $parm_cwd/dnszones/db.ip6.@nibbles: $!");
3172   print OUT "; This is a dynamically constructed fake zone file.\n" .
3173     "; The zone is @nibbles.ip6.arpa.\n\n";
3174
3175   @components = reverse @components;
3176   foreach $c (@components)
3177     {
3178     $c = "0$c" until $c =~ /^..../;
3179     @nibbles = reverse(split /\s*/, $c);
3180     print OUT "$sep@nibbles";
3181     $sep = ".";
3182     }
3183
3184   print OUT "  PTR  $parm_hostname.\n\n; End\n";
3185   close(OUT);
3186   $" = " ";
3187   }
3188
3189
3190
3191 ##################################################
3192 #    Create lists of mailboxes and message logs  #
3193 ##################################################
3194
3195 # We use these lists to check that a test has created the expected files. It
3196 # should be faster than looking for the file each time. For mailboxes, we have
3197 # to scan a complete subtree, in order to handle maildirs. For msglogs, there
3198 # is just a flat list of files.
3199
3200 @oldmails = list_files_below("mail");
3201 opendir(DIR, "msglog") || tests_exit(-1, "Failed to opendir msglog: $!");
3202 @oldmsglogs = readdir(DIR);
3203 closedir(DIR);
3204
3205
3206
3207 ##################################################
3208 #         Run the required tests                 #
3209 ##################################################
3210
3211 # Each test script contains a number of tests, separated by a line that
3212 # contains ****. We open input from the terminal so that we can read responses
3213 # to prompts.
3214
3215 open(T, "/dev/tty") || tests_exit(-1, "Failed to open /dev/tty: $!");
3216
3217 print "\nPress RETURN to run the tests: ";
3218 $_ = <T>;
3219 print "\n";
3220
3221 $lasttestdir = "";
3222
3223 foreach $test (@test_list)
3224   {
3225   local($lineno) = 0;
3226   local($commandno) = 0;
3227   local($subtestno) = 0;
3228   local($testno) = substr($test, -4);
3229   local($sortlog) = 0;
3230
3231   my($gnutls) = 0;
3232   my($docheck) = 1;
3233   my($thistestdir) = substr($test, 0, -5);
3234
3235   if ($lasttestdir ne $thistestdir)
3236     {
3237     $gnutls = 0;
3238     if (-s "scripts/$thistestdir/REQUIRES")
3239       {
3240       my($indent) = "";
3241       print "\n>>> The following tests require: ";
3242       open(IN, "scripts/$thistestdir/REQUIRES") ||
3243         tests_exit(-1, "Failed to open scripts/$thistestdir/REQUIRES: $1");
3244       while (<IN>)
3245         {
3246         $gnutls = 1 if /^support GnuTLS/;
3247         print $indent, $_;
3248         $indent = ">>>                              ";
3249         }
3250       close(IN);
3251       }
3252     }
3253   $lasttestdir = $thistestdir;
3254
3255   # Remove any debris in the spool directory and the test-mail directory
3256   # and also the files for collecting stdout and stderr. Then put back
3257   # the test-mail directory for appendfile deliveries.
3258
3259   system "sudo /bin/rm -rf spool test-*";
3260   system "mkdir test-mail 2>/dev/null";
3261
3262   # A privileged Exim will normally make its own spool directory, but some of
3263   # the tests run in unprivileged modes that don't always work if the spool
3264   # directory isn't already there. What is more, we want anybody to be able
3265   # to read it in order to find the daemon's pid.
3266
3267   system "mkdir spool; " .
3268          "sudo chown $parm_eximuser:$parm_eximgroup spool; " .
3269          "sudo chmod 0755 spool";
3270
3271   # Empty the cache that keeps track of things like message id mappings, and
3272   # set up the initial sequence strings.
3273
3274   undef %cache;
3275   $next_msgid = "aX";
3276   $next_pid = 1234;
3277   $next_port = 1111;
3278   $message_skip = 0;
3279   $msglog_skip = 0;
3280   $stderr_skip = 0;
3281   $stdout_skip = 0;
3282   $rmfiltertest = 0;
3283   $is_ipv6test = 0;
3284
3285   # Remove the associative arrays used to hold checked mail files and msglogs
3286
3287   undef %expected_mails;
3288   undef %expected_msglogs;
3289
3290   # Open the test's script
3291
3292   open(SCRIPT, "scripts/$test") ||
3293     tests_exit(-1, "Failed to open \"scripts/$test\": $!");
3294
3295   # The first line in the script must be a comment that is used to identify
3296   # the set of tests as a whole.
3297
3298   $_ = <SCRIPT>;
3299   $lineno++;
3300   tests_exit(-1, "Missing identifying comment at start of $test") if (!/^#/);
3301   printf("%s %s", (substr $test, 5), (substr $_, 2));
3302
3303   # Loop for each of the subtests within the script. The variable $server_pid
3304   # is used to remember the pid of a "server" process, for which we do not
3305   # wait until we have waited for a subsequent command.
3306
3307   local($server_pid) = 0;
3308   for ($commandno = 1; !eof SCRIPT; $commandno++)
3309     {
3310     # Skip further leading comments and blank lines, handle the flag setting
3311     # commands, and deal with tests for IP support.
3312
3313     while (<SCRIPT>)
3314       {
3315       $lineno++;
3316       if (/^no_message_check/) { $message_skip = 1; next; }
3317       if (/^no_msglog_check/)  { $msglog_skip = 1; next; }
3318       if (/^no_stderr_check/)  { $stderr_skip = 1; next; }
3319       if (/^no_stdout_check/)  { $stdout_skip = 1; next; }
3320       if (/^rmfiltertest/)     { $rmfiltertest = 1; next; }
3321       if (/^sortlog/)          { $sortlog = 1; next; }
3322
3323       if (/^need_largefiles/)
3324         {
3325         next if $have_largefiles;
3326         print ">>> Large file support is needed for test $testno, but is not available: skipping\n";
3327         $docheck = 0;      # don't check output
3328         undef $_;          # pretend EOF
3329         last;
3330         }
3331
3332       if (/^need_ipv4/)
3333         {
3334         next if $have_ipv4;
3335         print ">>> IPv4 is needed for test $testno, but is not available: skipping\n";
3336         $docheck = 0;      # don't check output
3337         undef $_;          # pretend EOF
3338         last;
3339         }
3340
3341       if (/^need_ipv6/)
3342         {
3343         if ($have_ipv6)
3344           {
3345           $is_ipv6test = 1;
3346           next;
3347           }
3348         print ">>> IPv6 is needed for test $testno, but is not available: skipping\n";
3349         $docheck = 0;      # don't check output
3350         undef $_;          # pretend EOF
3351         last;
3352         }
3353
3354       if (/^need_move_frozen_messages/)
3355         {
3356         next if defined $parm_support{"move_frozen_messages"};
3357         print ">>> move frozen message support is needed for test $testno, " .
3358           "but is not\n>>> available: skipping\n";
3359         $docheck = 0;      # don't check output
3360         undef $_;          # pretend EOF
3361         last;
3362         }
3363
3364       last unless /^(#|\s*$)/;
3365       }
3366     last if !defined $_;  # Hit EOF
3367
3368     my($subtest_startline) = $lineno;
3369
3370     # Now run the command. The function returns 0 if exim was run and waited
3371     # for, 1 if any other command was run and waited for, and 2 if a command
3372     # was run and not waited for (usually a daemon or server startup).
3373
3374     my($commandname) = "";
3375     my($expectrc) = 0;
3376     my($rc, $run_extra) = run_command($testno, \$subtestno, \$expectrc, \$commandname, $TEST_STATE);
3377     my($cmdrc) = $?;
3378
3379     if ($debug) {
3380       print ">> rc=$rc cmdrc=$cmdrc\n";
3381       if (defined $run_extra) {
3382         foreach my $k (keys %$run_extra) {
3383           my $v = defined $run_extra->{$k} ? qq!"$run_extra->{$k}"! : '<undef>';
3384           print ">>   $k -> $v\n";
3385         }
3386       }
3387     }
3388     $run_extra = {} unless defined $run_extra;
3389     foreach my $k (keys %$run_extra) {
3390       if (exists $TEST_STATE->{$k}) {
3391         my $nv = defined $run_extra->{$k} ? qq!"$run_extra->{$k}"! : 'removed';
3392         print ">> override of $k; was $TEST_STATE->{$k}, now $nv\n" if $debug;
3393       }
3394       if (defined $run_extra->{$k}) {
3395         $TEST_STATE->{$k} = $run_extra->{$k};
3396       } elsif (exists $TEST_STATE->{$k}) {
3397         delete $TEST_STATE->{$k};
3398       }
3399     }
3400
3401     # Hit EOF after an initial return code number
3402
3403     tests_exit(-1, "Unexpected EOF in script") if ($rc == 4);
3404
3405     # Carry on with the next command if we did not wait for this one. $rc == 0
3406     # if no subprocess was run; $rc == 3 if we started a process but did not
3407     # wait for it.
3408
3409     next if ($rc == 0 || $rc == 3);
3410
3411     # We ran and waited for a command. Check for the expected result unless
3412     # it died.
3413
3414     if ($cmdrc != $expectrc && !$sigpipehappened)
3415       {
3416       printf("** Command $commandno (\"$commandname\", starting at line $subtest_startline)\n");
3417       if (($cmdrc & 0xff) == 0)
3418         {
3419         printf("** Return code %d (expected %d)", $cmdrc/256, $expectrc/256);
3420         }
3421       elsif (($cmdrc & 0xff00) == 0)
3422         { printf("** Killed by signal %d", $cmdrc & 255); }
3423       else
3424         { printf("** Status %x", $cmdrc); }
3425
3426       for (;;)
3427         {
3428         print "\nshow stdErr, show stdOut, Retry, Continue (without file comparison), or Quit? [Q] ";
3429         $_ = <T>;
3430         tests_exit(1) if /^q?$/i;
3431         last if /^[rc]$/i;
3432         if (/^e$/i)
3433           {
3434           system("$more test-stderr");
3435           }
3436         elsif (/^o$/i)
3437           {
3438           system("$more test-stdout");
3439           }
3440         }
3441
3442       $retry = 1 if /^r$/i;
3443       $docheck = 0;
3444       }
3445
3446     # If the command was exim, and a listening server is running, we can now
3447     # close its input, which causes us to wait for it to finish, which is why
3448     # we didn't close it earlier.
3449
3450     if ($rc == 2 && $server_pid != 0)
3451       {
3452       close SERVERCMD;
3453       $server_pid = 0;
3454       if ($? != 0)
3455         {
3456         if (($? & 0xff) == 0)
3457           { printf("Server return code %d", $?/256); }
3458         elsif (($? & 0xff00) == 0)
3459           { printf("Server killed by signal %d", $? & 255); }
3460         else
3461           { printf("Server status %x", $?); }
3462
3463         for (;;)
3464           {
3465           print "\nShow server stdout, Retry, Continue, or Quit? [Q] ";
3466           $_ = <T>;
3467           tests_exit(1) if /^q?$/i;
3468           last if /^[rc]$/i;
3469
3470           if (/^s$/i)
3471             {
3472             open(S, "test-stdout-server") ||
3473               tests_exit(-1, "Failed to open test-stdout-server: $!");
3474             print while <S>;
3475             close(S);
3476             }
3477           }
3478         $retry = 1 if /^r$/i;
3479         }
3480       }
3481     }
3482
3483   close SCRIPT;
3484
3485   # The script has finished. Check the all the output that was generated. The
3486   # function returns 0 if all is well, 1 if we should rerun the test (the files
3487   # have been updated). It does not return if the user responds Q to a prompt.
3488
3489   if ($retry)
3490     {
3491     $retry = '0';
3492     print (("#" x 79) . "\n");
3493     redo;
3494     }
3495
3496   if ($docheck)
3497     {
3498     if (check_output($TEST_STATE->{munge}) != 0)
3499       {
3500       print (("#" x 79) . "\n");
3501       redo;
3502       }
3503     else
3504       {
3505       print ("  Script completed\n");
3506       }
3507     }
3508   }
3509
3510
3511 ##################################################
3512 #         Exit from the test script              #
3513 ##################################################
3514
3515 tests_exit(-1, "No runnable tests selected") if @test_list == 0;
3516 tests_exit(0);
3517
3518 # End of runtest script
3519 # vim: set sw=2 et :