e824bb41ca1e7e51d7d985dc8ea1c13050e9ee5a
[exim.git] / src / src / exigrep.src
1 #! PERL_COMMAND -w
2 # $Cambridge: exim/src/src/exigrep.src,v 1.2 2004/12/21 11:28:38 ph10 Exp $
3
4 use strict;
5
6 # Copyright (c) 2004 University of Cambridge.
7 # See the file NOTICE for conditions of use and distribution.
8
9 # Except when they appear in comments, the following placeholders in this
10 # source are replaced when it is turned into a runnable script:
11 #
12 # PERL_COMMAND
13 # ZCAT_COMMAND
14 # COMPRESS_SUFFIX
15
16 # PROCESSED_FLAG
17
18 # This is a perl script which extracts from an Exim log all entries
19 # for all messages that have an entry that matches a given pattern.
20 # If *any* entry for a particular message matches the pattern, *all*
21 # entries for that message are displayed.
22
23 # We buffer up information on a per-message basis. It is done this way rather
24 # than reading the input twice so that the input can be a pipe.
25
26 # There must be one argument, which is the pattern. Subsequent arguments
27 # are the files to scan; if none, the standard input is read. If any file
28 # appears to be compressed, it is passed through zcat. We can't just do this
29 # for all files, because zcat chokes on non-compressed files.
30
31 use Getopt::Std qw(getopts);
32 use POSIX qw(mktime);
33
34
35 # This subroutine converts a time/date string from an Exim log line into
36 # the number of seconds since the epoch. It handles optional timezone
37 # information.
38
39 sub seconds {
40 my($year,$month,$day,$hour,$min,$sec,$tzs,$tzh,$tzm) =
41   $_[0] =~ /^(\d{4})-(\d\d)-(\d\d)\s(\d\d):(\d\d):(\d\d)(?>\s([+-])(\d\d)(\d\d))?/;
42
43 my $seconds = mktime $sec, $min, $hour, $day, $month - 1, $year - 1900;
44
45 if (defined $tzs)
46   {
47   $seconds -= $tzh * 3600 + $tzm * 60 if $tzs eq "+";
48   $seconds += $tzh * 3600 + $tzm * 60 if $tzs eq "-";
49   }
50
51 return $seconds;
52 }
53
54
55 # This subroutine processes a single line (in $_) from a log file. Program
56 # defensively against short lines finding their way into the log.
57
58 my (%saved, %id_list, $pattern, $queue_time);
59
60 sub do_line {
61 return unless
62   my($date,$entry) = /^(\d{4}-\d\d-\d\d \d\d:\d\d:\d\d (?:[+-]\d{4} )?)(.*)/;
63
64 # Handle the case when the log line belongs to a specific message. We save
65 # lines for specific messages until the message is complete. Then either print
66 # discard.
67
68 if (my($id) = $entry =~ /^(\w{6}\-\w{6}\-\w{2})/)
69   {
70   $saved{$id} = '' unless defined($saved{$id});
71
72   # Save up the data for this message in case it becomes interesting later.
73
74   $saved{$id} .= $_;
75
76   # Are we interested in this id ?
77
78   $id_list{$id} = 1 if /$pattern/io;
79
80   # See if this is a completion for some message. If it is interesting,
81   # print it, but in any event, throw away what was saved.
82
83   if ($entry =~
84         /(?:Completed|rejected (?:by local_scan|by non-SMTP ACL|after DATA))/)
85     {
86     if ($saved{$id} =~ /^(\d{4}-\d\d-\d\d \d\d:\d\d:\d\d ([+-]\d{4} )?)(\w{6}\-\w{6}\-\w{2})/)
87       {
88       my $old_sec = &seconds($1);
89       my $sec = &seconds($date);
90       delete $id_list{$id} if $id_list{$id} && $sec - $old_sec <= $queue_time;
91       }
92
93     if ($id_list{$id})
94       {
95       delete $id_list{$id};
96       print "$saved{$id}\n";
97       }
98
99     delete $saved{$id};
100     }
101   }
102
103 # Handle the case where the log line does not belong to a specific message.
104 # Print it if it is interesting.
105
106 elsif ($entry =~ /$pattern/io) { print "$_\n"; }
107 }
108
109
110 # The main program. Extract the pattern and make sure any relevant characters
111 # are quoted if the -l flag is given. The -t flag gives a time-on-queue value
112 # which is an additional condition.
113
114 getopts('lt:',\my %args);
115 $queue_time = $args{'t'}? $args{'t'} : -1;
116
117 die "usage: exigrep [-l] [-t <seconds>] <pattern> [<log file>]...\n"
118   if ($#ARGV < 0);
119
120 $pattern = shift @ARGV;
121 $pattern = quotemeta $pattern if $args{l};
122
123
124 # If file arguments are given, open each one and process according as it is
125 # is compressed or not.
126
127 if (@ARGV)
128   {
129   foreach (@ARGV)
130     {
131     my $filename = $_;
132     if ($filename =~ /\.(?:COMPRESS_SUFFIX)$/)
133       {
134       open(LOG, "ZCAT_COMMAND $filename |") ||
135         die "Unable to zcat $filename: $!\n";
136       }
137     else
138       {
139       open(LOG, "<$filename") || die "Unable to open $filename: $!\n";
140       }
141     do_line() while (<LOG>);
142     close(LOG);
143     }
144   }
145
146 # If no files are named, process STDIN only
147
148 else { do_line() while (<STDIN>); }
149
150 # At the end of processing all the input, print any uncompleted data
151
152 for (keys %id_list) { print "+++ $_ not completed +++\n$saved{$_}\n;" }
153
154 # End of exigrep