src/src/exigrep.src

   1 #! PERL_COMMAND -w
   2
   3 use strict;
   4
   5 # Copyright (c) 2007-2015 University of Cambridge.
   6 # See the file NOTICE for conditions of use and distribution.
   7
   8 # Except when they appear in comments, the following placeholders in this
   9 # source are replaced when it is turned into a runnable script:
  10 #
  11 # PERL_COMMAND
  12 # ZCAT_COMMAND
  13 # COMPRESS_SUFFIX
  14
  15 # PROCESSED_FLAG
  16
  17 # This is a perl script which extracts from an Exim log all entries
  18 # for all messages that have an entry that matches a given pattern.
  19 # If *any* entry for a particular message matches the pattern, *all*
  20 # entries for that message are displayed.
  21
  22 # We buffer up information on a per-message basis. It is done this way rather
  23 # than reading the input twice so that the input can be a pipe.
  24
  25 # There must be one argument, which is the pattern. Subsequent arguments
  26 # are the files to scan; if none, the standard input is read. If any file
  27 # appears to be compressed, it is passed through zcat. We can't just do this
  28 # for all files, because zcat chokes on non-compressed files.
  29
  30 # Performance optimized in 02/02/2007 by Jori Hamalainen
  31 # Typical run time acceleration: 4 times
  32
  33
  34 use Getopt::Std qw(getopts);
  35 use POSIX qw(mktime);
  36
  37
  38 # This subroutine converts a time/date string from an Exim log line into
  39 # the number of seconds since the epoch. It handles optional timezone
  40 # information.
  41
  42 sub seconds {
  43 my($year,$month,$day,$hour,$min,$sec,$tzs,$tzh,$tzm) =
  44   $_[0] =~ /^(\d{4})-(\d\d)-(\d\d)\s(\d\d):(\d\d):(\d\d)(?>\s([+-])(\d\d)(\d\d))?/o;
  45
  46 my $seconds = mktime $sec, $min, $hour, $day, $month - 1, $year - 1900;
  47
  48 if (defined $tzs)
  49   {
  50   $seconds -= $tzh * 3600 + $tzm * 60 if $tzs eq "+";
  51   $seconds += $tzh * 3600 + $tzm * 60 if $tzs eq "-";
  52   }
  53
  54 return $seconds;
  55 }
  56
  57
  58 # This subroutine processes a single line (in $_) from a log file. Program
  59 # defensively against short lines finding their way into the log.
  60
  61 my (%saved, %id_list, $pattern, $queue_time, $insensitive, $invert);
  62
  63 # If using "related" option, have to track extra message IDs
  64 my $related;
  65 my $related_re='';
  66 my @Mids = ();
  67
  68 sub do_line {
  69
  70 # Convert syslog lines to mainlog format, as in eximstats.
  71
  72 if (!/^\d{4}-/o) { $_ =~ s/^.*? exim\b.*?: //o; }
  73
  74 return unless
  75   my($date,$id) = /^(\d{4}-\d\d-\d\d \d\d:\d\d:\d\d (?:[+-]\d{4} )?)(?:\[\d+\] )?(\w{6}\-\w{6}\-\w{2})?/o;
  76
  77 # Handle the case when the log line belongs to a specific message. We save
  78 # lines for specific messages until the message is complete. Then either print
  79 # or discard.
  80
  81 if (defined $id)
  82   {
  83   $saved{$id} = '' unless defined($saved{$id});
  84
  85   # Save up the data for this message in case it becomes interesting later.
  86
  87   $saved{$id} .= $_;
  88
  89   # Are we interested in this id ? Short circuit if we already were interested.
  90
  91   if ($invert)
  92     {
  93     $id_list{$id} = 1 if (!defined($id_list{$id}));
  94     $id_list{$id} = 0 if (($insensitive && /$pattern/io) || /$pattern/o);
  95     }
  96   else
  97     {
  98     if (defined $id_list{$id} ||
  99       ($insensitive && /$pattern/io) || /$pattern/o)
 100       {
 101       $id_list{$id} = 1;
 102       get_related_ids($id) if $related;
 103       }
 104     elsif ($related && $related_re)
 105       {
 106       grep_for_related($_, $id);
 107       }
 108     }
 109
 110   # See if this is a completion for some message. If it is interesting,
 111   # print it, but in any event, throw away what was saved.
 112
 113   if (index($_, 'Completed') != -1 ||
 114       index($_, 'SMTP data timeout') != -1 ||
 115         (index($_, 'rejected') != -1 &&
 116           /^(\d{4}-\d\d-\d\d \d\d:\d\d:\d\d (?:[+-]\d{4} )?)(?:\[\d+\] )?\w{6}\-\w{6}\-\w{2} rejected/o))
 117     {
 118     if ($queue_time != -1 &&
 119         $saved{$id} =~ /^(\d{4}-\d\d-\d\d \d\d:\d\d:\d\d ([+-]\d{4} )?)/o)
 120       {
 121       my $old_sec = &seconds($1);
 122       my $sec = &seconds($date);
 123       $id_list{$id} = 0 if $id_list{$id} && $sec - $old_sec <= $queue_time;
 124       }
 125
 126     print "$saved{$id}\n" if ($id_list{$id});
 127     delete $id_list{$id};
 128     delete $saved{$id};
 129     }
 130   }
 131
 132 # Handle the case where the log line does not belong to a specific message.
 133 # Print it if it is interesting.
 134
 135 elsif ( ($invert && (($insensitive && !/$pattern/io) || !/$pattern/o)) ||
 136        (!$invert && (($insensitive &&  /$pattern/io) ||  /$pattern/o)) )
 137   { print "$_\n"; }
 138 }
 139
 140 # Rotated log files are frequently compressed and there are a variety of
 141 # formats it could be compressed with. Rather than use just one that is
 142 # detected and hardcoded at Exim compile time, detect and use what the
 143 # logfile is compressed with on the fly.
 144 #
 145 # List of known compression extensions and their associated commands:
 146 my $compressors = {
 147   gz   => { cmd => 'zcat',  args => '' },
 148   bz2  => { cmd => 'bzcat', args => '' },
 149   xz   => { cmd => 'xzcat', args => '' },
 150   lzma => { cmd => 'lzma',  args => '-dc' }
 151 };
 152 my $csearch = 0;
 153
 154 sub detect_compressor_bin
 155   {
 156   my $ext = shift();
 157   my $c = $compressors->{$ext}->{cmd};
 158   $compressors->{$ext}->{bin} = `which $c 2>/dev/null`;
 159   chomp($compressors->{$ext}->{bin});
 160   }
 161
 162 sub detect_compressor_capable
 163   {
 164   my $filename = shift();
 165   map { &detect_compressor_bin($_) } keys %$compressors
 166     if (!$csearch);
 167   $csearch = 1;
 168   return undef
 169     unless (grep {$filename =~ /\.(?:$_)$/} keys %$compressors);
 170   # Loop through them, figure out which one it detected,
 171   # and build the commandline.
 172   my $cmdline = undef;
 173   foreach my $ext (keys %$compressors)
 174     {
 175     if ($filename =~ /\.(?:$ext)$/)
 176       {
 177       # Just die if compressor not found; if this occurrs in the middle of
 178       # two valid files with a lot of matches, error could easily be missed.
 179       die("Didn't find $ext decompressor for $filename\n")
 180         if ($compressors->{$ext}->{bin} eq '');
 181       $cmdline = $compressors->{$ext}->{bin} ." ".
 182                    $compressors->{$ext}->{args};
 183       last;
 184       }
 185     }
 186   return $cmdline;
 187   }
 188
 189 sub grep_for_related {
 190   my ($line,$id) = @_;
 191   $id_list{$id} = 1 if $line =~ m/$related_re/;
 192 }
 193
 194 sub get_related_ids {
 195   my ($id) = @_;
 196   push @Mids, $id unless grep /\b$id\b/, @Mids;
 197   my $re = join '|', @Mids;
 198   $related_re = qr/$re/;
 199 }
 200
 201 # The main program. Extract the pattern and make sure any relevant characters
 202 # are quoted if the -l flag is given. The -t flag gives a time-on-queue value
 203 # which is an additional condition. The -M flag will also display "related"
 204 # loglines (msgid from matched lines is searched in following lines).
 205
 206 getopts('Ilvt:M',\my %args);
 207 $queue_time  = $args{'t'}? $args{'t'} : -1;
 208 $insensitive = $args{'I'}? 0 : 1;
 209 $invert      = $args{'v'}? 1 : 0;
 210 $related     = $args{'M'}? 1 : 0;
 211
 212 die "usage: exigrep [-I] [-l] [-M] [-t <seconds>] [-v] <pattern> [<log file>]...\n"
 213   if ($#ARGV < 0);
 214
 215 $pattern = shift @ARGV;
 216 $pattern = quotemeta $pattern if $args{l};
 217
 218
 219 # If file arguments are given, open each one and process according as it is
 220 # is compressed or not.
 221
 222 if (@ARGV)
 223   {
 224   foreach (@ARGV)
 225     {
 226     my $filename = $_;
 227     if (-x 'ZCAT_COMMAND' && $filename =~ /\.(?:COMPRESS_SUFFIX)$/o)
 228       {
 229       open(LOG, "ZCAT_COMMAND $filename |") ||
 230         die "Unable to zcat $filename: $!\n";
 231       }
 232     elsif (my $cmdline = &detect_compressor_capable($filename))
 233       {
 234       open(LOG, "$cmdline $filename |") ||
 235         die "Unable to decompress $filename: $!\n";
 236       }
 237     else
 238       {
 239       open(LOG, "<$filename") || die "Unable to open $filename: $!\n";
 240       }
 241     do_line() while (<LOG>);
 242     close(LOG);
 243     }
 244   }
 245
 246 # If no files are named, process STDIN only
 247
 248 else { do_line() while (<STDIN>); }
 249
 250 # At the end of processing all the input, print any uncompleted messages.
 251
 252 for (keys %id_list)
 253   {
 254   print "+++ $_ has not completed +++\n$saved{$_}\n";
 255   }
 256
 257 # End of exigrep