TLS: refactor client-start interface
[exim.git] / release-process / scripts / mk_exim_release
CommitLineData
46c573de 1#!/usr/bin/env perl
525c441c 2# Copyright (c) The Exim Maintainers 2016-2018
3634fc25 3
8a483da6
NM
4use strict;
5use warnings;
6use Carp;
525c441c
HSHR
7use Cwd qw'abs_path';
8use File::Basename;
9use File::Path qw(make_path remove_tree);
8f29c950 10use File::Temp;
8a483da6 11use Getopt::Long;
ba41f854 12use IO::File;
8a483da6 13use Pod::Usage;
162e16b1 14use Digest::SHA;
525c441c
HSHR
15use if $ENV{DEBUG} => 'Smart::Comments';
16
17my $ME = basename $0;
18
8a483da6
NM
19
20my $debug = 0;
21my $verbose = 0;
22
525c441c
HSHR
23# MAJOR.MINOR[.SECURITY[.FIXES]][-RCX]
24# 4 .90 .0 .22 -RC1
25my $version_pattern = qr/
26 (?<release>
27 (?<major>\d) # 4
28 \.(?<minor>\d\d) # .90
29 (?:\.(?<security>\d+) # .0
30 (?:\.(?<fixes>)\d+)?)? # .22
31 (?:-(?<rc>RC\d+)?)? # -RC1
32 )
33/x;
8a483da6 34
525c441c 35# ------------------------------------------------------------------
8a483da6 36
525c441c
HSHR
37package Context {
38 use strict; # not strictly necessary yet, until in an own package
39 use warnings; # not strictly necessary yet, ...
40 use File::Spec::Functions qw'splitpath catfile catdir splitdir';
41 use File::Path qw'make_path remove_tree';
42 use File::Copy;
43 use Cwd qw'abs_path';
44 use Carp;
45
46 package PWD {
47 use Cwd;
48 sub TIESCALAR { bless do {\my $x} }
49 sub FETCH { cwd }
8a483da6 50 }
be914e6c 51
525c441c 52 tie my $cwd => 'PWD' or die;
8a483da6 53
525c441c
HSHR
54 sub new {
55 my $class = shift;
56 return bless { @_ } => $class;
57 }
8a483da6 58
525c441c
HSHR
59 sub check_version {
60 my $context = shift;
61 my $version = shift;
8a483da6 62
525c441c
HSHR
63 croak "The given version number does not look right - $version"
64 if not $version =~ /$version_pattern/;
8a483da6 65
525c441c
HSHR
66 $context->{v}{release} = $+{release};
67 $context->{v}{major} = $+{major};
68 $context->{v}{minor} = $+{minor};
69 $context->{v}{security} = $+{security};
70 $context->{v}{rc} = $+{rc};
8a483da6 71
b315e9a9
HSHR
72 die "$ME: This script doesn't work for versions prior 4.92-RCx. "
73 ."Please checkout an older version.\n"
aa672401
HSHR
74 if $context->{v}{major} < 4
75 or $context->{v}{major} == 4 && $context->{v}{minor} < 92;
76
525c441c 77 ### v: $context->{v}
8a483da6 78
525c441c
HSHR
79 # find a valid vcs tag matching the version
80 my $pattern = "$context->{pkgname}-$context->{v}{release}" =~ s/[-_.]/[-_.]/gr;
81 chomp(my @tags = qx{git tag --list '$pattern'});
8a483da6 82
525c441c
HSHR
83 croak "The given version is ambigous, tags: @tags\n" if @tags > 1;
84 croak "The given version does not exist (no such tag: exim-$version)\n" if @tags == 0;
8a483da6 85
525c441c 86 $context->{git_tag} = $tags[0];
46c573de 87
525c441c
HSHR
88 # target_release: the release we aim to reach with release candidates
89 # FIXME: re-construct from the parsed version number
90 ($context->{v}{target_release} = $context->{v}{release}) =~ s/-RC\d+//;
46c573de 91 }
8a483da6 92
8a483da6 93
525c441c
HSHR
94 # We prefer gtar to tar if gtar exists in $PATH
95 sub override_tar_cmd {
96 my $context = shift;
97 my $tar = $context->{tar_cmd};
8a483da6 98
525c441c 99 return unless $tar eq 'tar';
8a483da6 100
525c441c
HSHR
101 foreach my $d (File::Spec->path()) {
102 my $p = catfile($d, 'gtar');
103 if (-x $p) {
104 $context->{tar_cmd} = $p;
105 print "Switched tar command to: $p\n" if $verbose;
106 return;
107 }
108 }
109 }
8a483da6 110
525c441c
HSHR
111 sub prepare_working_directory {
112 my $context = shift;
113 my $workspace = $context->{workspace};
8f29c950 114
525c441c
HSHR
115 if (not defined $workspace) {
116 $workspace = $context->{workspace} = File::Temp->newdir(File::Spec->tmpdir . '/exim-packaging-XXXX');
117 }
118 else {
119 # ensure the working directory is not in place
120 if (-e $workspace) {
121 if ($context->{delete}) {
122 print "Deleting existing $workspace\n" if $verbose;
123 remove_tree $workspace, { verbose => $verbose || $debug };
124 }
125 else {
126 croak "Working directory $workspace exists" if -e $workspace;
127 }
128 }
129
130 # create base directory
131 make_path( $context->{directory}, { verbose => $verbose || $debug } );
132 }
8f29c950 133
525c441c
HSHR
134 # Set(!) and create subdirectories
135 foreach (qw(vcs_export pkg_tars pkg_trees tmp)) { # {dookbook}
136 make_path(
137 $context->{d}{$_} = catdir($workspace, $_),
138 { verbose => $verbose || $debug });
139 }
140 }
8f29c950 141
525c441c
HSHR
142 sub export_git_tree {
143 my $context = shift;
144
145 # build git command
146 my $archive_file = $context->{tmp_archive_file} = sprintf'%s/%s-%s.tar', $context->{d}{tmp}, $context->{pkgname}, $context->{v}{release};
147 ### $archive_file
148 my @cmd = ( 'git', 'archive', '--format=tar', "--output=$archive_file", $context->{git_tag} );
149 ### @cmd
150 # run git command
151 print "[$cwd] Running: @cmd\n" if $verbose;
152 0 == system @cmd or croak "Export failed";
153 }
8f29c950 154
525c441c
HSHR
155 sub unpack_tree {
156 # TODO: Why can't we combine the export_git_tree with the
157 # unpack_tree function?
158 my $context = shift;
ba41f854 159
525c441c
HSHR
160 ### $context
161 die "Cannot see archive file\n" unless -f $context->{tmp_archive_file};
162 my @cmd = ('tar',
163 xf => $context->{tmp_archive_file},
164 -C => $context->{d}{vcs_export} );
5901f0ab 165
525c441c
HSHR
166 # run command
167 print "[$cwd] Running: @cmd\n" if $verbose;
168 system @cmd and croak "Unpack failed\n";
5901f0ab 169
ba41f854
PP
170 }
171
525c441c
HSHR
172 sub make_version_script {
173 my $context = shift;
174
175 #my $variant = substr( $context->{v}{release}, length($context->{v}{target_release}) );
176 #if ( $context->{v}{release} ne $context->{v}{target_release} . $variant ) {
177 # die "Broken version numbering, I'm buggy";
178 #}
179
180
181 # Work
182 if (not my $pid = fork // die "$ME: Cannot fork: $!\n") {
183
184 my $source_tree = catdir($context->{d}{vcs_export}, 'src', 'src');
185 ### $source_tree
186
187 chdir $source_tree or die "chdir $source_tree: $!\n";
188
189
190 croak "WARNING: version.sh already exists - leaving it in place\n"
191 if -f 'version.sh';
192
193 # Currently (25. Feb. 2016) the mk_exim_release.pl up to now can't
194 # deal with security releases.!? So we need a current
195 # mk_exim_release.pl. But if we use a current (master), the
196 # reversion script returns wrong version info (it's running inside
197 # the Git tree and uses git --describe, which always returns the
198 # current version of master.) I do not want to change the old
199 # reversion scripts (in 4.86.1, 4.85.1).
200 #
201 # Thus we've to provide the version.sh, based on the info we have
202 # about the release. If reversion finds this, it doesn't try to find
203 # it's own way to get a valid version number from the git.
204 #
205 # 4.89 series: the logic here did not handle _RC<N> thus breaking RC
206 # status in versions. nb: rc in context should be same as $variant
207 # in local context.
208
209 #my $stamp = $context->{minor} ? '_'.$context->{minor} : '';
210 #$stamp .= $context->{rc} if $context->{rc};
211 my $variant = $context->{v}{rc} // '';
212
213 print "[$cwd] create version.sh\n" if $verbose;
214 open(my $v, '>', 'version.sh') or die "Can't open version.sh for writing: $!\n";
215 print {$v} <<__;
216# initial version automatically generated by $0
217EXIM_RELEASE_VERSION=$context->{v}{target_release}
218EXIM_VARIANT_VERSION=$variant
9677df8a 219EXIM_COMPILE_NUMBER=0
525c441c 220# echo "[[[ \$EXIM_RELEASE_VERSION | \$EXIM_VARIANT_VERSION | \$EXIM_COMPILE_NUMBER ]]]"
9677df8a 221__
525c441c
HSHR
222 close $v or die "$0: Can not close $source_tree/version.h: $!\n";
223 unlink 'version.h' or die "$ME: Can not unlink $source_tree/version.h: $!\n"
224 if -f 'version.h';
9677df8a 225
525c441c
HSHR
226 # Later, if we get the reversion script fixed, we can call it again.
227 # For now (25. Feb. 2016) we'll leave it unused.
228 #my @cmd = ('../scripts/reversion', 'release', $context->{git_tag});
5901f0ab 229
525c441c
HSHR
230 my @cmd = ('../scripts/reversion', 'release');
231 print "[$cwd] Running: @cmd\n" if $verbose;
232 system(@cmd) and croak "reversion failed";
ba41f854 233
525c441c
HSHR
234 die "$ME: failed to create version.sh"
235 unless -f 'version.sh';
ba41f854 236
525c441c
HSHR
237 exit 0;
238 }
239 else {
240 $pid == waitpid($pid, 0) or die "$0: waidpid: $!\n";
241 exit $? >> 8 if $?;
242 }
243 }
ba41f854 244
525c441c
HSHR
245 sub build_documentation {
246 my $context = shift;
247 my $docdir = catdir $context->{d}{vcs_export}, 'doc', 'doc-docbook';
248
249 # documentation building does a chdir, so we'll do it in a
250 # subprocess
251 if (not my $pid = fork // die "$ME: Can't fork: $!\n") {
252 chdir $docdir or die "$ME: Can't chdir to $docdir: $!\n";
253 system('./OS-Fixups') == 0 or exit $?;
254 exec $context->{make_cmd},
255 "EXIM_VER=$context->{v}{target_release}" .
256 ($context->{v}{rc} ? "-$context->{v}{rc}" : ''),
257 'everything';
258 die "$ME: [$cwd] Cannot exec $context->{make_cmd}: $!\n";
259 }
260 else {
261 waitpid($pid, 0);
262 exit $? >> 8 if $?;
263 }
be914e6c 264
525c441c 265 $context->copy_docbook_files;
525c441c 266 }
46c573de 267
525c441c
HSHR
268 sub copy_docbook_files {
269 my $context = shift;
be914e6c 270
525c441c
HSHR
271 # where the generated docbook files can be found
272 my $docdir = catdir $context->{d}{vcs_export}, 'doc', 'doc-docbook';
be914e6c 273
525c441c
HSHR
274 foreach ('spec.xml', 'filter.xml') {
275 my $from = catfile $docdir, $_;
276 my $to = catdir $context->{d}{tmp}; # {dookbook}
277 copy $from => $to or die $@;
278 }
279 }
be914e6c 280
525c441c
HSHR
281 sub build_html_documentation {
282 my $context = shift;
46c573de 283
525c441c
HSHR
284 # where the website docbook source dir is - push the generated
285 # files there
286 {
287 my $webdir = catdir $context->{website_base}, 'docbook', $context->{v}{target_release};
288 make_path $webdir, { verbose => $verbose + $debug };
289 copy catfile($context->{d}{vcs_export}, 'doc', 'doc-docbook', $_)
290 => $webdir or die $@
291 for 'spec.xml', 'filter.xml';
292 }
46c573de 293
525c441c
HSHR
294 my $gen = catfile $context->{website_base}, 'script/gen';
295 my $outdir = catdir $context->{d}{pkg_trees}, "exim-html-$context->{v}{release}";
46c573de 296
525c441c 297 make_path $outdir, { verbose => $verbose || $debug };
46c573de 298
525c441c
HSHR
299 my @cmd = (
300 $gen,
301 '--spec' => catfile($context->{d}{tmp}, 'spec.xml'), # {dookbook}
302 '--filter' => catfile($context->{d}{tmp}, 'filter.xml'), # {dookbok}
303 '--latest' => $context->{v}{target_release},
304 '--docroot' => $outdir,
305 '--localstatic',
306 ($verbose || $debug ? '--verbose' : ()),
307 );
46c573de 308
525c441c
HSHR
309 print "[$cwd] Executing @cmd\n";
310 0 == system @cmd or exit $? >> 8;
46c573de 311
46c573de 312 }
be914e6c 313
162e16b1
HSHR
314 sub sign {
315 my $context = shift;
316 foreach my $tar (glob "$context->{d}{pkg_tars}/*") {
317 system gpg =>
318 '--quiet', '--batch',
319 defined $context->{gpg}{key}
320 ? ('--local-user' => $context->{gpg}{key})
321 : (),
322 '--detach-sig', '--armor', $tar;
323 }
324 }
325
525c441c
HSHR
326 sub move_to_outdir {
327 my $context = shift;
328 make_path $context->{OUTDIR}, { verbose => $verbose || $debug };
329 move $_ => $context->{OUTDIR} or die $@
330 for glob "$context->{d}{pkg_tars}/*";
331 }
8a483da6 332
525c441c
HSHR
333 sub build_src_package_directory {
334 my $context = shift;
8a483da6 335
525c441c
HSHR
336 # build the exim package directory path
337 $context->{d}{src} = catdir $context->{d}{pkg_trees}, "exim-$context->{v}{release}";
8a483da6 338
525c441c
HSHR
339 # initially we move the exim-src directory to the new directory name
340 move
341 catdir( $context->{d}{vcs_export}, 'src')
342 => $context->{d}{src}
343 or croak "Move of src dir failed - $!";
8a483da6 344
525c441c
HSHR
345 # add Local subdirectory
346 make_path( catdir( $context->{d}{src}, 'Local' ), { verbose => $verbose || $debug } );
8a483da6 347
525c441c
HSHR
348 # now add the text docs
349 $context->move_text_docs_into_pkg;
8a483da6 350 }
8a483da6 351
525c441c
HSHR
352 sub build_doc_packages_directory {
353 my $context = shift;
354
355 ##foreach my $format (qw/pdf postscript texinfo info/) {
356 foreach my $format (qw/pdf postscript/) {
357 my $target = catdir $context->{d}{pkg_trees}, "exim-$format-$context->{v}{release}", 'doc';
358 make_path( $target, { verbose => $verbose || $debug } );
359
360 # move documents across
361 foreach my $file (
362 glob(
363 catfile(
364 $context->{d}{vcs_export},
365 'doc',
366 'doc-docbook',
367 (
368 ( $format eq 'postscript' )
369 ? '*.ps'
370 : ( '*.' . $format )
371 )
8a483da6
NM
372 )
373 )
374 )
525c441c
HSHR
375 {
376 move( $file, catfile( $target, ( splitpath($file) )[2] ) );
377 }
8a483da6
NM
378 }
379 }
46c573de 380
525c441c
HSHR
381 sub move_text_docs_into_pkg {
382 my $context = shift;
9d0311ff 383
525c441c
HSHR
384 my $old_docdir = catdir( $context->{d}{vcs_export}, 'doc', 'doc-docbook' );
385 my $old_txtdir = catdir( $context->{d}{vcs_export}, 'doc', 'doc-txt' );
386 my $new_docdir = catdir( $context->{d}{src}, 'doc' );
387 make_path( $new_docdir, { verbose => $verbose || $debug } );
9d0311ff 388
525c441c
HSHR
389 # move generated documents from docbook stuff
390 foreach my $file (qw/exim.8 spec.txt filter.txt/) {
391 die "Empty file \"$file\"\n" if -z catfile( $old_docdir, $file );
392 move( catfile( $old_docdir, $file ), catfile( $new_docdir, $file ) );
393 }
9d0311ff 394
525c441c
HSHR
395 # move text documents across
396 foreach my $file ( glob( catfile( $old_txtdir, '*' ) ) ) {
397
398 # skip a few we dont want
399 my $fn = ( splitpath($file) )[2];
400 next
401 if ( ( $fn eq 'ABOUT' )
402 || ( $fn eq 'ChangeLog.0' )
403 || ( $fn eq 'test-harness.txt' )
404 # Debian issue re licensing of RFCs
405 || ( $fn =~ /^draft-ietf-.*/ )
406 || ( $fn =~ /^rfc.*/ )
407 );
408 move( $file, catfile( $new_docdir, $fn ) );
9d0311ff
PP
409 }
410 }
9d0311ff 411
525c441c
HSHR
412 sub create_tar_files {
413 my $context = shift;
9d0311ff 414
525c441c
HSHR
415 my $pkg_tars = $context->{d}{pkg_tars};
416 my $pkg_trees = $context->{d}{pkg_trees};
417 my $tar = $context->{tar_cmd};
418 if ($verbose) {
419 foreach my $c (keys %{ $context->{compressors} }) {
420 print "Compression: $c\t$context->{compressors}{$c}\n";
421 }
422 }
8a483da6 423
525c441c
HSHR
424 # We ideally do not want local system user information in release tarballs;
425 # those are artifacts of use of tar for backups and have no place in
426 # software release packaging; if someone extracts as root, then they should
427 # get sane file ownerships.
b315e9a9
HSHR
428 my @ownership = (
429 '--owner' => $context->{tar_perms}{user},
430 '--group' => $context->{tar_perms}{group},
525c441c 431 # on this GNU tar, --numeric-owner works during creation too
b315e9a9
HSHR
432 '--numeric-owner'
433 ) if qx/tar --help 2>&1/ =~ /^\s*--owner=/m;
9d0311ff 434
525c441c 435 # See also environment variables set in main, tuning compression levels
b315e9a9
HSHR
436 my %COMPRESSION = (
437 gzip => { extension => 'gz', flags => '--gzip' },
438 bzip2 => { extension => 'bz2', flags => '--bzip2' },
439 lzip => { extension => 'lz', flags => '--lzip' },
440 xz => { extension => 'xz', flags => '--xz' },
525c441c
HSHR
441 );
442
b315e9a9 443
162e16b1 444 my (%size, %sha256);
b315e9a9 445
525c441c
HSHR
446 foreach my $dir ( glob( catdir( $pkg_trees, ( 'exim*-' . $context->{v}{release} ) ) ) ) {
447 my $dirname = ( splitdir($dir) )[-1];
b315e9a9
HSHR
448 foreach my $comp (keys %COMPRESSION) {
449 next unless $context->{compressors}{$comp};
162e16b1 450
b315e9a9 451 my $basename = "$dirname.tar.$COMPRESSION{$comp}{extension}";
162e16b1
HSHR
452 my $outfile = catfile $pkg_tars, $basename;
453
454 print "Creating: $outfile\n" if $verbose || $debug;
b315e9a9
HSHR
455 0 == system($tar,
456 cf => $outfile,
457 $COMPRESSION{$comp}{flags},
458 @ownership, -C => $pkg_trees, $dirname)
525c441c 459 or exit $? >> 8;
162e16b1
HSHR
460
461 # calculate size and md5sum
462 $size{$basename} = -s $outfile;
463 $sha256{$basename} = do {
464 my $sha = Digest::SHA->new(256);
465 $sha->addfile($outfile);
466 $sha->hexdigest;
467 };
525c441c
HSHR
468 }
469 }
162e16b1
HSHR
470
471 # write the sizes file
472 open my $sizes, '>', $_ = catfile $pkg_tars, 'sizes.txt'
473 or die "$ME: Can't open `$_': $!\n";
b315e9a9
HSHR
474
475 print $sizes join "\n",
476 (map { "SIZE($_) = $size{$_}" } sort keys %size),
477 (map { "SHA256($_) = $sha256{$_}" } sort keys %sha256);
478
162e16b1 479 close($sizes) or die "$ME: Can't close $_: $!\n";
45b75b0a
PP
480 }
481
525c441c
HSHR
482 sub do_cleanup {
483 my $context = shift;
00f7a87b 484
525c441c
HSHR
485 print "Cleaning up\n" if $verbose;
486 remove_tree $context->{d}{tmp}, { verbose => $debug + $verbose };
8a483da6 487 }
00f7a87b 488
8a483da6
NM
489}
490
91bde4a0
HSHR
491MAIN: {
492
525c441c
HSHR
493 # some of these settings are useful only if we're in the
494 # exim-projekt-root, but the check, if we're, is deferred
495 my $context = Context->new(
be914e6c 496 pkgname => 'exim',
525c441c 497 website_base => abs_path('../exim-website'),
9d0311ff 498 tar_cmd => 'tar',
45b75b0a
PP
499 tar_perms => {
500 user => '0',
501 group => '0',
502 },
a7637438 503 make_cmd => 'make',
9d0311ff
PP
504 compressors => {
505 gzip => 1,
506 bzip2 => 1,
00f7a87b 507 xz => 1,
e099cd0d 508 lzip => 0,
9d0311ff 509 },
525c441c 510 docs => 1,
2820726f 511 web => 1,
525c441c
HSHR
512 delete => 0,
513 cleanup => 1,
162e16b1
HSHR
514 gpg => {
515 sign => 1,
516 key => undef,
517 },
525c441c
HSHR
518 );
519
8f29c950 520 ##$ENV{'PATH'} = '/opt/local/bin:' . $ENV{'PATH'};
00f7a87b 521 # We are creating files for mass distribution, so work harder to make smaller files.
525c441c
HSHR
522 $ENV{GZIP} = -9;
523 $ENV{BZIP2} = -9;
00f7a87b
PP
524 # xz documents minimum file sizes for levels higher than -6 to be useful and each
525 # requires more RAM on the decompressing system. Exim tarball currently 24MiB so
526 # using -8.
525c441c 527 $ENV{XZ_DEFAULTS} = -8;
8a483da6 528
91bde4a0 529 GetOptions(
525c441c
HSHR
530 $context,
531 qw(workspace|tmp=s outdir=s website_base|webgen_base=s tar_cmd=s make_cmd=s docs|build-docs! web|build-web!
532 delete! cleanup!),
162e16b1
HSHR
533 'sign!' => \$context->{gpg}{sign},
534 'key=s' => \$context->{gpg}{key},
91bde4a0
HSHR
535 'lzip!' => \$context->{compressors}{lzip},
536 'verbose!' => \$verbose,
537 'debug!' => \$debug,
538 'help|?' => sub { pod2usage(-verbose => 1, -exit => 0) },
539 'man!' => sub { pod2usage(-verbose => 2, -exit => 0, -noperldoc => system('perldoc -V >/dev/null 2>&1')) },
525c441c
HSHR
540 ) and @ARGV == 2 or pod2usage;
541
162e16b1
HSHR
542 -f '.exim-project-root'
543 or die "$ME: please call this script from the root of the Exim project sources\n";
525c441c
HSHR
544
545 $context->{OUTDIR} = pop @ARGV;
546
162e16b1
HSHR
547 if ($context->{gpg}{sign}) {
548 $context->{gpg}{key} //= do { chomp($_ = qx/git config user.signingkey/); $_ }
549 || $ENV{EXIM_KEY}
550 || do {
551 warn "$ME: No GPG key, using default\n";
552 undef;
553 }
554 }
555
525c441c
HSHR
556
557 warn "$ME: changed umask to 022\n" if umask(022) != 022;
558
559 $context->check_version(shift);
560 $context->override_tar_cmd;
561 $context->prepare_working_directory;
562 $context->export_git_tree;
563 $context->unpack_tree;
564 $context->make_version_script;
565 $context->build_documentation if $context->{docs};
51420ec3 566 $context->build_html_documentation if $context->{docs} && $context->{web};
525c441c
HSHR
567
568 $context->build_src_package_directory;
569 $context->build_doc_packages_directory if $context->{docs};
570
571 $context->create_tar_files;
162e16b1 572 $context->sign if $context->{gpg}{sign};
525c441c
HSHR
573 $context->move_to_outdir;
574 $context->do_cleanup if $context->{cleanup};
575
576 ### $context
8a483da6
NM
577}
578
5791;
580
581__END__
582
583=head1 NAME
584
6bfa380e 585mk_exim_release - Build an exim release
8a483da6
NM
586
587=head1 SYNOPSIS
588
525c441c 589 mk_exim_release [options] version PKG-DIRECTORY
91bde4a0
HSHR
590
591=head1 DESCRIPTION
592
593B<mk_exim_release> builds an exim release.
594
595Starting in a populated git repo that has already been tagged for
596release it builds docs, packages etc. Parameter is the version number
525c441c
HSHR
597to build as - ie 4.72 4.72-RC1, 4.86.1, etc, without any prefix.
598
599This scripts expects to find a tag "exim-<version>".
91bde4a0
HSHR
600
601After creating the release files, they should be signed. There is another
602helper for creating the signatures:
603F<release-process/scripts/sign_exim_packages>.
604
605Call B<mk_exim_release> about like this:
606
525c441c 607 release-process/scripts/mk_exim_release 4.99 OUT-DIR
8a483da6 608
8a483da6
NM
609
610=head1 OPTIONS
611
612=over 4
613
525c441c
HSHR
614=item B<--[no]cleanup>
615
616Do (or do not) cleanup the tmp directory at exit (default: do cleanup)
617
91bde4a0 618=item B<--[no]debug>
8a483da6 619
91bde4a0 620Forces debug mode. (default: no debug info)
8a483da6 621
91bde4a0 622=item B<--[no]delete>
9d0311ff 623
525c441c 624Delete a pre-existing tmp- and package-directory at start. (default: don't delete)
9d0311ff 625
525c441c 626=item B<--tmpdir> I<dir>
a7637438 627
525c441c 628Change the name of the tmp directory (default: temporary directory)
a7637438 629
91bde4a0 630=item B<--[no]help>
9d0311ff 631
91bde4a0 632Display short help and exit cleanly. (default: don't do that)
9d0311ff 633
91bde4a0 634=item B<--[no]lzip>
8a483da6 635
91bde4a0 636Control the creation of B<lzip> tarballs. (default: do not use lzip)
8a483da6 637
91bde4a0 638=item B<--make> I<cmd>
8a483da6 639
91bde4a0
HSHR
640Force the use of a specific C<make> command. This may be necessary if C<make> is not
641C<gmake> (default: C<make>)
8a483da6 642
91bde4a0 643=item B<--[no]man>
8a483da6 644
91bde4a0 645Display man page and exit cleanly. (default: don't do that)
8a483da6 646
91bde4a0 647=item B<--tar> I<cmd>
8a483da6 648
91bde4a0
HSHR
649Use to override the path to the C<tar> command. Need GNU tar in case
650I<lzip> is selected. (default: C<gtar>, if not found, use C<tar>)
8a483da6 651
162e16b1
HSHR
652=item B<--[no]sign>
653
654Sign the created archive files (and the sizes.txt). (default: sign)
655
656=item B<--key> I<GPG key>
657
658Use this GPG key for signing. If nothing is specified the first one of this list
659is used:
660
661=over 8
662
663=item - git config user.signingkey
664
665=item - environment C<EXIM_KEY>
666
667=item - default GPG key
668
669=back
670
91bde4a0 671=item B<--[no]web>
8a483da6 672
91bde4a0 673Control the creation of the website. For creation of the website, the F<../exim-website>
525c441c
HSHR
674(but see the B<website-base> option) directory must exist. (default: create the website)
675
676=item B<--website-base> I<dir>
677
678Base directory for the web site generation (default: F<../exim-website>)
8a483da6 679
91bde4a0
HSHR
680=item B<--verbose>
681
682Force verbose mode. (default: no verbosity)
683
684=back
8a483da6
NM
685
686=head1 AUTHOR
687
91bde4a0
HSHR
688Nigel Metheringham <Nigel.Metheringham@dev.intechnology.co.uk>,
689some changes by Heiko Schlittermann <hs@schlittermann.de>
8a483da6
NM
690
691=head1 COPYRIGHT
692
91bde4a0 693Copyright 2010-2016 Exim Maintainers. All rights reserved.
8a483da6
NM
694
695=cut
9d0311ff 696# vim: set sw=4 et :