| 1 | #! PERL_COMMAND -w |
| 2 | |
| 3 | # Mail Queue Summary |
| 4 | # Christoph Lameter, 21 May 1997 |
| 5 | # Modified by Philip Hazel, June 1997 |
| 6 | # Bug fix: June 1998 by Philip Hazel |
| 7 | # Message sizes not listed by -bp with K or M |
| 8 | # suffixes were getting divided by 10. |
| 9 | # Bug fix: October 1998 by Philip Hazel |
| 10 | # Sorting wasn't working right with Perl 5.005 |
| 11 | # Fix provided by John Horne |
| 12 | # Bug fix: November 1998 by Philip Hazel |
| 13 | # Failing to recognize domain literals in recipient addresses |
| 14 | # Fix provided by Malcolm Ray |
| 15 | # Bug fix: July 2002 by Philip Hazel |
| 16 | # Not handling time periods of more than 100 days |
| 17 | # Fix provided by Randy Banks |
| 18 | # Added summary line: September 2002 by Philip Hazel |
| 19 | # Code provided by Joachim Wieland |
| 20 | # June 2003 by Philip Hazel |
| 21 | # Initialize $size, $age, $id to avoid warnings when bad |
| 22 | # data is provided |
| 23 | # Bug fix: July 2003 by Philip Hazel |
| 24 | # Incorrectly skipping the first lines of messages whose |
| 25 | # message ID ends in 'D'! Before Exim 4.14 this didn't |
| 26 | # matter because they never did. Looks like an original |
| 27 | # typo. Fix provided by Chris Liddiard. |
| 28 | # November 2006 by Jori Hamalainen |
| 29 | # Added feature to separate frozen and bounced messages from queue |
| 30 | # Adedd feature to list queue per source - destination pair |
| 31 | # Changed regexps to compile once to very minor speed optimization |
| 32 | # Short circuit for empty lines |
| 33 | # |
| 34 | # Usage: mailq | exiqsumm [-a] [-b] [-c] [-f] [-s] |
| 35 | # Default sorting is by domain name |
| 36 | # -a sorts by age of oldest message |
| 37 | # -b enables bounce message separation |
| 38 | # -c sorts by count of message |
| 39 | # -f enables frozen message separation |
| 40 | # -s enables source destination separation |
| 41 | |
| 42 | # Slightly modified sub from eximstats |
| 43 | |
| 44 | sub print_volume_rounded { |
| 45 | my($x) = pop @_; |
| 46 | if ($x < 10000) |
| 47 | { |
| 48 | return sprintf("%6d", $x); |
| 49 | } |
| 50 | elsif ($x < 10000000) |
| 51 | { |
| 52 | return sprintf("%4dKB", ($x + 512)/1024); |
| 53 | } |
| 54 | else |
| 55 | { |
| 56 | return sprintf("%4dMB", ($x + 512*1024)/(1024*1024)); |
| 57 | } |
| 58 | } |
| 59 | |
| 60 | sub s_conv { |
| 61 | my($x) = @_; |
| 62 | my($v,$s) = $x =~ /([\d\.]+)([A-Z]|)/o; |
| 63 | if ($s eq "K") { return $v * 1024 }; |
| 64 | if ($s eq "M") { return $v * 1024 * 1024 }; |
| 65 | return $v; |
| 66 | } |
| 67 | |
| 68 | sub older { |
| 69 | my($x1,$x2) = @_; |
| 70 | my($v1,$s1) = $x1 =~ /(\d+)(\w)/o; |
| 71 | my($v2,$s2) = $x2 =~ /(\d+)(\w)/o; |
| 72 | return $v1 <=> $v2 if ($s1 eq $s2); |
| 73 | return (($s2 eq "m") || |
| 74 | ($s2 eq "h" && $s1 eq "d") || |
| 75 | ($s2 eq "d" && $s1 eq "w"))? 1 : -1; |
| 76 | } |
| 77 | |
| 78 | # |
| 79 | # Main Program |
| 80 | # |
| 81 | |
| 82 | $sort_by_count = 0; |
| 83 | $sort_by_age = 0; |
| 84 | |
| 85 | $size = "0"; |
| 86 | $age = "0d"; |
| 87 | $id = ""; |
| 88 | |
| 89 | |
| 90 | while (@ARGV > 0 && substr($ARGV[0], 0, 1) eq "-") |
| 91 | { |
| 92 | if ($ARGV[0] eq "-a") { $sort_by_age = 1; } |
| 93 | if ($ARGV[0] eq "-c") { $sort_by_count = 1; } |
| 94 | if ($ARGV[0] eq "-f") { $enable_frozen = 1; } |
| 95 | if ($ARGV[0] eq "-b") { $enable_bounces = 1; } |
| 96 | if ($ARGV[0] eq "-s") { $enable_source = 1; } |
| 97 | shift @ARGV; |
| 98 | } |
| 99 | |
| 100 | while (<>) |
| 101 | { |
| 102 | # Skip empty and already delivered lines |
| 103 | |
| 104 | if (/^$/o || /^\s*D\s\S+/o) { next; } |
| 105 | |
| 106 | # If it's the first line of a message, pick out the data. Note: it may |
| 107 | # have text after the final > (e.g. frozen) so don't insist that it ends >. |
| 108 | |
| 109 | if (/^([\d\s]{2,3}\w)\s+(\S+)\s(\S+)\s\<(\S*)\>/o) |
| 110 | { |
| 111 | ($age,$size,$id,$src)=($1,$2,$3,$4); |
| 112 | $src =~ s/([^\@]*)\@(.*?)$/$2/o; |
| 113 | if (/\*\*\*\sfrozen\s\*\*\*/o) { $frozen=1; } else { $frozen=0; } |
| 114 | if ($src eq "") { $bounce=1; $src="<>"; } else { $bounce=0; } |
| 115 | } |
| 116 | |
| 117 | # Else check for a recipient line: to handle source-routed addresses, just |
| 118 | # pick off the first domain. |
| 119 | |
| 120 | elsif (/^\s+[^@]*\@([\w\.\-]+|\[(\d+\.){3}\d+\])/o) |
| 121 | { |
| 122 | if ($enable_source) { |
| 123 | $domain = "\L$src > $1"; |
| 124 | } else { |
| 125 | $domain = "\L$1"; |
| 126 | } |
| 127 | $domain .= " (b)" if ($bounce && $enable_bounces); |
| 128 | $domain .= " (f)" if ($frozen && $enable_frozen); |
| 129 | $queue{$domain}++; |
| 130 | $q_oldest{$domain} = $age |
| 131 | if (!defined $q_oldest{$domain} || &older($age,$q_oldest{$domain}) > 0); |
| 132 | $q_recent{$domain} = $age |
| 133 | if (!defined $q_recent{$domain} || &older($q_recent{$domain},$age) > 0); |
| 134 | $q_size{$domain} = 0 if (!defined $q_size{$domain}); |
| 135 | $q_size{$domain} += &s_conv($size); |
| 136 | } |
| 137 | } |
| 138 | |
| 139 | print "\nCount Volume Oldest Newest Domain"; |
| 140 | print "\n----- ------ ------ ------ ------\n\n"; |
| 141 | |
| 142 | my ($count, $volume, $max_age, $min_age) = (0, 0, "0m", undef); |
| 143 | |
| 144 | foreach $id (sort |
| 145 | { |
| 146 | $sort_by_age? &older($q_oldest{$b}, $q_oldest{$a}) : |
| 147 | $sort_by_count? ($queue{$b} <=> $queue{$a}) : |
| 148 | $a cmp $b |
| 149 | } |
| 150 | keys %queue) |
| 151 | { |
| 152 | printf("%5d %.6s %6s %6s %.80s\n", |
| 153 | $queue{$id}, &print_volume_rounded($q_size{$id}), $q_oldest{$id}, |
| 154 | $q_recent{$id}, $id); |
| 155 | $max_age = $q_oldest{$id} if &older($q_oldest{$id}, $max_age) > 0; |
| 156 | $min_age = $q_recent{$id} |
| 157 | if (!defined $min_age || &older($min_age, $q_recent{$id}) > 0); |
| 158 | $volume += $q_size{$id}; |
| 159 | $count += $queue{$id}; |
| 160 | } |
| 161 | $min_age ||= "0000d"; |
| 162 | printf("---------------------------------------------------------------\n"); |
| 163 | printf("%5d %.6s %6s %6s %.80s\n", |
| 164 | $count, &print_volume_rounded($volume), $max_age, $min_age, "TOTAL"); |
| 165 | print "\n"; |
| 166 | |
| 167 | # End |